/
Filter.pm
277 lines (225 loc) · 6.44 KB
/
Filter.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
# Copyright (c) 1997-2004 Graham Barr <gbarr@pobox.com>. All rights reserved.
# This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.
package Net::LDAP::Filter;
use strict;
use vars qw($VERSION);
$VERSION = "0.16";
# filter = "(" filtercomp ")"
# filtercomp = and / or / not / item
# and = "&" filterlist
# or = "|" filterlist
# not = "!" filter
# filterlist = 1*filter
# item = simple / present / substring / extensible
# simple = attr filtertype value
# filtertype = equal / approx / greater / less
# equal = "="
# approx = "~="
# greater = ">="
# less = "<="
# extensible = attr [":dn"] [":" matchingrule] ":=" value
# / [":dn"] ":" matchingrule ":=" value
# present = attr "=*"
# substring = attr "=" [initial] any [final]
# initial = value
# any = "*" *(value "*")
# final = value
# attr = AttributeDescription from Section 4.1.5 of [1]
# matchingrule = MatchingRuleId from Section 4.1.9 of [1]
# value = AttributeValue from Section 4.1.6 of [1]
#
# Special Character encodings
# ---------------------------
# * \2a, \*
# ( \28, \(
# ) \29, \)
# \ \5c, \\
# NUL \00
my $ErrStr;
sub new {
my $self = shift;
my $class = ref($self) || $self;
my $me = bless {}, $class;
if (@_) {
$me->parse(shift) or
return undef;
}
$me;
}
my $Attr = '[-;.:\d\w]*[-;\d\w]';
my %Op = qw(
& and
| or
! not
= equalityMatch
~= approxMatch
>= greaterOrEqual
<= lessOrEqual
:= extensibleMatch
);
my %Rop = reverse %Op;
sub errstr { $ErrStr }
# Unescape
# \xx where xx is a 2-digit hex number
# \y where y is one of ( ) \ *
sub _unescape {
$_[0] =~ s/
\\([\da-fA-F]{2}|.)
/
length($1) == 1
? $1
: chr(hex($1))
/soxeg;
$_[0];
}
sub _escape { (my $t = $_[0]) =~ s/([\\\(\)\*\0-\37\177-\377])/sprintf("\\%02x",ord($1))/sge; $t }
# encode a triplet ($attr,$op,$val) representing a single filter item
sub _encode {
my($attr,$op,$val) = @_;
# extensible match
if ($op eq ':=') {
# attr must be in the form type:dn:1.2.3.4
unless ($attr =~ /^([-;\d\w]*)(:dn)?(:(\w+|[.\d]+))?$/) {
$ErrStr = "Bad attribute $attr";
return undef;
}
my($type,$dn,$rule) = ($1,$2,$4);
return ( {
extensibleMatch => {
matchingRule => $rule,
type => length($type) ? $type : undef,
matchValue => _unescape($val),
dnAttributes => $dn ? 1 : undef
}
});
}
# special cases: present / substring match
if ($op eq '=') {
# present match
if ($val eq '*') {
return ({ present => $attr });
}
# if val contains unescaped *, then we have substring match
elsif ( $val =~ /^(\\.|[^\\*]+)*\*/o ) {
my $n = [];
my $type = 'initial';
while ($val =~ s/^((\\.|[^\\*]+)*)\*//) {
push(@$n, { $type, _unescape("$1") }) # $1 is readonly, copy it
if length($1) or $type eq 'any';
$type = 'any';
}
push(@$n, { 'final', _unescape($val) })
if length $val;
return ({
substrings => {
type => $attr,
substrings => $n
}
});
}
}
# in all other cases we must have an operator and no un-escaped *'s on the RHS
return {
$Op{$op} => {
attributeDesc => $attr, assertionValue => _unescape($val)
}
};
}
# parse & encode a filter string
sub parse {
my $self = shift;
my $filter = shift;
my @stack = (); # stack
my $cur = [];
my $op;
undef $ErrStr;
# a filter is required
if (!defined $filter) {
$ErrStr = "Undefined filter";
return undef;
}
# Algorithm depends on /^\(/;
$filter =~ s/^\s*//;
$filter = "(" . $filter . ")"
unless $filter =~ /^\(/;
while (length($filter)) {
# Process the start of (<op> (...)(...)), with <op> = [&!|]
if ($filter =~ s/^\(\s*([&!|])\s*//) {
push @stack, [$op,$cur];
$op = $1;
$cur = [];
next;
}
# Process the end of (<op> (...)(...)), with <op> = [&!|]
elsif ($filter =~ s/^\)\s*//o) {
unless (@stack) {
$ErrStr = "Bad filter, unmatched )";
return undef;
}
my($myop,$mydata) = ($op,$cur);
($op,$cur) = @{ pop @stack };
# Need to do more checking here
push @$cur, { $Op{$myop} => $myop eq '!' ? $mydata->[0] : $mydata };
next if @stack;
}
# process (attr op string)
elsif ($filter =~ s/^\(\s*
($Attr)\s*
([:~<>]?=)
((?:\\.|[^\\()]+)*)
\)\s*
//xo) {
push(@$cur, _encode($1,$2,$3));
next if @stack;
}
# If we get here then there is an error in the filter string
# so exit loop with data in $filter
last;
}
if (length $filter) {
# If we have anything left in the filter, then there is a problem
$ErrStr = "Bad filter, error before " . substr($filter,0,20);
return undef;
}
if (@stack) {
$ErrStr = "Bad filter, unmatched (";
return undef;
}
%$self = %{$cur->[0]};
$self;
}
sub print {
my $self = shift;
no strict 'refs'; # select may return a GLOB name
my $fh = @_ ? shift : select;
print $fh $self->as_string,"\n";
}
sub as_string { _string(%{$_[0]}) }
sub _string { # prints things of the form (<op> (<list>) ... )
my $str = "";
for ($_[0]) {
/^and/ and return "(&" . join("", map { _string(%$_) } @{$_[1]}) . ")";
/^or/ and return "(|" . join("", map { _string(%$_) } @{$_[1]}) . ")";
/^not/ and return "(!" . _string(%{$_[1]}) . ")";
/^present/ and return "($_[1]=*)";
/^(equalityMatch|greaterOrEqual|lessOrEqual|approxMatch)/
and return "(" . $_[1]->{attributeDesc} . $Rop{$1} . _escape($_[1]->{assertionValue}) .")";
/^substrings/ and do {
my $str = join("*", "",map { _escape($_) } map { values %$_ } @{$_[1]->{substrings}});
$str =~ s/^.// if exists $_[1]->{substrings}[0]{initial};
$str .= '*' unless exists $_[1]->{substrings}[-1]{final};
return "($_[1]->{type}=$str)";
};
/^extensibleMatch/ and do {
my $str = "(";
$str .= $_[1]->{type} if defined $_[1]->{type};
$str .= ":dn" if $_[1]->{dnAttributes};
$str .= ":$_[1]->{matchingRule}" if defined $_[1]->{matchingRule};
$str .= ":=" . _escape($_[1]->{matchValue}) . ")";
return $str;
};
}
die "Internal error $_[0]";
}
1;