/
ImageController.as
233 lines (207 loc) · 9.83 KB
/
ImageController.as
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
/*
Copyright 2012 Marek Standio.
This file is part of SaladoPlayer.
SaladoPlayer is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published
by the Free Software Foundation, either version 3 of the License,
or (at your option) any later version.
SaladoPlayer is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty
of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
See the GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with SaladoPlayer. If not, see <http://www.gnu.org/licenses/>.
*/
package com.panozona.modules.imagegallery.controller {
import caurina.transitions.Tweener;
import caurina.transitions.Equations;
import com.panozona.modules.imagegallery.events.ImageEvent;
import com.panozona.modules.imagegallery.events.ViewerEvent;
import com.panozona.modules.imagegallery.events.WindowEvent;
import com.panozona.modules.imagegallery.model.structure.Image;
import com.panozona.modules.imagegallery.view.ImageView;
import com.panozona.player.module.data.property.Size;
import com.panozona.player.module.Module;
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.DisplayObject;
import flash.display.Loader;
import flash.display.LoaderInfo;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.TimerEvent;
import flash.net.URLRequest;
import flash.utils.Timer;
import flash.system.ApplicationDomain;
import flash.system.LoaderContext;
public class ImageController {
private var imageLoader:Loader;
private var displayObject:DisplayObject;
private var displayObjectInitSize:Size;
private var nextDisplayObject:DisplayObject;
private var _imageView:ImageView;
private var _module:Module;
private var _throbberDelayTimer:Timer;
private const closedMultiplier:Number = 0.5
public function ImageController(imageView:ImageView, module:Module) {
_imageView = imageView;
_module = module;
displayObjectInitSize = new Size(0, 0);
imageLoader = new Loader();
imageLoader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, imageLost, false, 0, true);
imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded, false, 0, true);
_imageView.imagegalleryData.windowData.addEventListener(WindowEvent.CHANGED_OPEN, handleWindowOpenChange, false, 0, true);
_imageView.imagegalleryData.viewerData.addEventListener(ViewerEvent.CHANGED_CURRENT_IMAGE_INDEX, handleCurrentImageIndexChange, false, 0, true);
_imageView.imagegalleryData.windowData.addEventListener(WindowEvent.CHANGED_CURRENT_SIZE, handleWindowSizeChange, false, 0, true);
_imageView.imagegalleryData.imageData.addEventListener(ImageEvent.CHANGED_MAX_SCALE, handleMaxScaleChange, false, 0, true);
if (_imageView.imagegalleryData.viewerData.viewer.throbber != null ) {
_throbberDelayTimer = new Timer(250, 1);
_throbberDelayTimer.addEventListener(TimerEvent.TIMER, timesUp, false, 0, true);
}
}
private function handleWindowOpenChange(e:Event = null):void {
if (_imageView.imagegalleryData.windowData.open) {
handleCurrentImageIndexChange();
}else {
startClosing();
}
}
private function handleCurrentImageIndexChange(e:Event = null):void {
if (!_imageView.imagegalleryData.windowData.open) {
return;
}
if (_imageView.imagegalleryData.viewerData.viewer.throbber != null) {
_throbberDelayTimer.reset();
_throbberDelayTimer.start();
}
imageLoader.unload();
var path:String = _imageView.imagegalleryData.viewerData.getGroupById(
_imageView.imagegalleryData.viewerData.currentGroupId).getChildrenOfGivenClass(Image)
[_imageView.imagegalleryData.viewerData.currentImageIndex].path;
var context:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain);
context.checkPolicyFile = true;
imageLoader.load(new URLRequest(path), context);
}
private function imageLost(e:IOErrorEvent):void {
if (_imageView.imagegalleryData.viewerData.viewer.throbber != null) {
_throbberDelayTimer.stop();
}
_module.printError("Could not load image: " + e.text);
_imageView.imagegalleryData.imageData.isShowingThrobber = false;
}
private function imageLoaded(e:Event):void {
if (_imageView.imagegalleryData.viewerData.viewer.throbber != null) {
_throbberDelayTimer.stop();
}
_imageView.imagegalleryData.imageData.isShowingThrobber = false;
var displayObjectTmp:DisplayObject = imageLoader.content;
if (displayObjectTmp is Bitmap) {
(displayObjectTmp as Bitmap).smoothing = true;
}
if (_imageView.imagegalleryData.imageData.isOpened) {
nextDisplayObject = displayObjectTmp;
startClosing();
} else {
displayObject = displayObjectTmp;
startOpening();
}
}
private function startOpening():void {
_imageView.imagegalleryData.imageData.isOpening = true;
displayObjectInitSize.width = displayObject.width;
displayObjectInitSize.height = displayObject.height;
recalculateMaxScale();
displayObject.alpha = 0,
displayObject.scaleX = displayObject.scaleY = _imageView.imagegalleryData.imageData.maxScale * closedMultiplier;
displayObject.x = (_imageView.imagegalleryData.windowData.currentSize.width - displayObject.width) * 0.5
displayObject.y = (_imageView.imagegalleryData.windowData.currentSize.height - displayObject.height) * 0.5
while (_imageView.numChildren) {
_imageView.removeChildAt(0);
}
_imageView.addChild(displayObject);
Tweener.addTween(displayObject, {
time:0.25,
transition:Equations.easeOutCirc,
scaleX:_imageView.imagegalleryData.imageData.maxScale,
scaleY:_imageView.imagegalleryData.imageData.maxScale,
x:(_imageView.imagegalleryData.windowData.currentSize.width
- displayObjectInitSize.width * _imageView.imagegalleryData.imageData.maxScale) * 0.5,
y:(_imageView.imagegalleryData.windowData.currentSize.height
- displayObjectInitSize.height * _imageView.imagegalleryData.imageData.maxScale) * 0.5,
alpha:1,
onComplete:openingComplete});
}
private function openingComplete():void {
_imageView.imagegalleryData.imageData.isOpening = false;
_imageView.imagegalleryData.imageData.isOpened = true;
}
private function startClosing():void {
_imageView.imagegalleryData.imageData.isClosing = true;
Tweener.addTween(displayObject, {
time:0.25,
transition:Equations.easeInCirc,
scaleX:_imageView.imagegalleryData.imageData.maxScale * closedMultiplier,
scaleY:_imageView.imagegalleryData.imageData.maxScale * closedMultiplier,
x:(_imageView.imagegalleryData.windowData.currentSize.width -
displayObjectInitSize.width * _imageView.imagegalleryData.imageData.maxScale * closedMultiplier) * 0.5,
y:(_imageView.imagegalleryData.windowData.currentSize.height -
displayObjectInitSize.height * _imageView.imagegalleryData.imageData.maxScale * closedMultiplier) * 0.5,
alpha:0,
onComplete:closingComplete});
}
private function closingComplete():void {
_imageView.imagegalleryData.imageData.isClosing = false;
_imageView.imagegalleryData.imageData.isOpened = false;
if (nextDisplayObject != null) {
displayObject = nextDisplayObject;
nextDisplayObject = null;
startOpening();
}
}
private function timesUp(e:Event):void {
_imageView.imagegalleryData.imageData.isShowingThrobber = true;
}
private function handleWindowSizeChange(event:Event = null):void {
if (displayObject == null) {
return;
}
recalculateMaxScale();
displayObject.x = (_imageView.imagegalleryData.windowData.currentSize.width
- displayObjectInitSize.width * _imageView.imagegalleryData.imageData.maxScale) * 0.5
displayObject.y = (_imageView.imagegalleryData.windowData.currentSize.height
- displayObjectInitSize.height * _imageView.imagegalleryData.imageData.maxScale) * 0.5
}
private function recalculateMaxScale():void {
var maxSize:Size = new Size(_imageView.imagegalleryData.windowData.currentSize.width
- _imageView.imagegalleryData.viewerData.viewer.padding,
_imageView.imagegalleryData.windowData.currentSize.height
- _imageView.imagegalleryData.viewerData.viewer.padding);
if (displayObjectInitSize.width <= maxSize.width && displayObjectInitSize.height <= maxSize.height ) {
_imageView.imagegalleryData.imageData.maxScale = 1;
} else {
var scale:Number = maxSize.height / displayObjectInitSize.height
if (displayObjectInitSize.width * scale > maxSize.width) {
scale = maxSize.width / displayObjectInitSize.width;
}
_imageView.imagegalleryData.imageData.maxScale = scale;
}
}
private function handleMaxScaleChange(event:Event = null):void {
if (_imageView.imagegalleryData.imageData.isOpening) {
_imageView.imagegalleryData.imageData.isOpening = false;
Tweener.addTween(displayObject, { // no time parameter
scaleX:_imageView.imagegalleryData.imageData.maxScale,
scaleY:_imageView.imagegalleryData.imageData.maxScale});
_imageView.alpha = _imageView.imagegalleryData.windowData.window.alpha;
} if (_imageView.imagegalleryData.imageData.isClosing) {
_imageView.imagegalleryData.imageData.isClosing = false;
Tweener.addTween(displayObject, { // no time parameter
scaleX:_imageView.imagegalleryData.imageData.maxScale * closedMultiplier,
scaleY:_imageView.imagegalleryData.imageData.maxScale * closedMultiplier});
_imageView.alpha = 0;
} else if (_imageView.imagegalleryData.imageData.isOpened) {
displayObject.scaleX = displayObject.scaleY = _imageView.imagegalleryData.imageData.maxScale;
}
}
}
}