Insert link to daily file using the date selector

[elsehow]

Brief Abstract

org-roam-dailies-insert-date could produce a link to a date using the date selection minibuffer interface.

Long Description

When inserting a timestamp with org-roam-dailies-find-date, a minibuffer interface appears, allowing the user to select a date. A command like org-roam-dailies-insert-date could produce the same minibuffer, but instead produce a link to the specified daily file.

Proposed Implementation (if any)

Conceptually: (org-roam-insert (org-roam-dailies-find-date))?

Please check the following:

• No similar feature requests

[mchowning]

A while back I made a org-roam-dailies-insert-date function to provide allow me to insert a linked reference to a specific "daily" file. I'm not super-familiar with elisp, so I wouldn't be at all surprised if there is a better way to write this, but it's worked well for me.

  (defun matt/org-insert-last-stored-link-without-newline (arg)
    "Insert the last link stored in `org-stored-links' like
`org-insert-last-stored-link', but without a trailing newline."
    (interactive "p")
    (org-insert-all-links arg "" ""))

  (defun matt/org-roam-dailies-insert-date ()
    (interactive)
    (save-window-excursion (save-excursion
                             (org-roam-dailies-find-date)
                             (save-buffer)
                             (org-store-link nil 'not-interactive)
                             (let* ((id (car (car org-stored-links)))
                                    (description (org-roam--file-keyword-get "TITLE"))
                                    (updated (list id description)))
                               (setq org-stored-links (cons updated (cdr org-stored-links))))))
    (call-interactively 'matt/org-insert-last-stored-link-without-newline))

[zipy124]

@mchowning Does your code still work for you? I'm getting an error on "org-roam--file-keyword-get"?

[mchowning]

👋 @zipy124 ! I did have to modify that function to work code with the latest changes to org-roam. This is my current function:

(defun matt/org-roam-dailies-insert-date ()
  (interactive)
  (save-window-excursion (save-excursion
                           (org-roam-dailies-goto-date)
                           (save-buffer)
                           (org-store-link nil 'not-interactive)
                           (let* ((id (caar org-stored-links))
                                  (description (cadar (org-collect-keywords '("TITLE" "title"))))
                                  (updated (list id description)))
                             (setq org-stored-links (cons updated (cdr org-stored-links))))))
  (call-interactively 'matt/org-insert-last-stored-link-without-newline))