-
Notifications
You must be signed in to change notification settings - Fork 1
/
core.clj
651 lines (577 loc) · 27.9 KB
/
core.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
(ns meta-csv.core
(:require [clojure.java.io :as io]
[clojure.string :as str]
[clojure.spec.alpha :as s])
(:import [de.siegmar.fastcsv.reader CsvReader CsvRow CsvParser]
[de.siegmar.fastcsv.writer CsvWriter]
[java.nio.charset Charset]
[com.ibm.icu.text CharsetDetector]
[java.io Reader BufferedReader]))
(def default-preprocess-fn str/trim)
(def default-postprocess-fn identity)
(defn default-write-fn
[v]
(cond (keyword? v) (name v)
(symbol? v) (name v)
(string? v) v
:else (str v)))
(defn ^:no-doc integer-string?
[s]
(boolean (re-matches #"-?\d+" s)))
(defn ^:no-doc float-string?
[s]
(boolean (re-matches #"-?\d[\d\p{Zs}']*([\.,][\d\p{Zs}']*\d)?" s)))
(defn ^:no-doc percent-string?
[s]
(boolean (re-matches #"-?\d+([\.,]\d+)?\s*%\s*$" s)))
(def base-types
{:long {:predicate integer-string?
:coercer #(when (> (count %) 0)
(Long/parseLong %))
:priority 0}
:double {:predicate float-string?
:coercer #(-> %
(str/replace #"[\p{Sc}\s]+" "")
(cond-> (not (re-find #"\." %)) (str/replace #"," "."))
(cond-> (re-find #"\." %) (str/replace #"\,+" ""))
(Double/parseDouble))
:priority 1}
:percent {:predicate percent-string?
:coercer (fn [s] (let [[num-str] (re-find #"-?\d[\d\p{Zs}']*([\.,][\d\p{Zs}']*\d)?" s)
num (Double/parseDouble num-str)]
(/ num 100.0)))
:priority 2}
:string {:predicate string?
:coercer identity
:priority 3}})
(def ^:no-doc other-types
{:float {:predicate float-string?
:coercer #(Float/parseFloat %)}
:integer {:predicate integer-string?
:coercer #(Integer/parseInt %)}})
(def ^:no-doc synonym-types
{:int (:integer other-types)
:str (:string base-types)})
(def ^:no-doc guessable-csv-types base-types)
(def ^:no-doc csv-types (merge base-types other-types synonym-types))
(def ^:no-doc available-charsets (into #{} (.keySet (Charset/availableCharsets))))
(defn ^:no-doc guess-charset
[^java.io.InputStream is]
(try
(let [^CharsetDetector detector (CharsetDetector.)]
(.enableInputFilter detector true)
(.setText detector is)
(let [m (.detect detector)
encoding (.getName m)]
(if (available-charsets encoding)
encoding
"utf-8")))
(catch Exception _
"utf-8")))
(def ^:no-doc boms
{[(byte -1) (byte -2)] [:utf16-le 2]
[(byte -2) (byte -1)] [:utf16-be 2]
[(byte -17) (byte -69) (byte -65)] [:utf8 3]
[(byte -1) (byte -2) (byte 0) (byte 0)] [:utf32-le 4]
[(byte 0) (byte 0) (byte -2) (byte -1)] [:utf32-be 4]
[] [:none 0]})
(def ^:no-doc bom-names
(reduce (fn
[acc [_ [bom-name _]]]
(conj acc bom-name))
#{} boms))
(def ^:no-doc bom-sizes
(reduce (fn
[acc [_ [bom-name bom-size]]]
(assoc acc bom-name bom-size))
{} boms))
(def ^:no-doc bom-bytes
(reduce (fn
[acc [bts [bom-name _]]]
(assoc acc bom-name bts))
{} boms))
(defn ^:no-doc skip-bom-from-stream-if-present
[^java.io.InputStream stream]
(let [pbis (java.io.PushbackInputStream. stream 4)
bom (byte-array 4)]
(.read pbis bom)
(let [[a b c _ :as first-four] (into [] (seq bom))
first-two [a b]
first-three [a b c]
[bom-name bom-size] (or (boms first-two) (boms first-three) (boms first-four))]
(if bom-size
(let [to-put-back (byte-array (drop bom-size bom))]
(.unread pbis to-put-back)
[(io/input-stream pbis) bom-name])
(do
(.unread pbis bom)
[(io/input-stream pbis) :none])))))
(defn ^:no-doc get-reader
([src encoding bom]
(if (instance? java.io.Reader src)
[src (fn [& _] nil) encoding nil]
(let [[^java.io.InputStream raw-stream close-fn] (if (instance? java.io.InputStream src)
[src (fn [& _] nil)]
(let [istream (io/input-stream src)]
[istream
(fn [& args]
(.close istream)
(doseq [^java.lang.AutoCloseable arg args]
(.close arg))
true)]))
enc (or encoding (guess-charset raw-stream))
[^java.io.InputStream istream bom-name] (if (nil? bom)
(skip-bom-from-stream-if-present raw-stream)
(do (.read raw-stream (byte-array (get bom-sizes bom 0)))
[raw-stream bom]))
rdr (io/reader istream :encoding enc)]
[rdr close-fn enc bom-name])))
([src encoding] (get-reader src encoding nil))
([src] (get-reader src nil nil)))
(defmacro ^:private ^:no-doc sdef-enum
[nam enum]
`(s/def ~nam ~(eval enum)))
(s/def :meta-csv.core.field/field (s/or :string string? :keyword keyword?))
(sdef-enum :meta-csv.core.field/type (into #{} (keys csv-types)))
(s/def :meta-csv.core.field/preprocess-fn fn?)
(s/def :meta-csv.core.field/postprocess-fn fn?)
(s/def :meta-csv.core.field/write-fn fn?)
(s/def :meta-csv.core.field/skip? boolean?)
(s/def ::field-definition (s/or
:full-spec (s/keys :opt-un [:meta-csv.core.field/field
:meta-csv.core.field/type
:meta-csv.core.field/preprocess-fn
:meta-csv.core.field/postprocess-fn
:meta-csv.core.field/write-fn
:meta-csv.core.field/skip?])
:field-name :meta-csv.core.field/field
:skip-field nil?))
(s/def ::fields-definition-list (s/coll-of ::field-definition :min-count 1))
(defn ^:no-doc is-header?
[line schema]
(if (> (count (filter nil? line)) 0)
false
(loop [todo schema
idx 0]
(if-let [{:keys [type]} (first todo)]
(let [v (get line idx)
{:keys [predicate]} (csv-types type)]
(if (#{:string :str} type)
(recur (rest todo) (inc idx))
(if (predicate v)
(recur (rest todo) (inc idx))
true)))
false))))
(defn ^:no-doc is-quoted?
[lines delimiter]
(let [quoted-delim (java.util.regex.Pattern/quote (str delimiter))
regexp (re-pattern (str (format "\"%s|%s\"" quoted-delim quoted-delim)))]
;; skip the first line in case it's a header
(every? #(re-find regexp %) (take 10 (rest lines)))))
(defn ^:no-doc find-char-pos
[^String line char]
(loop [found []
cur 0]
(let [pos (.indexOf line (int char) cur)]
(if (not= pos -1)
(recur (conj found pos) (inc pos))
found))))
(defn ^:no-doc guess-delimiter
[lines]
(let [all-dels (for [line lines
:let [clean-line (str/replace line #"\"[^\"]*\"" "")]]
(into {}
(map
(fn [character]
[character
(count (find-char-pos clean-line character))])
[\, \; \space \tab \|])))
freqs (first all-dels)
report (loop [todo all-dels
candidates (into {}
(map (fn [k] [k 0]) (keys (first all-dels))))]
(if-let [dels (first todo)]
(let [diffs (filter
(fn [[k v]] (or (= v 0) (not= v (freqs k))))
dels)]
(recur (rest todo) (reduce (fn [acc k]
(update-in acc [k] #(if % (inc %) 1)))
candidates (map first diffs))))
candidates))
[[fc fv] [_ sv] & _] (sort-by (fn [[_ v]] v) report)]
(when (or (<= fv sv) (nil? sv))
fc)))
(defn ^:no-doc make-csv-reader
^CsvReader [{:keys [delimiter skip-empty-rows? header?
text-delimiter error-on-different-field-count?]}]
(let [^CsvReader reader (CsvReader.)]
(when delimiter (.setFieldSeparator reader delimiter))
(when skip-empty-rows? (.setSkipEmptyRows reader true))
(when header? (.setContainsHeader reader true))
(when text-delimiter (.setTextDelimiter reader text-delimiter))
(when error-on-different-field-count? (.setErrorOnDifferentFieldCount reader true))
reader))
(defn row->clj
[^CsvRow row {:keys [fields field-names-fn named-fields? skip null]
:or {skip 0}}]
(try
(loop [todo fields
row-idx 0
idx 0
acc (transient [])]
(if (seq todo)
(let [{:keys [field type skip? postprocess-fn preprocess-fn]
:or {postprocess-fn default-postprocess-fn
preprocess-fn default-preprocess-fn} :as spec} (first todo)]
(if (or skip? (nil? spec))
(recur (rest todo) (inc row-idx) idx acc)
(let [kname (if named-fields? (field-names-fn field) idx)
^String v (.getField row row-idx)
preproc-v (preprocess-fn v)
filter-v (if (and null preproc-v
(if (set? null) (null preproc-v) (= preproc-v null)))
nil
preproc-v)
{:keys [coercer]} (type csv-types)
coerced (if (and filter-v (not (.isEmpty filter-v)))
(coercer preproc-v)
nil)
transformed (when coerced (postprocess-fn coerced))]
(recur (rest todo)
(inc row-idx)
(inc idx)
(if named-fields?
(-> acc (conj! kname) (conj! transformed))
(assoc! acc kname transformed))))))
(with-meta
(if named-fields?
(apply array-map (persistent! acc))
(persistent! acc))
{::original-line-number (+ skip (.getOriginalLineNumber row))})))
(catch Exception e
(throw (ex-info (format "Error reading row %d" (+ skip (.getOriginalLineNumber row)))
{:line-number (+ skip (.getOriginalLineNumber row))}
e)))))
(defn ^:no-doc parse-fields
[lines delimiter]
(let [txt (str/join "\n" lines)]
(with-open [rdr (java.io.StringReader. txt)]
(let [csv-rdr (make-csv-reader {:delimiter delimiter})
seg-lines (map (fn [^CsvRow row] (into [] (.getFields row))) (.getRows (.read csv-rdr rdr)))]
seg-lines))))
(defn ^:no-doc take-higher-priority
[cands]
(if (empty? cands)
{:type :string}
(key (first (sort-by (comp :priority val) cands)))))
(defn ^:no-doc guess-types
[lines]
(for [offset (range (count (first lines)))]
(loop [todo lines
candidates guessable-csv-types
not-nil 0]
(if-let [line (first todo)]
(let [field (nth line offset)
valid (reduce (fn [acc [type {:keys [predicate] :as cand}]]
(if (or (nil? field) (predicate field))
(assoc acc type cand)
acc))
{} candidates)
new-nil (if (nil? field) not-nil (inc not-nil))]
(recur (rest todo) valid new-nil))
(if (> not-nil (* 0.5 (count lines)))
{:type (take-higher-priority candidates)}
{:type :string})))))
(defn ^:no-doc analyze-csv
[uri lookahead]
(when (instance? Reader uri)
(let [^Reader rdr uri]
(if (.markSupported rdr)
(.mark rdr 1000000)
(throw (Exception. "Cannot analyze csv from unmarkable reader")))))
(let [^java.io.BufferedReader rdr (io/reader uri)]
(try
(let [lines (loop [ls []]
(if-let [line (.readLine rdr)]
(if (< (count ls) lookahead)
(recur (conj ls line))
ls)
ls))
delimiter (guess-delimiter lines)
seg-lines (parse-fields lines delimiter)
fields-schema (guess-types (rest seg-lines))
has-header? (is-header? (first seg-lines) fields-schema)
quoted? (is-quoted? lines delimiter)]
(when (instance? Reader uri)
(let [^Reader typed-rdr uri]
(.reset typed-rdr)))
{:delimiter delimiter :fields fields-schema :header? has-header? :quoted? quoted?
:possible-header (first seg-lines)})
(finally
(if-not (instance? Reader uri)
(.close rdr))))))
(defn ^:no-doc normalize-fields-schema
[schema]
(cond
(sequential? schema) (mapv (fn [x] (cond
(keyword? x) {:field x}
(string? x) {:field x}
:else x))
schema)
(map? schema) schema
:else nil))
(defn ^:no-doc normalize-csv-options
[{:keys [field-names-fn fields] :as opts}]
(-> opts
(cond-> (not field-names-fn) (assoc :field-names-fn identity))
(cond-> fields (assoc :fields (normalize-fields-schema (:fields opts))))))
(defn ^:no-doc defined-name?
[v]
(cond (string? v) (> (.length ^String v) 0)
(keyword? v) true
:else false))
(s/def :meta-csv.core.reader-option/header? boolean?)
(s/def :meta-csv.core.reader-option/sample-size integer?)
(s/def :meta-csv.core.reader-option/guess-types? boolean?)
(s/def :meta-csv.core.reader-option/skip integer?)
(s/def :meta-csv.core.reader-option/null (s/or :string string?
:set set?))
(s/def :meta-csv.core.reader-option/fields ::fields-definition-list)
(sdef-enum :meta-csv.core.reader-option/encoding (into #{} (map str/lower-case available-charsets)))
(sdef-enum :meta-csv.core.reader-option/bom bom-names)
(s/def :meta-csv.core.reader-option/field-names-fn fn?)
(s/def :meta-csv.core.reader-option/delimiter #(instance? Character %))
(s/def ::guess-spec-args (s/keys :opt-un [:meta-csv.core.reader-option/header?
:meta-csv.core.reader-option/sample-size
:meta-csv.core.reader-option/guess-types?
:meta-csv.core.reader-option/skip
:meta-csv.core.reader-option/fields
:meta-csv.core.reader-option/encoding
:meta-csv.core.reader-option/bom
:meta-csv.core.reader-option/field-names-fn
:meta-csv.core.reader-option/delimiter
:meta-csv.core.reader-option/null]))
(s/def ::csv-source (s/or :java-reader #(instance? Reader %)
:java-input-stream #(instance? java.io.InputStream %)
:uri string?))
(s/def :meta-csv.core.reader-option/skip-analysis? boolean?)
(s/def ::read-csv-args (s/merge
::guess-spec-args
(s/keys :opt-un [:meta-csv.core.reader-option/skip-analysis?])))
(s/fdef guess-spec
:args (s/cat :input ::csv-source
:options (s/? ::guess-spec-args))
:ret ::read-csv-args)
(defn guess-spec
"This function takes a source of csv lines (either a *Reader*, *InputStream* or *String* URI)
and tries to guess the specs necessary to parse it. You can use the option map to specify some values
for the spec. Recognised options are:
*Analysis options*
+ **:header?**: Whether the file has a header on the first line
+ **:sample-size**: number of lines on which heuristics are applied. Defaults to *100*
+ **:guess-types?**: Whether to try to guess types for each field. Defaults to *true*
+ **:skip**: Number of lines to skip before starting to parse. Defaults to 0
*Schema options*
In a **:fields** key, the seq of fields specs you want to override in the inference process.
Mostly used to specify manually name of column or type for special needs. The same effect cab be had by editing the resulting spec.
Fields specs are maps with the following keys:
+ **:field**: The name of the column in the results
+ **:type**: the type to use for coercing the value. Can be one of (:float :percent :double :long :integer :string)
A *nil* field spec means to skip this column in the results.
An empty map means full inference for this field.
A *Keyword* or *String* instead of a map simply defines the name of the column in the results.
Example:
```clojure
{:fields [{:type :string :field :my-field-name} nil {} {:type :float :field :my-float-field}]}
```
*File options*
+ **:encoding**: Character encoding for the file
*Processing options*
+ **:field-names-fn**: fn to apply to the name of each field. Defaults to trim function
*Format options*
+ **:delimiter**: Character used as a delimiter"
([uri
{:keys [header? fields field-names-fn encoding
guess-types? delimiter
sample-size bom skip]
:or {guess-types? true
sample-size 100
skip 0}
:as opts}]
(let [norm-opts (normalize-csv-options opts)
fields-seq (:fields norm-opts)
[^BufferedReader rdr clean-rdr enc bom-name] (get-reader uri encoding bom)]
(try
(when (and skip (> skip 0)) (dotimes [_ skip] (.readLine rdr)))
(let [{guessed-schema :fields
guessed-delimiter :delimiter
guessed-header :header?
guessed-quote :quoted?
:as analysis} (try
(analyze-csv rdr sample-size)
(catch Exception e
(throw e)
{}))
given-field-names? (some boolean (map :field (:fields norm-opts)))
vec-output? (or (and (not given-field-names?) (false? header?))
(and (not given-field-names?) (not guessed-header) (not header?)))
fnames (when-not vec-output?
(if (and fields-seq (every? #(or (:field %) (nil? %)) fields-seq))
(map :field fields-seq)
(when (or header? guessed-header given-field-names?)
(let [raw-headers (:possible-header analysis)
fname-fn (cond
field-names-fn field-names-fn
(false? header?) (if (every? keyword?
(remove nil?
(map :field fields-seq)))
keyword
identity)
(not (some (fn [col]
(if (nil? col)
false
(re-find #"[\s':\\/@\(\)]" col))) raw-headers)) keyword
:else identity)]
(for [[idx raw-header] (map-indexed (fn [idx v] [idx v]) raw-headers)
:let [trimmed-header (if (seq raw-header)
(str/trim raw-header)
::null)
given-field (nth fields-seq idx ::not-found)
given-field-label (:field given-field ::not-found)]]
(cond
(and given-field
(not (or (map? given-field) (= ::not-found given-field))))
(:field given-field)
(and (or (= trimmed-header ::null) (false? header?))
(= given-field-label ::not-found)) (fname-fn (str "col" idx))
trimmed-header (fname-fn trimmed-header)
(= given-field ::not-found) nil))))))
full-schema (for [idx (range (max ((fnil count []) (:fields norm-opts))
((fnil count []) fnames)
((fnil count []) guessed-schema)))]
(let [guessed-type (nth guessed-schema idx ::not-found)
given-field (nth fields-seq idx ::not-found)
label (nth fnames idx ::not-found)]
(if (or (nil? label) (nil? given-field))
nil
(-> {}
(cond-> (not= label ::not-found) (assoc :field label))
(cond-> (and guess-types? (not= guessed-type ::not-found))
(merge guessed-type))
(cond-> (not= given-field ::not-found) (merge given-field))
(update :type #(if (keyword? %) % :string))))))]
{:fields (into [] full-schema) :delimiter (or delimiter guessed-delimiter) :bom bom-name
:encoding enc :skip-analysis? true :header? (if (nil? header?) guessed-header header?)
:quoted? guessed-quote})
(finally
(clean-rdr rdr)))))
([uri] (guess-spec uri {})))
(defn ^:no-doc parse-csv
[^java.io.Reader rdr clean-rdr csv-opts]
(let [csv-rdr (make-csv-reader csv-opts)
lazy-parse-csv (fn lazy-parse-csv [^CsvParser parser]
(lazy-seq
(if-let [row (.nextRow parser)]
(cons (row->clj row csv-opts) (lazy-parse-csv parser)))))]
(lazy-parse-csv (.parse csv-rdr rdr))))
(s/fdef read-csv
:args (s/cat :input ::csv-source
:options (s/? ::read-csv-args)))
(defn read-csv
"This function takes a source of csv lines (either a *Reader*, *InputStream* or *String* URI)
and returns the parsed results. If headers are found on the file or field names where given
as options, it will return a collection of one map per line, associating each field name with
its value. If not, one vector will be returned for each line, in order.
You can use the option map to specify some values for the spec. Recognised options are:
*Analysis options*
+ **header?**: Whether the file has a header on the first line
+ **sample-size**: number of lines on which heuristics are applied. Defaults to *100*
+ **guess-types?**: Whether to try to guess types for each field. Defaults to *true*
+ **skip-analysis?**: Whether to completely bypass analysis and only use spec
Defaults to *false*
+ **skip**: Number of lines to skip before starting to parse. Defaults to 0
+ **null**: String or set of strings to be coerced to nil
*Schema options*
In a **:fields** key, the seq of fields specs you want to override in the inference process.
Mostly used to specify manually name of column or type for special needs.
Fields specs are maps with the following keys:
+ **:field**: The name of the column in the results
+ **:type**: the type to use for coercing the value. Can be one of :float :percent :double :long :integer :string
+ **:preprocess-fn**: function applied to value as strings, before type coercion. Defaults to (fn [^String v] str/trim)
+ **:postprocess-fn**: function applied to values after type coercion. Defaults to *identity*
A *nil* field spec means to skip this column in the results.
An empty map means full inference for this field.
A *Keyword* or *String* instead of a map simply defines the name of the column in the results.
Example:
```clojure
{:fields [{:type :string :field :my-field-name} nil {} {:type :float :field :my-float-field}]}
```
*Processing options*
+ **field-names-fn**: fn to apply to the name of each field. Can be used to sanitize header
names. Defaults to trim function
*Format options*
+ **delimiter**: Character used as a delimiter"
([uri
{:keys [header? field-names-fn fields encoding
guess-types?
skip-analysis?
bom skip null]
:or {guess-types? true
skip 0}
:as opts}]
(let [{:keys [header? fields field-names-fn encoding
guess-types? greedy?
limit skip-analysis? bom]
:or {guess-types? true
field-names-fn str/trim}
:as full-spec} (normalize-csv-options
(if skip-analysis?
opts
(do
(when-not (or (instance? String uri)
(instance? java.io.File uri))
(throw (ex-info "Cannot guess the specs of inputs that are neither String path nor File" {:uri uri})))
(guess-spec uri opts))))
[^BufferedReader rdr clean-rdr _] (get-reader uri encoding bom)]
(try
(let [given-field-names? (some boolean (map :field (:fields full-spec)))
named-fields? (or header? given-field-names?)
csv-opts (merge opts full-spec {:named-fields? named-fields?})
_ (when (and skip (> skip 0)) (dotimes [_ skip] (.readLine rdr)))
csv-seq (parse-csv rdr clean-rdr csv-opts)]
csv-seq)
(catch Exception e
(clean-rdr rdr)
(throw e)))))
([uri] (read-csv uri {})))
;; (defn write-csv
;; [input data {:keys [encoding fields delimiter headers?]
;; :or {encoding "utf-8"
;; delimiter \;}
;; :as opts}]
;; (let [norm-fields (normalize-fields-schema fields)
;; named-fields? (map? (first fields))
;; given-header-fields (when (every? :field norm-fields)
;; (map :field norm-fields))
;; extracted-header-fields (when (map? fields)
;; (sort-by :field (map (fn [k v] (assoc v :field k)) fields)))
;; actual-headers (or given-header-fields extracted-header-fields)
;; [writer clean-writer] (if (instance? java.io.Writer input)
;; [input (constantly true)]
;; (let [wrt (io/writer input :encoding encoding)]
;; [wrt #(.close wrt)]))
;; with-headers? (if (not (nil? headers?))
;; headers?
;; (boolean actual-headers))
;; process-row (if named-fields?
;; (fn [r]
;; (reduce (fn [acc {:keys [field key]}]
;; ())
;; (transient {}) )))
;; csv-writer (CsvWriter.)]
;; (.setFieldSeparator csv-writer delimiter)
;; (let [appender (.append csv-writer writer)]
;; (when with-headers?
;; (.appendLine appender (map name actual-headers)))
;; (doseq [line data]
;; (.appendLine appender data)))))