-
Notifications
You must be signed in to change notification settings - Fork 164
/
Continuous.mo
4542 lines (4196 loc) · 180 KB
/
Continuous.mo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
within Modelica.Blocks;
package Continuous "Library of continuous control blocks with internal states"
import Modelica.Blocks.Interfaces;
extends Modelica.Icons.Package;
block Integrator "Output the integral of the input signal with optional reset"
import Modelica.Blocks.Types.Init;
parameter Real k(unit="1")=1 "Integrator gain";
parameter Boolean use_reset = false "= true, if reset port enabled"
annotation(Evaluate=true, HideResult=true, choices(checkBox=true));
parameter Boolean use_set = false "= true, if set port enabled and used as reinitialization value when reset"
annotation(Dialog(enable=use_reset), Evaluate=true, HideResult=true, choices(checkBox=true));
/* InitialState is the default, because it was the default in Modelica 2.2
and therefore this setting is backward compatible
*/
parameter Init initType=Init.InitialState
"Type of initialization (1: no init, 2: steady state, 3,4: initial output)" annotation(Evaluate=true,
Dialog(group="Initialization"));
parameter Real y_start=0 "Initial or guess value of output (= state)"
annotation (Dialog(group="Initialization"));
extends Interfaces.SISO(y(start=y_start));
Modelica.Blocks.Interfaces.BooleanInput reset if use_reset "Optional connector of reset signal" annotation(Placement(
transformation(
extent={{-20,-20},{20,20}},
rotation=90,
origin={60,-120})));
Modelica.Blocks.Interfaces.RealInput set if use_reset and use_set "Optional connector of set signal" annotation(Placement(
transformation(
extent={{-20,-20},{20,20}},
rotation=270,
origin={60,120})));
protected
Modelica.Blocks.Interfaces.BooleanOutput local_reset annotation(HideResult=true);
Modelica.Blocks.Interfaces.RealOutput local_set annotation(HideResult=true);
initial equation
if initType == Init.SteadyState then
der(y) = 0;
elseif initType == Init.InitialState or
initType == Init.InitialOutput then
y = y_start;
end if;
equation
if use_reset then
connect(reset, local_reset);
if use_set then
connect(set, local_set);
else
local_set = y_start;
end if;
when local_reset then
reinit(y, local_set);
end when;
else
local_reset = false;
local_set = 0;
end if;
der(y) = k*u;
annotation (
Documentation(info="<html>
<p>
This blocks computes output <strong>y</strong> as
<em>integral</em> of the input <strong>u</strong> multiplied with
the gain <em>k</em>:
</p>
<blockquote><pre>
k
y = - u
s
</pre></blockquote>
<p>
It might be difficult to initialize the integrator in steady state.
This is discussed in the description of package
<a href=\"modelica://Modelica.Blocks.Continuous#info\">Continuous</a>.
</p>
<p>
If the <em>reset</em> port is enabled, then the output <strong>y</strong> is reset to <em>set</em>
or to <em>y_start</em> (if the <em>set</em> port is not enabled), whenever the <em>reset</em>
port has a rising edge.
</p>
</html>"), Icon(coordinateSystem(
preserveAspectRatio=true,
extent={{-100.0,-100.0},{100.0,100.0}}),
graphics={
Line(
points={{-80.0,78.0},{-80.0,-90.0}},
color={192,192,192}),
Polygon(
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{-80.0,90.0},{-88.0,68.0},{-72.0,68.0},{-80.0,90.0}}),
Line(
points={{-90.0,-80.0},{82.0,-80.0}},
color={192,192,192}),
Polygon(
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{90.0,-80.0},{68.0,-72.0},{68.0,-88.0},{90.0,-80.0}}),
Text(
textColor={192,192,192},
extent={{0.0,-70.0},{60.0,-10.0}},
textString="I"),
Text(
extent={{-150.0,-150.0},{150.0,-110.0}},
textString="k=%k"),
Line(
points=DynamicSelect({{-80.0,-80.0},{80.0,80.0}}, if use_reset then {{-80.0,-80.0},{60.0,60.0},{60.0,-80.0},{80.0,-60.0}} else {{-80.0,-80.0},{80.0,80.0}}),
color={0,0,127}),
Line(
visible=use_reset,
points={{60,-100},{60,-80}},
color={255,0,255},
pattern=LinePattern.Dot),
Text(
visible=use_reset,
extent={{-28,-62},{94,-86}},
textString="reset")}));
end Integrator;
block LimIntegrator "Integrator with limited value of the output and optional reset"
import Modelica.Blocks.Types.Init;
parameter Real k(unit="1")=1 "Integrator gain";
parameter Real outMax(start=1) "Upper limit of output";
parameter Real outMin=-outMax "Lower limit of output";
parameter Boolean use_reset = false "= true, if reset port enabled"
annotation(Evaluate=true, HideResult=true, choices(checkBox=true));
parameter Boolean use_set = false "= true, if set port enabled and used as reinitialization value when reset"
annotation(Dialog(enable=use_reset), Evaluate=true, HideResult=true, choices(checkBox=true));
parameter Init initType=Init.InitialState
"Type of initialization (1: no init, 2: steady state, 3/4: initial output)"
annotation(Evaluate=true, Dialog(group="Initialization"));
parameter Boolean limitsAtInit = true
"= false, if limits are ignored during initialization (i.e., der(y)=k*u)"
annotation(Evaluate=true, Dialog(group="Initialization"));
parameter Real y_start=0
"Initial or guess value of output (must be in the limits outMin .. outMax)"
annotation (Dialog(group="Initialization"));
parameter Boolean strict=false "= true, if strict limits with noEvent(..)"
annotation (Evaluate=true, choices(checkBox=true), Dialog(tab="Advanced"));
extends Interfaces.SISO(y(start=y_start));
Modelica.Blocks.Interfaces.BooleanInput reset if use_reset "Optional connector of reset signal" annotation(Placement(
transformation(
extent={{-20,-20},{20,20}},
rotation=90,
origin={60,-120})));
Modelica.Blocks.Interfaces.RealInput set if use_reset and use_set "Optional connector of set signal" annotation(Placement(
transformation(
extent={{-20,-20},{20,20}},
rotation=270,
origin={60,120})));
protected
Modelica.Blocks.Interfaces.BooleanOutput local_reset annotation(HideResult=true);
Modelica.Blocks.Interfaces.RealOutput local_set annotation(HideResult=true);
initial equation
if initType == Init.SteadyState then
der(y) = 0;
elseif initType == Init.InitialState or
initType == Init.InitialOutput then
y = y_start;
end if;
equation
if use_reset then
connect(reset, local_reset);
if use_set then
connect(set, local_set);
else
local_set = y_start;
end if;
when local_reset then
reinit(y, if local_set < outMin then outMin elseif local_set > outMax then outMax else local_set);
end when;
else
local_reset = false;
local_set = 0;
end if;
if initial() and not limitsAtInit then
der(y) = k*u;
assert(y >= outMin - 0.001*abs(outMax-outMin) and y <= outMax + 0.001*abs(outMax-outMin),
"LimIntegrator: During initialization the limits have been ignored.\n"
+ "However, the result is that the output y is not within the required limits:\n"
+ " y = " + String(y) + ", outMin = " + String(outMin) + ", outMax = " + String(outMax));
elseif strict then
der(y) = noEvent(if y < outMin and k*u < 0 or y > outMax and k*u > 0 then 0 else k*u);
else
der(y) = if y < outMin and k*u < 0 or y > outMax and k*u > 0 then 0 else k*u;
end if;
annotation (
Documentation(info="<html>
<p>
This blocks computes <strong>y</strong> as <em>integral</em>
of the input <strong>u</strong> multiplied with the gain <em>k</em>. If the
integral reaches a given upper or lower <em>limit</em> and the
input will drive the integral outside of this bound, the
integration is halted and only restarted if the input drives
the integral away from the bounds.
</p>
<p>
It might be difficult to initialize the integrator in steady state.
This is discussed in the description of package
<a href=\"modelica://Modelica.Blocks.Continuous#info\">Continuous</a>.
</p>
<p>
If parameter <strong>limitsAtInit</strong> = <strong>false</strong>, the limits of the
integrator are removed from the initialization problem which
leads to a much simpler equation system. After initialization has been
performed, it is checked via an assert whether the output is in the
defined limits. For backward compatibility reasons
<strong>limitsAtInit</strong> = <strong>true</strong>. In most cases it is best
to use <strong>limitsAtInit</strong> = <strong>false</strong>.
</p>
<p>
If the <em>reset</em> port is enabled, then the output <strong>y</strong> is reset to <em>set</em>
or to <em>y_start</em> (if the <em>set</em> port is not enabled), whenever the <em>reset</em>
port has a rising edge.
</p>
</html>"), Icon(coordinateSystem(
preserveAspectRatio=true,
extent={{-100,-100},{100,100}}), graphics={
Line(points={{-80,78},{-80,-90}}, color={192,192,192}),
Polygon(
points={{-80,90},{-88,68},{-72,68},{-80,90}},
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid),
Line(points={{-90,-80},{82,-80}}, color={192,192,192}),
Polygon(
points={{90,-80},{68,-72},{68,-88},{90,-80}},
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid),
Line(
points=DynamicSelect({{-80,-80},{20,20},{80,20}}, if use_reset then {{-80,-80},{20,20},{60,20},{60,-80},{80,-60}} else {{-80,-80},{20,20},{80,20}}),
color={0,0,127}),
Text(
extent={{0,-10},{60,-70}},
textColor={192,192,192},
textString="I"),
Text(
extent={{-150,-150},{150,-110}},
textString="k=%k"),
Line(
visible=strict,
points=DynamicSelect({{20,20},{80,20}}, if use_reset then {{20,20},{60,20}} else {{20,20},{80,20}}),
color={255,0,0}),
Line(
visible=use_reset,
points={{60,-100},{60,-80}},
color={255,0,255},
pattern=LinePattern.Dot),
Text(
visible=use_reset,
extent={{-28,-62},{94,-86}},
textString="reset")}));
end LimIntegrator;
block Derivative "Approximated derivative block"
import Modelica.Blocks.Types.Init;
parameter Real k(unit="1")=1 "Gains";
parameter SI.Time T(min=Modelica.Constants.small) = 0.01
"Time constants (T>0 required; T=0 is ideal derivative block)";
parameter Init initType=Init.NoInit
"Type of initialization (1: no init, 2: steady state, 3: initial state, 4: initial output)"
annotation(Evaluate=true,
Dialog(group="Initialization"));
parameter Real x_start=0 "Initial or guess value of state"
annotation (Dialog(group="Initialization"));
parameter Real y_start=0 "Initial value of output (= state)"
annotation(Dialog(enable=initType == Init.InitialOutput, group=
"Initialization"));
extends Interfaces.SISO;
output Real x(start=x_start) "State of block";
protected
parameter Boolean zeroGain = abs(k) < Modelica.Constants.eps;
initial equation
if initType == Init.SteadyState then
der(x) = 0;
elseif initType == Init.InitialState then
x = x_start;
elseif initType == Init.InitialOutput then
if zeroGain then
x = u;
else
y = y_start;
end if;
end if;
equation
der(x) = if zeroGain then 0 else (u - x)/T;
y = if zeroGain then 0 else (k/T)*(u - x);
annotation (
Documentation(info="<html>
<p>
This blocks defines the transfer function between the
input u and the output y
as <em>approximated derivative</em>:
</p>
<blockquote><pre>
k * s
y = ------------ * u
T * s + 1
</pre></blockquote>
<p>
If you would like to be able to change easily between different
transfer functions (FirstOrder, SecondOrder, ... ) by changing
parameters, use the general block <strong>TransferFunction</strong> instead
and model a derivative block with parameters<br>
b = {k,0}, a = {T, 1}.
</p>
<p>
If k=0, the block reduces to y=0.
</p>
</html>"), Icon(
coordinateSystem(preserveAspectRatio=true,
extent={{-100.0,-100.0},{100.0,100.0}}),
graphics={
Line(points={{-80.0,78.0},{-80.0,-90.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{-80.0,90.0},{-88.0,68.0},{-72.0,68.0},{-80.0,90.0}}),
Line(points={{-90.0,-80.0},{82.0,-80.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{90.0,-80.0},{68.0,-72.0},{68.0,-88.0},{90.0,-80.0}}),
Line(origin = {-24.667,-27.333},
points = {{-55.333,87.333},{-19.333,-40.667},{86.667,-52.667}},
color = {0,0,127},
smooth = Smooth.Bezier),
Text(textColor={192,192,192},
extent={{-30.0,14.0},{86.0,60.0}},
textString="DT1"),
Text(extent={{-150.0,-150.0},{150.0,-110.0}},
textString="k=%k")}));
end Derivative;
block FirstOrder "First order transfer function block (= 1 pole)"
import Modelica.Blocks.Types.Init;
parameter Real k(unit="1")=1 "Gain";
parameter SI.Time T(start=1) "Time Constant";
parameter Init initType=Init.NoInit
"Type of initialization (1: no init, 2: steady state, 3/4: initial output)" annotation(Evaluate=true,
Dialog(group="Initialization"));
parameter Real y_start=0 "Initial or guess value of output (= state)"
annotation (Dialog(group="Initialization"));
extends Interfaces.SISO(y(start=y_start));
initial equation
if initType == Init.SteadyState then
der(y) = 0;
elseif initType == Init.InitialState or initType == Init.InitialOutput then
y = y_start;
end if;
equation
der(y) = (k*u - y)/T;
annotation (
Documentation(info="<html>
<p>
This blocks defines the transfer function between the input u
and the output y as <em>first order</em> system:
</p>
<blockquote><pre>
k
y = ------------ * u
T * s + 1
</pre></blockquote>
<p>
If you would like to be able to change easily between different
transfer functions (FirstOrder, SecondOrder, ... ) by changing
parameters, use the general block <strong>TransferFunction</strong> instead
and model a first order SISO system with parameters<br>
b = {k}, a = {T, 1}.
</p>
<blockquote><pre>
Example:
parameter: k = 0.3, T = 0.4
results in:
0.3
y = ----------- * u
0.4 s + 1.0
</pre></blockquote>
</html>"), Icon(
coordinateSystem(preserveAspectRatio=true,
extent={{-100.0,-100.0},{100.0,100.0}}),
graphics={
Line(points={{-80.0,78.0},{-80.0,-90.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{-80.0,90.0},{-88.0,68.0},{-72.0,68.0},{-80.0,90.0}}),
Line(points={{-90.0,-80.0},{82.0,-80.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{90.0,-80.0},{68.0,-72.0},{68.0,-88.0},{90.0,-80.0}}),
Line(origin = {-26.667,6.667},
points = {{106.667,43.333},{-13.333,29.333},{-53.333,-86.667}},
color = {0,0,127},
smooth = Smooth.Bezier),
Text(textColor={192,192,192},
extent={{0.0,-60.0},{60.0,0.0}},
textString="PT1"),
Text(extent={{-150.0,-150.0},{150.0,-110.0}},
textString="T=%T")}));
end FirstOrder;
block SecondOrder "Second order transfer function block (= 2 poles)"
import Modelica.Blocks.Types.Init;
parameter Real k(unit="1")=1 "Gain";
parameter Real w(start=1) "Angular frequency";
parameter Real D(start=1) "Damping";
parameter Init initType=Init.NoInit
"Type of initialization (1: no init, 2: steady state, 3/4: initial output)" annotation(Evaluate=true,
Dialog(group="Initialization"));
parameter Real y_start=0 "Initial or guess value of output (= state)"
annotation (Dialog(group="Initialization"));
parameter Real yd_start=0
"Initial or guess value of derivative of output (= state)"
annotation (Dialog(group="Initialization"));
extends Interfaces.SISO(y(start=y_start));
output Real yd(start=yd_start) "Derivative of y";
initial equation
if initType == Init.SteadyState then
der(y) = 0;
der(yd) = 0;
elseif initType == Init.InitialState or initType == Init.InitialOutput then
y = y_start;
yd = yd_start;
end if;
equation
der(y) = yd;
der(yd) = w*(w*(k*u - y) - 2*D*yd);
annotation (
Documentation(info="<html>
<p>
This blocks defines the transfer function between the input u and
the output y as <em>second order</em> system:
</p>
<blockquote><pre>
k
y = --------------------------------- * u
( s / w )^2 + 2*D*( s / w ) + 1
</pre></blockquote>
<p>
If you would like to be able to change easily between different
transfer functions (FirstOrder, SecondOrder, ... ) by changing
parameters, use the general model class <strong>TransferFunction</strong>
instead and model a second order SISO system with parameters<br>
b = {k}, a = {1/w^2, 2*D/w, 1}.
</p>
<blockquote><pre>
Example:
parameter: k = 0.3, w = 0.5, D = 0.4
results in:
0.3
y = ------------------- * u
4.0 s^2 + 1.6 s + 1
</pre></blockquote>
</html>"), Icon(
coordinateSystem(preserveAspectRatio=true,
extent={{-100.0,-100.0},{100.0,100.0}}),
graphics={
Line(points={{-80.0,78.0},{-80.0,-90.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{-80.0,90.0},{-88.0,68.0},{-72.0,68.0},{-80.0,90.0}}),
Line(points={{-90.0,-80.0},{82.0,-80.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{90.0,-80.0},{68.0,-72.0},{68.0,-88.0},{90.0,-80.0}}),
Line(origin = {-1.939,-1.816},
points = {{81.939,36.056},{65.362,36.056},{14.39,-26.199},{-29.966,113.485},{-65.374,-61.217},{-78.061,-78.184}},
color = {0,0,127},
smooth = Smooth.Bezier),
Text(textColor={192,192,192},
extent={{0.0,-70.0},{60.0,-10.0}},
textString="PT2"),
Text(extent={{-150.0,-150.0},{150.0,-110.0}},
textString="w=%w")}));
end SecondOrder;
block PI "Proportional-Integral controller"
import Modelica.Blocks.Types.Init;
parameter Real k(unit="1")=1 "Gain";
parameter SI.Time T(start=1,min=Modelica.Constants.small)
"Time Constant (T>0 required)";
parameter Init initType=Init.NoInit
"Type of initialization (1: no init, 2: steady state, 3: initial state, 4: initial output)"
annotation(Evaluate=true,
Dialog(group="Initialization"));
parameter Real x_start=0 "Initial or guess value of state"
annotation (Dialog(group="Initialization"));
parameter Real y_start=0 "Initial value of output"
annotation(Dialog(enable=initType == Init.SteadyState or initType == Init.InitialOutput, group=
"Initialization"));
extends Interfaces.SISO;
output Real x(start=x_start) "State of block";
initial equation
if initType == Init.SteadyState then
der(x) = 0;
elseif initType == Init.InitialState then
x = x_start;
elseif initType == Init.InitialOutput then
y = y_start;
end if;
equation
der(x) = u/T;
y = k*(x + u);
annotation (defaultComponentName="PI",
Documentation(info="<html>
<p>
This blocks defines the transfer function between the input u and
the output y as <em>PI</em> system:
</p>
<blockquote><pre>
1
y = k * (1 + ---) * u
T*s
T*s + 1
= k * ------- * u
T*s
</pre></blockquote>
<p>
If you would like to be able to change easily between different
transfer functions (FirstOrder, SecondOrder, ... ) by changing
parameters, use the general model class <strong>TransferFunction</strong>
instead and model a PI SISO system with parameters<br>
b = {k*T, k}, a = {T, 0}.
</p>
<blockquote><pre>
Example:
parameter: k = 0.3, T = 0.4
results in:
0.4 s + 1
y = 0.3 ----------- * u
0.4 s
</pre></blockquote>
<p>
It might be difficult to initialize the PI component in steady state
due to the integrator part.
This is discussed in the description of package
<a href=\"modelica://Modelica.Blocks.Continuous#info\">Continuous</a>.
</p>
</html>"), Icon(coordinateSystem(
preserveAspectRatio=true,
extent={{-100,-100},{100,100}}), graphics={
Line(points={{-80,78},{-80,-90}}, color={192,192,192}),
Polygon(
points={{-80,90},{-88,68},{-72,68},{-80,90}},
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid),
Line(points={{-90,-80},{82,-80}}, color={192,192,192}),
Polygon(
points={{90,-80},{68,-72},{68,-88},{90,-80}},
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid),
Line(points = {{-80.0,-80.0},{-80.0,-20.0},{60.0,80.0}}, color = {0,0,127}),
Text(
extent={{0,6},{60,-56}},
textColor={192,192,192},
textString="PI"),
Text(
extent={{-150,-150},{150,-110}},
textString="T=%T")}));
end PI;
block PID "PID-controller in additive description form"
import Modelica.Blocks.Types.Init;
extends Interfaces.SISO;
parameter Real k(unit="1")=1 "Gain";
parameter SI.Time Ti(min=Modelica.Constants.small, start=0.5)
"Time Constant of Integrator";
parameter SI.Time Td(min=0, start=0.1)
"Time Constant of Derivative block";
parameter Real Nd(min=Modelica.Constants.small) = 10
"The higher Nd, the more ideal the derivative block";
parameter Init initType= Init.InitialState
"Type of initialization (1: no init, 2: steady state, 3: initial state, 4: initial output)"
annotation(Evaluate=true,
Dialog(group="Initialization"));
parameter Real xi_start=0
"Initial or guess value for integrator output (= integrator state)"
annotation (Dialog(group="Initialization"));
parameter Real xd_start=0
"Initial or guess value for state of derivative block"
annotation (Dialog(group="Initialization"));
parameter Real y_start=0 "Initial value of output"
annotation(Dialog(enable=initType == Init.InitialOutput, group=
"Initialization"));
constant SI.Time unitTime=1 annotation(HideResult=true);
Blocks.Math.Gain P(k=1) "Proportional part of PID controller"
annotation (Placement(transformation(extent={{-60,60},{-20,100}})));
Blocks.Continuous.Integrator I(k=unitTime/Ti, y_start=xi_start,
initType=if initType==Init.SteadyState then
Init.SteadyState else
if initType==Init.InitialState then
Init.InitialState else Init.NoInit)
"Integral part of PID controller"
annotation (Placement(transformation(extent={{-60,-20},{-20,20}})));
Blocks.Continuous.Derivative D(k=Td/unitTime, T=max([Td/Nd, 100*Modelica.
Constants.eps]), x_start=xd_start,
initType=if initType==Init.SteadyState or
initType==Init.InitialOutput then Init.SteadyState else
if initType==Init.InitialState then Init.InitialState else
Init.NoInit) "Derivative part of PID controller"
annotation (Placement(transformation(extent={{-60,-100},{-20,-60}})));
Blocks.Math.Gain Gain(k=k) "Gain of PID controller"
annotation (Placement(transformation(extent={{60,-10},{80,10}})));
Blocks.Math.Add3 Add annotation (Placement(transformation(extent={{20,-10},
{40,10}})));
initial equation
if initType==Init.InitialOutput then
y = y_start;
end if;
equation
connect(u, P.u) annotation (Line(points={{-120,0},{-80,0},{-80,80},{-64,80}}, color={0,0,127}));
connect(u, I.u)
annotation (Line(points={{-120,0},{-64,0}}, color={0,0,127}));
connect(u, D.u) annotation (Line(points={{-120,0},{-80,0},{-80,-80},{-64,-80}},
color={0,0,127}));
connect(P.y, Add.u1) annotation (Line(points={{-18,80},{0,80},{0,8},{18,8}}, color={0,0,127}));
connect(I.y, Add.u2)
annotation (Line(points={{-18,0},{18,0}}, color={0,0,127}));
connect(D.y, Add.u3) annotation (Line(points={{-18,-80},{0,-80},{0,-8},{18,-8}},
color={0,0,127}));
connect(Add.y, Gain.u)
annotation (Line(points={{41,0},{58,0}}, color={0,0,127}));
connect(Gain.y, y)
annotation (Line(points={{81,0},{110,0}}, color={0,0,127}));
annotation (defaultComponentName="PID",
Icon(
coordinateSystem(preserveAspectRatio=true,
extent={{-100.0,-100.0},{100.0,100.0}}),
graphics={
Line(points={{-80.0,78.0},{-80.0,-90.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{-80.0,90.0},{-88.0,68.0},{-72.0,68.0},{-80.0,90.0}}),
Line(points={{-90.0,-80.0},{82.0,-80.0}},
color={192,192,192}),
Polygon(lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid,
points={{90.0,-80.0},{68.0,-72.0},{68.0,-88.0},{90.0,-80.0}}),
Line(points = {{-80,-80},{-80,-20},{60,80}}, color = {0,0,127}),
Text(textColor={192,192,192},
extent={{-20.0,-60.0},{80.0,-20.0}},
textString="PID"),
Text(extent={{-150.0,-150.0},{150.0,-110.0}},
textString="Ti=%Ti")}),
Documentation(info="<html>
<p>
This is the text-book version of a PID-controller.
For a more practically useful PID-controller, use
block LimPID.
</p>
<p>
The PID block can be initialized in different
ways controlled by parameter <strong>initType</strong>. The possible
values of initType are defined in
<a href=\"modelica://Modelica.Blocks.Types.Init\">Modelica.Blocks.Types.Init</a>.
</p>
<p>
Based on the setting of initType, the integrator (I) and derivative (D)
blocks inside the PID controller are initialized according to the following table:
</p>
<table border=\"1\" cellspacing=\"0\" cellpadding=\"2\">
<tr><td><strong>initType</strong></td>
<td><strong>I.initType</strong></td>
<td><strong>D.initType</strong></td></tr>
<tr><td><strong>NoInit</strong></td>
<td>NoInit</td>
<td>NoInit</td></tr>
<tr><td><strong>SteadyState</strong></td>
<td>SteadyState</td>
<td>SteadyState</td></tr>
<tr><td><strong>InitialState</strong></td>
<td>InitialState</td>
<td>InitialState</td></tr>
<tr><td><strong>InitialOutput</strong><br>
and initial equation: y = y_start</td>
<td>NoInit</td>
<td>SteadyState</td></tr>
</table>
<p>
In many cases, the most useful initial condition is
<strong>SteadyState</strong> because initial transients are then no longer
present. If initType = Init.SteadyState, then in some
cases difficulties might occur. The reason is the
equation of the integrator:
</p>
<blockquote><pre>
<strong>der</strong>(y) = k*u;
</pre></blockquote>
<p>
The steady state equation \"der(x)=0\" leads to the condition that the input u to the
integrator is zero. If the input u is already (directly or indirectly) defined
by another initial condition, then the initialization problem is <strong>singular</strong>
(has none or infinitely many solutions). This situation occurs often
for mechanical systems, where, e.g., u = desiredSpeed - measuredSpeed and
since speed is both a state and a derivative, it is natural to
initialize it with zero. As sketched this is, however, not possible.
The solution is to not initialize u or the variable that is used
to compute u by an algebraic equation.
</p>
</html>"));
end PID;
block LimPID
"P, PI, PD, and PID controller with limited output, anti-windup compensation, setpoint weighting and optional feed-forward"
import Modelica.Blocks.Types.Init;
import Modelica.Blocks.Types.SimpleController;
extends Modelica.Blocks.Interfaces.SVcontrol;
output Real controlError = u_s - u_m
"Control error (set point - measurement)";
parameter .Modelica.Blocks.Types.SimpleController controllerType=
.Modelica.Blocks.Types.SimpleController.PID "Type of controller";
parameter Real k(min=0, unit="1") = 1 "Gain of controller";
parameter SI.Time Ti(min=Modelica.Constants.small)=0.5
"Time constant of Integrator block" annotation (Dialog(enable=
controllerType == .Modelica.Blocks.Types.SimpleController.PI or
controllerType == .Modelica.Blocks.Types.SimpleController.PID));
parameter SI.Time Td(min=0)=0.1
"Time constant of Derivative block" annotation (Dialog(enable=
controllerType == .Modelica.Blocks.Types.SimpleController.PD or
controllerType == .Modelica.Blocks.Types.SimpleController.PID));
parameter Real yMax(start=1) "Upper limit of output";
parameter Real yMin=-yMax "Lower limit of output";
parameter Real wp(min=0) = 1
"Set-point weight for Proportional block (0..1)";
parameter Real wd(min=0) = 0 "Set-point weight for Derivative block (0..1)"
annotation(Dialog(enable=controllerType==.Modelica.Blocks.Types.SimpleController.PD or
controllerType==.Modelica.Blocks.Types.SimpleController.PID));
parameter Real Ni(min=100*Modelica.Constants.eps) = 0.9
"Ni*Ti is time constant of anti-windup compensation"
annotation(Dialog(enable=controllerType==.Modelica.Blocks.Types.SimpleController.PI or
controllerType==.Modelica.Blocks.Types.SimpleController.PID));
parameter Real Nd(min=100*Modelica.Constants.eps) = 10
"The higher Nd, the more ideal the derivative block"
annotation(Dialog(enable=controllerType==.Modelica.Blocks.Types.SimpleController.PD or
controllerType==.Modelica.Blocks.Types.SimpleController.PID));
parameter Boolean withFeedForward=false "Use feed-forward input?"
annotation(Evaluate=true, choices(checkBox=true));
parameter Real kFF=1 "Gain of feed-forward input"
annotation(Dialog(enable=withFeedForward));
parameter Init initType = Init.NoInit
"Type of initialization (1: no init, 2: steady state, 3: initial state, 4: initial output)"
annotation(Evaluate=true, Dialog(group="Initialization"));
parameter Real xi_start=0
"Initial or guess value for integrator output (= integrator state)"
annotation (Dialog(group="Initialization",
enable=controllerType==.Modelica.Blocks.Types.SimpleController.PI or
controllerType==.Modelica.Blocks.Types.SimpleController.PID));
parameter Real xd_start=0
"Initial or guess value for state of derivative block"
annotation (Dialog(group="Initialization",
enable=controllerType==.Modelica.Blocks.Types.SimpleController.PD or
controllerType==.Modelica.Blocks.Types.SimpleController.PID));
parameter Real y_start=0 "Initial value of output"
annotation(Dialog(enable=initType == Init.InitialOutput, group=
"Initialization"));
parameter Modelica.Blocks.Types.LimiterHomotopy homotopyType = Modelica.Blocks.Types.LimiterHomotopy.Linear
"Simplified model for homotopy-based initialization"
annotation (Evaluate=true, Dialog(group="Initialization"));
parameter Boolean strict=false "= true, if strict limits with noEvent(..)"
annotation (Evaluate=true, choices(checkBox=true), Dialog(tab="Advanced"));
constant SI.Time unitTime=1 annotation (HideResult=true);
Modelica.Blocks.Interfaces.RealInput u_ff if withFeedForward
"Optional connector of feed-forward input signal"
annotation (Placement(
transformation(
origin={60,-120},
extent={{20,-20},{-20,20}},
rotation=270)));
Modelica.Blocks.Math.Add addP(k1=wp, k2=-1)
annotation (Placement(transformation(extent={{-80,40},{-60,60}})));
Modelica.Blocks.Math.Add addD(k1=wd, k2=-1) if with_D
annotation (Placement(transformation(extent={{-80,-10},{-60,10}})));
Modelica.Blocks.Math.Gain P(k=1)
annotation (Placement(transformation(extent={{-50,40},{-30,60}})));
Modelica.Blocks.Continuous.Integrator I(
k=unitTime/Ti,
y_start=xi_start,
initType=if initType == Init.SteadyState then Init.SteadyState else if
initType == Init.InitialState
then Init.InitialState else Init.NoInit) if with_I
annotation (Placement(transformation(extent={{-50,-60},{-30,-40}})));
Modelica.Blocks.Continuous.Derivative D(
k=Td/unitTime,
T=max([Td/Nd,1.e-14]),
x_start=xd_start,
initType=if initType == Init.SteadyState or initType == Init.InitialOutput
then Init.SteadyState else if initType == Init.InitialState then
Init.InitialState else Init.NoInit) if with_D
annotation (Placement(transformation(extent={{-50,-10},{-30,10}})));
Modelica.Blocks.Math.Gain gainPID(k=k)
annotation (Placement(transformation(extent={{20,-10},{40,10}})));
Modelica.Blocks.Math.Add3 addPID
annotation (Placement(transformation(extent={{-10,-10},{10,10}})));
Modelica.Blocks.Math.Add3 addI(k2=-1) if with_I
annotation (Placement(transformation(extent={{-80,-60},{-60,-40}})));
Modelica.Blocks.Math.Add addSat(k1=+1, k2=-1) if with_I annotation (Placement(
transformation(
origin={80,-50},
extent={{-10,-10},{10,10}},
rotation=270)));
Modelica.Blocks.Math.Gain gainTrack(k=1/(k*Ni)) if with_I
annotation (Placement(transformation(extent={{0,-80},{-20,-60}})));
Modelica.Blocks.Nonlinear.Limiter limiter(
uMax=yMax,
uMin=yMin,
strict=strict,
homotopyType=homotopyType)
annotation (Placement(transformation(extent={{70,-10},{90,10}})));
protected
parameter Boolean with_I = controllerType==SimpleController.PI or
controllerType==SimpleController.PID annotation(Evaluate=true, HideResult=true);
parameter Boolean with_D = controllerType==SimpleController.PD or
controllerType==SimpleController.PID annotation(Evaluate=true, HideResult=true);
public
Modelica.Blocks.Sources.Constant Dzero(k=0) if not with_D
annotation (Placement(transformation(extent={{-40,20},{-30,30}})));
Modelica.Blocks.Sources.Constant Izero(k=0) if not with_I
annotation (Placement(transformation(extent={{0,-55},{-10,-45}})));
Modelica.Blocks.Sources.Constant FFzero(k=0) if not withFeedForward
annotation (Placement(transformation(extent={{30,-35},{40,-25}})));
Modelica.Blocks.Math.Add addFF(k1=1, k2=kFF)
annotation (Placement(transformation(extent={{48,-6},{60,6}})));
initial equation
if initType==Init.InitialOutput then
gainPID.y = y_start;
end if;
equation
if initType == Init.InitialOutput and (y_start < yMin or y_start > yMax) then
Modelica.Utilities.Streams.error("LimPID: Start value y_start (=" + String(y_start) +
") is outside of the limits of yMin (=" + String(yMin) +") and yMax (=" + String(yMax) + ")");
end if;
connect(u_s, addP.u1) annotation (Line(points={{-120,0},{-96,0},{-96,56},{
-82,56}}, color={0,0,127}));
connect(u_s, addD.u1) annotation (Line(points={{-120,0},{-96,0},{-96,6},{
-82,6}}, color={0,0,127}));
connect(u_s, addI.u1) annotation (Line(points={{-120,0},{-96,0},{-96,-42},{
-82,-42}}, color={0,0,127}));
connect(addP.y, P.u) annotation (Line(points={{-59,50},{-52,50}}, color={0,
0,127}));
connect(addD.y, D.u)
annotation (Line(points={{-59,0},{-52,0}}, color={0,0,127}));
connect(addI.y, I.u) annotation (Line(points={{-59,-50},{-52,-50}}, color={
0,0,127}));
connect(P.y, addPID.u1) annotation (Line(points={{-29,50},{-20,50},{-20,8},{-12,
8}}, color={0,0,127}));
connect(D.y, addPID.u2)
annotation (Line(points={{-29,0},{-12,0}},color={0,0,127}));
connect(I.y, addPID.u3) annotation (Line(points={{-29,-50},{-20,-50},{-20,-8},
{-12,-8}}, color={0,0,127}));
connect(limiter.y, addSat.u1) annotation (Line(points={{91,0},{94,0},{94,
-20},{86,-20},{86,-38}}, color={0,0,127}));
connect(limiter.y, y)
annotation (Line(points={{91,0},{110,0}}, color={0,0,127}));
connect(addSat.y, gainTrack.u) annotation (Line(points={{80,-61},{80,-70},{2,-70}},
color={0,0,127}));
connect(gainTrack.y, addI.u3) annotation (Line(points={{-21,-70},{-88,-70},{-88,
-58},{-82,-58}}, color={0,0,127}));
connect(u_m, addP.u2) annotation (Line(points={{0,-120},{0,-92},{-92,-92},{-92,44},{-82,44}}, color={0,0,127}));
connect(u_m, addD.u2) annotation (Line(points={{0,-120},{0,-92},{-92,-92},{-92,-6},{-82,-6}}, color={0,0,127}));
connect(u_m, addI.u2) annotation (Line(points={{0,-120},{0,-92},{-92,-92},{-92,-50},{-82,-50}}, color={0,0,127}));
connect(Dzero.y, addPID.u2) annotation (Line(points={{-29.5,25},{-24,25},{-24,
0},{-12,0}}, color={0,0,127}));
connect(Izero.y, addPID.u3) annotation (Line(points={{-10.5,-50},{-20,-50},{-20,
-8},{-12,-8}}, color={0,0,127}));
connect(addPID.y, gainPID.u)
annotation (Line(points={{11,0},{18,0}}, color={0,0,127}));
connect(addFF.y, limiter.u)
annotation (Line(points={{60.6,0},{68,0}}, color={0,0,127}));
connect(gainPID.y, addFF.u1) annotation (Line(points={{41,0},{44,0},{44,3.6},
{46.8,3.6}},color={0,0,127}));
connect(FFzero.y, addFF.u2) annotation (Line(points={{40.5,-30},{44,-30},{44,
-3.6},{46.8,-3.6}},
color={0,0,127}));
connect(addFF.u2, u_ff) annotation (Line(points={{46.8,-3.6},{44,-3.6},{44,
-92},{60,-92},{60,-120}},
color={0,0,127}));
connect(addFF.y, addSat.u2) annotation (Line(points={{60.6,0},{64,0},{64,-20},
{74,-20},{74,-38}}, color={0,0,127}));
annotation (defaultComponentName="PID",
Icon(coordinateSystem(
preserveAspectRatio=true,
extent={{-100,-100},{100,100}}), graphics={
Line(points={{-80,78},{-80,-90}}, color={192,192,192}),
Polygon(
points={{-80,90},{-88,68},{-72,68},{-80,90}},
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid),
Line(points={{-90,-80},{82,-80}}, color={192,192,192}),
Polygon(
points={{90,-80},{68,-72},{68,-88},{90,-80}},
lineColor={192,192,192},
fillColor={192,192,192},
fillPattern=FillPattern.Solid),
Line(points={{-80,-80},{-80,-20},{30,60},{80,60}}, color={0,0,127}),
Text(
extent={{-20,-20},{80,-60}},
textColor={192,192,192},
textString="%controllerType"),
Line(
visible=strict,
points={{30,60},{81,60}},
color={255,0,0})}),
Diagram(graphics={Text(
extent={{79,-112},{129,-102}},
textColor={0,0,255},
textString=" (feed-forward)")}),
Documentation(info="<html>
<p>
Via parameter <strong>controllerType</strong> either <strong>P</strong>, <strong>PI</strong>, <strong>PD</strong>,
or <strong>PID</strong> can be selected. If, e.g., PI is selected, all components belonging to the
D-part are removed from the block (via conditional declarations).
The example model
<a href=\"modelica://Modelica.Blocks.Examples.PID_Controller\">Modelica.Blocks.Examples.PID_Controller</a>
demonstrates the usage of this controller.
Several practical aspects of PID controller design are incorporated
according to chapter 3 of the book:
</p>
<dl>
<dt>Åström K.J., and Hägglund T.:</dt>
<dd> <strong>PID Controllers: Theory, Design, and Tuning</strong>.
Instrument Society of America, 2nd edition, 1995.
</dd>
</dl>
<p>
Besides the additive <strong>proportional, integral</strong> and <strong>derivative</strong>
part of this controller, the following features are present:
</p>
<ul>
<li> The output of this controller is limited. If the controller is
in its limits, anti-windup compensation is activated to drive
the integrator state to zero.</li>
<li> The high-frequency gain of the derivative part is limited
to avoid excessive amplification of measurement noise.</li>
<li> Setpoint weighting is present, which allows to weight
the setpoint in the proportional and the derivative part
independently from the measurement. The controller will respond
to load disturbances and measurement noise independently of this setting
(parameters wp, wd). However, setpoint changes will depend on this
setting. For example, it is useful to set the setpoint weight wd
for the derivative part to zero, if steps may occur in the