-
Notifications
You must be signed in to change notification settings - Fork 68
/
execute_x64.S
2461 lines (2423 loc) · 54.3 KB
/
execute_x64.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#define CKB_VM_ASM_GENERATE_LABEL_TABLES 1
#include "cdefinitions_generated.h"
#ifdef _WIN32
#define IS_WINDOWS 1
#endif
#define INT64_MIN 0x8000000000000000
#define UINT64_MAX 0xffffffffffffffff
#ifdef IS_WINDOWS
#define ARG1 %rcx
#define ARG2 %rdx
#else
#define ARG1 %rdi
#define ARG2 %rsi
#endif
#ifdef IS_WINDOWS
#define PREPCALL \
push %rdi; \
push %rsi; \
push %rax; \
push %rcx; \
push %rdx; \
push %r8; \
push %r9; \
push %r10; \
push %rbp; \
movq %rsp, %rbp; \
andq $-16, %rsp; \
sub $32, %rsp
#define POSTCALL \
add $32, %rsp; \
movq %rbp, %rsp; \
pop %rbp; \
pop %r10; \
pop %r9; \
pop %r8; \
pop %rdx; \
pop %rcx; \
pop %rax; \
pop %rsi; \
pop %rdi
#else
#define PREPCALL \
push %rdi; \
push %rsi; \
push %rax; \
push %rcx; \
push %rdx; \
push %r8; \
push %r9; \
push %r10; \
push %rbp; \
movq %rsp, %rbp; \
andq $-16, %rsp
#define POSTCALL \
movq %rbp, %rsp; \
pop %rbp; \
pop %r10; \
pop %r9; \
pop %r8; \
pop %rdx; \
pop %rcx; \
pop %rax; \
pop %rsi; \
pop %rdi
#endif
/* rax is used both in Microsoft x64 and System V AMD64 ABI */
#define ARG_RETd %eax
#define MACHINE %rsi
#define TRACE %rbx
#define MEMORY_SIZE %r13
#define INVOKE_DATA %r14
/*
* INST_PC contains the current address of decoded Instruction in
* Trace item, which is different from the RISC-V PC
*/
#define INST_PC %r8
#define INST_ARGS %r9
/*
* Rules to meet when considering register allocations:
* * RD and TEMP1 cannot be %rcx to set aside %cl for shifts
* * RS2r and TEMP1 cannot be %rax to allow using imul and idiv
* * RS2r cannot be %rdx to allow using idiv
*/
#define RD_RS2s %rax
#define RD RD_RS2s
#define RS1 %rdx
#define RS2r %rbp
#define RS2s RD_RS2s
#define RS3 %r12
#define IMMEDIATE %rcx
#define TEMP1 %rdi
#define TEMP2 %r10
#define TEMP3 %r11
/* This helps remind us that RS4 and TEMP1 shares the same register */
#define RS4_TEMP1 TEMP1
#define RDd_RS2sd %eax
#define RDd RDd_RS2sd
#define RS1d %edx
#define RS1h %dx
#define RS1b %dl
#define RS2rd %ebp
#define RS2rb %bpl
#define RS2sd %eax
#define RS2sb %al
#define RS2sh %ax
#define RS3d %r12d
#define IMMEDIATEb %cl
#define IMMEDIATEd %ecx
#define TEMP1b %dil
#define TEMP1d %edi
#define TEMP2d %r10d
#define TEMP2b %r10b
#define TEMP3d %r11d
#define TEMP3b %r11b
#define RS4_TEMP1d TEMP1d
#define PC_ADDRESS \
CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_PC(MACHINE)
#define ZERO_ADDRESS \
CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_REGISTERS(MACHINE)
#define RA_ADDRESS \
(CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_REGISTERS + CKB_VM_ASM_REGISTER_RA * 8)(MACHINE)
#define SP_ADDRESS \
(CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_REGISTERS + CKB_VM_ASM_REGISTER_SP * 8)(MACHINE)
#define REGISTER_ADDRESS(r) \
CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_REGISTERS(MACHINE, r, 8)
#define LOAD_RESERVATION_ADDRESS \
CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_LOAD_RESERVATION_ADDRESS(MACHINE)
/*
* Those macros provide slight abstractions over register allocations,
* they might change when we alter register allocations. For example:
*
* * A push operation needs to do nothing if the variable to push is not
* the register we need to save
* * A move operation becomes nop if the variable is assigned the same
* register as the target
*/
#define PUSH_RD_IF_RAX push %rax
#define PUSH_RD_IF_RDX
#define POP_RD_IF_RAX pop %rax
#define POP_RD_IF_RDX
#define PUSH_RS1_IF_RAX
#define PUSH_RS1_IF_RDX push %rdx
#define POP_RS1_IF_RAX
#define POP_RS1_IF_RDX pop %rdx
#define MOV_RS1_TO_RAX movq RS1, %rax
#define MOV_RAX_TO_RS1 movq %rax, RS1
#define MOV_RS2r_TO_RAX movq RS2r, %rax
#define MOV_RAX_TO_RS2r movq %rax, RS2r
#define MOV_RS1_TO_RDX
#define MOV_RDX_TO_RS1
#define MOV_RS2r_TO_RDX movq RS2r, %rdx
#define MOV_RDX_TO_RS2r movq %rdx, RS2r
#define MOV_IMM_TO_RCX
#ifdef IS_WINDOWS
#define MOV_TEMP1_TO_ARG1 movq TEMP1, ARG1
#define MOV_MACHINE_TO_ARG2 movq MACHINE, ARG2
#else
#define MOV_TEMP1_TO_ARG1
#define MOV_MACHINE_TO_ARG2
#endif
#ifdef __APPLE__
#define CALL_INITED_MEMORY call _inited_memory
#elif defined IS_WINDOWS
#define CALL_INITED_MEMORY call inited_memory
#else
#define CALL_INITED_MEMORY call inited_memory@plt
#endif
/*
* This is an internal macro used by other macros, it should not be used
* in instruction implementation directly.
*/
#define _CHECK_READ_FRAMES(address_reg, length) \
movq address_reg, TEMP1; \
shr $CKB_VM_ASM_MEMORY_FRAME_SHIFTS, TEMP1; \
movq TEMP1, CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_LAST_READ_FRAME(MACHINE); \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FRAMES_PTR(MACHINE), TEMP3; \
movzbl (TEMP3, TEMP1), TEMP2d; \
cmp $0, TEMP2d; \
jne 1f; \
movb $1, (TEMP3, TEMP1); \
PREPCALL; \
MOV_TEMP1_TO_ARG1; \
MOV_MACHINE_TO_ARG2; \
CALL_INITED_MEMORY; \
POSTCALL; \
1: \
movq address_reg, TEMP1; \
addq $length, TEMP1; \
subq $1, TEMP1; \
shr $CKB_VM_ASM_MEMORY_FRAME_SHIFTS, TEMP1; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FRAMES_PTR(MACHINE), TEMP3; \
movzbl (TEMP3, TEMP1), TEMP2d; \
cmp $0, TEMP2d; \
jne 2f; \
movb $1, (TEMP3, TEMP1);\
PREPCALL; \
MOV_TEMP1_TO_ARG1; \
MOV_MACHINE_TO_ARG2; \
CALL_INITED_MEMORY; \
POSTCALL; \
2:
#define CHECK_READ_VERSION0(address_reg, length) \
movq address_reg, TEMP1; \
shr $CKB_VM_ASM_MEMORY_FRAME_SHIFTS, TEMP1; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_LAST_READ_FRAME(MACHINE), TEMP2; \
cmp TEMP2, TEMP1; \
jne 3f; \
movq address_reg, TEMP2; \
addq $length, TEMP2; \
shr $CKB_VM_ASM_MEMORY_FRAME_SHIFTS, TEMP2; \
cmp TEMP2, TEMP1; \
je 2f; \
3: ; \
movq address_reg, TEMP3; \
cmp MEMORY_SIZE, TEMP3; \
jae .exit_out_of_bound; \
addq $length, TEMP3; \
cmp MEMORY_SIZE, TEMP3; \
jae .exit_out_of_bound; \
_CHECK_READ_FRAMES(address_reg, length)
#define CHECK_READ_VERSION1(address_reg, length) \
movq address_reg, TEMP1; \
shr $CKB_VM_ASM_MEMORY_FRAME_SHIFTS, TEMP1; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_LAST_READ_FRAME(MACHINE), TEMP2; \
cmp TEMP2, TEMP1; \
jne 3f; \
movq address_reg, TEMP2; \
addq $length, TEMP2; \
shr $CKB_VM_ASM_MEMORY_FRAME_SHIFTS, TEMP2; \
cmp TEMP2, TEMP1; \
je 2f; \
3: ;\
movq address_reg, TEMP3; \
cmp MEMORY_SIZE, TEMP3; \
jae .exit_out_of_bound; \
addq $length, TEMP3; \
cmp MEMORY_SIZE, TEMP3; \
ja .exit_out_of_bound; \
_CHECK_READ_FRAMES(address_reg, length)
#define CHECK_WRITE(address_reg, temp_regd, length) \
movq address_reg, TEMP1; \
shr $CKB_VM_ASM_RISCV_PAGE_SHIFTS, TEMP1; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_LAST_WRITE_PAGE(MACHINE), TEMP2; \
cmp TEMP2, TEMP1; \
jne 3f;\
movq address_reg, TEMP2; \
addq $length, TEMP2; \
shr $CKB_VM_ASM_RISCV_PAGE_SHIFTS, TEMP2; \
cmp TEMP2, TEMP1; \
je 2f;\
3:; \
movq address_reg, TEMP3; \
movq TEMP1, CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_LAST_WRITE_PAGE(MACHINE); \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FLAGS_SIZE(MACHINE), TEMP2; \
cmp TEMP2, TEMP1; \
jae .exit_out_of_bound; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FLAGS_PTR(MACHINE), TEMP3; \
movzbl (TEMP3, TEMP1), temp_regd; \
mov temp_regd, TEMP2d; \
and $CKB_VM_ASM_MEMORY_FLAG_WXORX_BIT, temp_regd; \
cmp $CKB_VM_ASM_MEMORY_FLAG_WRITABLE, temp_regd; \
jne .exit_invalid_permission; \
or $CKB_VM_ASM_MEMORY_FLAG_DIRTY, TEMP2b; \
movb TEMP2b, (TEMP3, TEMP1); \
movq TEMP1, TEMP2; \
shr $CKB_VM_ASM_MEMORY_FRAME_PAGE_SHIFTS, TEMP1; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FRAMES_PTR(MACHINE), TEMP3; \
movzbl (TEMP3, TEMP1), temp_regd; \
cmp $0, temp_regd; \
jne 1f; \
movb $1, (TEMP3, TEMP1); \
PREPCALL; \
MOV_TEMP1_TO_ARG1; \
MOV_MACHINE_TO_ARG2; \
CALL_INITED_MEMORY; \
POSTCALL; \
1: \
movq TEMP2, TEMP1; \
addq $1, TEMP1; \
shl $CKB_VM_ASM_RISCV_PAGE_SHIFTS, TEMP1; \
movq address_reg, TEMP3; \
addq $length, TEMP3; \
cmp TEMP1, TEMP3; \
jbe 2f; \
shr $CKB_VM_ASM_RISCV_PAGE_SHIFTS, TEMP1; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FLAGS_SIZE(MACHINE), TEMP2; \
cmp TEMP2, TEMP1; \
jae .exit_out_of_bound; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FLAGS_PTR(MACHINE), TEMP3; \
movzbl (TEMP3, TEMP1), temp_regd; \
mov temp_regd, TEMP2d; \
and $CKB_VM_ASM_MEMORY_FLAG_WXORX_BIT, temp_regd; \
cmp $CKB_VM_ASM_MEMORY_FLAG_WRITABLE, temp_regd; \
jne .exit_invalid_permission; \
or $CKB_VM_ASM_MEMORY_FLAG_DIRTY, TEMP2b; \
movb TEMP2b, (TEMP3, TEMP1); \
shr $CKB_VM_ASM_MEMORY_FRAME_PAGE_SHIFTS, TEMP1; \
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_FRAMES_PTR(MACHINE), TEMP3; \
movzbl (TEMP3, TEMP1), temp_regd; \
cmp $0, temp_regd; \
jne 2f; \
movb $1, (TEMP3, TEMP1); \
PREPCALL; \
MOV_TEMP1_TO_ARG1; \
MOV_MACHINE_TO_ARG2; \
CALL_INITED_MEMORY; \
POSTCALL; \
2:
#define WRITE_RD_VALUE(v, temp_reg) \
movq v, temp_reg; \
movq temp_reg, REGISTER_ADDRESS(RD); \
movq $0, ZERO_ADDRESS
#define WRITE_RD(v) \
movq v, REGISTER_ADDRESS(RD); \
movq $0, ZERO_ADDRESS
#define WRITE_RD_V2(v) \
movq v, REGISTER_ADDRESS(RD); \
#define WRITE_RS1(v) \
movq v, REGISTER_ADDRESS(RS1); \
#define WRITE_RS2r(v) \
movq v, REGISTER_ADDRESS(RS2r); \
#define WRITE_RS3(v) \
movq v, REGISTER_ADDRESS(RS3); \
/*
* This macro is added to cope with an implementation bug in the x64 assembly code,
* where address bigger than u32 limit will be truncated unexpectedly.
*
* Useful tip: https://stackoverflow.com/a/66416462
*/
#define LOAD_PC(reg1, reg1d, reg2, reg2d, temp_regd) \
movq PC_ADDRESS, reg1; \
mov reg1d, reg2d; \
movzbl CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_VERSION(MACHINE), temp_regd; \
cmp $2, temp_regd; \
cmovae reg1, reg2
/*
* Notice we could replace the last 3 instructions with the following:
*
* addq $8, INST_PC
* jmp *-8(TEMP1)
*
* Even though this would save us one instruction to exectue, keeping the jump
* target in TEMP1 actually aids branch predictor for better performance.
*/
#define NEXT_INST \
movq (INST_ARGS), %rcx; \
addq $16, INST_ARGS; \
movzbl %ch, RDd_RS2sd; \
sar $32, %rcx; \
movq (INST_PC), TEMP1; \
addq $16, INST_PC; \
jmp *TEMP1
#define NEXT_INST_V2 \
movq $0, ZERO_ADDRESS; \
NEXT_INST
#define DECODE_R \
movzbl %cl, RS1d; \
movzbl %ch, RS2rd
#define DECODE_I \
movzbl %cl, RS1d; \
sar $8, %rcx
#define DECODE_S \
movzbl %cl, RS1d; \
sar $8, %rcx
#define DECODE_U
#define DECODE_R4 \
movzbl %cl, RS1d; \
movzbl %ch, RS2rd; \
sar $16, %rcx; \
movzbl %cl, RS3d
#define DECODE_R5 \
movzbl %cl, RS1d; \
movzbl %ch, RS2rd; \
sar $16, %rcx; \
movzbl %cl, RS3d; \
movzbl %ch, RS4_TEMP1d
#ifdef __APPLE__
.globl _ckb_vm_x64_execute
_ckb_vm_x64_execute:
#else
.globl ckb_vm_x64_execute
ckb_vm_x64_execute:
#endif
#ifdef IS_WINDOWS
push %rsi
push %rdi
#endif
push %rbp
push %rbx
push %r12
push %r13
push %r14
mov ARG2, INVOKE_DATA
mov ARG1, MACHINE
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_SIZE(MACHINE), MEMORY_SIZE
.p2align 3
.CKB_VM_ASM_LABEL_OP_CUSTOM_TRACE_END:
LOAD_PC(%rax, %eax, %rcx, %ecx, TEMP3d)
shr $2, %eax
andq CKB_VM_ASM_INVOKE_DATA_OFFSET_FIXED_TRACE_MASK(INVOKE_DATA), %rax
imul $CKB_VM_ASM_FIXED_TRACE_STRUCT_SIZE, %eax
movq CKB_VM_ASM_INVOKE_DATA_OFFSET_FIXED_TRACES(INVOKE_DATA), TRACE
addq %rax, TRACE
movq CKB_VM_ASM_TRACE_OFFSET_ADDRESS(TRACE), %rdx
cmp %rcx, %rdx
jne .exit_trace
mov CKB_VM_ASM_TRACE_OFFSET_LENGTH(TRACE), %edx
cmp $0, %rdx
je .exit_trace
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_CYCLES(MACHINE), %rax
addq CKB_VM_ASM_TRACE_OFFSET_CYCLES(TRACE), %rax
jc .exit_cycles_overflow
cmp CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MAX_CYCLES(MACHINE), %rax
ja .exit_max_cycles_exceeded
movq %rax, CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_CYCLES(MACHINE)
addq %rdx, PC_ADDRESS
/* Prefetch trace info for the consecutive block */
movq PC_ADDRESS, %rax
shr $2, %eax
andq CKB_VM_ASM_INVOKE_DATA_OFFSET_FIXED_TRACE_MASK(INVOKE_DATA), %rax
imul $CKB_VM_ASM_FIXED_TRACE_STRUCT_SIZE, %eax
movq CKB_VM_ASM_INVOKE_DATA_OFFSET_FIXED_TRACES(INVOKE_DATA), %rdx
prefetcht2 0(%rdx, %rax)
lea CKB_VM_ASM_TRACE_OFFSET_THREADS(TRACE), INST_PC
mov INST_PC, INST_ARGS
add $8, INST_ARGS
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_CUSTOM_ASM_TRACE_JUMP:
/* Load current instruction as the full trace address */
movq -16(INST_ARGS), TRACE
/* Prefetch trace info for the consecutive block */
prefetcht2 CKB_VM_ASM_TRACE_OFFSET_THREADS(TRACE)
mov CKB_VM_ASM_TRACE_OFFSET_LENGTH(TRACE), %edx
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_CYCLES(MACHINE), %rax
addq CKB_VM_ASM_TRACE_OFFSET_CYCLES(TRACE), %rax
jc .exit_cycles_overflow
cmp CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MAX_CYCLES(MACHINE), %rax
ja .exit_max_cycles_exceeded
movq %rax, CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_CYCLES(MACHINE)
addq %rdx, PC_ADDRESS
lea CKB_VM_ASM_TRACE_OFFSET_THREADS(TRACE), INST_PC
mov INST_PC, INST_ARGS
add $8, INST_ARGS
NEXT_INST
.p2align 3
.prepare_trace:
movq CKB_VM_ASM_INVOKE_DATA_OFFSET_PAUSE(INVOKE_DATA), %rax
movzbl 0(%rax), %eax
cmp $0, %rax
jnz .exit_pause
LOAD_PC(%rax, %eax, %rcx, %ecx, TEMP3d)
shr $2, %eax
andq CKB_VM_ASM_INVOKE_DATA_OFFSET_FIXED_TRACE_MASK(INVOKE_DATA), %rax
imul $CKB_VM_ASM_FIXED_TRACE_STRUCT_SIZE, %eax
movq CKB_VM_ASM_INVOKE_DATA_OFFSET_FIXED_TRACES(INVOKE_DATA), TRACE
addq %rax, TRACE
movq CKB_VM_ASM_TRACE_OFFSET_ADDRESS(TRACE), %rdx
cmp %rcx, %rdx
jne .exit_trace
mov CKB_VM_ASM_TRACE_OFFSET_LENGTH(TRACE), %edx
cmp $0, %rdx
je .exit_trace
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_CYCLES(MACHINE), %rax
addq CKB_VM_ASM_TRACE_OFFSET_CYCLES(TRACE), %rax
jc .exit_cycles_overflow
cmp CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MAX_CYCLES(MACHINE), %rax
ja .exit_max_cycles_exceeded
movq %rax, CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_CYCLES(MACHINE)
addq %rdx, PC_ADDRESS
lea CKB_VM_ASM_TRACE_OFFSET_THREADS(TRACE), INST_PC
mov INST_PC, INST_ARGS
add $8, INST_ARGS
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_ADDI:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_ADD:
DECODE_R
movq REGISTER_ADDRESS(RS1), RS1
addq REGISTER_ADDRESS(RS2r), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_ADDIW:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
movslq RS1d, RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_ADDW:
DECODE_R
movq REGISTER_ADDRESS(RS1), RS1
addq REGISTER_ADDRESS(RS2r), RS1
movslq RS1d, RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_AND:
DECODE_R
movq REGISTER_ADDRESS(RS1), RS1
andq REGISTER_ADDRESS(RS2r), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_ANDI:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
andq IMMEDIATE, RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_AUIPC:
DECODE_U
movq PC_ADDRESS, RS1
subq $4, RS1
addq IMMEDIATE, RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_BEQ:
DECODE_S
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2s), RS2s
cmpq RS2s, RS1
je .i_branch_success
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_BGE:
DECODE_S
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2s), RS2s
cmpq RS2s, RS1
jge .i_branch_success
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_BGEU:
DECODE_S
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2s), RS2s
cmpq RS2s, RS1
jae .i_branch_success
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_BLT:
DECODE_S
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2s), RS2s
cmpq RS2s, RS1
jl .i_branch_success
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_BLTU:
DECODE_S
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2s), RS2s
cmpq RS2s, RS1
jb .i_branch_success
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_BNE:
DECODE_S
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2s), RS2s
cmpq RS2s, RS1
jne .i_branch_success
NEXT_INST
.i_branch_success:
movq PC_ADDRESS, RS1
/* Loading flag of current instruction */
movq -16(INST_ARGS), TEMP3
sar $24, TEMP3
andq $0xF, TEMP3
shl $1, TEMP3
subq TEMP3, RS1
addq IMMEDIATE, RS1
movq RS1, PC_ADDRESS
jmp .prepare_trace
.p2align 3
.CKB_VM_ASM_LABEL_OP_DIV:
DECODE_R
push RD
movq $INT64_MIN, RD
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2r), RS2r
cmp RD, RS1
jne .div_branch1
cmp $-1, RS2r
jne .div_branch1
jmp .div_branch3
.div_branch1:
cmp $0, RS2r
jne .div_branch2
movq $UINT64_MAX, RS1
jmp .div_branch3
.div_branch2:
MOV_RS1_TO_RAX
cqo
idivq RS2r
MOV_RAX_TO_RS1
.div_branch3:
pop RD
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_DIVU:
DECODE_R
movq REGISTER_ADDRESS(RS2r), RS2r
cmp $0, RS2r
jne .divu_branch1
WRITE_RD_VALUE($UINT64_MAX, RS2r)
NEXT_INST
.divu_branch1:
PUSH_RD_IF_RAX
PUSH_RD_IF_RDX
movq REGISTER_ADDRESS(RS1), %rax
xorq %rdx, %rdx
divq RS2r
mov %rax, RS2r
POP_RD_IF_RDX
POP_RD_IF_RAX
WRITE_RD(RS2r)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_DIVUW:
DECODE_R
movq REGISTER_ADDRESS(RS2r), RS2r
mov RS2rd, RS2rd
cmp $0, RS2r
jne .divuw_branch1
WRITE_RD_VALUE($UINT64_MAX, RS2r)
NEXT_INST
.divuw_branch1:
PUSH_RD_IF_RAX
PUSH_RD_IF_RDX
movq REGISTER_ADDRESS(RS1), %rax
mov %eax, %eax
xorq %rdx, %rdx
divq RS2r
mov %rax, RS2r
POP_RD_IF_RDX
POP_RD_IF_RAX
movslq RS2rd, RS2r
WRITE_RD(RS2r)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_DIVW:
DECODE_R
push RD
movq $INT64_MIN, RD
movq REGISTER_ADDRESS(RS1), RS1
movslq RS1d, RS1
movq REGISTER_ADDRESS(RS2r), RS2r
movslq RS2rd, RS2r
cmp RD, RS1
jne .divw_branch1
cmp $-1, RS2r
jne .divw_branch1
jmp .divw_branch3
.divw_branch1:
cmp $0, RS2r
jne .divw_branch2
movq $UINT64_MAX, RS1
jmp .divw_branch3
.divw_branch2:
MOV_RS1_TO_RAX
cqo
idivq RS2r
MOV_RAX_TO_RS1
.divw_branch3:
pop RD
movslq RS1d, RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_EBREAK:
DECODE_U
mov $CKB_VM_ASM_RET_EBREAK, ARG_RETd
jmp .exit
.p2align 3
.CKB_VM_ASM_LABEL_OP_ECALL:
DECODE_U
mov $CKB_VM_ASM_RET_ECALL, ARG_RETd
jmp .exit
.p2align 3
.CKB_VM_ASM_LABEL_OP_FENCE:
.CKB_VM_ASM_LABEL_OP_FENCEI:
DECODE_U
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_JAL:
DECODE_U
movq PC_ADDRESS, RS1
WRITE_RD(RS1)
/* Loading flag of current instruction */
movq -16(INST_ARGS), TEMP3
sar $24, TEMP3
andq $0xF, TEMP3
shl $1, TEMP3
subq TEMP3, RS1
addq IMMEDIATE, RS1
movq RS1, PC_ADDRESS
jmp .prepare_trace
.p2align 3
.CKB_VM_ASM_LABEL_OP_JALR_VERSION0:
DECODE_I
movq PC_ADDRESS, TEMP1
WRITE_RD(TEMP1)
movq REGISTER_ADDRESS(RS1), TEMP1
addq IMMEDIATE, TEMP1
andq $-2, TEMP1
movq TEMP1, PC_ADDRESS
jmp .prepare_trace
/* RS2r is used as a temporary register here */
.p2align 3
.CKB_VM_ASM_LABEL_OP_JALR_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS2r
movq PC_ADDRESS, TEMP1
WRITE_RD(TEMP1)
addq IMMEDIATE, RS2r
andq $-2, RS2r
movq RS2r, PC_ADDRESS
jmp .prepare_trace
.p2align 3
.CKB_VM_ASM_LABEL_OP_LB_VERSION0:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION0(RS1, 1)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movsbq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LB_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION1(RS1, 1)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movsbq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LBU_VERSION0:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION0(RS1, 1)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movzbq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LBU_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION1(RS1, 1)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movzbq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LD_VERSION0:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION0(RS1, 8)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LD_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION1(RS1, 8)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LH_VERSION0:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION0(RS1, 2)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movswq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LH_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION1(RS1, 2)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movswq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LHU_VERSION0:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION0(RS1, 2)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movzwq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LHU_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION1(RS1, 2)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movzwq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LUI:
.CKB_VM_ASM_LABEL_OP_CUSTOM_LOAD_IMM:
DECODE_U
WRITE_RD(IMMEDIATE)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_CUSTOM_LOAD_UIMM:
DECODE_U
mov IMMEDIATEd, IMMEDIATEd
WRITE_RD(IMMEDIATE)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LW_VERSION0:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION0(RS1, 4)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movslq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LW_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION1(RS1, 4)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
movslq (TEMP1, RS1), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LWU_VERSION0:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION0(RS1, 4)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
mov (TEMP1, RS1), RS1d
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_LWU_VERSION1:
DECODE_I
movq REGISTER_ADDRESS(RS1), RS1
addq IMMEDIATE, RS1
CHECK_READ_VERSION1(RS1, 4)
movq CKB_VM_ASM_ASM_CORE_MACHINE_OFFSET_MEMORY_PTR(MACHINE), TEMP1
mov (TEMP1, RS1), RS1d
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_MUL:
DECODE_R
movq REGISTER_ADDRESS(RS1), RS1
imul REGISTER_ADDRESS(RS2r), RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_MULH:
DECODE_R
PUSH_RD_IF_RAX
PUSH_RD_IF_RDX
movq REGISTER_ADDRESS(RS1), %rax
imulq REGISTER_ADDRESS(RS2r)
MOV_RDX_TO_RS2r
POP_RD_IF_RDX
POP_RD_IF_RAX
WRITE_RD(RS2r)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_MULHSU:
DECODE_R
PUSH_RD_IF_RAX
PUSH_RD_IF_RDX
PUSH_RS1_IF_RAX
PUSH_RS1_IF_RDX
movq REGISTER_ADDRESS(RS1), %rax
test %rax, %rax
jns .mulhsu_branch1
neg %rax
mulq REGISTER_ADDRESS(RS2r)
xor $-1, %rdx
movq %rdx, TEMP1
POP_RS1_IF_RDX
POP_RS1_IF_RAX
movq REGISTER_ADDRESS(RS1), %rax
imulq REGISTER_ADDRESS(RS2r)
test %rax, %rax
setz %al
movzbl %al, %eax
addq %rax, TEMP1
POP_RD_IF_RDX
POP_RD_IF_RAX
WRITE_RD(TEMP1)
NEXT_INST
.mulhsu_branch1:
mulq REGISTER_ADDRESS(RS2r)
movq %rdx, TEMP1
POP_RS1_IF_RDX
POP_RS1_IF_RAX
POP_RD_IF_RDX
POP_RD_IF_RAX
WRITE_RD(TEMP1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_MULHU:
DECODE_R
PUSH_RD_IF_RAX
PUSH_RD_IF_RDX
movq REGISTER_ADDRESS(RS1), %rax
mulq REGISTER_ADDRESS(RS2r)
movq %rdx, RS2r
POP_RD_IF_RDX
POP_RD_IF_RAX
WRITE_RD(RS2r)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_MULW:
DECODE_R
movq REGISTER_ADDRESS(RS1), RS1
movq REGISTER_ADDRESS(RS2r), RS2r
imul RS2rd, RS1d
movslq RS1d, RS1
WRITE_RD(RS1)
NEXT_INST
.p2align 3
.CKB_VM_ASM_LABEL_OP_OR:
DECODE_R
movq REGISTER_ADDRESS(RS1), RS1