Neo.TransientError.Transaction.Outdated Error

[ppoliani]

I get an error from a query that used to run correctly.

Neo4j Version: 3.5.8-enterprice
Operating System: MacOS Mojave
API: Docker

Steps to reproduce

1. Create a new HAS_PERSONAL relationship

MATCH (d:Document), (u:User {userId:"id1"})
WHERE ID(d)=16
MERGE (u)-[:HAS_PERSONAL]->(d)
RETURN d

2. After the previous query is successful (and it is because I can see it in the Neo4j browser) I try to delete it

MATCH (u:User {userId:"id1"})-[ss:HAS_PERSONAL]->(d:Document)
WHERE ID(d)=16
DELETE ss
RETURN ss

Expected behavior

The relationship should be removed.

Actual behavior

I get the following error:

Database elements (nodes, relationships, properties) were observed during query execution, but got deleted by an overlapping committed transaction before the query results could be serialised. The transaction might succeed if it is retried.

[chrisvest]

It occurs because your query is returning the deleted relationship, and the relationship object is not materialised (fully populated with properties, etc) until the result is being serialised, which, if you are using automatic rather than explicit transactions, happens after the transaction commits.

[ppoliani]

@chrisvest thanks for the answer. Pardon my ignorance, but does it mean that you can return a deleted relationship? Is there a suggested alternative. The thing is that the same query works fine on version 3.3.3 but not in 3.5.8.

[InverseFalcon]

If you need to return the properties of the relationship, you can project those out before your delete and return those:

MATCH (u:User {userId:"id1"})-[ss:HAS_PERSONAL]->(d:Document)
WHERE ID(d)=16
WITH properties(ss) as deletedRelProps
DELETE ss
RETURN deletedRelProps

If you want the graph ID of the relationship too (and anything else you might need) you can use map projection first before the deletion:

MATCH (u:User {userId:"id1"})-[ss:HAS_PERSONAL]->(d:Document)
WHERE ID(d)=16
WITH ss {.*, graphID:id(ss)} as deletedRelProps
DELETE ss
RETURN deletedRelProps

[sherfert]

@chrisvest The error message ... overlapping committed transaction ... is not very accurate though. Any chance on improving that?

[chrisvest]

@ppoliani The semantics of returning deleted entities are not well defined in the current Cypher versions. A proposal has been put forward that pins down the semantics in this area, but the current versions of Cypher do not yet implement it. Until then, we'll improve the error message.

[ppoliani]

@chrisvest Thanks for the reference. Will @InverseFalcon solution work at the moment?

[chrisvest]

@ppoliani Yes, capturing the properties with a WITH prior to deleting the relationship works.

[ppoliani]

Fantastic! Shall we remove the bug label and close this issue?