Skip to content
Browse files

most basic version working

  • Loading branch information...
0 parents commit 000ea7312fb9ceeb6159bc671d248eaf0c30bab8 Neeraj Singh committed Nov 27, 2010
Showing with 207 additions and 0 deletions.
  1. BIN .vimrc.swp
  2. +139 −0 autoload/pathogen.vim
  3. +1 −0 bundle/nerdcommenter
  4. +1 −0 bundle/nerdtree
  5. +1 −0 bundle/vim-cucumber
  6. +1 −0 bundle/vim-endwise
  7. +1 −0 bundle/vim-haml
  8. +1 −0 bundle/vim-rails
  9. +1 −0 bundle/vim-surround
  10. +1 −0 bundle/vim-unimpaired
  11. +1 −0 bundle/vim-vividchalk
  12. +42 −0 gvimrc
  13. +17 −0 vimrc
BIN .vimrc.swp
Binary file not shown.
139 autoload/pathogen.vim
@@ -0,0 +1,139 @@
+" pathogen.vim - path option manipulation
+" Maintainer: Tim Pope <vimNOSPAM@tpope.org>
+" Version: 1.2
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" API is documented below.
+
+if exists("g:loaded_pathogen") || &cp
+ finish
+endif
+let g:loaded_pathogen = 1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+ if type(a:path) == type([]) | return a:path | endif
+ let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+ return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+ if type(a:1) == type(1) && a:1
+ let i = 1
+ let space = ' '
+ else
+ let i = 0
+ let space = ''
+ endif
+ let path = ""
+ while i < a:0
+ if type(a:000[i]) == type([])
+ let list = a:000[i]
+ let j = 0
+ while j < len(list)
+ let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+ let path .= ',' . escaped
+ let j += 1
+ endwhile
+ else
+ let path .= "," . a:000[i]
+ endif
+ let i += 1
+ endwhile
+ return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+ return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+ let i = 0
+ let seen = {}
+ while i < len(a:list)
+ if has_key(seen,a:list[i])
+ call remove(a:list,i)
+ else
+ let seen[a:list[i]] = 1
+ let i += 1
+ endif
+ endwhile
+ return a:list
+endfunction " }}}1
+
+" Returns a hash indicating which filetype features are enabled.
+function! pathogen#filetype() abort " {{{1
+ redir => output
+ silent filetype
+ redir END
+ let result = {}
+ let result.detection = match(output,'detection:ON') >= 0
+ let result.indent = match(output,'indent:ON') >= 0
+ let result.plugin = match(output,'plugin:ON') >= 0
+ return result
+endfunction " }}}1
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#separator() abort " {{{1
+ return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+ let files = split(glob(a:pattern),"\n")
+ return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+ return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Prepend all subdirectories of path to the rtp, and append all after
+" directories in those subdirectories.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+ let sep = pathogen#separator()
+ let before = pathogen#glob_directories(a:path.sep."*[^~]")
+ let after = pathogen#glob_directories(a:path.sep."*[^~]".sep."after")
+ let rtp = pathogen#split(&rtp)
+ let path = expand(a:path)
+ call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+ let &rtp = pathogen#join(pathogen#uniq(before + rtp + after))
+ return &rtp
+endfunction " }}}1
+
+" For each directory in rtp, check for a subdirectory named dir. If it
+" exists, add all subdirectories of that subdirectory to the rtp, immediately
+" after the original directory. If no argument is given, 'bundle' is used.
+" Repeated calls with the same arguments are ignored.
+function! pathogen#runtime_append_all_bundles(...) " {{{1
+ let sep = pathogen#separator()
+ let name = a:0 ? a:1 : 'bundle'
+ let list = []
+ for dir in pathogen#split(&rtp)
+ if dir =~# '\<after$'
+ let list += pathogen#glob_directories(substitute(dir,'after$',name.sep.'*[^~]'.sep.'after','')) + [dir]
+ else
+ let list += [dir] + pathogen#glob_directories(dir.sep.name.sep.'*[^~]')
+ endif
+ endfor
+ let &rtp = pathogen#join(pathogen#uniq(list))
+ return 1
+endfunction
+
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() " {{{1
+ for dir in pathogen#split(&rtp)
+ if dir[0 : strlen($VIM)-1] !=# $VIM && isdirectory(dir.'/doc') && (!filereadable(dir.'/doc/tags') || filewritable(dir.'/doc/tags'))
+ helptags `=dir.'/doc'`
+ endif
+ endfor
+endfunction " }}}1
+
+" vim:set ft=vim ts=8 sw=2 sts=2:
1 bundle/nerdcommenter
@@ -0,0 +1 @@
+Subproject commit 930be32a23e902ddc46135ddbb9e76b0fac0c14b
1 bundle/nerdtree
@@ -0,0 +1 @@
+Subproject commit 7650cdc6621cd15b047dc04605b8b0bc0396564d
1 bundle/vim-cucumber
@@ -0,0 +1 @@
+Subproject commit 35b4a3ea17bab837540c7d371d3bd71b5d46eaf5
1 bundle/vim-endwise
@@ -0,0 +1 @@
+Subproject commit 780fa5603c0917d9b22e3b64dd8ab0423e006eb5
1 bundle/vim-haml
@@ -0,0 +1 @@
+Subproject commit a0345d5c224aa8c473b11514cf5914823016ffd7
1 bundle/vim-rails
@@ -0,0 +1 @@
+Subproject commit 26dade8251a07da3d78467bcbc08bd1b2767008d
1 bundle/vim-surround
@@ -0,0 +1 @@
+Subproject commit 27710a2224d6dd0486d1c40d09ef18dd752e7d37
1 bundle/vim-unimpaired
@@ -0,0 +1 @@
+Subproject commit 9b898d31988640f2bbc07fc35f588bd1247ffa33
1 bundle/vim-vividchalk
@@ -0,0 +1 @@
+Subproject commit c824c2a5c1d96a7d2ec2df6baf7231dcee621130
42 gvimrc
@@ -0,0 +1,42 @@
+" -----------------------------------------------------------------------------
+" | VIM Settings |
+" | GUI stuff |
+" -----------------------------------------------------------------------------
+
+
+" OS Specific *****************************************************************
+set fuoptions=maxvert,maxhorz " fullscreen options (MacVim only), resized window when changed to fullscreen
+set guifont=Monaco:h17.00
+
+set guioptions-=m " remove menubar
+set guioptions-=T " remove toolbar
+set guioptions-=r " remove right scroll bar
+set stal=2 " turn on tabs by default
+
+set encoding=utf-8 " User UTF-8 everywhere
+
+set anti " Antialias font
+set antialias " Antialias font
+
+
+" Default size of window
+set columns=120
+set lines=50
+
+" Tab headings
+set gtl=%t gtt=%F
+
+
+" For File Browser
+nnoremap <silent> <F8> :Exp<CR>
+nnoremap <silent> <D-e> :Exp<cr>
+"FuzzyFinderTextMate
+nnoremap <silent><D-r> :FuzzyFinderTextMate<CR>
+
+" save
+noremap <silent> <D-s> :w<CR>
+
+" tabs
+map <silent> <D-t> :tabnew %<cr>
+map <silent> <D-w> :tabclose<cr>
+
17 vimrc
@@ -0,0 +1,17 @@
+filetype off
+
+call pathogen#runtime_append_all_bundles()
+
+syntax on
+filetype plugin indent on
+set tabstop=2
+set smarttab
+set shiftwidth=2
+set autoindent
+set expandtab
+
+" Color scheme
+colorscheme vividchalk
+highlight NonText guibg=#060606
+highlight Folded guibg=#0A0A0A guifg=#9090D0
+

0 comments on commit 000ea73

Please sign in to comment.
Something went wrong with that request. Please try again.