-
Notifications
You must be signed in to change notification settings - Fork 0
/
ZCODE.ASM
1465 lines (1327 loc) · 20.9 KB
/
ZCODE.ASM
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; include ../../DEVMAP.INC
; include ../UNI/MEMORY.INC
; NAM SMALL-C INTERPRETER
; OPT NOP,NOG
;
; LAST UPDATE 9-SEP-82
;
; LIB FLEXPTRS
SECTION $E8
PC DS 2 ; PSEUDO PROGRAM COUNTER
R1A DS 1 ; WORKING 16 BIT
R1B DS 1 ; --REGISTER
STEMP DS 2 ; TEMP STORAGE FOR STACK POINTER
X1TMP DS 2 ; TEMP STORAGE FOR X REG
X2TMP DS 2 ; ... DITTO ...
DFLAG DS 1 ; DIVIDE ROUTINE FLAG
ERRNO DS 1
FTABLE DS 4
FCHARIO DS 2
DS 2
FCHARBUF DS 1
DS 1
CODEADR DS 2
ENDS
;**************************************************
CURR_PCB EQU $EC00
ARGC EQU $1D
ARGV EQU $20
ORG $C000
DW $5AA5
DB 'ZCodeVM '
JMP INIT
JMP PRINT_VERSION
DB $E8
DW EXECUTE
DB 0
INIT BSR PRINT_VERSION
RTS
PRINT_VERSION LDX #TITLE
INT $23
RTS
TITLE DB 10, 'ZCodeVM Version 1.0 ', 0
DS $C100-*,$FF
DS 4
DB 86
JMP fclose+1
DB 86
JMP fopen+1
DB 86
JMP getc+1
DB 86
JMP getchar+1
DB 86
JMP gets+1
DB 86
JMP putc+1
DB 86
JMP putchar+1
DB 86
JMP puts+1
NOP
JMP RTSC
DB 86
JMP isalpha+1
DB 86
JMP isdigit+1
DB 86
JMP isalnum+1
DB 86
JMP islower+1
DB 86
JMP isupper+1
DB 86
JMP isspace+1
DB 86
JMP toupper+1
DB 86
JMP tolower+1
DB 86
JMP strclr+1
DB 86
JMP strlen+1
DB 86
JMP strcpy+1
DB 86
JMP strcat+1
DB 86
JMP strcmp+1
DB 86
JMP sysexit+1
DB 86
JMP fgets+1
DB 86
JMP fputs+1
DB 86
JMP fread+1
DB 86
JMP fwrite+1
DB 86
JMP feof+1
DB 86
JMP fflush+1
DB 86
JMP fseek+1
DB 86
JMP ftell+1
DB 86
JMP unlink+1
DB 86
JMP system+1
DB 86
JMP geterrno+1
DB 86
JMP getstrerr+1
DS 4*4,$FF ;ROOM FOR 4 MORE
EXECUTE STX CODEADR
LDX #FCHARBUF
STX FCHARIO
LDX #1
STX FCHARIO+2
LDX CURR_PCB
LDAB ARGC,X
CLRA
XGDX
ADDD #ARGV
PSHX
PSHB
PSHA
LDX CODEADR
BRA NEXT2 ; START THE INTERPRETATION
;*************************************************************
;
; THE HEART OF THE INTERPRETER--- NEXT INSTRUCTION FETCHER.
;
BUMP2 LDX PC ; GET PROG COUNTER
BUMP2A INX ; INCR BY 2
INX
BRA NEXT1 ; FETCH NEXT INSTRUCTION
NEXT LDX PC
NEXT1 STD R1A ; SAVE THE WORK REGISTER
NEXT2 LDAB 0,X ; GET THE PSEUDO-INSTRUCTION
INX ; (B CONTAINS A TABLE OFFSET)
STX PC ; SAVE NEW PC
LDX #JTABLE
ABX
LDX 0,X
LDD R1A ; RESTORE
JMP 0,X ; GO EXECUTE THE PSEUDO-INSTR.
;*************************************************************
; THE JUMP TABLE *
;*************************************************************
DS $C200-* ; MUST START ON A PAGE BOUNDARY
JTABLE
DW LD1IM ; #0
DW LD1SOFF ; #1
DW LD1 ; #2
DW LDB1 ; #3
DW LD1R ; #4
DW LDB1R ; #5
DW ST1 ; #6
DW STB1 ; #7
DW ST1SP ; #8
DW STB1SP ; #9
DW PUSHR1 ; #10
DW EXG1 ; #11
DW JMPL ; #12
DW BRZL ; #13
DW JSRL ; #14
DW JSRSP ; #15
DW RTSC ; #16
DW MODSP ; #17
DW DBL1 ; #18
DW ADDS ; #19
DW SUBFST ; #20
DW MUL1 ; #21
DW DIV1 ; #22
DW MOD ; #23
DW ORS ; #24
DW XORS ; #25
DW ANDS ; #26
DW ASRS ; #27
DW ASLS ; #28
DW NEGR ; #29
DW NOTR ; #30
DW INCR ; #31
DW DECR ; #32
DW ZEQ ; #33
DW ZNE ; #34
DW ZLT ; #35
DW ZLE ; #36
DW ZGT ; #37
DW ZGE ; #38
DW ULT ; #39
DW ULE ; #40
DW UGT ; #41
DW UGE ; #42
DW ASMC ; #43
;************************************************************
;-------------------------
; #0 LOAD REG WITH IMMED. VALUE
LD1IM LDX PC
LDD 0,X
JMP BUMP2A
;-------------------------
; #1 LOAD STACK ADDRESS + OFFSET INTO REG
LD1SOFF STS R1A ; SAVE STACK VALUE
LDX PC
LDD 0,X ; GET OFFSET VALUE
ADDD R1A
ADDD #1 ; ADD OFFSET + 1
JMP BUMP2A
;-------------------------
; #2 LOAD WORD @ ADDRESS
LD1 LDX PC
LDX 0,X ; GET ADDRESS
LDD 0,X ; GET WORD
JMP BUMP2
;-------------------------
; #3 LOAD BYTE @ ADDRESS
LDB1 LDX PC
LDX 0,X ; GET ADDRESS
CLRA
LDAB 0,X ; GET BYTE
BPL LDB1A
COMA ; SIGN EXTEND
LDB1A JMP BUMP2
;-------------------------
; #4 LOAD WORD INDIRECT (ADDR IN REG)
LD1R LDX R1A ; GET ADDRESS
LDD 0,X ; GET WORD
JMP NEXT
;-------------------------
; #5 LOAD BYTE INDIRECT (ADDR IN REG)
LDB1R LDX R1A
CLRA
LDAB 0,X ; GET BYTE
BPL LDB1RA
COMA
LDB1RA JMP NEXT
;-------------------------
; #6 STORE WORD @ ADDRESS
ST1 LDX PC
LDX 0,X ; GET ADDRESS
STD 0,X ; STORE WORD
JMP BUMP2
;-------------------------
; #7 STORE BYTE @ ADDRESS
STB1 LDX PC
LDX 0,X ; GET ADDR
STAB 0,X ; STORE BYTE
JMP BUMP2
;-------------------------
; #8 STORE WORD @ ADDRESS ON STACK
ST1SP TSX ; STACK TO INDEX
LDX 0,X ; GET ADDRESS
STD 0,X ; STORE WORD
INS
INS ; POP STACK
JMP NEXT
;-------------------------
; #9 STORE BYTE @ ADDRESS ON STACK
STB1SP TSX
LDX 0,X
STAB 0,X ; STORE BYTE
INS ; POP ...
INS
JMP NEXT
;-------------------------
; #10 PUSH WORD ON STACK
PUSHR1 PSHB
PSHA
LDX PC
JMP NEXT2
;-------------------------
; #11 SWAP REG AND TOP OF STACK
EXG1 TSX
LDX 0,X ; GET VALUE ON STACK
STX R1A ; SAVE
INS
INS
PSHB
PSHA ; REG ON STACK
LDD R1A ; NEW REG
LDX PC
JMP NEXT2
;-------------------------
; #12 JUMP TO LABEL
JMPL LDX PC
JMP1 LDX 0,X ; GET ADDRESS (NEW PC)
JMP NEXT2
;-------------------------
; #13 JUMP TO LABEL IF FALSE
BRZL ORAA R1B ; SET FLAGS
BEQ JMPL ; IF REG=0 -- JUMP
JMP BUMP2 ; ELSE, PROCEED
;-------------------------
; #14 CALL TO LABEL
JSRL LDX PC
INX ; ADJUST RETURN
INX ; -- ADDRESS
PSHX
BRA JMPL
;-------------------------
; #15 CALL TO TOP OF STACK
JSRSP TSX ; POINT TO STACK
LDX 0,X ; GET ADDRESS (NEW PC)
INS ; POP
INS
LDD PC
PSHB
PSHA
JMP NEXT2
;-------------------------
; #16 RETURN TO CALLER
RTSC TSX
LDX 0,X ; GET ADDRESS
INS ; POP
INS
JMP NEXT1
;-------------------------
; #17 MODIFY THE STACK POINTER
MODSP LDX PC
LDD 0,X ; GET VALUE
STS STEMP
ADDD STEMP ; ADD STACK POINTER
STD STEMP
LDS STEMP ; NEW STACK POINTER
LDD R1A ; RESTORE REGISTER
JMP BUMP2A
;---------------------------
; #18 DOUBLE THE PRIMARY REGISTER
DBL1 ASLB
ROLA
JMP NEXT
;---------------------------
; #19 ADD REG AND TOP OF STACK (THEN POP)
ADDS TSX
ADDD 0,X ; DO THE ADD
JMP POPS ; POP & RETURN
;---------------------------
; #20 SUBTRACT REG FROM TOP OF STACK
SUBFST PULA ; GET VALUE OFF STACK
PULB
SUBD R1A ; SUBTRACK REGISTER
JMP NEXT
;---------------------------
; #21 MULTIPLY TOP OF STACK BY REG (RESULT IN REG)
MUL1 PSHB
PSHA ; REG ON STACK
LDAA #16
PSHA ; SET COUNTER
CLRA
CLRB
TSX ; POINT TO DATA
M2 ROR 3,X ; SHIFT MULTIPLIER
ROR 4,X
DEC 0,X ; DONE ?
BMI M4
BCC M3
ADDD 1,X
M3 RORA
RORB ; SHIFT RESULT
BRA M2 ; AND LOOP
M4 INS ; CLEAN STACK
INS
INS
PULA ; GET RESULT
PULB
JMP NEXT
;-----------------------------
; #22 DIVIDE THE TOP OF STACK BY REG --- RESULT IN REG.
DIV1 BSR BDIV ; DO THE BASIC DIVIDE
LDAA DFLAG ; GET SIGN FLAG
ANDA #1 ; MASK OFF BIT ZERO
PULA ; GET RESULT
PULB
BEQ DIV1R
DIV1N BSR NEGATE ; NEGATE THE VALUE IN A,B
DIV1R JMP NEXT
;-----------------------------
; #23 DIVIDE TOP OF STACK BY REG --- REMAINDER IN REG
MOD BSR BDIV
INS ; CLEAN STACK
INS
PSHA ; TEMP SAVE
LDAA DFLAG ; GET SIGN FLAG
BPL MOD1
COMA
MOD1 ANDA #1 ; MASK OFF BIT 0
PULA
BNE DIV1N ; IF BIT 0 SET, NEGATE
JMP NEXT
;****************************************************
; BASIC 16 BIT DIVIDE ROUTINE
; ENTER WITH: DIVIDEND ON STACK
; DIVISOR IN A,B
; EXIT WITH: QUOTIENT ON STACK
; REMAINDER IN A,B
; SIGN FLAG IN DFLAG
;
BDIV CLR DFLAG
TSTA ; CHECK DIVISOR SIGN
BPL BDIV1
INC DFLAG ; ADJUST SIGN FLAG
BSR NEGATE ; TAKE ABSOLUTE VALUE
BDIV1 PSHB ; FORCE ON STACK
PSHA
LDAA #17 ; BIT COUNTER
PSHA
TSX ; POINT TO DATA
LDAA 5,X ; CHECK SIGN
BPL BDIV2 ; -- OF DIVIDEND
COM DFLAG ; ADJUST FLAG
LDAB 6,X
BSR NEGATE
STD 5,X
BDIV2 CLRA
CLRB
; MAIN DIVIDE LOOP (UNSIGNED)
UDIV1 CMPA 1,X
BHI UDIV3
BCS UDIV2
CMPB 2,X
BCC UDIV3
UDIV2 CLC
BRA UDIV4
UDIV3 SUBD 1,X
SEC
UDIV4 ROL 6,X
ROL 5,X
DEC 0,X
BEQ UDIV5
ROLB
ROLA
BCC UDIV1
BRA UDIV3
UDIV5 INS
INS
INS
RTS
;----------------------------------------
; NEGATE THE VALUE IN A,B
NEGATE COMA
COMB
ADDD #1
RTS
;----------------------------------
; #24 INCLUSIVE OR THE TOP OF STACK AND REG.
ORS TSX
ORAA 0,X
ORAB 1,X
POPS INS ; POP THE STACK
INS
JMP NEXT
;----------------------------------
; #25 EXCLUSIVE OR ......
XORS TSX
EORA 0,X
EORB 1,X
BRA POPS
;----------------------------------
; #26 AND .........
ANDS TSX
ANDA 0,X
ANDB 1,X
BRA POPS
;----------------------------------
; #27 ARITH. SHIFT RIGHT THE TOP OF STACK
ASRS TSX
ANDB #$1F ; MAX REASONABLE SHIFT
BEQ ASRS2
ASRS1 ASR 0,X
ROR 1,X
DECB
BNE ASRS1
ASRS2 PULA ; GET THE RESULT
PULB
JMP NEXT
;--------------------------------
; #28 ARITH. SHIFT LEFT THE TOP OF STACK
ASLS TSX
ANDB #$1F
BEQ ASRS2
ASLS1 ASL 1,X
ROL 0,X
DECB
BNE ASLS1
BRA ASRS2
;--------------------------------
; #29 NEGATE THE REGISTER
NEGR BSR NEGATE
JMP NEXT
;--------------------------------
; #30 COMPLEMENT THE REGISTER
NOTR COMA
COMB
JMP NEXT
;--------------------------------
; #31 ADD 1 TO REG
INCR ADDD #1
JMP NEXT
;--------------------------------
; #32 SUBTRACT 1 FROM REG
DECR SUBD #1
JMP NEXT
;****************************************************
;
; BASIC COMPARE INSTRUCTION SUBROUTINE
; Compare the top of Stack to Register and set Condition codes
;
; Signed compare -- Carry reflects the sign of difference
; (set means: top of stack < A,B )
;
SCMP TSX
LDD 2,X ; GET TOP OF STACK
SUBD R1A ; SET CONDITION FLAGS
BPL STCMP1 ; SKIP IF PLUS
STAB R1B ; TEMP SAVE
ORAA R1B ; SET/RESET ZERO FLAG
SEC ; AND SET CARRY
RTS
STCMP1 STAB R1B
ORAA R1B
CLC ; CLEAR THE CARRY
RTS
;
; Unsigned compare, Carry set if top of stack < A,B
;
BCMP TSX
LDD 2,X ; GET TOP OF STACK
CMPA R1A ; CHECK TOP BYTE
BNE BCMP1
CMPB R1B
BCMP1 RTS
;-------------------------------
; #33 TEST FOR EQUALITY
ZEQ BSR BCMP
BEQ TRUE
BRA FALSE
;-------------------------------
; #34 TEST FOR NOT-EQUAL
ZNE BSR BCMP
BNE TRUE
BRA FALSE
;-------------------------------
; #35 TEST FOR LESS THAN
ZLT BSR SCMP
BCS TRUE
BRA FALSE
;-------------------------------
; #36 TEST FOR LESS THAN OR EQUAL
ZLE BSR SCMP
BLS TRUE
BRA FALSE
;-------------------------------
; #37 TEST FOR GREATER THAN
ZGT BSR SCMP
BHI TRUE
BRA FALSE
;-------------------------------
; #38 TEST FOR GREATER THAN OR EQUAL
ZGE BSR SCMP
BCC TRUE
BRA FALSE
;-------------------------------
; #39 TEST FOR LESS THAN (UNSIGNED)
ULT BSR BCMP
BCS TRUE
BRA FALSE
;-------------------------------
; #40 TEST FOR LESS THAN OR EQUAL (UNSIGNED)
ULE BSR BCMP
BLS TRUE
BRA FALSE
;-------------------------------
; #41 TEST FOR GREATER THAN (UNSIGNED)
UGT BSR BCMP
BHI TRUE
BRA FALSE
;------------------------------
; #42 TEST FOR GREATER THAN OR EQUAL (UNSIGNED)
UGE BSR BCMP
BCC TRUE
FALSE CLRB ; RETURN FALSE
BRA TRUE1
TRUE LDAB #1 ; RETURN TRUE
TRUE1 CLRA
JMP POPS ; POP STACK AND PROCEED
;-------------------------------------
; #43 SWITCH TO EXECUTABLE (ASSEMBLY) CODE
ASMC LDX PC ; POINT TO CODE
JMP 0,X ; GO EXECUTE IT
;**********************************************************
;
; RUN-TIME SUBROUTINE LIBRARY
;
;**********************************************************
; fopen(file-name, "type")
; Open a File..........
fopen PROC
GLOBAL FEXIT
DB 86 ; SWITCH TO INLINE CODE
LDAA #$EB ; WRONG FILE OPEN MODE
STAA ERRNO
TSX
LDX 4,X ; POINTER TO FILE NAME
STX FTABLE
LDX #0
STX FTABLE+2
TSX
LDX 2,X ; POINTER TO MODE
LDAB 0,X
CMPB #'w'
BNE FOPEN1
LDAA #2
LDX #FTABLE
INT $4A
TSTA
BNE FCREAT
PSHA
PSHB
TBA
INT $6C ; truncate
PULB
PULA
FWRRD PSHB
TSX
LDX 2,X
LDAB 1,X
CMPB #'+'
PULB
BNE FEXIT
TSTA
BNE FEXIT
TBA
INT $4E
BRA FOPENRW
FCREAT CLRA
LDX #FTABLE
INT $4B
BRA FWRRD
FOPEN1 CMPB #'r'
BNE FOPERR
LDAA #1
LDAB 1,X
BEQ FOPENR
CMPB #'+'
BNE FOPERR
FOPENRW LDAA #3
FOPENR LDX #FTABLE
INT $4A
FEXIT STAA ERRNO
TSTA
BEQ FOPEXIT
FOPERR LDD #0 ; FIXME STDIN
FOPEXIT JMP RTSC
ENDP
;-------------------------------------------------
; fclose(unit)
; CLOSE A FILE
fclose PROC
DB 86 ; SWITCH TO IN-LINE
TSX
LDD 2,X ; FILE HANDLE
TBA
INT $4E
BRA FEXIT
ENDP
;--------------------------------------------------
; getc(unit) read a byte from file
; return a char, else a -1 if EOF
getc PROC
GLOBAL FRWERR
DB 86
TSX
LDD 2,X
TBA
LDX #FCHARIO
INT $4C
FRWERR STAA ERRNO
TSTA
BNE GETCER
CPX #1
BNE GETCER
LDAB FCHARBUF
CLRA
BRA GETCOK
GETCER LDD #-1
GETCOK JMP RTSC
ENDP
;----------------------------------------------
; putc(c,unit) write to file
putc PROC
DB 86
TSX
LDAA 5,X
STAA FCHARBUF
LDAA 3,X
LDX #FCHARIO
INT $4D
BRA FRWERR
ENDP
; getchar() get a char from standard input
getchar PROC
DB 86
INT $20
CMPA #$1A ; COMPARE TO CNTRL-Z (EOF)
BNE GETCHOK ; NO
LDD #-1 ; YES...
BRA GETCH1
GETCHOK TAB ; COPY CHAR IN A
CLRA
GETCH1 JMP RTSC
ENDP
;-----------------------------------------------
; putchar(c) write a char to standard output
putchar PROC
DB 86
TSX
LDAA 3,X ; GET THE CHAR
INT $22
TAB
CLRA
JMP RTSC
ENDP
;----------------------------------------------
; gets(buffer) get a char string into buffer
gets PROC
DB 86
TSX
LDX 2,X GET START OF BUFFER
LDAB #80 ; max buffer size
INT $21
CLRA
TSX
LDD 2,X
JMP RTSC
ENDP
;----------------------------------------------
; puts(string) print a string on the terminal
puts PROC
DB 86
TSX
LDX 2,X ; GET STRING ADDRESS
INT $23
LDAA #10
INT $22
LDD #1
JMP RTSC
ENDP
;----------------------------------------------
;
;
; Test if given char is alpha *
; isalpha(c)
; char c;
; { c=c&127;
; return(((c>='a')&(c<='z'))|
; ((c>='A')&(c<='Z'))|
; (c='_'));
; }
;
isalpha PROC
DB 86 ; switch to assembly
TSX
LDAB 3,X ; get char
BSR alPHA
JMP RTSC
ENDP
;
;---------------------------------------------
; Test if given char is numeric *
;
; isdigit(c)
; char c;
; { c=c&127;
; return((c>='0')&(c<='9'));
; }
;
isdigit PROC
DB 86
TSX
LDAB 3,X
BSR nuMERIC
JMP RTSC
ENDP
;
;----------------------------------------------
; Test if given char is alphanumeric *
;
; isalnum(c)
; char c;
; { return((alpha(c)|(numeric(c)));
; }
;
isalnum PROC
GLOBAL alPHA, nuMERIC
DB 86
TSX
LDAB 3,X ;get char
BSR alPHA ;check if alpha
TSX
PSHB ;save result
LDAB 3,X ;get char again
BSR nuMERIC ;check if decimal
TSX
ORAB 0,X ;fix flag
INS ;clean stack
JMP RTSC
;
;
alPHA CLRA
ANDB #$7F
CMPB #'a'
BLT alPHA1
CMPB #'z'
BLE alYES
alPHA1 CMPB #'A'
BLT alPHA2
CMPB #'Z'
BLE alYES
alPHA2 CMPB #'_'
BEQ alYES
;
alNO CLRB
RTS
;
alYES LDAB #1
RTS
;
;
nuMERIC CLRA
ANDB #$7F
CMPB #'0'
BLT alNO
CMPB #'9'
BLE alYES
BRA alNO
ENDP
;
;-----------------------------------------------
; islower(c)
; char c; returns TRUE if c is lower case alpha,
; FALSE otherwise.
;
islower PROC
GLOBAL ISNO, ISYES
DB 86 ; SWITCH TO IN-LINE
TSX
LDAB 3,X ; GET CHAR
ANDB #$7F
CLRA
CMPB #'a'
BLT ISNO
CMPB #'z'
BLE ISYES
;
ISNO CLRB
JMP RTSC ; RETURN FALSE
;
ISYES LDAB #1
JMP RTSC ; RETURN TRUE
ENDP
;
;----------------------------------------------
; isupper(c)
; char c; return TRUE if c is upper case alpha.
;
isupper PROC
DB 86
TSX
LDAB 3,X
ANDB #$7F
CLRA
CMPB #'A'
BLT ISNO
CMPB #'Z'
BLE ISYES
BRA ISNO
ENDP
;
;-----------------------------------------------