This repository has been archived by the owner on Feb 11, 2022. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 28
/
CheckstyleConfigurator.groovy
83 lines (73 loc) · 3.17 KB
/
CheckstyleConfigurator.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
package com.novoda.staticanalysis.internal.checkstyle
import com.novoda.staticanalysis.EvaluateViolationsTask
import com.novoda.staticanalysis.internal.CodeQualityConfigurator
import com.novoda.staticanalysis.internal.QuietLogger
import groovy.util.slurpersupport.GPathResult
import org.gradle.api.Action
import org.gradle.api.Project
import org.gradle.api.plugins.quality.Checkstyle
import org.gradle.api.plugins.quality.CheckstyleExtension
import org.gradle.internal.logging.ConsoleRenderer
class CheckstyleConfigurator extends CodeQualityConfigurator<Checkstyle, CheckstyleExtension> {
CheckstyleConfigurator(Project project, EvaluateViolationsTask evaluateViolationsTask) {
super(project, evaluateViolationsTask.maybeCreate('Checkstyle'), evaluateViolationsTask)
}
@Override
protected String getToolName() {
'checkstyle'
}
@Override
protected Class<CheckstyleExtension> getExtensionClass() {
CheckstyleExtension
}
@Override
protected Action<CheckstyleExtension> getDefaultConfiguration() {
new Action<CheckstyleExtension>() {
@Override
void execute(CheckstyleExtension checkstyleExtension) {
checkstyleExtension.toolVersion = '7.1.2'
}
}
}
@Override
protected Class<Checkstyle> getTaskClass() {
Checkstyle
}
@Override
protected void configureAndroidProject(Object variants) {
project.with {
variants.all { variant ->
variant.sourceSets.each { sourceSet ->
def taskName = "checkstyle${sourceSet.name.capitalize()}"
Checkstyle task = tasks.findByName(taskName)
if (task == null) {
task = tasks.create(taskName, Checkstyle)
task.with {
description = "Run Checkstyle analysis for ${sourceSet.name} classes"
source = sourceSet.java.srcDirs
classpath = files("$buildDir/intermediates/classes/")
}
}
sourceFilter.applyTo(task)
task.mustRunAfter variant.javaCompile
}
}
}
}
@Override
protected void configureReportEvaluation(Checkstyle checkstyle) {
checkstyle.showViolations = false
checkstyle.ignoreFailures = true
checkstyle.metaClass.getLogger = { QuietLogger.INSTANCE }
checkstyle.doLast {
File xmlReportFile = checkstyle.reports.xml.destination
File htmlReportFile = new File(xmlReportFile.absolutePath - '.xml' + '.html')
GPathResult xml = new XmlSlurper().parse(xmlReportFile)
int errors = xml.'**'.findAll { node -> node.name() == 'error' && node.@severity == 'error' }.size()
int warnings = xml.'**'.findAll { node -> node.name() == 'error' && node.@severity == 'warning' }.size()
String reportUrl = new ConsoleRenderer().asClickableFileUrl(htmlReportFile ?: xmlReportFile)
violations.addViolations(errors, warnings, reportUrl)
}
evaluateViolations.dependsOn checkstyle
}
}