/
Rules.groovy
322 lines (278 loc) · 12.1 KB
/
Rules.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
/*
* Copyright 2015-2016 Netflix, Inc.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package nebula.plugin.resolutionrules
import org.gradle.api.Action
import org.gradle.api.Project
import org.gradle.api.artifacts.*
import org.gradle.api.artifacts.component.ComponentSelector
import org.gradle.api.artifacts.component.ModuleComponentIdentifier
import org.gradle.api.artifacts.component.ProjectComponentIdentifier
import org.gradle.api.internal.artifacts.ivyservice.ivyresolve.strategy.DefaultVersionComparator
import org.gradle.api.internal.artifacts.ivyservice.ivyresolve.strategy.DefaultVersionSelectorScheme
import org.gradle.api.internal.artifacts.ivyservice.ivyresolve.strategy.VersionSelectorScheme
import org.gradle.api.specs.Specs
import org.joda.time.DateTime
import org.joda.time.DateTimeZone
public class Rules {
List<ReplaceRule> replace
List<SubstituteRule> substitute
List<RejectRule> reject
List<DenyRule> deny
List<AlignRule> align
List<ExcludeRule> exclude
public List<ProjectRule> projectRules() {
return replace
}
public List<ConfigurationRule> configurationRules() {
return [deny].flatten()
}
public List<ResolutionRule> resolutionRules() {
return [substitute, reject].flatten()
}
public List<ProjectConfigurationRule> projectConfigurationRules() {
return [new AlignRules(aligns: align), exclude]
}
}
interface ProjectRule {
public void apply(Project project)
}
interface ResolutionRule {
public void apply(ResolutionStrategy rs)
}
interface ConfigurationRule {
public void apply(Configuration configuration)
}
interface ProjectConfigurationRule {
public void apply(Project project, ResolutionStrategy rs, Configuration configuration, NebulaResolutionRulesExtension extension)
}
abstract class BaseRule {
String ruleSet
String reason
String author
DateTime date
BaseRule(String ruleSet, Map map) {
this.ruleSet = ruleSet
reason = map.reason
author = map.author
date = new DateTime(map.date as String).toDateTime(DateTimeZone.UTC)
}
}
class ReplaceRule extends BaseRule implements ProjectRule {
String module
String with
ReplaceRule(String ruleSet, Map map) {
super(ruleSet, map)
module = map.module
with = map.with
}
public void apply(Project project) {
ModuleIdentifier moduleId = ModuleIdentifier.valueOf(module)
ModuleIdentifier withModuleId = ModuleIdentifier.valueOf(with)
project.dependencies.modules.module(moduleId.toString()) {
ComponentModuleMetadataDetails details = it as ComponentModuleMetadataDetails
details.replacedBy(withModuleId.toString())
}
}
}
class SubstituteRule extends BaseRule implements ResolutionRule {
String module
String with
SubstituteRule(String ruleSet, Map map) {
super(ruleSet, map)
module = map.module
with = map.with
}
@Override
public void apply(ResolutionStrategy resolutionStrategy) {
DependencySubstitutions substitution = resolutionStrategy.dependencySubstitution
ComponentSelector selector = substitution.module(module)
ModuleVersionIdentifier withModuleId = ModuleVersionIdentifier.valueOf(with)
if (!withModuleId.hasVersion()) {
throw new SubstituteRuleMissingVersionException(withModuleId, this)
}
ComponentSelector withSelector = substitution.module(withModuleId.toString())
resolutionStrategy.dependencySubstitution {
it.substitute(selector).with(withSelector)
}
}
@Override
String toString() {
return "${this.class.simpleName}(module=$module, with=$with, reason=$reason, author=$author, date=$date)"
}
}
class RejectRule extends BaseRule implements ResolutionRule {
String module
RejectRule(String ruleSet, Map map) {
super(ruleSet, map)
module = map.module
}
@Override
public void apply(ResolutionStrategy resolutionStrategy) {
ModuleVersionIdentifier moduleId = ModuleVersionIdentifier.valueOf(module)
resolutionStrategy.componentSelection.all({ selection ->
ModuleComponentIdentifier candidate = selection.candidate
if (candidate.group == moduleId.organization && candidate.module == moduleId.name) {
if (!moduleId.hasVersion() || candidate.version == moduleId.version) {
selection.reject("Rejected by resolution rule $ruleSet - $reason")
}
}
})
}
}
class DenyRule extends BaseRule implements ConfigurationRule {
String module
DenyRule(String ruleSet, Map map) {
super(ruleSet, map)
module = map.module
}
@Override
public void apply(Configuration configuration) {
ModuleVersionIdentifier moduleId = ModuleVersionIdentifier.valueOf(module)
Dependency match = configuration.dependencies.find {
it instanceof ExternalModuleDependency && it.group == moduleId.organization && it.name == moduleId.name
}
if (match != null && (!moduleId.hasVersion() || match.version == moduleId.version)) {
throw new DependencyDeniedException(moduleId, this)
}
}
}
class AlignRule extends BaseRule {
String group
Collection<String> includes
Collection<String> excludes
AlignRule(String ruleSet, Map map) {
super(ruleSet, map)
group = map.group
includes = map.includes ?: []
excludes = map.excludes ?: []
}
boolean resolvedMatches(ResolvedModuleVersion dep) {
ruleMatches(dep.id.group, dep.id.name)
}
boolean dependencyMatches(DependencyResolveDetails details) {
ruleMatches(details.requested.group, details.requested.name)
}
boolean ruleMatches(String inputGroup, String inputName) {
def matchedIncludes = includes.findAll { inputName.matches(it) }
def matchedExcludes = excludes.findAll { inputName.matches(it) }
inputGroup.matches(group) &&
(includes.isEmpty() || !matchedIncludes.isEmpty()) &&
(excludes.isEmpty() || matchedExcludes.isEmpty())
}
@Override
String toString() {
return "[group: $group, includes: $includes, excludes: $excludes]"
}
}
class AlignRules implements ProjectConfigurationRule {
List<AlignRule> aligns
@Override
void apply(Project project, ResolutionStrategy resolutionStrategy, Configuration configuration, NebulaResolutionRulesExtension extension) {
if (aligns.size() == 0) { // don't do extra resolves if there are no align rules
return
}
def logger = project.logger
def copy = configuration.copyRecursive()
// Hacky workaround to prevent Gradle from attempting to resolve a project dependency as an external dependency
copy.exclude group: project.group.toString(), module: project.name
Set<ResolvedArtifact> artifacts
def resolvedConfiguration = copy.resolvedConfiguration
if (resolvedConfiguration.hasError()) {
def lenientConfiguration = resolvedConfiguration.lenientConfiguration
logger.info("Resolution rules could not resolve all dependencies to align in configuration '${configuration.name}' should also fail to resolve")
artifacts = lenientConfiguration.getArtifacts(Specs.SATISFIES_ALL)
} else {
artifacts = resolvedConfiguration.resolvedArtifacts
}
def moduleVersions = artifacts.findAll {
// Exclude project artifacts from alignment
!(it.id.componentIdentifier instanceof ProjectComponentIdentifier)
}.collect { it.moduleVersion }
def comparator = new DefaultVersionComparator()
def scheme = new DefaultVersionSelectorScheme(comparator)
Map<AlignRule, String> selectedVersion = [:]
aligns.each { AlignRule align ->
def matches = moduleVersions.findAll { ResolvedModuleVersion dep -> align.resolvedMatches(dep) }
if (matches) {
selectedVersion[align] = alignedVersion(project, align, matches, configuration, scheme, comparator.asStringComparator())
}
}
resolutionStrategy.eachDependency(new Action<DependencyResolveDetails>() {
@Override
void execute(DependencyResolveDetails details) {
def foundMatch = selectedVersion.find { AlignRule rule, String version -> rule.dependencyMatches(details) }
if (foundMatch) {
def rule = foundMatch.key
def version = foundMatch.value
if (version != details.requested.version) {
logger.info("Resolution rules ruleset ${rule.ruleSet} rule $rule aligning ${details.requested.group}:${details.requested.name} to $version")
details.useVersion version
}
}
}
})
}
private
static String alignedVersion(Project project, AlignRule rule, List<ResolvedModuleVersion> moduleVersions, Configuration configuration,
VersionSelectorScheme scheme, Comparator<String> comparator) {
List<ModuleVersionSelector> forced = moduleVersions.findResults { moduleVersion ->
configuration.resolutionStrategy.forcedModules.find {
def id = moduleVersion.id
it.group == id.group && it.name == id.name
}
}
if (forced) {
def versions = forced.collect { it.version }.toUnique()
def (dynamicVersions, staticVersions) = versions.split { version ->
def selector = scheme.parseSelector(version)
selector.dynamic
}
def logger = project.logger
if (!dynamicVersions.isEmpty()) {
logger.warn("Resolution rules ruleset ${rule.ruleSet} align rule $rule is unable to honor forced versions $dynamicVersions. For a force to take precedence on an align rule, it must use a static version")
}
if (!staticVersions.isEmpty()) {
return staticVersions.min { String a, String b -> comparator.compare(a, b) }
} else {
logger.warn("No static forces found for ruleset ${rule.ruleSet} align rule $rule. Falling back to default alignment logic")
}
}
def versions = moduleVersions.collect { ResolvedModuleVersion dep -> dep.id.version }.toUnique()
return versions.max { String a, String b -> comparator.compare(a, b) }
}
}
class ExcludeRule extends BaseRule implements ProjectConfigurationRule {
ModuleIdentifier moduleId
ExcludeRule(String ruleSet, Map map) {
super(ruleSet, map)
moduleId = ModuleIdentifier.valueOf(map.module as String)
}
@Override
void apply(Project project, ResolutionStrategy rs, Configuration configuration, NebulaResolutionRulesExtension extension) {
project.logger.info("Resolution rule ruleset $ruleSet excluding ${moduleId.organization}:${moduleId.name}")
configuration.exclude(group: moduleId.organization, module: moduleId.name)
}
}
public class DependencyDeniedException extends Exception {
public DependencyDeniedException(ModuleVersionIdentifier moduleId, DenyRule rule) {
super("Dependency ${moduleId} denied by dependency rule: ${rule.reason}")
}
}
public class SubstituteRuleMissingVersionException extends Exception {
public SubstituteRuleMissingVersionException(ModuleVersionIdentifier moduleId, SubstituteRule rule) {
super("The dependency to be substituted ($moduleId) must have a version. Invalid rule: $rule")
}
}