TCustomSerializer for Simple Type (not for Class)

[hafedh-trimeche]

Please how to implement TCustomSerializer for TBytes?
The content of TBytes would be a container for a Binary Data, Encrepted Data, ... So marshaling TBytes is made by Base64 encoding/decoding.

  TBytesSerializer = class(TCustomSerializer)
  protected
    class function GetTargetInfo:PTypeInfo;override;
    class function CanHandle(AType:PTypeInfo):Boolean;override;
  public
    function Serialize(const AValue:TValue;ANeonObject:TNeonRttiObject;AContext:ISerializerContext):TJSONValue;override;
    function Deserialize(AValue:TJSONValue;const AData:TValue;ANeonObject:TNeonRttiObject;AContext:IDeserializerContext):TValue;override;
  end;

implementation

class function TBytesSerializer.GetTargetInfo: PTypeInfo;
begin
  Result := TypeInfo(TBytes);
end;

class function TBytesSerializer.CanHandle(AType: PTypeInfo): Boolean;
begin
  Result := (AType=GetTargetInfo);
end;

function TBytesSerializer.Serialize(const AValue:TValue;ANeonObject:TNeonRttiObject;AContext:ISerializerContext):TJSONValue;
var
  LBytes  : TBytes;
  LBase64 : string;
begin
  SetLength(LBytes,AValue.GetArrayLength);
  if Length(LBytes)>0 then 
  begin
    AValue.ExtractRawData(LBytes);
    LBase64 := TBase64.Encode(LBytes);
  end
  else LBase64 := '';
  Result := TJSONString.Create(LBase64);
end;

function TBytesSerializer.Deserialize(AValue:TJSONValue;const AData:TValue;ANeonObject:TNeonRttiObject;AContext:IDeserializerContext):TValue;
var
  LBytes : TBytes;
begin
  LBytes := TBase64.Decode(AValue.Value);
  AData.Make(LBytes,GetTargetInfo,Result);
end;

Best regards.

[JensMertelmeyer]

You're using TValue.Make and TValue.ExtractRawData. This basically marshals your array pointer, not the array content.

Your serializer methods can be much easier:

function TBytesSerializer.Serialize(
  const AValue: TValue;
  ANeonObject: TNeonRttiObject;
  AContext: ISerializerContext
): TJSONValue;
var
	LBytes:  TBytes;
	LBase64: string;
begin
	LBytes := AValue.AsType<TBytes>();
	LBase64 := TBase64.Encode(LBytes);
	Result := TJSONString.Create(LBase64);
end;

function TBytesSerializer.Deserialize(
  AValue: TJSONValue;
  const AData: TValue;
  ANeonObject: TNeonRttiObject;
  AContext: IDeserializerContext
): TValue;
var
	LBytes: TBytes;
begin
	LBytes := TBase64.Decode(AValue.Value);
	Result := TValue.From(LBytes);
end;

I have attached your modified unit and a few testcases here:
https://gist.github.com/JensMertelmeyer/db915827dd550f19e46cb3f6de09df1f

It shows it will also work with TBytes that represent things like a 'Hello World 😎'

PS: No testcases yet on how it handles invalid Base64 strings 😉

PPS: Neon handles TBytes just fine. Why are you implementing a custom Base64 encoder/decoder? To save space?

[hafedh-trimeche]

Hi,
Thank you for these clarifications.
Indeed, when a TBytes field holds a large binary content, this content would be compressed and Base64 encoded.
I think that parsing Base64 is more performant than decoding array (TBytes) representation byte by byte.
Result (TBytes) := Decompress( Base64Decode(JsonBase64Content) ).

Best regards.