This repository has been archived by the owner on Feb 11, 2022. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 28
/
FindbugsConfigurator.groovy
160 lines (137 loc) · 6.31 KB
/
FindbugsConfigurator.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
package com.novoda.staticanalysis.internal.findbugs
import com.novoda.staticanalysis.Violations
import com.novoda.staticanalysis.internal.CodeQualityConfigurator
import org.gradle.api.*
import org.gradle.api.file.ConfigurableFileTree
import org.gradle.api.file.FileCollection
import org.gradle.api.plugins.quality.FindBugs
import org.gradle.api.plugins.quality.FindBugsExtension
import org.gradle.api.tasks.SourceSet
import java.nio.file.Path
class FindbugsConfigurator extends CodeQualityConfigurator<FindBugs, FindBugsExtension> {
static FindbugsConfigurator create(Project project,
NamedDomainObjectContainer<Violations> violationsContainer,
Task evaluateViolations) {
Violations violations = violationsContainer.maybeCreate('Findbugs')
return new FindbugsConfigurator(project, violations, evaluateViolations)
}
private FindbugsConfigurator(Project project,
Violations violations,
Task evaluateViolations) {
super(project, violations, evaluateViolations)
}
@Override
protected String getToolName() {
'findbugs'
}
@Override
protected Object getToolPlugin() {
QuietFindbugsPlugin
}
@Override
protected Class<FindBugsExtension> getExtensionClass() {
FindBugsExtension
}
@Override
protected Class<FindBugs> getTaskClass() {
FindBugs
}
@Override
protected Action<FindBugsExtension> getDefaultConfiguration() {
new Action<FindBugsExtension>() {
@Override
void execute(FindBugsExtension findBugsExtension) {
findBugsExtension.toolVersion = '3.0.1'
}
}
}
@Override
protected void configureAndroidVariant(variant) {
FindBugs task = project.tasks.maybeCreate("findbugs${variant.name.capitalize()}", QuietFindbugsPlugin.Task)
List<File> androidSourceDirs = variant.sourceSets.collect { it.javaDirectories }.flatten()
task.with {
description = "Run FindBugs analysis for ${variant.name} classes"
source = androidSourceDirs
classpath = variant.javaCompile.classpath
exclude '**/*.kt'
}
sourceFilter.applyTo(task)
task.conventionMapping.map("classes") {
List<String> includes = createIncludePatterns(task.source, androidSourceDirs)
getAndroidClasses(variant, includes)
}
task.dependsOn variant.javaCompile
}
private FileCollection getAndroidClasses(Object variant, List<String> includes) {
includes.isEmpty() ? project.files() : project.fileTree(variant.javaCompile.destinationDir).include(includes)
}
@Override
protected void configureJavaProject() {
project.afterEvaluate {
project.sourceSets.each { SourceSet sourceSet ->
String taskName = sourceSet.getTaskName(toolName, null)
FindBugs task = project.tasks.findByName(taskName)
if (task != null) {
sourceFilter.applyTo(task)
task.conventionMapping.map("classes", {
List<File> sourceDirs = sourceSet.allJava.srcDirs.findAll { it.exists() }.toList()
List<String> includes = createIncludePatterns(task.source, sourceDirs)
getJavaClasses(sourceSet, includes)
})
task.exclude '**/*.kt'
}
}
}
}
private static List<String> createIncludePatterns(FileCollection sourceFiles, List<File> sourceDirs) {
List<Path> includedSourceFilesPaths = sourceFiles.matching { '**/*.java' }.files.collect { it.toPath() }
List<Path> sourceDirsPaths = sourceDirs.collect { it.toPath() }
createRelativePaths(includedSourceFilesPaths, sourceDirsPaths)
.collect { Path relativePath -> (relativePath as String) - '.java' + '*' }
}
private static List<Path> createRelativePaths(List<Path> includedSourceFiles, List<Path> sourceDirs) {
includedSourceFiles.collect { Path sourceFile ->
sourceDirs
.findAll { Path sourceDir -> sourceFile.startsWith(sourceDir) }
.collect { Path sourceDir -> sourceDir.relativize(sourceFile) }
}
.flatten()
}
private FileCollection getJavaClasses(SourceSet sourceSet, List<String> includes) {
includes.isEmpty() ? project.files() : createClassesTreeFrom(sourceSet).include(includes)
}
/**
* The simple "classes = sourceSet.output" may lead to non-existing resources directory
* being passed to FindBugs Ant task, resulting in an error
* */
private ConfigurableFileTree createClassesTreeFrom(SourceSet sourceSet) {
project.fileTree(sourceSet.output.classesDir, {
it.builtBy(sourceSet.output)
})
}
@Override
protected void configureReportEvaluation(FindBugs findBugs, Violations violations) {
findBugs.ignoreFailures = true
findBugs.reports.xml.enabled = true
findBugs.reports.html.enabled = false
def collectViolations = createViolationsCollectionTask(findBugs, violations)
def generateHtmlReport = createHtmlReportTask(findBugs, collectViolations.xmlReportFile, collectViolations.htmlReportFile)
evaluateViolations.dependsOn collectViolations
collectViolations.dependsOn generateHtmlReport
generateHtmlReport.dependsOn findBugs
}
private CollectFindbugsViolationsTask createViolationsCollectionTask(FindBugs findBugs, Violations violations) {
def task = project.tasks.maybeCreate("collect${findBugs.name.capitalize()}Violations", CollectFindbugsViolationsTask)
task.xmlReportFile = findBugs.reports.xml.destination
task.violations = violations
task
}
private GenerateFindBugsHtmlReport createHtmlReportTask(FindBugs findBugs, File xmlReportFile, File htmlReportFile) {
def task = project.tasks.maybeCreate("generate${findBugs.name.capitalize()}HtmlReport", GenerateFindBugsHtmlReport)
task.xmlReportFile = xmlReportFile
task.htmlReportFile = htmlReportFile
task.classpath = findBugs.findbugsClasspath
task.onlyIf { xmlReportFile?.exists() }
task
}
}