generated from netascode/terraform-nxos-scaffolding
-
Notifications
You must be signed in to change notification settings - Fork 0
/
main.tf
192 lines (178 loc) · 7.53 KB
/
main.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
locals {
rd_none = var.route_distinguisher == null ? true : false
rd_auto = var.route_distinguisher == "auto" ? true : false
rd_ipv4 = can(regex("\\.", var.route_distinguisher)) ? true : false
rd_as2 = !can(regex("\\.", var.route_distinguisher)) && can(regex(":", var.route_distinguisher)) ? (tonumber(split(":", var.route_distinguisher)[0]) <= 65535 ? true : false) : false
rd_as4 = !can(regex("\\.", var.route_distinguisher)) && can(regex(":", var.route_distinguisher)) ? (tonumber(split(":", var.route_distinguisher)[0]) >= 65536 ? true : false) : false
rd_dme_format = local.rd_none ? "unknown:unknown:0:0" : (
local.rd_auto ? "rd:unknown:0:0" : (
local.rd_ipv4 ? "rd:ipv4-nn2:${var.route_distinguisher}" : (
local.rd_as2 ? "rd:as2-nn2:${var.route_distinguisher}" : (
local.rd_as4 ? "rd:as4-nn2:${var.route_distinguisher}" : "unexpected_rd_format"
))))
address_family_names_map = {
"ipv4_unicast" : "ipv4-ucast"
"ipv6_unicast" : "ipv6-ucast"
}
# set default values for the map
# change map key
address_family_with_defaults = {
for value in var.address_families : local.address_family_names_map[value.address_family] => {
"route_target_both_auto" = value.route_target_both_auto
"route_target_both_auto_evpn" = value.route_target_both_auto_evpn
"route_target_import" = value.route_target_import
"route_target_export" = value.route_target_export
"route_target_import_evpn" = value.route_target_import_evpn
"route_target_export_evpn" = value.route_target_export_evpn
}
}
# add RT "auto" to import/export lists
address_family_raw = {
for key, value in local.address_family_with_defaults : key => {
"route_target_import_list_raw" = value.route_target_both_auto ? concat(["auto"], value.route_target_import) : value.route_target_import
"route_target_export_list_raw" = value.route_target_both_auto ? concat(["auto"], value.route_target_export) : value.route_target_export
"route_target_import_list_evpn_raw" = value.route_target_both_auto_evpn ? concat(["auto"], value.route_target_import_evpn) : value.route_target_import_evpn
"route_target_export_list_evpn_raw" = value.route_target_both_auto_evpn ? concat(["auto"], value.route_target_export_evpn) : value.route_target_export_evpn
}
}
address_family_flat_all = flatten([
for key, value in local.address_family_raw : [
{
"direction" = "import"
"address_family" = key
"address_family_rt" = key
"rt_set" = toset(value.route_target_import_list_raw)
},
{
"direction" = "export"
"address_family" = key
"address_family_rt" = key
"rt_set" = toset(value.route_target_export_list_raw)
},
{
"direction" = "import"
"address_family" = key
"address_family_rt" = "l2vpn-evpn"
"rt_set" = toset(value.route_target_import_list_evpn_raw)
},
{
"direction" = "export"
"address_family" = key
"address_family_rt" = "l2vpn-evpn"
"rt_set" = toset(value.route_target_export_list_evpn_raw)
}
]
])
# filter only import/export lists with length > 0
# loop for resource "nxos_vrf_route_target_direction"
address_family_map = {
for entry in local.address_family_flat_all :
"${entry.address_family}_${entry.address_family_rt}_${entry.direction}" => entry if length(entry.rt_set) > 0
}
# Route Target converter from CLI format to DME format
rt_helper = {
for k, v in local.address_family_map : k => [
for value in v.rt_set : {
"format_auto" = value == "auto" ? true : false
"format_ipv4" = can(regex("\\.", value)) ? true : false
"format_as2" = !can(regex("\\.", value)) && can(regex(":", value)) ? (tonumber(split(":", value)[0]) <= 65535 ? true : false) : false
"format_as4" = !can(regex("\\.", value)) && can(regex(":", value)) ? (tonumber(split(":", value)[0]) >= 65536 ? true : false) : false
"value" = value
}
]
}
rt_dme_format_map = {
for k, v in local.rt_helper : k => [
for entry in v :
entry.format_auto ? "route-target:unknown:0:0" : (
entry.format_ipv4 ? "route-target:ipv4-nn2:${entry.value}" : (
entry.format_as2 ? "route-target:as2-nn2:${entry.value}" : (
entry.format_as4 ? "route-target:as4-nn2:${entry.value}" : "unexpected_rt_format"
)))
]
}
# Add DME formatted list of RT to the address_family_map
address_family_map_dme = {
for key, value in local.address_family_map : key => merge(value, { "rt_dme_format" : local.rt_dme_format_map[key] })
}
# loop for resource "nxos_vrf_route_target"
address_family_flat_dme = {
for entry in flatten([
for key, value in local.address_family_map_dme : [
for rt in value.rt_dme_format : {
"address_family" = value.address_family
"address_family_rt" = value.address_family_rt
"direction" = value.direction
"rt" = rt
"key" = "${key}_${rt}"
}
]
]) : entry.key => entry }
}
resource "nxos_vrf" "l3Inst" {
count = var.name == "default" ? 0 : 1 # l3Inst is always present for default VRF, can not be deleted
device = var.device
name = var.name
description = var.description
encap = var.vni != null ? "vxlan-${var.vni}" : "unknown"
}
resource "nxos_vrf_routing" "rtctrlDom" {
count = var.name == "default" ? 0 : 1 # no need to create for default VRF
device = var.device
vrf = var.name
route_distinguisher = local.rd_dme_format
depends_on = [
nxos_vrf.l3Inst
]
}
resource "nxos_vrf_address_family" "rtctrlDomAf" {
for_each = local.address_family_with_defaults
device = var.device
vrf = var.name
address_family = each.key
depends_on = [
nxos_vrf_routing.rtctrlDom
]
}
resource "nxos_vrf_route_target_address_family" "rtctrlAfCtrl" {
for_each = {
for entry in toset([for i in local.address_family_map : "${i.address_family}_${i.address_family_rt}"]) : entry => {
"address_family" = split("_", entry)[0]
"address_family_rt" = split("_", entry)[1]
}
}
device = var.device
vrf = var.name
address_family = each.value.address_family
route_target_address_family = each.value.address_family_rt
depends_on = [
nxos_vrf_address_family.rtctrlDomAf
]
}
resource "nxos_vrf_route_target_direction" "rtctrlRttP" {
for_each = local.address_family_map
device = var.device
vrf = var.name
address_family = each.value.address_family
route_target_address_family = each.value.address_family_rt
direction = each.value.direction
depends_on = [
nxos_vrf_route_target_address_family.rtctrlAfCtrl
]
}
resource "nxos_vrf_route_target" "rtctrlRttEntry" {
for_each = local.address_family_flat_dme
device = var.device
vrf = var.name
address_family = each.value.address_family
route_target_address_family = each.value.address_family_rt
direction = each.value.direction
route_target = each.value.rt
depends_on = [
nxos_vrf_route_target_direction.rtctrlRttP
]
}
resource "nxos_ipv4_vrf" "ipv4Dom" {
device = var.device
name = var.name
}