-
Notifications
You must be signed in to change notification settings - Fork 1
/
flake.nix
178 lines (158 loc) · 5.2 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
{
description = "Device driver implementations for many embedded sensors and devices";
inputs = {
advisory-db = {
url = "github:rustsec/advisory-db";
flake = false;
};
crane = {
url = "github:ipetkov/crane";
inputs.nixpkgs.follows = "nixpkgs";
};
devshell = {
url = "github:numtide/devshell";
inputs.nixpkgs.follows = "nixpkgs";
};
flake-utils.url = "github:numtide/flake-utils";
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
pre-commit-hooks = {
url = "github:cachix/pre-commit-hooks.nix";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-utils.follows = "flake-utils";
};
rust-overlay = {
url = "github:oxalica/rust-overlay";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-utils.follows = "flake-utils";
};
};
outputs = {
self,
advisory-db,
devshell,
crane,
flake-utils,
nixpkgs,
pre-commit-hooks,
rust-overlay,
} @ inputs:
flake-utils.lib.eachDefaultSystem (localSystem: let
pkgs = import nixpkgs {
inherit localSystem;
overlays = [
devshell.overlays.default
rust-overlay.overlays.default
];
};
inherit (pkgs) lib;
rustToolchain = pkgs.pkgsBuildHost.rust-bin.nightly.latest.default;
craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;
commonArgs = {
src = craneLib.cleanCargoSource (craneLib.path ./.);
buildInputs =
[
# nothing yet
]
++ lib.optionals pkgs.stdenv.isDarwin [
# Additional darwin specific inputs can be set here
pkgs.libiconv
];
};
# Build *just* the cargo dependencies, so we can reuse
# all of that work (e.g. via cachix) when running in CI
cargoArtifacts = craneLib.buildDepsOnly commonArgs;
# Build the actual package
package = craneLib.buildPackage (commonArgs
// {
inherit cargoArtifacts;
});
in {
checks =
{
# Build the crate as part of `nix flake check` for convenience
embedded-devices = package;
# Run clippy (and deny all warnings) on the crate source,
# again, resuing the dependency artifacts from above.
#
# Note that this is done as a separate derivation so that
# we can block the CI if there are issues here, but not
# prevent downstream consumers from building our crate by itself.
embedded-devices-clippy = craneLib.cargoClippy (commonArgs
// {
inherit cargoArtifacts;
cargoClippyExtraArgs = "--all-targets -- --deny warnings";
});
embedded-devices-doc = craneLib.cargoDoc (commonArgs
// {
inherit cargoArtifacts;
});
# Check formatting
embedded-devices-fmt = craneLib.cargoFmt {
inherit (commonArgs) src;
};
# Audit dependencies
embedded-devices-audit = craneLib.cargoAudit {
inherit (commonArgs) src;
inherit advisory-db;
};
}
// {
pre-commit = pre-commit-hooks.lib.${localSystem}.run {
src = ./.;
hooks = {
alejandra.enable = true;
cargo-check.enable = true;
rustfmt.enable = true;
statix.enable = true;
};
};
};
packages.default = package; # `nix build`
packages.embedded-devices = package; # `nix build .#embedded-devices`
# `nix develop`
devShells.default = pkgs.devshell.mkShell {
name = "embedded-devices";
imports = [
"${devshell}/extra/language/c.nix"
"${devshell}/extra/language/rust.nix"
];
language.rust.enableDefaultToolchain = false;
commands = [
{
package = pkgs.alejandra;
help = "Format nix code";
}
{
package = pkgs.statix;
help = "Lint nix code";
}
{
package = pkgs.deadnix;
help = "Find unused expressions in nix code";
}
];
devshell.startup.pre-commit.text = self.checks.${localSystem}.pre-commit.shellHook;
packages = let
# Do not expose rust's gcc: https://github.com/oxalica/rust-overlay/issues/70
# Create a wrapper that only exposes $pkg/bin. This prevents pulling in
# development deps, like python interpreter + $PYTHONPATH, when adding
# packages to a nix-shell. This is especially important when packages
# are combined from different nixpkgs versions.
mkBinOnlyWrapper = pkg:
pkgs.runCommand "${pkg.pname}-${pkg.version}-bin" {inherit (pkg) meta;} ''
mkdir -p "$out/bin"
for bin in "${lib.getBin pkg}/bin/"*; do
ln -s "$bin" "$out/bin/"
done
'';
in
commonArgs.buildInputs
++ [
(mkBinOnlyWrapper rustToolchain)
pkgs.probe-run
pkgs.rust-analyzer
];
};
formatter = pkgs.alejandra; # `nix fmt`
});
}