This repository has been archived by the owner on Feb 11, 2022. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 28
/
FindbugsConfigurator.groovy
142 lines (124 loc) · 5.61 KB
/
FindbugsConfigurator.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
package com.novoda.staticanalysis.internal.findbugs
import com.novoda.staticanalysis.EvaluateViolationsTask
import com.novoda.staticanalysis.internal.CodeQualityConfigurator
import org.gradle.api.Action
import org.gradle.api.Project
import org.gradle.api.file.ConfigurableFileTree
import org.gradle.api.file.FileCollection
import org.gradle.api.plugins.quality.FindBugs
import org.gradle.api.plugins.quality.FindBugsExtension
import org.gradle.api.tasks.SourceSet
import org.gradle.internal.logging.ConsoleRenderer
import java.nio.file.Path
class FindbugsConfigurator extends CodeQualityConfigurator<FindBugs, FindBugsExtension> {
FindbugsConfigurator(Project project, EvaluateViolationsTask evaluateViolations) {
super(project, evaluateViolations.maybeCreate('Findbugs'), evaluateViolations)
}
@Override
protected String getToolName() {
'findbugs'
}
@Override
protected Object getToolPlugin() {
QuietFindbugsPlugin
}
@Override
protected Class<FindBugsExtension> getExtensionClass() {
FindBugsExtension
}
@Override
protected Class<FindBugs> getTaskClass() {
FindBugs
}
@Override
protected Action<FindBugsExtension> getDefaultConfiguration() {
new Action<FindBugsExtension>() {
@Override
void execute(FindBugsExtension findBugsExtension) {
findBugsExtension.toolVersion = '3.0.1'
}
}
}
@Override
protected void configureAndroidProject(Object variants) {
variants.all { variant ->
FindBugs task = project.tasks.create("findbugs${variant.name.capitalize()}", QuietFindbugsPlugin.Task)
List<File> androidSourceDirs = variant.sourceSets.collect { it.javaDirectories }.flatten()
task.with {
description = "Run FindBugs analysis for ${variant.name} classes"
source = androidSourceDirs
classpath = variant.javaCompile.classpath
}
sourceFilter.applyTo(task)
task.conventionMapping.map("classes", {
List<String> includes = createIncludePatterns(task.source, androidSourceDirs)
project.fileTree(variant.javaCompile.destinationDir).include(includes)
}.memoize());
task.dependsOn variant.javaCompile
}
}
@Override
protected void configureJavaProject() {
project.sourceSets.each { SourceSet sourceSet ->
String taskName = sourceSet.getTaskName(toolName, null)
FindBugs task = project.tasks.findByName(taskName)
if (task != null) {
sourceFilter.applyTo(task)
task.conventionMapping.map("classes", {
List<File> sourceDirs = sourceSet.allJava.srcDirs.findAll { it.exists() }.toList()
List<String> includes = createIncludePatterns(task.source, sourceDirs)
createClassesTreeFrom(sourceSet).include(includes)
}.memoize());
}
}
}
private static List<String> createIncludePatterns(FileCollection sourceFiles, List<File> sourceDirs) {
List<Path> includedSourceFilesPaths = sourceFiles.matching { '**/*.java' }.files.collect { it.toPath() }
List<Path> sourceDirsPaths = sourceDirs.collect { it.toPath() }
createRelativePaths(includedSourceFilesPaths, sourceDirsPaths)
.collect { Path relativePath -> (relativePath as String) - '.java' + '*' }
}
private static List<Path> createRelativePaths(List<Path> includedSourceFiles, List<Path> sourceDirs) {
includedSourceFiles.collect { Path sourceFile ->
sourceDirs
.findAll { Path sourceDir -> sourceFile.startsWith(sourceDir) }
.collect { Path sourceDir -> sourceDir.relativize(sourceFile) }
}
.flatten()
}
/**
* The simple "classes = sourceSet.output" may lead to non-existing resources directory
* being passed to FindBugs Ant task, resulting in an error
* */
private ConfigurableFileTree createClassesTreeFrom(SourceSet sourceSet) {
project.fileTree(sourceSet.output.classesDir, {
it.builtBy(sourceSet.output)
})
}
@Override
protected void configureReportEvaluation(FindBugs findBugs) {
findBugs.ignoreFailures = true
findBugs.reports.xml.enabled = true
findBugs.reports.html.enabled = false
File xmlReportFile = findBugs.reports.xml.destination
File htmlReportFile = new File(xmlReportFile.absolutePath - '.xml' + '.html')
findBugs.doLast {
evaluateReports(xmlReportFile, htmlReportFile)
}
createHtmlReportTask(findBugs, xmlReportFile, htmlReportFile)
}
private void evaluateReports(File xmlReportFile, File htmlReportFile) {
def evaluator = new FinbugsViolationsEvaluator(xmlReportFile)
String reportUrl = new ConsoleRenderer().asClickableFileUrl(htmlReportFile)
violations.addViolations(evaluator.errorsCount(), evaluator.warningsCount(), reportUrl)
}
private GenerateHtmlReport createHtmlReportTask(FindBugs findBugs, File xmlReportFile, File htmlReportFile) {
project.tasks.create("generate${findBugs.name.capitalize()}HtmlReport", GenerateHtmlReport) { GenerateHtmlReport generateHtmlReport ->
generateHtmlReport.xmlReportFile = xmlReportFile
generateHtmlReport.htmlReportFile = htmlReportFile
generateHtmlReport.classpath = findBugs.findbugsClasspath
generateHtmlReport.dependsOn findBugs
evaluateViolations.dependsOn generateHtmlReport
}
}
}