-
Notifications
You must be signed in to change notification settings - Fork 67
/
SpurSweeper.class.st
95 lines (78 loc) · 3.29 KB
/
SpurSweeper.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
"
SpurSweeper is a sweep-only algorithm, setting the compactor to SpurSweeper effectively changes the fullGC to a mark-sweep non-moving algorithm.
SpurSweeper is a reference implementation if one wants to evaluate GC performance and compare it to a Mark-Sweep. It's also the only non-moving GC available right now which can be convenient for some experiments. One of the main reason why it was implemented is because advanced compaction algorithm includes a sweep phase (See SelectiveCompactor for example) and SpurSweeper allows to debug the sweep phase separatedly.
"
Class {
#name : #SpurSweeper,
#superclass : #SpurCompactor,
#category : #'VMMaker-SpurMemoryManager'
}
{ #category : #api }
SpurSweeper >> biasForGC [
]
{ #category : #api }
SpurSweeper >> biasForSnapshot [
]
{ #category : #'sweep phase' }
SpurSweeper >> bulkFreeChunkFrom: objOop [
"The old space entity before objOop is necessarily a marked object. Attempts to free as many bytes
from objOop start as possible, looking ahead to free contiguous freechunks / unmarked objects"
| bytes start next currentObj |
self assert: ((manager isMarked: objOop) not or: [manager isFreeObject: objOop]).
start := manager startOfObject: objOop.
currentObj := objOop.
bytes := 0.
[bytes := bytes + (manager bytesInObject: currentObj).
(manager isRemembered: currentObj)
ifTrue:
[self assert: (manager isFreeObject: currentObj) not.
scavenger forgetObject: currentObj].
next := manager objectStartingAt: start + bytes.
self assert: ((manager oop: next isLessThan: manager endOfMemory)
or: [next = manager endOfMemory and: [(self canUseAsFreeSpace: next) not]]).
self canUseAsFreeSpace: next]
whileTrue: [currentObj := next].
^self interceptAddFreeChunkWithBytes: bytes at: start
]
{ #category : #'sweep phase' }
SpurSweeper >> canUseAsFreeSpace: objOop [
<inline: true>
^ (manager isFreeObject: objOop) or: [(manager isMarked: objOop) not]
]
{ #category : #api }
SpurSweeper >> compact [
<inline: #never> "for profiling"
self resetFreeLists.
self globalSweep.
manager updateSweepEndUsecs
]
{ #category : #'sweep phase' }
SpurSweeper >> globalSweep [
"Iterate over all entities, in order, making large free chunks from free chunks and unmarked objects,
unmarking live objects and rebuilding the free lists."
| currentEntity |
currentEntity := manager firstObject.
[self oop: currentEntity isLessThan: manager endOfMemory] whileTrue:
[(self canUseAsFreeSpace: currentEntity)
ifTrue: [currentEntity := self bulkFreeChunkFrom: currentEntity]
ifFalse: [self unmark: currentEntity].
currentEntity := manager objectAfter: currentEntity limit: manager endOfMemory].
manager checkFreeSpace: GCModeFull.
manager unmarkSurvivingObjectsForCompact.
]
{ #category : #'sweep phase' }
SpurSweeper >> interceptAddFreeChunkWithBytes: bytes at: start [
<inline: true>
^manager addFreeChunkWithBytes: bytes at: start
]
{ #category : #api }
SpurSweeper >> resetFreeLists [
manager resetFreeListHeads.
manager totalFreeOldSpace: 0.
]
{ #category : #'sweep phase' }
SpurSweeper >> unmark: objOop [
self assert: ((manager isMarked: objOop) and: [(manager isFreeObject: objOop) not]).
(manager isSegmentBridge: objOop) ifFalse: [manager setIsMarkedOf: objOop to: false].
(manager isPinned: objOop) ifTrue: [manager segmentManager notePinned: objOop]
]