build.gradle

import com.github.jk1.license.filter.LicenseBundleNormalizer
import com.github.jk1.license.render.InventoryHtmlReportRenderer

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id 'jacoco'
    id 'java-library'
    id 'io.freefair.lombok' version '8.4'

    id 'org.cadixdev.licenser' version '0.6.1'
    id 'com.github.jk1.dependency-license-report' version '2.5'

    id 'signing'
    id 'maven-publish'
    id 'io.github.gradle-nexus.publish-plugin' version '1.0.0'
}

repositories {
    mavenLocal()
    mavenCentral()
}

group = 'ru.oleg-cherednik.json'
version = '3.0'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.compilerArgs += ['-Xlint:unchecked']
}

configurations {
    jar.archiveFileName = "${rootProject.name}-${version}.jar"
}

apply from: "${projectDir}/gradle/checkstyle.gradle"
apply from: "${projectDir}/gradle/pmd.gradle"

dependencies {
    annotationProcessor "org.projectlombok:lombok:${property('lombok.version')}"

    implementation 'org.slf4j:slf4j-api:2.0.9'

    testAnnotationProcessor "org.projectlombok:lombok:${property('lombok.version')}"

    testImplementation('org.testng:testng:7.5.1') {
        exclude group: 'junit', module: 'junit'
        exclude group: 'org.apache.ant', module: 'ant'
    }

    testImplementation "com.google.code.gson:gson:${property('gson.version')}"
    testImplementation 'org.assertj:assertj-core:3.24.2'
    testImplementation 'org.mockito:mockito-core:4.11.0'
    testImplementation 'commons-io:commons-io:2.15.0'
    testImplementation 'org.apache.commons:commons-collections4:4.4'
}

jacocoTestReport {
    reports {
        xml.required = true
        html.required = true
    }
}

javadoc {
    options.addBooleanOption('Xdoclint:-missing', true)
}

check.finalizedBy(checkLicense)
check.finalizedBy(generateLicenseReport)
check.finalizedBy(jacocoTestReport)

test {
    dependsOn('jar')
    useTestNG()
}

license {
    header rootProject.file('APACHE.txt')
    include '**/*.java'
}

licenseReport {
    configurations = ['compileClasspath', 'runtimeClasspath', 'testCompileClasspath', 'testRuntimeClasspath']
    renderers = [new InventoryHtmlReportRenderer()]
    allowedLicensesFile = new File("$projectDir/misc/license/allowed-licenses.json")
    filters = [new LicenseBundleNormalizer(bundlePath: "$projectDir/misc/license/license-normalizer-bundle.json")]
}

signing {
    sign publishing.publications
}

java {
    withJavadocJar()
    withSourcesJar()
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java

            pom {
                name = rootProject.name

                description = "\n" +
                        "    Jackson usability utilities.\n" +
                        "    It's designed to add additional features like easy and centralized configuration,\n" +
                        "    builder or static method set.\n" +
                        "  "

                url = 'https://github.com/oleg-cherednik/json-api'
                inceptionYear = '2020'

                licenses {
                    license {
                        name = 'The Apache Software License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution = 'repo'
                    }
                }

                developers {
                    developer {
                        id = 'oleg.cherednik'
                        name = 'Oleg Cherednik'
                        email = 'oleg.cherednik@gmail.com'
                    }
                }

                scm {
                    url = 'https://github.com/oleg-cherednik/json-api'
                    connection = 'scm:https://github.com/oleg-cherednik/json-api.git'
                    developerConnection = 'scm:git@github.com:oleg-cherednik/json-api.git'
                }
            }
        }
    }

    repositories {
        mavenLocal()
    }
}

nexusPublishing {
    repositories {
        sonatype()
    }
}