-
Notifications
You must be signed in to change notification settings - Fork 67
/
Spur64BitMemoryManager.class.st
1258 lines (1117 loc) · 44.3 KB
/
Spur64BitMemoryManager.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
Class {
#name : #Spur64BitMemoryManager,
#superclass : #SpurMemoryManager,
#category : #'VMMaker-SpurMemoryManager'
}
{ #category : #'class initialization' }
Spur64BitMemoryManager class >> initializeWithOptions: optionsDictionary [
"SpurMemoryManager initializeWithOptions: Dictionary new"
optionsDictionary at: #Spur64BitMemoryManager put: true.
super initializeWithOptions: optionsDictionary
]
{ #category : #'simulation only' }
Spur64BitMemoryManager class >> isImmediate: anObject [
self flag: 'The float range is close but probably wrong. Revisit when immediate floats are implemented'.
^(anObject isInteger and: [anObject between: self minSmallInteger and: self maxSmallInteger])
or: [anObject isCharacter
or: [anObject isFloat and: [anObject exponent between: -126 and: 127]]]
"1.0e-38 exponent -127
1.0e38 exponent 126
NumberParser new makeFloatFromMantissa: 1 exponent: 127 base: 2 1.7014118346046923e38
(NumberParser new makeFloatFromMantissa: 1 exponent: 127 base: 2) exponent 127
NumberParser new makeFloatFromMantissa: 1 exponent: -126 base: 2 1.1754943508222875e-38
(NumberParser new makeFloatFromMantissa: 1 exponent: -126 base: 2) exponent -126"
]
{ #category : #translation }
Spur64BitMemoryManager class >> maxSmallInteger [
^16rFFFFFFFFFFFFFFF
]
{ #category : #translation }
Spur64BitMemoryManager class >> minSmallInteger [
^-16r1000000000000000
]
{ #category : #'simulation only' }
Spur64BitMemoryManager class >> numSmallIntegerTagBits [
^3
]
{ #category : #'simulation only' }
Spur64BitMemoryManager class >> simulatorClass [
^ Spur64BitMMLESimulator
]
{ #category : #'word size' }
Spur64BitMemoryManager class >> wordSize [
"Answer the manager's word size, which is the size of an oop, and which
is assumed to be equivalent to the underlying machine's word size."
^8
]
{ #category : #'object enumeration' }
Spur64BitMemoryManager >> addressAfter: objOop [
"Answer the address immediately following an object."
<returnTypeC: #usqInt>
| numSlots |
numSlots := self rawNumSlotsOf: objOop.
numSlots = 0 ifTrue: [^objOop + self allocationUnit + self baseHeaderSize].
numSlots = self numSlotsMask ifTrue:
[numSlots := self rawOverflowSlotsOf: objOop].
^objOop + self baseHeaderSize + (numSlots bitShift: self shiftForWord)
]
{ #category : #'type-support' }
Spur64BitMemoryManager >> asSignedPlatformInteger: anInteger [
^ anInteger signedIntFromLong64
]
{ #category : #snapshot }
Spur64BitMemoryManager >> byteSwapped: w [
"Answer the given integer with its bytes in the reverse order."
<api>
<returnTypeC: #sqInt>
^w byteSwap64
]
{ #category : #'object enumeration' }
Spur64BitMemoryManager >> bytesInObject: objOop [
"Answer the total number of bytes in an object including header and possible overflow size header."
<returnTypeC: #usqInt>
| header headerNumSlots numSlots |
<var: 'header' type: #usqLong>
self flag: #endianness.
header := self long64At: objOop.
headerNumSlots := header >> self numSlotsFullShift.
numSlots := headerNumSlots = self numSlotsMask
ifTrue: [self rawOverflowSlotsOf: objOop]
ifFalse: [headerNumSlots = 0 ifTrue: [1] ifFalse: [headerNumSlots]].
^numSlots << self shiftForWord
+ (headerNumSlots = self numSlotsMask
ifTrue: [self baseHeaderSize + self baseHeaderSize]
ifFalse: [self baseHeaderSize])
]
{ #category : #'object enumeration' }
Spur64BitMemoryManager >> bytesInObject: objOop given: rawNumSotsOfObjOop [
"Answer the total number of bytes in an object including header and possible overflow size header, given the value of the object's numSlots field."
<returnTypeC: #usqInt>
<inline: true>
| numSlots |
numSlots := rawNumSotsOfObjOop = self numSlotsMask
ifTrue: [self rawOverflowSlotsOf: objOop]
ifFalse: [rawNumSotsOfObjOop = 0 ifTrue: [1] ifFalse: [rawNumSotsOfObjOop]].
^numSlots << self shiftForWord
+ (rawNumSotsOfObjOop = self numSlotsMask
ifTrue: [self baseHeaderSize + self baseHeaderSize]
ifFalse: [self baseHeaderSize])
]
{ #category : #accessing }
Spur64BitMemoryManager >> bytesPerOop [
^8
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> changeClassOf: rcvr to: argClass [
"Attempt to change the class of the receiver to the argument given that the
format of the receiver matches the format of the argument. If successful,
answer 0, otherwise answer an error code indicating the reason for failure.
Fail if the format of the receiver is incompatible with the format of the argument,
or if the argument is a fixed class and the receiver's size differs from the size
that an instance of the argument should have."
<inline: false>
| classFormat fixedFields instFormat newFormat classIndex instSlots instBytes |
(self isObjImmutable: rcvr) ifTrue:
[^PrimErrNoModification].
classFormat := self formatOfClass: argClass.
fixedFields := self fixedFieldsOfClassFormat: classFormat.
classFormat := self instSpecOfClassFormat: classFormat.
instFormat := self formatOf: rcvr.
"Fail for inability to access classIndex before making contexts snapshot-safe."
(classIndex := self ensureBehaviorHash: argClass) < 0 ifTrue:
[^classIndex negated].
"Now check the instance for compatibility and compute odd bits if necessary."
classFormat <= self lastPointerFormat
ifTrue:
[instFormat > self lastPointerFormat ifTrue:
[^PrimErrInappropriate].
((instSlots := self numSlotsOf: rcvr) < fixedFields
or: [instSlots > fixedFields and: [self isFixedSizePointerFormat: classFormat]]) ifTrue:
[^PrimErrBadReceiver].
(instFormat = self indexablePointersFormat
and: [self isContextNonImm: rcvr]) ifTrue:
[coInterpreter makeContextSnapshotSafe: rcvr].
newFormat := classFormat]
ifFalse:
["Fail if the class's format is somehow invalid."
classFormat ~= (self classFormatForInstanceFormat: classFormat) ifTrue:
[^PrimErrBadArgument].
instBytes := self numBytesOf: rcvr.
classFormat
caseOf: {
[self sixtyFourBitIndexableFormat]
-> [(instBytes anyMask: 7) ifTrue: [^PrimErrBadReceiver].
newFormat := classFormat].
[self firstLongFormat]
-> [(instBytes anyMask: 3) ifTrue: [^PrimErrBadReceiver].
newFormat := classFormat + (2 - (instBytes >> 2) bitAnd: 1)].
[self firstShortFormat]
-> [(instBytes anyMask: 1) ifTrue: [^PrimErrBadReceiver].
newFormat := classFormat + (4 - (instBytes >> 1) bitAnd: 3)].
[self firstByteFormat]
-> [newFormat := classFormat + (8 - instBytes bitAnd: 7)].
[self firstCompiledMethodFormat]
-> [classFormat ~= self firstCompiledMethodFormat ifTrue:
[^PrimErrInappropriate].
newFormat := instFormat] }
otherwise: "bits instances cannot be adopted by pointer-like classes..."
[^PrimErrInappropriate]].
self set: rcvr classIndexTo: classIndex formatTo: newFormat.
self assert: (self numBytesOf: rcvr) = (classFormat <= self lastPointerFormat
ifTrue: [instSlots * self bytesPerOop]
ifFalse: [instBytes]).
"ok"
^0
]
{ #category : #'gc - global' }
Spur64BitMemoryManager >> coalesce: obj1 and: obj2 [
| header1NumSlots header2NumSlots obj2slots newNumSlots |
header1NumSlots := self rawNumSlotsOf: obj1.
header2NumSlots := self rawNumSlotsOf: obj2.
"compute total number of slots in obj2, including header"
obj2slots := header2NumSlots = self numSlotsMask
ifTrue: [(self rawOverflowSlotsOf: obj2) + (2 * self baseHeaderSize / self wordSize)]
ifFalse: [(header2NumSlots = 0 ifTrue: [1] ifFalse: [header2NumSlots]) + (self baseHeaderSize / self wordSize)].
self assert: obj2slots * self wordSize = (self bytesInObject: obj2).
"if obj1 already has a double header things are simple..."
header1NumSlots = self numSlotsMask ifTrue:
[self rawOverflowSlotsOf: obj1 put: obj2slots + (self rawOverflowSlotsOf: obj1).
^obj1].
"compute total number of slots in obj1, excluding header"
header1NumSlots := header1NumSlots = 0 ifTrue: [1] ifFalse: [header1NumSlots].
self assert: header1NumSlots * self wordSize + self baseHeaderSize = (self bytesInObject: obj1).
newNumSlots := obj2slots + header1NumSlots.
"if obj1 still only requires a single header things are simple..."
newNumSlots < self numSlotsMask ifTrue:
[self rawNumSlotsOf: obj1 put: newNumSlots.
^obj1].
"convert from single to double header..."
newNumSlots := newNumSlots - (self baseHeaderSize / self wordSize).
self
rawNumSlotsOf: obj1 + self baseHeaderSize put: self numSlotsMask;
rawOverflowSlotsOf: obj1 + self baseHeaderSize put: newNumSlots.
^obj1 + self baseHeaderSize
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> dbgFloatValueOf: oop [
"Answer the C double precision floating point value of the argument,
or if it is not, answer 0."
| result tagBits |
<returnTypeC: #double>
<var: #result type: #double>
(tagBits := oop bitAnd: self tagMask) ~= 0
ifTrue:
[tagBits = self smallFloatTag ifTrue:
[^self smallFloatValueOf: oop]]
ifFalse:
[(self classIndexOf: oop) = ClassFloatCompactIndex ifTrue:
[self cCode: '' inSmalltalk: [result := Float new: 2].
self fetchFloatAt: oop + self baseHeaderSize into: result.
^result]].
^0.0
]
{ #category : #snapshot }
Spur64BitMemoryManager >> defaultEdenBytes [
"Answer the default amount of memory to allocate for the eden space.
The actual value can be set via vmParameterAt: and/or a preference in the ini file.
The shootout tests seem to plateau at 5 or 6Mb.
Originally, both the 32-bit and 64-bit versions used the same 4Mb default. Measuring
the simulator on image start-up, the 64-bit system's eden at the same point in start-up
(the first copyBits) is only 8% larger in bytes because it allocates 26% fewer objects.
Some 21% of the objects in the 32-bit version's eden are large integers and floats that
are representable as 64-bit immediates.
But when running benchmarks such as the computer language shootout's binary trees,
using the same amount of memory for the 64-bit system causes a significant slow-down
and a lot of compactions. So we now use 4Mb for 32-bits and 7Mb for 64-bits."
<inline: false>
^7 * 1024 * 1024
"Here are the expressions used to collect the above-mentioned figures:"
"freeStart - self newSpaceStart"
"| n | n := 0. self allNewSpaceObjectsDo: [:o| n := n + 1]. n"
"| f | f := 0. self allNewSpaceObjectsDo: [:o| (self isFloatObject: o) ifTrue: [f := f + 1]]. f"
"| l | l := 0. self allNewSpaceObjectsDo: [:o|
(((self classIndexOf: o)
between: ClassLargeNegativeIntegerCompactIndex
and: ClassLargePositiveIntegerCompactIndex)
and: [(self numBytesOfBytes: o) <= 8
and: [self isIntegerValue: (coInterpreter signed64BitValueOf: o)]]) ifTrue: [l := l + 1]]. l"
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> exponentOfSmallFloat: oop [
"Answer the exponent of the argument, a SmallFloat.
See section 61-bit Immediate Floats in the SpurMemoryManager class comment.
msb lsb
[8expsubset][52mantissa][1s][3tags]"
| exp |
self assert: (oop bitAnd: self tagMask) = self smallFloatTag.
^oop asUnsignedInteger <= 15
ifTrue: [0]
ifFalse:
[exp := oop asUnsignedInteger >> (self numTagBits + self smallFloatMantissaBits + 1).
exp + self smallFloatExponentOffset - 1022]
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> fetchClassTagOf: oop [
<api>
<returnTypeC: #sqInt>
| tagBits |
^(tagBits := oop bitAnd: self tagMask) ~= 0
ifTrue: [tagBits]
ifFalse: [self classIndexOf: oop]
]
{ #category : #'object access' }
Spur64BitMemoryManager >> fetchLong32: fieldIndex ofFloatObject: oop [
"index by word size, and return a pointer as long as the word size"
<returnTypeC: #usqInt>
| bits |
(self isImmediateFloat: oop) ifFalse: [
^ self fetchLong32: fieldIndex ofObject: oop ].
bits := self smallFloatBitsOf: oop.
^ fieldIndex = 0
ifTrue: [ bits bitAnd: 16rFFFFFFFF ]
ifFalse: [ bits >> 32 ]
]
{ #category : #instantiation }
Spur64BitMemoryManager >> fillObj: objOop numSlots: numSlots with: fillValue [
<inline: true>
<var: #p type: #usqInt>
self assert: (self oop: objOop + self baseHeaderSize + (numSlots * self bytesPerOop) - 1
isLessThan: (self addressAfter: objOop)).
(objOop + self baseHeaderSize) asUnsignedInteger
to: (objOop + self baseHeaderSize + (numSlots * self bytesPerOop) - 1) asUnsignedInteger
by: self allocationUnit
do: [:p| self uint64At: p put: fillValue]
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> floatObjectOf: aFloat [
<inline: false>
<var: #aFloat type: #double>
<api>
(self isSmallFloatValue: aFloat) ifTrue:
[^self smallFloatObjectOf: aFloat].
^ self boxedFloatObjectOf: aFloat
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> floatValueOf: oop [
"Answer the C double precision floating point value of the argument,
or fail if it is not a Float, and answer 0.
Note: May be called by translated primitive code."
| result tagBits |
<returnTypeC: #double>
<var: #result type: #double>
(tagBits := oop bitAnd: self tagMask) ~= 0
ifTrue:
[tagBits = self smallFloatTag ifTrue:
[^self smallFloatValueOf: oop]]
ifFalse:
[(self classIndexOf: oop) = ClassFloatCompactIndex ifTrue:
[self cCode: '' inSmalltalk: [result := Float new: 2].
self fetchFloatAt: oop + self baseHeaderSize into: result.
^result]].
coInterpreter primitiveFail.
^0.0
]
{ #category : #accessing }
Spur64BitMemoryManager >> freeLists [
<doNotGenerate>
^ freeLists
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> hasSixtyFourBitImmediates [
"The V3 64-bit memory manager has 64-bit oops, but its SmallIntegers only have
31 bits of precision. The Spur 64-bit memory manager has 61-bit immediates."
^true
]
{ #category : #immediates }
Spur64BitMemoryManager >> imageFormatVersion [
"Return a magic constant that changes when the image format changes.
Since the image reading code uses this to detect byte ordering, one
must avoid version numbers that are invariant under byte reversal.
N.B. Bit 4 (=16) is the isSpur bit"
"^68019" "The first 64-bit Spur format, which unfortunately chose SmallFloat64's tag to be 3."
^68021
]
{ #category : #'free space' }
Spur64BitMemoryManager >> initFreeChunkWithBytes: numBytes at: address [
<var: #numBytes type: #usqLong>
| numSlots |
"must have room for a header (single or double) plus the next free pointer"
self assert: (numBytes \\ self allocationUnit = 0
and: [numBytes >= (self baseHeaderSize + self bytesPerOop)]).
"double header"
numBytes >= ((self numSlotsMask << self shiftForWord) + self baseHeaderSize) ifTrue:
[numSlots := numBytes - self baseHeaderSize - self baseHeaderSize >> self shiftForWord.
self longAt: address put: self numSlotsMask << self numSlotsFullShift + numSlots;
longAt: address + 8 put: self numSlotsMask << self numSlotsFullShift. "0's classIndex; 0 = classIndex of free chunks"
^address + 8].
"single header"
numSlots := numBytes - self baseHeaderSize >> self shiftForWord.
self assert: numSlots < self numSlotsMask.
self longAt: address put: numSlots << self numSlotsFullShift. "0's classIndex; 0 = classIndex of free chunks"
^address
]
{ #category : #segments }
Spur64BitMemoryManager >> initSegmentBridgeWithBytes: numBytes at: address [
<var: #numBytes type: #usqLong>
| numSlots |
"must have room for a double header"
self assert: (numBytes \\ self allocationUnit = 0
and: [numBytes >= (self baseHeaderSize + self baseHeaderSize)]).
numSlots := numBytes - self baseHeaderSize - self baseHeaderSize >> self shiftForWord.
numSlots = 0
ifTrue: "short bridge for adjacent segments"
[self longAt: address
put: (1 << self pinnedBitShift)
+ (1 << self markedBitFullShift)
+ (self wordIndexableFormat << self formatShift)
+ self segmentBridgePun]
ifFalse: "long bridge"
[self longAt: address
put: self numSlotsMask << self numSlotsFullShift + numSlots;
longAt: address + self baseHeaderSize
put: (self numSlotsMask << self numSlotsFullShift)
+ (1 << self pinnedBitShift)
+ (1 << self markedBitFullShift)
+ (self wordIndexableFormat << self formatShift)
+ self segmentBridgePun]
]
{ #category : #instantiation }
Spur64BitMemoryManager >> instantiateClass: classObj indexableSize: nElements isPinned: isPinned [
<api>
<var: #nElements type: #usqInt>
"Allocate an instance of a variable class, excepting CompiledMethod."
| instSpec classFormat numSlots classIndex newObj fillValue |
classFormat := self formatOfClass: classObj.
instSpec := self instSpecOfClassFormat: classFormat.
classIndex := self rawHashBitsOf: classObj.
fillValue := 0.
instSpec caseOf: {
[self arrayFormat] ->
[numSlots := nElements.
fillValue := nilObj].
[self indexablePointersFormat] ->
[numSlots := (self fixedFieldsOfClassFormat: classFormat) + nElements.
fillValue := nilObj].
[self weakArrayFormat] ->
[numSlots := (self fixedFieldsOfClassFormat: classFormat) + nElements.
fillValue := nilObj].
[self sixtyFourBitIndexableFormat] ->
[numSlots := nElements].
[self firstLongFormat] ->
[(classIndex = ClassFloatCompactIndex and: [nElements ~= 2]) ifTrue:
[coInterpreter primitiveFailFor: PrimErrBadReceiver.
^nil].
numSlots := nElements + 1 // 2.
instSpec := instSpec + (nElements bitAnd: 1)].
[self firstShortFormat] ->
[numSlots := nElements + 3 // 4.
instSpec := instSpec + (4 - nElements bitAnd: 3)].
[self firstByteFormat] ->
[numSlots := nElements + 7 // 8.
instSpec := instSpec + (8 - nElements bitAnd: 7)] }
otherwise: "non-indexable"
["Some Squeak images include funky fixed subclasses of abstract variable
superclasses. e.g. DirectoryEntry as a subclass of ArrayedCollection.
The (Threaded)FFIPlugin expects to be able to instantiate ExternalData via
this method.
Hence allow fixed classes to be instantiated here iff nElements = 0."
(nElements ~= 0 or: [instSpec > self lastPointerFormat]) ifTrue:
[^nil].
numSlots := self fixedFieldsOfClassFormat: classFormat.
fillValue := nilObj].
classIndex = 0 ifTrue:
[classIndex := self ensureBehaviorHash: classObj.
classIndex < 0 ifTrue:
[coInterpreter primitiveFailFor: classIndex negated.
^nil]].
(numSlots > self maxSlotsForNewSpaceAlloc or: [isPinned])
ifTrue:
[numSlots > self maxSlotsForAlloc ifTrue:
[coInterpreter primitiveFailFor: PrimErrUnsupported.
^nil].
newObj := self
allocateSlotsInOldSpace: numSlots
format: instSpec
classIndex: classIndex
isPinned: isPinned]
ifFalse:
[newObj := self allocateSlots: numSlots format: instSpec classIndex: classIndex].
newObj ifNotNil:
[self fillObj: newObj numSlots: numSlots with: fillValue].
^newObj
]
{ #category : #instantiation }
Spur64BitMemoryManager >> instantiateCompiledMethodClass: classObj indexableSize: nElements [
<var: #nElements type: #usqInt>
"Allocate an instance of a CompiledMethod class."
<inline: true>
| instSpec classFormat numSlots classIndex newObj |
classFormat := self formatOfClass: classObj.
instSpec := self instSpecOfClassFormat: classFormat.
instSpec ~= self firstCompiledMethodFormat ifTrue:
[^nil].
numSlots := nElements + 7 // 8.
instSpec := instSpec + (8 - nElements bitAnd: 7).
classIndex := self ensureBehaviorHash: classObj.
classIndex < 0 ifTrue:
[coInterpreter primitiveFailFor: classIndex negated.
^nil].
numSlots > self maxSlotsForNewSpaceAlloc
ifTrue:
[numSlots > self maxSlotsForAlloc ifTrue:
[^nil].
newObj := self allocateSlotsInOldSpace: numSlots format: instSpec classIndex: classIndex]
ifFalse:
[newObj := self allocateSlots: numSlots format: instSpec classIndex: classIndex].
newObj ifNotNil:
[self fillObj: newObj numSlots: numSlots with: 0].
^newObj
]
{ #category : #immediates }
Spur64BitMemoryManager >> integerObjectOf: value [
"Convert the integer value, assumed to be in SmallInteger range, into a tagged SmallInteger object.
In C, use a shift and an add to set the tag bit.
In Smalltalk we have to work harder because the simulator works with strictly positive bit patterns."
<returnTypeC: #sqInt>
^self
cCode: [value asUnsignedInteger << self numTagBits + 1]
inSmalltalk: [value << self numTagBits
+ (value >= 0
ifTrue: [1]
ifFalse: [16r10000000000000001])]
]
{ #category : #immediates }
Spur64BitMemoryManager >> integerObjectOfCharacterObject: oop [
"Immediate characters are unsigned"
^oop - (self characterTag - self smallIntegerTag)
]
{ #category : #immediates }
Spur64BitMemoryManager >> integerValueOf: oop [
"Translator produces 'oop >> 3'"
self cCode: [ ^ oop >>> 3 ] inSmalltalk: [
^ (oop bitShift: -63) = 1
ifTrue: [ "negative"
((oop bitShift: self numTagBits negated) bitAnd:
16r1FFFFFFFFFFFFFFF) - 16r1FFFFFFFFFFFFFFF - 1 "Faster than -16r4000000000000000 (a LgInt)" ]
ifFalse: [ "positive" oop bitShift: self numTagBits negated ] "tests top bit" ]
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> isFloatInstance: oop [
<inline: true>
| tagBits |
^(tagBits := oop bitAnd: self tagMask) ~= 0
ifTrue: [tagBits = self smallFloatTag]
ifFalse: [(self classIndexOf: oop) = ClassFloatCompactIndex]
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> isFloatOrInt: anOop [
"Answer if anOop is either a SmallInteger or a Float."
<inline: true>
^(self isImmediate: anOop)
ifTrue: [(self isCharacterObject: anOop) not]
ifFalse: [(self classIndexOf: anOop) = ClassFloatCompactIndex]
]
{ #category : #'object testing' }
Spur64BitMemoryManager >> isImmediateCharacter: oop [
<inline: true>
^oop anyMask: self characterTag
]
{ #category : #'object testing' }
Spur64BitMemoryManager >> isImmediateFloat: oop [
<inline: true>
^oop anyMask: self smallFloatTag
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> isIntegerValue: intValue [
"Answer if the given value can be represented as a Smalltalk integer value.
In 64-bits we use a 3 bit tag which leaves 61 bits for 2's complement signed
integers. In C, use a shift add and mask to test if the top 4 bits are all the same.
Since 16rFFFFFFFFFFFFFFFF >> 60 = 16rF the computation intValue >> 60 + 1 bitAnd: 16rF
maps in-range -ve values to 0 and in-range +ve values to 1."
<api>
^self
cCode: [(intValue >> 60 + 1 bitAnd: 16rF) <= 1] "N.B. (16rFFFFFFFFFFFFFFFF >> 60) + 1 = 16"
inSmalltalk: [intValue >= self minSmallInteger and: [intValue <= self maxSmallInteger]]
]
{ #category : #'free space' }
Spur64BitMemoryManager >> isLilliputianSize: chunkBytes [
"To have a prev pointer, which follows the next pointer, we need at least two slots."
self assert: chunkBytes >= (self baseHeaderSize + self allocationUnit).
^chunkBytes = (self baseHeaderSize + self allocationUnit)
]
{ #category : #'header access' }
Spur64BitMemoryManager >> isMarked: objOop [
<api>
^((self longAt: objOop) >> self markedBitFullShift bitAnd: 1) ~= 0
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> isNegativeSmallFloat: aSmallFloat [
<inline: true>
self assert: (self isImmediateFloat: aSmallFloat).
^aSmallFloat anyMask: self smallFloatSignBit
]
{ #category : #'object testing' }
Spur64BitMemoryManager >> isNonIntegerObject: oop [
^oop noMask: self smallIntegerTag
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> isSmallFloatValue: aFloat [
<inline: true>
<var: #rawFloat type: #usqLong>
<var: #aFloat type: #double>
| exponent rawFloat |
self
cCode: [ self rawFloatBitsOf: aFloat in: rawFloat ]
inSmalltalk: [ rawFloat := (aFloat at: 1) << 32 + (aFloat at: 2) ].
exponent := rawFloat >> self smallFloatMantissaBits bitAnd: 16r7FF.
^ exponent > self smallFloatExponentOffset
ifTrue: [ exponent <= (255 + self smallFloatExponentOffset) ]
ifFalse: [
(rawFloat bitAnd: 1 << self smallFloatMantissaBits - 1) = 0
ifTrue: [ exponent = 0 ]
ifFalse: [ exponent = self smallFloatExponentOffset ] ]
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> isSmallFloatZero: aSmallFloat [
<inline: #always>
self assert: (self isImmediateFloat: aSmallFloat).
^aSmallFloat asUnsignedInteger <= self negativeSmallFloatZero
]
{ #category : #'object testing' }
Spur64BitMemoryManager >> isWordsNonImm: objOop [
"Answer if the argument contains only indexable words (no oops). See comment in formatOf:"
^(self formatOf: objOop) between: self firstLongFormat and: self firstShortFormat - 1
]
{ #category : #allocation }
Spur64BitMemoryManager >> largeObjectBytesForSlots: numSlots [
"Answer the total number of bytes in an object with an overflow header, including header bytes."
<returnTypeC: #usqInt>
^self baseHeaderSize + self baseHeaderSize "double header"
+ (numSlots * self bytesPerOop) "no rounding; bytesPerOop = allocationUnit"
]
{ #category : #'object access' }
Spur64BitMemoryManager >> lengthOf: objOop format: fmt [
"Answer the number of indexable units in the given object.
For a CompiledMethod, the size of the method header (in bytes)
should be subtracted from the result of this method."
| numSlots |
<inline: true>
numSlots := self numSlotsOfAny: objOop. "don't let forwarders freak us out..."
fmt <= self ephemeronFormat ifTrue:
[^numSlots].
fmt >= self firstByteFormat ifTrue: "bytes, including CompiledMethod"
[^numSlots << self shiftForWord - (fmt bitAnd: 7)].
fmt >= self firstShortFormat ifTrue:
[^numSlots << (self shiftForWord - 1) - (fmt bitAnd: 3)].
fmt >= self firstLongFormat ifTrue:
[^numSlots << (self shiftForWord - 2) - (fmt bitAnd: 1)].
fmt = self sixtyFourBitIndexableFormat ifTrue:
[^numSlots].
"fmt = self forwardedFormat"
^0
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> loadFloatOrIntFrom: floatOrIntOop [
"If floatOrInt is an integer, then convert it to a C double float and return it.
If it is a Float, then load its value and return it.
Otherwise fail -- ie return with primErrorCode non-zero."
<inline: true>
<returnTypeC: #double>
| tagBits shift |
(tagBits := floatOrIntOop bitAnd: self tagMask) ~= 0
ifTrue: [
tagBits = self smallFloatTag ifTrue: [
^ self smallFloatValueOf: floatOrIntOop ].
(tagBits = self smallIntegerTag and: [
shift := 64 - self numTagBits - self smallFloatMantissaBits.
(self
cCode: [ floatOrIntOop << shift ]
inSmalltalk: [ floatOrIntOop << shift bitAnd: 1 << 64 - 1 ])
>>> shift = floatOrIntOop ]) ifTrue: [
^ (self integerValueOf: floatOrIntOop) asFloat ] ]
ifFalse: [
(self classIndexOf: floatOrIntOop) = ClassFloatCompactIndex
ifTrue: [
^ self float64At: floatOrIntOop + self baseHeaderSize ] ].
coInterpreter primitiveFail.
^ 0.0
]
{ #category : #accessing }
Spur64BitMemoryManager >> logBytesPerOop [
^3
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> mapSignedSmallFloatToSignedSmallFloatZero: aSmallFloat [
<inline: true>
self assert: (self isImmediateFloat: aSmallFloat).
^aSmallFloat bitAnd: self smallFloatSignBit + self tagMask
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> maxCInteger [
^16rFFFFFFFFFFFFFFFF
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> maxCSignedInteger [
^16r7FFFFFFFFFFFFFFF
]
{ #category : #instantiation }
Spur64BitMemoryManager >> maxSlotsForAlloc [
"Answer the maximum number of slots we are willing to attempt to allocate in an object.
Must fit in 56-bits; c.f. bytesInObject:"
^1024*1024*1024*1024
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> maxSmallInteger [
^16rFFFFFFFFFFFFFFF
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> methodDictionaryHash: oop mask: mask [
<inline: true>
^mask bitAnd: ((self isImmediate: oop)
ifTrue: [self integerValueOf: oop] "this will fail for SmallFloat64 but we don't care"
ifFalse: [self rawHashBitsOf: oop]) "If no hash then it isn't in the dictionary..."
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> minCInteger [
"-maxInt - 1"
^-16r10000000000000000
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> minSmallInteger [
^-16r1000000000000000
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> negativeSmallFloatZero [
<inline: true>
^self smallFloatSignBit + self smallFloatTag
]
{ #category : #'free space' }
Spur64BitMemoryManager >> numFreeLists [
"Answer the number of free lists. We use freeListsMask, a bitmap, to avoid
reading empty list heads. This should fit in a machine word to end up in a
register during free chunk allocation."
^64
]
{ #category : #allocation }
Spur64BitMemoryManager >> numSlotsForShortening: objOop toIndexableSize: indexableSize [
<inline: true>
^(self formatOf: objOop) caseOf:
{ [self arrayFormat] -> [indexableSize].
[self firstLongFormat] -> [self numSlotsForBytes: indexableSize * 4].
[self firstLongFormat + 1] -> [self numSlotsForBytes: indexableSize * 4] }
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> numSmallIntegerBits [
^61
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> numSmallIntegerTagBits [
^3
]
{ #category : #'object access' }
Spur64BitMemoryManager >> numTagBits [
<api>
<cmacro>
"4th bit reserved for object alignment, which could imply e.g. what space the object is in."
^3
]
{ #category : #'object enumeration' }
Spur64BitMemoryManager >> objectAfter: objOop limit: limit [
"Object parsing.
1. all objects have at least a word following the header, for a forwarding pointer.
2. objects with an overflow size have a preceding word with a saturated numSlots. If the word
following an object doesn't have a saturated numSlots field it must be a single-header object.
If the word following does have a saturated numSlots it must be the overflow size word."
<inline: true>
| followingWordAddress followingWord |
followingWordAddress := self addressAfter: objOop.
(self oop: followingWordAddress isGreaterThanOrEqualTo: limit) ifTrue:
[^limit].
self flag: #endianness.
followingWord := self unsignedLongAt: followingWordAddress.
^followingWord >> self numSlotsFullShift = self numSlotsMask
ifTrue: [followingWordAddress + self baseHeaderSize]
ifFalse: [followingWordAddress]
]
{ #category : #'object enumeration' }
Spur64BitMemoryManager >> objectBytesForSlots: numSlots [
"Answer the total number of bytes in an object with the given
number of slots, including header and possible overflow size header."
<returnTypeC: #usqInt>
^numSlots = 0
ifTrue: [self allocationUnit + self baseHeaderSize] "always at least one slot for forwarding pointer"
ifFalse:
[numSlots << self shiftForWord
+ (numSlots >= self numSlotsMask
ifTrue: [self baseHeaderSize + self baseHeaderSize]
ifFalse: [self baseHeaderSize])]
]
{ #category : #'object access' }
Spur64BitMemoryManager >> oldRawNumSlotsOf: objOop [
<returnTypeC: #usqInt>
<inline: true>
^(self longAt: objOop) asUnsignedInteger >> self numSlotsFullShift
]
{ #category : #'cog jit support' }
Spur64BitMemoryManager >> oldSmallFloatTag [
^3
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> positiveSmallFloatZero [
<inline: true>
^self smallFloatTag
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> rawFloatBitsOf: aFloat in: rawFloat [
<inline: true>
self
memcpy: (self addressOf: rawFloat)
_: (self addressOf: aFloat)
_: (self sizeof: rawFloat)
]
{ #category : #'object access' }
Spur64BitMemoryManager >> rawOverflowSlotsOf: objOop [
<returnTypeC: #usqLong>
<inline: true>
self flag: #endianness.
^self
cCode: [((self wordAt: objOop - self baseHeaderSize) << 8) asUnsignedInteger >> 8]
inSmalltalk: [(self wordAt: objOop - self baseHeaderSize) bitAnd: 16rFFFFFFFFFFFFFF]
]
{ #category : #'object access' }
Spur64BitMemoryManager >> rawOverflowSlotsOf: objOop put: numSlots [
<returnTypeC: #usqLong>
<inline: true>
self flag: #endianness.
self longAt: objOop - self baseHeaderSize put: self numSlotsMask << 56 + numSlots.
^numSlots
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> rotateLeft: anInteger [
^(anInteger >> 63 bitAnd: 1) + ((self cCode: [anInteger] inSmalltalk: [anInteger bitAnd: 16r7FFFFFFFFFFFFFFF]) << 1)
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> rotateRight: anInteger [
^(self cCode: [anInteger] inSmalltalk: [anInteger bitAnd: 1]) << 63 + (anInteger asUnsignedInteger >> 1)
]
{ #category : #'interpreter access' }
Spur64BitMemoryManager >> rotatedFloatBitsOf: oop [
"Answer the signed, but unadjusted value of a SmallFloat64, suitable for use as a hash.
Keeping the exponent unadjusted keeps the value in the SmallInteger range.
See section 61-bit Immediate Floats in the SpurMemoryManager class comment.
msb lsb
Decode: [8expsubset][52mantissa][1s][3tags]
shift away tags & sign: [ 0000 ][8expsubset][52mantissa]
add sign: [ ssss ][8expsubset][52mantissa]"
self assert: (self isImmediateFloat: oop).
^oop asUnsignedInteger >> (self numTagBits + 1)
+ ((oop anyMask: self smallFloatSignBit)
ifTrue: [-1 asUnsignedInteger << (64 - self numTagBits - 1)]
ifFalse: [0])
]
{ #category : #'header access' }
Spur64BitMemoryManager >> rtRefCountOf: obj put: refCount [
"Set the rt reference count of obj; this is the three bit field comprised
of isGrey,isPinned,isRemembered. See computeRefCountToShrinkRT."
| header |
self assert: (refCount between: 0 and: MaxRTRefCount).
header := self longAt: obj.
header := header bitAnd: (7 << self rememberedBitShift) bitInvert64.
header := header + (refCount << self rememberedBitShift).
self longAt: obj put: header
]
{ #category : #'header access' }
Spur64BitMemoryManager >> set: objOop classIndexTo: classIndex formatTo: format [
"0 = 0 sized objects (UndefinedObject True False et al)
1 = non-indexable objects with inst vars (Point et al)
2 = indexable objects with no inst vars (Array et al)
3 = indexable objects with inst vars (MethodContext AdditionalMethodState et al)
4 = weak indexable objects with inst vars (WeakArray et al)
5 = weak non-indexable objects with inst vars (ephemerons) (Ephemeron)
6 unused, reserved for exotic pointer objects?
7 Forwarded Object, 1st field is pointer, rest of fields are ignored
8 unused, reserved for exotic non-pointer objects?
9 64-bit indexable
10 - 11 32-bit indexable
12 - 15 16-bit indexable
16 - 23 byte indexable
24 - 31 compiled method"
<inline: true>
self assert: (classIndex between: 0 and: self classIndexMask).
self assert: (format between: 0 and: self formatMask).
self longAt: objOop
put: ((self longAt: objOop) bitAnd: (self formatMask << self formatShift + self classIndexMask) bitInvert64)
+ (classIndex
+ (format << self formatShift))
]
{ #category : #'header access' }
Spur64BitMemoryManager >> setClassIndexOf: objOop to: classIndex [
self assert: (classIndex between: 0 and: self classIndexMask).
self longAt: objOop
put: ((self longAt: objOop) bitAnd: self classIndexMask bitInvert64)
+ classIndex
]
{ #category : #'header access' }
Spur64BitMemoryManager >> setFormatOf: objOop to: format [
"0 = 0 sized objects (UndefinedObject True False et al)
1 = non-indexable objects with inst vars (Point et al)
2 = indexable objects with no inst vars (Array et al)
3 = indexable objects with inst vars (MethodContext AdditionalMethodState et al)
4 = weak indexable objects with inst vars (WeakArray et al)
5 = weak non-indexable objects with inst vars (ephemerons) (Ephemeron)
6 unused, reserved for exotic pointer objects?
7 Forwarded Object, 1st field is pointer, rest of fields are ignored
8 unused, reserved for exotic non-pointer objects?
9 64-bit indexable
10 - 11 32-bit indexable
12 - 15 16-bit indexable
16 - 23 byte indexable
24 - 31 compiled method"
self assert: (format between: 0 and: self formatMask).
self longAt: objOop
put: ((self longAt: objOop) bitAnd: (self formatMask << self formatShift) bitInvert64)
+ (format << self formatShift)
]
{ #category : #'header access' }
Spur64BitMemoryManager >> setIsGreyOf: objOop to: aBoolean [
self longAt: objOop
put: (aBoolean
ifTrue: [(self longAt: objOop) bitOr: 1 << self greyBitShift]
ifFalse: [(self longAt: objOop) bitAnd: (1 << self greyBitShift) bitInvert64])
]
{ #category : #'header access' }
Spur64BitMemoryManager >> setIsImmutableOf: objOop to: aBoolean [
self longAt: objOop
put: (aBoolean
ifTrue: [(self longAt: objOop) bitOr: 1 << self immutableBitShift]
ifFalse: [(self longAt: objOop) bitAnd: (1 << self immutableBitShift) bitInvert64])
]