/
Next.pm
440 lines (299 loc) · 11.2 KB
/
Next.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
package File::Next;
use strict;
use warnings;
=head1 NAME
File::Next - File-finding iterator
=head1 VERSION
Version 0.36
=cut
our $VERSION = '0.36';
=head1 SYNOPSIS
File::Next is a lightweight, taint-safe file-finding module.
It's lightweight and has no non-core prerequisites.
use File::Next;
my $files = File::Next->files( '/tmp' );
while ( my $file = $files->() ) {
# do something...
}
=head1 OPERATIONAL THEORY
Each of the public functions in File::Next returns an iterator that
will walk through a directory tree. The simplest use case is:
use File::Next;
my $iter = File::Next->files( '/tmp' );
while ( my $file = $iter->() ) {
print $file, "\n";
}
# Prints...
/tmp/foo.txt
/tmp/bar.pl
/tmp/baz/1
/tmp/baz/2.txt
/tmp/baz/wango/tango/purple.txt
Note that only files are returned by C<files()>'s iterator.
Directories are ignored.
In list context, the iterator returns a list containing I<$dir>,
I<$file> and I<$fullpath>, where I<$fullpath> is what would get
returned in scalar context.
The first parameter to any of the iterator factory functions may
be a hashref of parameters.
Note that the iterator will only return files, not directories.
=head1 PARAMETERS
=head2 file_filter -> \&file_filter
The file_filter lets you check to see if it's really a file you
want to get back. If the file_filter returns a true value, the
file will be returned; if false, it will be skipped.
The file_filter function takes no arguments but rather does its work through
a collection of variables.
=over 4
=item * C<$_> is the current filename within that directory
=item * C<$File::Next::dir> is the current directory name
=item * C<$File::Next::name> is the complete pathname to the file
=back
These are analogous to the same variables in L<File::Find>.
my $iter = File::Find::files( { file_filter => sub { /\.txt$/ } }, '/tmp' );
By default, the I<file_filter> is C<sub {1}>, or "all files".
This filter has no effect if your iterator is only returning directories.
=head2 descend_filter => \&descend_filter
The descend_filter lets you check to see if the iterator should
descend into a given directory. Maybe you want to skip F<CVS> and
F<.svn> directories.
my $descend_filter = sub { $_ ne "CVS" && $_ ne ".svn" }
The descend_filter function takes no arguments but rather does its work through
a collection of variables.
=over 4
=item * C<$_> is the current filename of the directory
=item * C<$File::Next::dir> is the complete directory name
=back
The descend filter is NOT applied to any directory names specified
in the constructor. For example,
my $iter = File::Next::files( { descend_filter => sub{0} }, '/tmp' );
always descends into I</tmp>, as you would expect.
By default, the I<descend_filter> is C<sub {1}>, or "always descend".
=head2 error_handler => \&error_handler
If I<error_handler> is set, then any errors will be sent through
it. By default, this value is C<CORE::die>.
=head2 sort_files => [ 0 | 1 | \&sort_sub]
If you want files sorted, pass in some true value, as in
C<< sort_files => 1 >>.
If you want a special sort order, pass in a sort function like
C<< sort_files => sub { $a->[1] cmp $b->[1] } >>.
Note that the parms passed in to the sub are arrayrefs, where $a->[0]
is the directory name, $a->[1] is the file name and $a->[2] is the
full path. Typically you're going to be sorting on $a->[2].
=head2 follow_symlinks => [ 0 | 1 ]
If set to false, File::Next will ignore any files and directories
that are actually symlinks. This has no effect on non-Unixy systems
such as Windows. By default, this is true.
Note that this filter does not apply to any of the starting files
passed in to the constructor.
=head1 FUNCTIONS
=head2 files( { \%parameters }, @starting points )
Returns an iterator that walks directories starting with the items
in I<@starting_points>. Each call to the iterator returns another file.
=head2 dirs( { \%parameters }, @starting points )
Returns an iterator that walks directories starting with the items
in I<@starting_points>. Each call to the iterator returns another
directory.
=head2 sort_standard( $a, $b )
A sort function for passing as a C<sort_files> parameter:
my $iter = File::Next::files( {
sort_files => \&File::Next::sort_reverse
}, 't/swamp' );
This function is the default, so the code above is identical to:
my $iter = File::Next::files( {
sort_files => \&File::Next::sort_reverse
}, 't/swamp' );
=head2 sort_reverse( $a, $b )
Same as C<sort_standard>, but in reverse.
=cut
use File::Spec ();
## no critic (ProhibitPackageVars)
our $name; # name of the current file
our $dir; # dir of the current file
our %files_defaults;
our %skip_dirs;
BEGIN {
%files_defaults = (
file_filter => undef,
descend_filter => undef,
error_handler => sub { CORE::die @_ },
sort_files => undef,
follow_symlinks => 1,
);
%skip_dirs = map {($_,1)} (File::Spec->curdir, File::Spec->updir);
}
sub files {
my $passed_parms = ref $_[0] eq 'HASH' ? {%{+shift}} : {}; # copy parm hash
my $parms = _handle_constructor_parms( $passed_parms, \%files_defaults );
my @queue = _init_queue( @_ );
return sub {
while (@queue) {
my ($dir,$file,$fullpath) = splice( @queue, 0, 3 );
# XXX This should be in _candidate_files
if ( !$parms->{follow_symlinks} ) {
next if -l $fullpath;
}
if (-f $fullpath) {
if ( $parms->{file_filter} ) {
local $_ = $file;
local $File::Next::dir = $dir;
local $File::Next::name = $fullpath;
next if not $parms->{file_filter}->();
}
return wantarray ? ($dir,$file,$fullpath) : $fullpath;
}
elsif (-d $fullpath) {
unshift( @queue, _candidate_files( $parms, $fullpath ) );
}
} # while
return;
}; # iterator
}
sub dirs {
my $passed_parms = ref $_[0] eq 'HASH' ? {%{+shift}} : {}; # copy parm hash
my $parms = _handle_constructor_parms( $passed_parms, \%files_defaults );
my @queue = _init_queue( @_ );
return sub {
while (@queue) {
my ($dir,$file,$fullpath) = splice( @queue, 0, 3 );
# XXX This should be in _candidate_files
if ( !$parms->{follow_symlinks} ) {
next if -l $fullpath;
}
if (-d $fullpath) {
unshift( @queue, _candidate_files( $parms, $fullpath ) );
return $fullpath;
}
} # while
return;
}; # iterator
}
=for private _handle_constructor_parms( $passed_parms )
Returns a hashref of operational parameters, combined between
I<$passed_parms> and I<$defaults>.
=cut
sub _handle_constructor_parms {
my $passed_parms = shift;
my $defaults = shift;
my %passed_parms = %{$passed_parms};
my $parms = {};
for my $key ( keys %$defaults ) {
$parms->{$key} =
exists $passed_parms{$key}
? delete $passed_parms{$key}
: $defaults->{$key};
}
# Any leftover keys are bogus
for my $badkey ( keys %passed_parms ) {
my $sub = (caller(1))[3];
$parms->{error_handler}->( "Invalid parameter passed to $sub(): $badkey" );
}
# If it's not a code ref, assume standard sort
if ( $parms->{sort_files} && ( ref($parms->{sort_files}) ne 'CODE' ) ) {
$parms->{sort_files} = \&sort_standard;
}
return $parms;
}
=for private _init_queue( @starting_points )
Takes the strings in I<@starting_points> and puts them in the format that queue needs.
The C<@queue> that gets passed around is an array that has three
elements for each of the entries in the queue: $dir, $file and
$fullpath. Items must be pushed and popped off the queue three at
a time (spliced, really).
=cut
sub _init_queue {
my @queue;
for ( @_ ) {
my $start = reslash( $_ );
if (-d $start) {
push @queue, ($start,undef,$start);
}
else {
push @queue, (undef,$start,$start);
}
}
return @queue;
}
=for private _candidate_files( $parms, $dir )
Pulls out the files/dirs that might be worth looking into in I<$dir>.
If I<$dir> is the empty string, then search the current directory.
This is different than explicitly passing in a ".", because that
will get prepended to the path names.
I<$parms> is the hashref of parms passed into File::Next constructor.
=cut
sub _candidate_files {
my $parms = shift;
my $dir = shift;
my $dh;
if ( !opendir $dh, $dir ) {
$parms->{error_handler}->( "$dir: $!" );
return;
}
my @newfiles;
while ( my $file = readdir $dh ) {
next if $skip_dirs{$file};
# Only do directory checking if we have a descend_filter
my $fullpath = File::Spec->catdir( $dir, $file );
if ( $parms->{descend_filter} && -d $fullpath ) {
local $File::Next::dir = $fullpath;
local $_ = $file;
next if not $parms->{descend_filter}->();
}
push( @newfiles, $dir, $file, $fullpath );
}
if ( my $sub = $parms->{sort_files} ) {
my @triplets;
while ( @newfiles ) {
push @triplets, [splice( @newfiles, 0, 3 )];
}
@newfiles = map { @{$_} } sort $sub @triplets;
}
return @newfiles;
}
sub sort_standard($$) { return $_[0]->[1] cmp $_[1]->[1] }; ## no critic (ProhibitSubroutinePrototypes)
sub sort_reverse($$) { return $_[1]->[1] cmp $_[0]->[1] }; ## no critic (ProhibitSubroutinePrototypes)
=head2 reslash( $path )
Takes a path with all forward slashes and rebuilds it with whatever
is appropriate for the platform. For example 'foo/bar/bat' will
become 'foo\bar\bat' on Windows.
This is really just a convenience function.
=cut
sub reslash {
my $path = shift;
my @parts = split( /\//, $path );
return $path if @parts < 2;
return File::Spec->catfile( @parts );
}
=head1 AUTHOR
Andy Lester, C<< <andy at petdance.com> >>
=head1 BUGS
Please report any bugs or feature requests to
C<bug-file-next at rt.cpan.org>, or through the web interface at
L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=File-Next>.
I will be notified, and then you'll automatically be notified of
progress on your bug as I make changes.
=head1 SUPPORT
You can find documentation for this module with the perldoc command.
perldoc File::Next
You can also look for information at:
=over 4
=item * AnnoCPAN: Annotated CPAN documentation
L<http://annocpan.org/dist/File-Next>
=item * CPAN Ratings
L<http://cpanratings.perl.org/d/File-Next>
=item * RT: CPAN's request tracker
L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=File-Next>
=item * Search CPAN
L<http://search.cpan.org/dist/File-Next>
=item * Subversion repository
L<https://file-next.googlecode.com/svn/trunk>
=back
=head1 ACKNOWLEDGEMENTS
All file-finding in this module is adapted from Mark Jason Dominus'
marvelous I<Higher Order Perl>, page 126.
=head1 COPYRIGHT & LICENSE
Copyright 2006-2007 Andy Lester, all rights reserved.
This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.
=cut
1; # End of File::Next