android-ait-before-p.gradle

buildscript {
    ext.kotlin_version = '1.4.20'
    ext.kotlin_gradle_version = '1.4.20'
    ext.android_gradle_version = '3.1.2'
    ext.coroutines_version = '0.27.0-eap13'
    ext.junit_jupiter_version = '5.6.2'
    ext.junit_vintage_version = '5.6.2'
    ext.mockk_version = '1.8.8-SNAPSHOT'

    repositories {
        mavenCentral()
        google()
        jcenter()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_gradle_version"
        classpath "com.android.tools.build:gradle:$android_gradle_version"
        classpath "org.jetbrains.kotlin:kotlin-allopen:$kotlin_version"
    }
}

repositories {
    mavenLocal()
    mavenCentral()
    google()
    jcenter()
    maven { url 'https://jitpack.io' }
}

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'

android {
    compileSdkVersion 'android-28'
    buildToolsVersion '27.0.3'

    lintOptions {
        disable 'InvalidPackage'
        warning 'NewApi'
        abortOnError false
    }

    packagingOptions {
        exclude 'META-INF/main.kotlin_module'
        exclude 'META-INF/LICENSE.md'
        exclude 'META-INF/LICENSE-notice.md'
    }

    defaultConfig {
        minSdkVersion 14
        targetSdkVersion 28
        versionName "1"
        testInstrumentationRunner 'com.github.tmurakami.dexopener.DexOpenerAndroidJUnitRunner'
    }

    sourceSets {
        test.kotlin.srcDirs += '../common/src/test/kotlin'
        androidTest.kotlin.srcDirs += '../common/src/test/kotlin'
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
}


dependencies {
    testImplementation "io.mockk:mockk:${mockk_version}"

    testImplementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    testImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$coroutines_version"
    testImplementation("org.jetbrains.kotlin:kotlin-test-junit:$kotlin_version") {
        exclude group: "junit", module: "junit"
    }

    testImplementation "org.junit.jupiter:junit-jupiter-api:$junit_jupiter_version"
    testImplementation "org.junit.jupiter:junit-jupiter-engine:$junit_jupiter_version"
    testImplementation "org.junit.vintage:junit-vintage-engine:$junit_vintage_version"

    androidTestImplementation "io.mockk:mockk-android:${mockk_version}"

    androidTestImplementation('com.android.support.test.espresso:espresso-core:3.0.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })

    androidTestImplementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    androidTestImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$coroutines_version"
    androidTestImplementation("org.jetbrains.kotlin:kotlin-test-junit:$kotlin_version")

    androidTestImplementation 'com.github.tmurakami:dexopener:0.12.1'
}