-
Notifications
You must be signed in to change notification settings - Fork 67
/
SlangMemoryManager.class.st
411 lines (294 loc) · 10.3 KB
/
SlangMemoryManager.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
Class {
#name : #SlangMemoryManager,
#superclass : #Object,
#instVars : [
'memoryMap',
'wordSize',
'initialAddress'
],
#category : #'Slang-Simulation'
}
{ #category : #allocating }
SlangMemoryManager >> allocate: desiredSize [
^ self allocate: desiredSize desiredPosition: initialAddress
]
{ #category : #allocating }
SlangMemoryManager >> allocate: desiredSize desiredPosition: desiredPos [
| allocatedAddress newMemoryRegion allocatedSize newMemory desiredPosition |
"Allocate chunks multiple of 4KB, as they are required by the machine code simulator"
allocatedSize := self roundUpToPageSize: desiredSize.
desiredPosition := self roundUpToPageSize: desiredPos.
self checkIsRegionAddress: desiredPosition.
allocatedAddress := self findHoleBiggerThan: allocatedSize from: desiredPosition.
"Warrantee that memory regions do not move, for simulation purposes with the FFI"
newMemory := ByteArray new: allocatedSize.
newMemory pinInMemory.
newMemoryRegion := SlangMemoryRegion new
start: allocatedAddress;
memory: newMemory;
originallyRequestedMemory: desiredSize;
yourself.
"Index regions by the high bits of the address"
self
registerNewRegion: newMemoryRegion
size: desiredSize
address: allocatedAddress.
^ allocatedAddress
]
{ #category : #allocating }
SlangMemoryManager >> checkIsRegionAddress: address [
((address bitAnd: 16rfff) > 0)
ifTrue: [ self error: 'Not a region start address' ]
]
{ #category : #accessing }
SlangMemoryManager >> copyFrom: start to: end [
| region |
region := self regionForAddress: start.
^ region memory
copyFrom: start - region start + 1
to: ((end - region start + 1) min: region memory size)
]
{ #category : #allocating }
SlangMemoryManager >> findHoleBiggerThan: desiredSize from: desiredPosition [
| foundPosition |
self assert: desiredSize >= self pageSize.
foundPosition := desiredPosition.
[ self wholeAt: foundPosition fits: desiredSize ]
whileFalse: [ foundPosition := foundPosition + desiredSize ].
^ foundPosition
]
{ #category : #'memory-access' }
SlangMemoryManager >> float32At: address [
| region |
"Check the access is aligned to the size we want to read"
address \\ 4 ~= 0 ifTrue: [self unalignedAccessError].
"Get the memory region where the address is stored"
region := self regionForAddress: address.
^ region
floatAt: address - region start
]
{ #category : #'memory-access' }
SlangMemoryManager >> float32At: address put: value [
| region |
"Check the access is aligned to the size we want to read"
address \\ 4 ~= 0 ifTrue: [self unalignedAccessError].
"Get the memory region where the address is stored"
region := self regionForAddress: address.
^ region
floatAt: address - region start
put: value
]
{ #category : #'memory-access' }
SlangMemoryManager >> float64At: address [
| region |
"Check the access is aligned to the size we want to read"
address \\ 8 ~= 0 ifTrue: [self unalignedAccessError].
"Get the memory region where the address is stored"
region := self regionForAddress: address.
^ region
doubleAt: address - region start
]
{ #category : #'memory-access' }
SlangMemoryManager >> float64At: address put: value [
| region |
"Check the access is aligned to the size we want to read"
address \\ 8 ~= 0 ifTrue: [self unalignedAccessError].
"Get the memory region where the address is stored"
region := self regionForAddress: address.
^ region
doubleAt: address - region start
put: value
]
{ #category : #allocating }
SlangMemoryManager >> free: address [
self checkIsRegionAddress: address.
memoryMap removeKey: address >> 12
]
{ #category : #accessing }
SlangMemoryManager >> initialAddress: anInteger [
initialAddress := anInteger
]
{ #category : #allocating }
SlangMemoryManager >> initialize [
super initialize.
initialAddress := 4*1024.
memoryMap := Dictionary new
]
{ #category : #'memory-access' }
SlangMemoryManager >> int32AtPointer: address put: aValue [
^ self writeSignedInteger: aValue at: address size: 4
]
{ #category : #'memory-access' }
SlangMemoryManager >> isValidAddress: address [
"Memory regions are allocated in multiples of 4KB (12 bits).
The Memory map indexes memory regions by the high part"
^ memoryMap includesKey: address >> 12
]
{ #category : #'memory-access' }
SlangMemoryManager >> long32At: address [
^ self readUnsignedIntegerAt: address size: 4
]
{ #category : #'memory-access' }
SlangMemoryManager >> long32At: address put: a32BitValue [
^ self writeSignedInteger: a32BitValue at: address size: 4
]
{ #category : #'memory-access' }
SlangMemoryManager >> long64At: address [
^ self readSignedIntegerAt: address size: 8
]
{ #category : #'memory-access' }
SlangMemoryManager >> long64At: address put: a64BitValue [
^ self writeSignedInteger: a64BitValue at: address size: 8
]
{ #category : #'memory-access' }
SlangMemoryManager >> longAt: address [
^ self readSignedIntegerAt: address size: self wordSize
]
{ #category : #'memory-access' }
SlangMemoryManager >> longAt: address put: aWordSizedValue [
^ self writeSignedInteger: aWordSizedValue at: address size: self wordSize
]
{ #category : #utils }
SlangMemoryManager >> pageSize [
^ 4096
]
{ #category : #'memory-access' }
SlangMemoryManager >> readIntegerAt: address size: size signed: aBoolean [
| region |
"Check the access is aligned to the size we want to read"
address \\ size ~= 0 ifTrue: [self unalignedAccessError].
"Get the memory region where the address is stored"
region := self regionForAddress: address.
^ region
integerAt: address - region start
size: size
signed: aBoolean
]
{ #category : #'memory-access' }
SlangMemoryManager >> readSignedIntegerAt: address size: size [
^ self readIntegerAt: address size: size signed: true
]
{ #category : #'memory-access' }
SlangMemoryManager >> readUnsignedIntegerAt: address size: size [
^ self readIntegerAt: address size: size signed: false
]
{ #category : #'memory-allocation' }
SlangMemoryManager >> reallocate: originalAddress withSize: desiredSize [
| newAddress oldRegion newRegion |
newAddress := self allocate: desiredSize.
oldRegion := self regionAtAddress: originalAddress.
newRegion := self regionAtAddress: newAddress.
newRegion replaceFrom: 1 to: oldRegion originallyRequestedMemory with: oldRegion.
self free: originalAddress.
^ newAddress
]
{ #category : #'memory-access' }
SlangMemoryManager >> regionAtAddress: address [
self checkIsRegionAddress: address.
^ self regionForAddress: address
]
{ #category : #'memory-access' }
SlangMemoryManager >> regionForAddress: address [
"Memory regions are allocated in multiples of 4KB (12 bits).
The Memory map indexes memory regions by the high part"
^ memoryMap at: address >> 12
]
{ #category : #enumerating }
SlangMemoryManager >> regionsDo: aFullBlockClosure [
memoryMap values asSet do: [ :region |
aFullBlockClosure
value: region start
value: region memory ]
]
{ #category : #allocating }
SlangMemoryManager >> registerNewRegion: newMemoryRegion size: desiredSize address: allocatedAddress [
allocatedAddress to: (allocatedAddress + desiredSize - 1) by: self pageSize do: [
:pageAddress | "Index regions by the high bits of the address"
memoryMap at: pageAddress >> 12 put: newMemoryRegion ]
]
{ #category : #utils }
SlangMemoryManager >> roundUpToPageSize: desiredSize [
^ (desiredSize / self pageSize) ceiling * self pageSize
]
{ #category : #'memory-access' }
SlangMemoryManager >> uint32AtPointer: anInteger [
^ self unsignedLong32At: anInteger
]
{ #category : #'memory-access' }
SlangMemoryManager >> uint32AtPointer: anInteger put: anInteger2 [
^ self unsignedLong32At: anInteger put: anInteger2
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedByteAt: anInteger [
^ self readUnsignedIntegerAt: anInteger size: 1
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedByteAt: anAddress put: aValue [
^ self writeUnsignedInteger: aValue at: anAddress size: 1
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedLong32At: address [
^ self readUnsignedIntegerAt: address size: 4
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedLong32At: address put: aValue [
^ self writeUnsignedInteger: aValue at: address size: 4
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedLong64At: address [
^ self readUnsignedIntegerAt: address size: 8
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedLong64At: address put: a64BitValue [
^ self writeUnsignedInteger: a64BitValue at: address size: 8
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedLongAt: address [
^ self readUnsignedIntegerAt: address size: self wordSize
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedLongAt: address put: aValue [
^ self writeUnsignedInteger: aValue at: address size: self wordSize
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedShortAt: anAddress [
^ self readUnsignedIntegerAt: anAddress size: 2
]
{ #category : #'memory-access' }
SlangMemoryManager >> unsignedShortAt: anAddress put: aValue [
^ self writeUnsignedInteger: aValue at: anAddress size: 2
]
{ #category : #allocating }
SlangMemoryManager >> wholeAt: foundPosition fits: desiredSize [
^ (foundPosition to: (foundPosition + desiredSize) by: self pageSize)
allSatisfy: [ :position | self checkIsRegionAddress: position. (memoryMap includesKey: position >> 12) not ]
]
{ #category : #accessing }
SlangMemoryManager >> wordSize [
^ wordSize
]
{ #category : #accessing }
SlangMemoryManager >> wordSize: anObject [
wordSize := anObject
]
{ #category : #'memory-access' }
SlangMemoryManager >> writeInteger: aValue at: address size: size signed: aBoolean [
| region |
"Check the access is aligned to the size we want to read"
address \\ size ~= 0 ifTrue: [self unalignedAccessError].
"Get the memory region where the address is stored"
region := self regionForAddress: address.
^ region
integerAt: address - region start
put: aValue
size: size
signed: aBoolean
]
{ #category : #'memory-access' }
SlangMemoryManager >> writeSignedInteger: aValue at: address size: size [
^ self writeInteger: aValue at: address size: size signed: true
]
{ #category : #'memory-access' }
SlangMemoryManager >> writeUnsignedInteger: aValue at: address size: size [
^ self writeInteger: aValue at: address size: size signed: false
]