-
Notifications
You must be signed in to change notification settings - Fork 8
/
bash.ohm
186 lines (146 loc) · 4.57 KB
/
bash.ohm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
Bash {
Script
= (Shebang)? allwhitespace* CmdSequence? semicolon*
CmdSequence = NonemptyListOf<Cmd, semicolon>
Shebang = "#!" (~"sh" any)* "sh\n"
Cmd = FunctionDecl
| CodeBlock
| IfCommand
| comment
| ForCommand
| WhileCommand
| CmdWithComment
| PipeCmd
| Export
| Assignment
| SimpleCmd
| CaseCommand
| ("" ~keyword)
IfCommand
= IfCase ElseIfThen* ElseCase? EndIf
IfCase
= "if" #(allwhitespace+) Conditional semicolon "then" #(allwhitespace+) CmdSequence
ElseIfThen
= semicolon "elif" #(allwhitespace+) Conditional semicolon "then" #(allwhitespace+) CmdSequence
ElseCase
= semicolon "else" #(allwhitespace+) CmdSequence
EndIf = semicolon "fi"
Conditional
= TestCmd -- test
| SimpleCmd -- cmd
ForCommand
= "for" "((" ControlStruct "))" semicolon "do" #(allwhitespace+) CmdSequence Done
-- c_style
| "for" id "in" (Call | arrayReference) semicolon "do" #(allwhitespace+) CmdSequence Done -- for_each
ControlStruct
= Assignment ";" id BinaryOp Bashword ";" (~")" Bashword)
WhileCommand
= "while" #(allwhitespace+) Conditional semicolon "do" #(allwhitespace+) CmdSequence Done
Done = semicolon "done"
FunctionDecl
= ("function" #(space+))? id_std "()" allwhitespace* CodeBlock // "foo()"
| "function" #(space+) id_std "()"? allwhitespace* CodeBlock // "function foo"
CodeBlock
= "{" allwhitespace* CmdSequence allwhitespace* "}"
CaseCommand
= "case" Bashword "in" #(allwhitespace+) NonemptyListOf<CaseCase, #(allwhitespace+)> #(allwhitespace+) "esac"
CaseCase
= NonemptyListOf<Bashword, "|"> ")" #(allwhitespace*) ListOf<Cmd, (~";;" semicolon)> #(allwhitespace*) (";;" | ";&") comment?
BinaryOp (Binary infix operator)
= "==" | "=" | "-eq"
| "!=" | "-ne"
| "-lt" | "\\<"
| "-gt" | "\\>"
| "-le"
| "-ge"
UnaryOp (Unary operator)
= "-z" | "-n" | "-b" | "-c" | "-d" | "-e" | "-f" | "-L" | "-p" | "-S"
SequenceCmd
= Cmd semicolon Cmd -- std
| Cmd semicolon -- null
PipeCmd = (PipeCmd | SimpleCmd) "|" allwhitespace* (PipeCmd | SimpleCmd)
CmdWithComment
= SimpleCmd comment
SimpleCmd
= SimpleCmdBase Redirect* "&"?
Redirect
= ">" Bashword
| ">>" Bashword
SimpleCmdBase
= TestCmd
| CmdName Bashword* -- std
TestCmd
= "test " TestInsides -- cmd
| #("[[" space+) TestInsides "]]" -- doubleBracket
| #("[" space+) TestInsides "]" -- singleBracket
TestInsides
= "!"? UnaryOp Bashword -- unary
| "!"? Bashword BinaryOp Bashword -- binary
| "!"? Bashword -- str
CmdName = (~keyword Bashword #(~alnum))
comment = space* "#" (~"\n" any)*
/* modOptions = ("-" |"+" ) letter+ */
Bashword
= Call
| ArrayLiteral
| arrayLength
| arrayReference
| number
| bareWord
ArrayLiteral
= "(" allwhitespace* (Bashword allwhitespace*)* ")"
Call
= "$(" Cmd ")"
| "\"$(" Cmd ")\""
| "`" Cmd "`"
| "\"`" Cmd "`\""
arrayReference
= "${" id "[@]}"
| "\"${" id "[@]}\""
arrayLength
= "${#" id "[@]}"
reference
= "$" id -- simple
| "${" id "}" -- wrapped
| "${" id ":" digit+ ":"? digit* "}" -- substr
| "${" id ("//" | "/") alnum* "/"? alnum* "}" -- substit
| "${#" id "}" -- length
number
= "-"? digit+
bareWord
= barewordChar+
barewordChar
= stringLiteral -- str
| (~(badchars | "\\") (reference | any)) -- normal
| "\\" any -- escape
keyword
= keywordRoot ~alnum
keywordRoot
= "case" | "esac" | "if" | "then" | "else" | "elif" | "fi" | "for" | "done" | "do" | "function"
stringLiteral
= singleString
| doubleString
singleString = "'" notSingleQuote* "'"
doubleString = "\"" notDoubleQuote* "\""
notSingleQuote
= (~"'" any)
| "\\" any -- escape
notDoubleQuote
= (~("\"" | "\\") (reference | any))
| "\\" any -- escape
badchars = allwhitespace | "|" | ";" | ">" | "#" | "'" | "\"" | "`" | "(" | ")" | "&" | "{" | "}"
Export
= "export " Assignment -- assign
| "export " id -- bare
Assignment
= ("local " | "readonly ")? #(id_std "=" ~space) Bashword?
id = (~keyword (letter | "_") (alnum | "_")*) -- std
| digit+ -- arg
| "?" -- error
| "#" -- argLength
space := " " | "\t"
allwhitespace = space | "\n"
semicolon
= ";"* "\n" -- both
| ";"+
}