-
Notifications
You must be signed in to change notification settings - Fork 65
/
BitBltSimulation.class.st
4391 lines (4043 loc) · 160 KB
/
BitBltSimulation.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
"
This class implements BitBlt, much as specified in the Blue Book spec.
Performance has been enhanced through the use of pointer variables such as sourceIndex and destIndex, and by separating several special cases of the inner loop.
Operation has been extended to color, with support for 1, 2, 4, 8, 16, and 32-bit pixel sizes. Conversion between different pixel sizes is facilitated by accepting an optional color map.
In addition to the original 16 combination rules, this BitBlt supports
16 fail (for old paint mode)
17 fail (for old mask mode)
18 sourceWord + destinationWord
19 sourceWord - destinationWord
20 rgbAdd: sourceWord with: destinationWord
21 rgbSub: sourceWord with: destinationWord
22 OLDrgbDiff: sourceWord with: destinationWord
23 OLDtallyIntoMap: destinationWord -- old vers doesn't clip to bit boundary
24 alphaBlend: sourceWord with: destinationWord
25 pixPaint: sourceWord with: destinationWord
26 pixMask: sourceWord with: destinationWord
27 rgbMax: sourceWord with: destinationWord
28 rgbMin: sourceWord with: destinationWord
29 rgbMin: sourceWord bitInvert32 with: destinationWord
30 alphaBlendConst: sourceWord with: destinationWord -- alpha passed as an arg
31 alphaPaintConst: sourceWord with: destinationWord -- alpha passed as an arg
32 rgbDiff: sourceWord with: destinationWord
33 tallyIntoMap: destinationWord
34 alphaBlendScaled: sourceWord with: destinationWord
35 alphaBlendScaled: sourceWord with: ""unused here - only used by FXBlt""
36 alphaBlendScaled: sourceWord with: ""unused here - only used by FXBlt""
37 rgbMul: sourceWord with: destinationWord
38 pixSwap: sourceWord with: destinationWord
39 pixClear: sourceWord with: destinationWord
40 fixAlpha: sourceWord with: destinationWord
41 rgbComponentAlpha: sourceWord with: destinationWord
This implementation has also been fitted with an experimental ""warp drive"" that allows abritrary scaling and rotation (and even limited affine deformations) with all BitBlt storage modes supported.
To add a new rule to BitBlt...
1. add the new rule method or methods in the category 'combination rules' of BBSim
2. describe it in the class comment of BBSim and in the class comment for BitBlt
3. add refs to initializeRuleTable in proper positions
4. add refs to initBBOpTable, following the pattern
"
Class {
#name : #BitBltSimulation,
#superclass : #SmartSyntaxInterpreterPlugin,
#instVars : [
'destForm',
'sourceForm',
'halftoneForm',
'combinationRule',
'destX',
'destY',
'width',
'height',
'sourceX',
'sourceY',
'clipX',
'clipY',
'clipWidth',
'clipHeight',
'sourceWidth',
'sourceHeight',
'sourceDepth',
'sourcePitch',
'sourceBits',
'sourcePPW',
'sourceMSB',
'destWidth',
'destHeight',
'destDepth',
'destPitch',
'destBits',
'destPPW',
'destMSB',
'bitCount',
'skew',
'mask1',
'mask2',
'preload',
'nWords',
'destMask',
'hDir',
'vDir',
'sourceIndex',
'sourceDelta',
'destIndex',
'destDelta',
'sx',
'sy',
'dx',
'dy',
'bbW',
'bbH',
'halftoneHeight',
'noSource',
'noHalftone',
'halftoneBase',
'sourceAlpha',
'srcBitShift',
'dstBitShift',
'bitBltOop',
'affectedL',
'affectedR',
'affectedT',
'affectedB',
'opTable',
'maskTable',
'ditherMatrix4x4',
'ditherThresholds16',
'ditherValues16',
'hasSurfaceLock',
'warpSrcShift',
'warpSrcMask',
'warpAlignShift',
'warpAlignMask',
'warpBitShiftTable',
'querySurfaceFn',
'lockSurfaceFn',
'unlockSurfaceFn',
'isWarping',
'cmFlags',
'cmMask',
'cmShiftTable',
'cmMaskTable',
'cmLookupTable',
'cmBitsPerColor',
'dither8Lookup',
'componentAlphaModeColor',
'componentAlphaModeAlpha',
'ungammaLookupTable',
'gammaLookupTable',
'numGCsOnInvocation',
'bitBltIsReceiver',
'endOfDestination',
'endOfSource'
],
#classVars : [
'AllOnes',
'AlphaIndex',
'BBClipHeightIndex',
'BBClipWidthIndex',
'BBClipXIndex',
'BBClipYIndex',
'BBColorMapIndex',
'BBDestFormIndex',
'BBDestXIndex',
'BBDestYIndex',
'BBHalftoneFormIndex',
'BBHeightIndex',
'BBLastIndex',
'BBRuleIndex',
'BBSourceFormIndex',
'BBSourceXIndex',
'BBSourceYIndex',
'BBWarpBase',
'BBWidthIndex',
'BBXTableIndex',
'BEBitBltIndex',
'BinaryPoint',
'BlueIndex',
'ColorMapFixedPart',
'ColorMapIndexedPart',
'ColorMapNewStyle',
'ColorMapPresent',
'CrossedX',
'EndOfRun',
'FixedPt1',
'FormBitsIndex',
'FormDepthIndex',
'FormHeightIndex',
'FormWidthIndex',
'GreenIndex',
'OpTable',
'OpTableSize',
'RedIndex'
],
#category : #'VMMaker-Interpreter'
}
{ #category : #'system simulation' }
BitBltSimulation class >> copyBitsFrom: aBitBlt [
"Simulate the copyBits primitive"
| proxy bb |
proxy := InterpreterProxy new.
proxy loadStackFrom: thisContext sender home.
bb := self simulatorClass new.
bb initialiseModule.
bb setInterpreter: proxy.
proxy success: (bb loadBitBltFrom: aBitBlt).
bb primitiveCopyBits.
^ proxy stackValue: 0
]
{ #category : #translation }
BitBltSimulation class >> declareCVarsIn: aCCodeGenerator [
"add option of fast path BitBLT code header"
aCCodeGenerator
addHeaderFile:'"sqAssert.h"';
addHeaderFile:'#ifdef ENABLE_FAST_BLT
#include "BitBltDispatch.h"
#else
// to handle the unavoidable decl in the spec of copyBitsFallback();
#define operation_t void
#endif'.
aCCodeGenerator var: 'opTable'
declareC: 'void *opTable[' , OpTableSize printString , ']'.
aCCodeGenerator var: 'maskTable'
declareC:'int maskTable[33] = {
0, 1, 3, 0, 15, 31, 0, 0, 255, 0, 0, 0, 0, 0, 0, 0, 65535,
0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, -1
}'.
aCCodeGenerator var: 'ditherMatrix4x4'
declareC:'const int ditherMatrix4x4[16] = {
0, 8, 2, 10,
12, 4, 14, 6,
3, 11, 1, 9,
15, 7, 13, 5
}'.
aCCodeGenerator var: 'ditherThresholds16'
declareC:'const int ditherThresholds16[8] = { 0, 2, 4, 6, 8, 12, 14, 16 }'.
aCCodeGenerator var: 'ditherValues16'
declareC:'const int ditherValues16[32] = {
0, 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14,
15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30
}'.
aCCodeGenerator var: 'warpBitShiftTable'
declareC:'int warpBitShiftTable[32]'.
aCCodeGenerator var:'cmShiftTable'
type:'int *'.
aCCodeGenerator var:'cmMaskTable'
type:'unsigned int *'.
aCCodeGenerator var:'cmLookupTable'
type:'unsigned int *'.
aCCodeGenerator var: 'dither8Lookup'
declareC:' unsigned char dither8Lookup[4096]'.
aCCodeGenerator var:'ungammaLookupTable'
type: 'unsigned char *'.
aCCodeGenerator var:'gammaLookupTable'
type: 'unsigned char *'.
aCCodeGenerator
var: 'querySurfaceFn' declareC: 'int (*querySurfaceFn)(sqIntptr_t, int*, int*, int*, int*)';
var: 'lockSurfaceFn' declareC: 'sqIntptr_t (*lockSurfaceFn)(sqIntptr_t, int*, int, int, int, int)';
var: 'unlockSurfaceFn' declareC: 'int (*unlockSurfaceFn)(sqIntptr_t, int, int, int, int)'.
#(sourcePitch sourceWidth sourceHeight sourceDepth sourceMSB sx sy
destPitch destWidth destHeight destDepth destMSB dx dy bbW bbH)
do: [:ivar | aCCodeGenerator var: ivar type: #int].
#('sourceIndex' 'destIndex' 'endOfDestination' 'endOfSource') do:
[:ivar| aCCodeGenerator var: ivar type: #usqInt]
]
{ #category : #initialization }
BitBltSimulation class >> initialize [
"BitBltSimulation initialize"
self initializeRuleTable.
"Mask constants"
AllOnes := 16rFFFFFFFF.
BinaryPoint := 14.
FixedPt1 := 1 << BinaryPoint. "Value of 1.0 in Warp's fixed-point representation"
"Indices into stopConditions for scanning"
EndOfRun := 257.
CrossedX := 258.
"Form fields"
FormBitsIndex := 0.
FormWidthIndex := 1.
FormHeightIndex := 2.
FormDepthIndex := 3.
"BitBlt fields"
BBDestFormIndex := 0.
BBSourceFormIndex := 1.
BBHalftoneFormIndex := 2.
BBRuleIndex := 3.
BBDestXIndex := 4.
BBDestYIndex := 5.
BBWidthIndex := 6.
BBHeightIndex := 7.
BBSourceXIndex := 8.
BBSourceYIndex := 9.
BBClipXIndex := 10.
BBClipYIndex := 11.
BBClipWidthIndex := 12.
BBClipHeightIndex := 13.
BBColorMapIndex := 14.
BBWarpBase := 15.
BBLastIndex := 15.
BBXTableIndex := 16.
"BalloonEngineFields"
BEBitBltIndex := (Smalltalk classNamed: #BalloonEngine)
ifNil: [2]
ifNotNil: [:be| (be allInstVarNames indexOf: 'bitBlt') - 1].
"RGBA indexes"
RedIndex := 0.
GreenIndex := 1.
BlueIndex := 2.
AlphaIndex := 3.
"Color map flags"
ColorMapPresent := 1. "do we have one?"
ColorMapFixedPart := 2. "does it have a fixed part?"
ColorMapIndexedPart := 4. "does it have an indexed part?"
ColorMapNewStyle := 8. "new style color map"
]
{ #category : #initialization }
BitBltSimulation class >> initializeRuleTable [
"BitBltSimulation initializeRuleTable"
"**WARNING** You MUST change initBBOpTable if you change this"
OpTable := #(
"0" clearWord:with:
"1" bitAnd:with:
"2" bitAndInvert:with:
"3" sourceWord:with:
"4" bitInvertAnd:with:
"5" destinationWord:with:
"6" bitXor:with:
"7" bitOr:with:
"8" bitInvertAndInvert:with:
"9" bitInvertXor:with:
"10" bitInvertDestination:with:
"11" bitOrInvert:with:
"12" bitInvertSource:with:
"13" bitInvertOr:with:
"14" bitInvertOrInvert:with:
"15" destinationWord:with:
"16" destinationWord:with: "unused - was old paint"
"17" destinationWord:with: "unused - was old mask"
"18" addWord:with:
"19" subWord:with:
"20" rgbAdd:with:
"21" rgbSub:with:
"22" OLDrgbDiff:with:
"23" OLDtallyIntoMap:with:
"24" alphaBlend:with:
"25" pixPaint:with:
"26" pixMask:with:
"27" rgbMax:with:
"28" rgbMin:with:
"29" rgbMinInvert:with:
"30" alphaBlendConst:with:
"31" alphaPaintConst:with:
"32" rgbDiff:with:
"33" tallyIntoMap:with:
"34" alphaBlendScaled:with:
"35" alphaBlendScaled:with: "unused here - only used by FXBlt"
"36" alphaBlendScaled:with: "unused here - only used by FXBlt"
"37" rgbMul:with:
"38" pixSwap:with:
"39" pixClear:with:
"40" fixAlpha:with:
"41" rgbComponentAlpha:with:
).
OpTableSize := OpTable size + 1. "0-origin indexing"
]
{ #category : #translation }
BitBltSimulation class >> moduleName [
^'BitBltPlugin'
]
{ #category : #translation }
BitBltSimulation class >> opTable [
^ OpTable
]
{ #category : #translation }
BitBltSimulation class >> requiredMethodNames: options [
^self opTable asSet
]
{ #category : #'system simulation' }
BitBltSimulation class >> simulatorClass [
^BitBltSimulator
]
{ #category : #testing }
BitBltSimulation class >> test2 [
"BitBltSimulation test2"
| f |
Display fillWhite: (0 @ 0 extent: 300 @ 140).
1 to: 12 do: [:i |
f := (Form extent: i @ 5) fillBlack.
0 to: 20 do: [:x | f displayOn: Display at: x * 13 @ (i * 10)]]
]
{ #category : #testing }
BitBltSimulation class >> timingTest: extent [
"BitBltSimulation timingTest: 640@480"
| f f2 map |
f := Form extent: extent depth: 8.
f2 := Form extent: extent depth: 8.
map := Bitmap new: 1 << f2 depth.
^ Array
with: (Time millisecondsToRun: [100 timesRepeat: [f fillWithColor: Color white]])
with: (Time millisecondsToRun: [100 timesRepeat: [f copy: f boundingBox from: 0 @ 0 in: f2 rule: Form over]])
with: (Time millisecondsToRun: [100 timesRepeat: [f copyBits: f boundingBox from: f2 at: 0 @ 0 colorMap: map]])
]
{ #category : #'system simulation' }
BitBltSimulation class >> warpBitsFrom: aBitBlt [
"Simulate the warpBits primitive"
| proxy bb |
proxy := InterpreterProxy new.
proxy loadStackFrom: thisContext sender home.
bb := self simulatorClass new.
bb initialiseModule.
bb setInterpreter: proxy.
proxy success: (bb loadWarpBltFrom: aBitBlt).
bb warpBits.
proxy failed ifFalse:[
proxy showDisplayBits: aBitBlt destForm Left: bb affectedLeft Top: bb affectedTop Right: bb affectedRight Bottom: bb affectedBottom].
^proxy stackValue: 0
]
{ #category : #'combination rules' }
BitBltSimulation >> OLDrgbDiff: sourceWord with: destinationWord [
"Subract the pixels in the source and destination, color by color,
and return the sum of the absolute value of all the differences.
For non-rgb, XOR the two and return the number of differing pixels.
Note that the region is not clipped to bit boundaries, but only to the
nearest (enclosing) word. This is because copyLoop does not do
pre-merge masking. For accurate results, you must subtract the
values obtained from the left and right fringes."
| diff pixMask |
<inline: false>
destDepth < 16 ifTrue:
["Just xor and count differing bits if not RGB"
diff := sourceWord bitXor: destinationWord.
pixMask := maskTable at: destDepth.
[diff = 0] whileFalse:
[(diff bitAnd: pixMask) ~= 0 ifTrue: [bitCount := bitCount + 1].
diff := diff >> destDepth].
^ destinationWord "for no effect"].
destDepth = 16
ifTrue:
[diff := (self partitionedSub: sourceWord from: destinationWord
nBits: 5 nPartitions: 3).
bitCount := bitCount + (diff bitAnd: 16r1F)
+ (diff>>5 bitAnd: 16r1F)
+ (diff>>10 bitAnd: 16r1F).
diff := (self partitionedSub: sourceWord>>16 from: destinationWord>>16
nBits: 5 nPartitions: 3).
bitCount := bitCount + (diff bitAnd: 16r1F)
+ (diff>>5 bitAnd: 16r1F)
+ (diff>>10 bitAnd: 16r1F)]
ifFalse:
[diff := (self partitionedSub: sourceWord from: destinationWord
nBits: 8 nPartitions: 3).
bitCount := bitCount + (diff bitAnd: 16rFF)
+ (diff>>8 bitAnd: 16rFF)
+ (diff>>16 bitAnd: 16rFF)].
^ destinationWord "For no effect on dest"
]
{ #category : #'combination rules' }
BitBltSimulation >> OLDtallyIntoMap: sourceWord with: destinationWord [
"Tally pixels into the color map. Note that the source should be
specified = destination, in order for the proper color map checks
to be performed at setup.
Note that the region is not clipped to bit boundaries, but only to the
nearest (enclosing) word. This is because copyLoop does not do
pre-merge masking. For accurate results, you must subtract the
values obtained from the left and right fringes."
| mapIndex pixMask shiftWord |
(cmFlags bitAnd: (ColorMapPresent bitOr: ColorMapIndexedPart)) =
(ColorMapPresent bitOr: ColorMapIndexedPart)
ifFalse: [^ destinationWord "no op"].
destDepth < 16 ifTrue:
["loop through all packed pixels."
pixMask := (maskTable at: destDepth) bitAnd: cmMask.
shiftWord := destinationWord.
1 to: destPPW do:
[:i |
mapIndex := shiftWord bitAnd: pixMask.
self tallyMapAt: mapIndex put: (self tallyMapAt: mapIndex) + 1.
shiftWord := shiftWord >> destDepth].
^ destinationWord].
destDepth = 16 ifTrue:
["Two pixels Tally the right half..."
mapIndex := self rgbMap: (destinationWord bitAnd: 16rFFFF) from: 5 to: cmBitsPerColor.
self tallyMapAt: mapIndex put: (self tallyMapAt: mapIndex) + 1.
"... and then left half"
mapIndex := self rgbMap: destinationWord>>16 from: 5 to: cmBitsPerColor.
self tallyMapAt: mapIndex put: (self tallyMapAt: mapIndex) + 1]
ifFalse:
["Just one pixel."
mapIndex := self rgbMap: destinationWord from: 8 to: cmBitsPerColor.
self tallyMapAt: mapIndex put: (self tallyMapAt: mapIndex) + 1].
^ destinationWord "For no effect on dest"
]
{ #category : #'combination rules' }
BitBltSimulation >> addWord: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord + destinationWord
]
{ #category : #accessing }
BitBltSimulation >> affectedBottom [
^affectedB
]
{ #category : #accessing }
BitBltSimulation >> affectedLeft [
^affectedL
]
{ #category : #accessing }
BitBltSimulation >> affectedRight [
^affectedR
]
{ #category : #accessing }
BitBltSimulation >> affectedTop [
^affectedT
]
{ #category : #'combination rules' }
BitBltSimulation >> alphaBlend: sourceWord with: destinationWord [
"Blend sourceWord with destinationWord, assuming both are 32-bit pixels.
The source is assumed to have 255*alpha in the high 8 bits of each pixel,
while the high 8 bits of the destinationWord will be ignored.
The blend produced is alpha*source + (1-alpha)*dest, with
the computation being performed independently on each color
component. The high byte of the result will be 0."
| alpha unAlpha result blendRB blendAG |
<inline: false>
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
<var: #blendRB type: 'unsigned int'>
<var: #blendAG type: 'unsigned int'>
<var: #result type: 'unsigned int'>
<var: #alpha type: 'unsigned int'>
<var: #unAlpha type: 'unsigned int'>
alpha := sourceWord >> 24. "High 8 bits of source pixel"
alpha = 0 ifTrue: [ ^ destinationWord ].
alpha = 255 ifTrue: [ ^ sourceWord ].
unAlpha := 255 - alpha.
blendRB := ((sourceWord bitAnd: 16rFF00FF) * alpha) +
((destinationWord bitAnd: 16rFF00FF) * unAlpha)
+ 16rFF00FF. "blend red and blue"
blendAG := (((sourceWord>> 8 bitOr: 16rFF0000) bitAnd: 16rFF00FF) * alpha) +
((destinationWord>>8 bitAnd: 16rFF00FF) * unAlpha)
+ 16rFF00FF. "blend alpha and green"
blendRB := blendRB + (blendRB - 16r10001 >> 8 bitAnd: 16rFF00FF) >> 8 bitAnd: 16rFF00FF. "divide by 255"
blendAG := blendAG + (blendAG - 16r10001 >> 8 bitAnd: 16rFF00FF) >> 8 bitAnd: 16rFF00FF.
result := blendRB bitOr: blendAG<<8.
^ result
]
{ #category : #'combination rules' }
BitBltSimulation >> alphaBlendConst: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^ self alphaBlendConst: sourceWord with: destinationWord paintMode: false
]
{ #category : #'combination rules' }
BitBltSimulation >> alphaBlendConst: sourceWord with: destinationWord paintMode: paintMode [
"Blend sourceWord with destinationWord using a constant alpha.
Alpha is encoded as 0 meaning 0.0, and 255 meaning 1.0.
The blend produced is alpha*source + (1.0-alpha)*dest, with the
computation being performed independently on each color component.
This function could eventually blend into any depth destination,
using the same color averaging and mapping as warpBlt.
paintMode = true means do nothing if the source pixel value is zero."
"This first implementation works with dest depths of 16 and 32 bits only.
Normal color mapping will allow sources of lower depths in this case,
and results can be mapped directly by truncation, so no extra color maps are needed.
To allow storing into any depth will require subsequent addition of two other
colormaps, as is the case with WarpBlt."
| pixMask destShifted sourceShifted destPixVal rgbMask sourcePixVal unAlpha result pixBlend shift blend maskShifted bitsPerColor blendAG blendRB |
<inline: false>
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
<var: #blendRB type: 'unsigned int'>
<var: #blendAG type: 'unsigned int'>
<var: #result type: 'unsigned int'>
<var: #sourceAlpha type: 'unsigned int'>
<var: #unAlpha type: 'unsigned int'>
<var: #sourceShifted type: 'unsigned int'>
<var: #destShifted type: 'unsigned int'>
<var: #maskShifted type: 'unsigned int'>
<var: #pixMask type: 'unsigned int'>
<var: #rgbMask type: 'unsigned int'>
<var: #pixBlend type: 'unsigned int'>
<var: #blend type: 'unsigned int'>
destDepth < 16 ifTrue: [^ destinationWord "no-op"].
unAlpha := 255 - sourceAlpha.
result := destinationWord.
destPPW = 1 ifTrue:["32bpp blends include alpha"
(paintMode and: [ sourceWord = 0 ]) "painting a transparent pixel" ifFalse:[
blendRB := ((sourceWord bitAnd: 16rFF00FF) * sourceAlpha) +
((destinationWord bitAnd: 16rFF00FF) * unAlpha) + 16rFF00FF. "blendRB red and blue"
blendAG := ((sourceWord>> 8 bitAnd: 16rFF00FF) * sourceAlpha) +
((destinationWord>>8 bitAnd: 16rFF00FF) * unAlpha) + 16rFF00FF. "blendRB alpha and green"
blendRB := blendRB + (blendRB - 16r10001 >> 8 bitAnd: 16rFF00FF) >> 8 bitAnd: 16rFF00FF. "divide by 255"
blendAG := blendAG + (blendAG - 16r10001 >> 8 bitAnd: 16rFF00FF) >> 8 bitAnd: 16rFF00FF.
result := blendRB bitOr: blendAG<<8.
].
] ifFalse:[
pixMask := maskTable at: destDepth.
bitsPerColor := 5.
rgbMask := 16r1F.
maskShifted := destMask.
destShifted := destinationWord.
sourceShifted := sourceWord.
1 to: destPPW do:[:j |
sourcePixVal := sourceShifted bitAnd: pixMask.
((maskShifted bitAnd: pixMask) = 0 "no effect if outside of dest rectangle"
or: [ (paintMode and: [ sourcePixVal = 0 ]) "or painting a transparent pixel"])
ifFalse:
[destPixVal := destShifted bitAnd: pixMask.
pixBlend := 0.
1 to: 3 do:
[:i | shift := (i-1)*bitsPerColor.
blend := (((sourcePixVal>>shift bitAnd: rgbMask) * sourceAlpha)
+ ((destPixVal>>shift bitAnd: rgbMask) * unAlpha))
+ 254 // 255 bitAnd: rgbMask.
pixBlend := pixBlend bitOr: blend<<shift].
result := (result bitAnd: (pixMask << (j-1*16)) bitInvert32)
bitOr: pixBlend << (j-1*16)].
maskShifted := maskShifted >> destDepth.
sourceShifted := sourceShifted >> destDepth.
destShifted := destShifted >> destDepth].
].
^ result
]
{ #category : #'combination rules' }
BitBltSimulation >> alphaBlendScaled: sourceWord with: destinationWord [
"Blend sourceWord with destinationWord using the alpha value from sourceWord.
Alpha is encoded as 0 meaning 0.0, and 255 meaning 1.0.
In contrast to alphaBlend:with: the color produced is
srcColor + (1-srcAlpha) * dstColor
e.g., it is assumed that the source color is already scaled."
| unAlpha rb ag |
<inline: false> "Do NOT inline this into optimized loops"
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
<var: #rb type: 'unsigned int'>
<var: #ag type: 'unsigned int'>
<var: #unAlpha type: 'unsigned int'>
unAlpha := 255 - (sourceWord >> 24). "High 8 bits of source pixel is source opacity (ARGB format)"
rb := ((destinationWord bitAnd: 16rFF00FF) * unAlpha >> 8 bitAnd: 16rFF00FF) + (sourceWord bitAnd: 16rFF00FF). "blend red and blue components"
ag := ((destinationWord>>8 bitAnd: 16rFF00FF) * unAlpha >> 8 bitAnd: 16rFF00FF) + (sourceWord>>8 bitAnd: 16rFF00FF). "blend alpha and green components"
rb := (rb bitAnd: 16rFF00FF) bitOr: (rb bitAnd: 16r1000100) * 16rFF >> 8. "saturate red and blue components if there is a carry"
ag := (ag bitAnd: 16rFF00FF) << 8 bitOr: (ag bitAnd: 16r1000100) * 16rFF. "saturate alpha and green components if there is a carry"
^ag bitOr: rb "recompose"
]
{ #category : #'combination rules' }
BitBltSimulation >> alphaPaintConst: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
sourceWord = 0 ifTrue: [^ destinationWord "opt for all-transparent source"].
^ self alphaBlendConst: sourceWord with: destinationWord paintMode: true
]
{ #category : #'inner loop' }
BitBltSimulation >> alphaSourceBlendBits16 [
"This version assumes
combinationRule = 34
sourcePixSize = 32
destPixSize = 16
sourceForm ~= destForm.
"
| srcIndex dstIndex sourceWord srcAlpha destWord deltaX deltaY
srcY dstY dstMask srcShift ditherBase ditherIndex ditherThreshold |
<inline: false> "This particular method should be optimized in itself"
<var: #sourceWord type: #'unsigned int'>
<var: #destWord type: #'unsigned int'>
<var: #dstMask type: #'unsigned int'>
deltaY := bbH + 1. "So we can pre-decrement"
srcY := sy.
dstY := dy.
srcShift := (dx bitAnd: 1) * 16.
destMSB ifTrue:[srcShift := 16 - srcShift].
mask1 := 16rFFFF << (16 - srcShift).
"This is the outer loop"
[(deltaY := deltaY - 1) ~= 0] whileTrue:[
srcIndex := sourceBits + (srcY * sourcePitch) + (sx * 4).
dstIndex := destBits + (dstY * destPitch) + (dx // 2 * 4).
ditherBase := (dstY bitAnd: 3) * 4.
ditherIndex := (sx bitAnd: 3) - 1. "For pre-increment"
deltaX := bbW + 1. "So we can pre-decrement"
dstMask := mask1.
dstMask = 16rFFFF ifTrue:[srcShift := 16] ifFalse:[srcShift := 0].
"This is the inner loop"
[(deltaX := deltaX - 1) ~= 0] whileTrue:[
ditherThreshold := ditherMatrix4x4 at: ditherBase + (ditherIndex := ditherIndex + 1 bitAnd: 3).
sourceWord := self srcLongAt: srcIndex.
srcAlpha := sourceWord >> 24.
srcAlpha = 255 ifTrue:[
"Dither from 32 to 16 bit"
sourceWord := self dither32To16: sourceWord threshold: ditherThreshold.
sourceWord = 0
ifTrue:[sourceWord := 1 << srcShift]
ifFalse: [sourceWord := sourceWord << srcShift].
"Store masked value"
self dstLongAt: dstIndex put: sourceWord mask: dstMask.
] ifFalse:[ "srcAlpha ~= 255"
srcAlpha = 0 ifFalse:[ "0 < srcAlpha < 255"
"If we have to mix colors then just copy a single word"
destWord := self dstLongAt: dstIndex.
destWord := destWord bitAnd: dstMask bitInvert32.
destWord := destWord >> srcShift.
"Expand from 16 to 32 bit by adding zero bits"
destWord := (((destWord bitAnd: 16r7C00) bitShift: 9) bitOr:
((destWord bitAnd: 16r3E0) bitShift: 6)) bitOr:
(((destWord bitAnd: 16r1F) bitShift: 3) bitOr:
16rFF000000).
"Mix colors"
sourceWord := self alphaBlendScaled: sourceWord with: destWord.
"And dither"
sourceWord := self dither32To16: sourceWord threshold: ditherThreshold.
sourceWord = 0
ifTrue:[sourceWord := 1 << srcShift]
ifFalse:[sourceWord := sourceWord << srcShift].
"Store back"
self dstLongAt: dstIndex put: sourceWord mask: dstMask.
].
].
srcIndex := srcIndex + 4.
destMSB
ifTrue:[srcShift = 0 ifTrue:[dstIndex := dstIndex + 4]]
ifFalse:[srcShift = 0 ifFalse:[dstIndex := dstIndex + 4]].
srcShift := srcShift bitXor: 16. "Toggle between 0 and 16"
dstMask := dstMask bitInvert32. "Mask other half word"
].
srcY := srcY + 1.
dstY := dstY + 1.
].
]
{ #category : #'inner loop' }
BitBltSimulation >> alphaSourceBlendBits32 [
"This version assumes
combinationRule = 34
sourcePixSize = destPixSize = 32
sourceForm ~= destForm.
Note: The inner loop has been optimized for dealing
with the special cases of srcAlpha = 0.0 and srcAlpha = 1.0
"
| srcIndex dstIndex sourceWord srcAlpha destWord deltaX deltaY srcY dstY |
<inline: false> "This particular method should be optimized in itself"
<var: #sourceWord type: #'unsigned int'>
<var: #destWord type: #'unsigned int'>
"Give the compile a couple of hints"
"The following should be declared as pointers so the compiler will
notice that they're used for accessing memory locations
(good to know on an Intel architecture) but then the increments
would be different between ST code and C code so must hope the
compiler notices what happens (MS Visual C does)"
deltaY := bbH + 1. "So we can pre-decrement"
srcY := sy.
dstY := dy.
"This is the outer loop"
[(deltaY := deltaY - 1) ~= 0] whileTrue:[
srcIndex := sourceBits + (srcY * sourcePitch) + (sx * 4).
dstIndex := destBits + (dstY * destPitch) + (dx * 4).
deltaX := bbW + 1. "So we can pre-decrement"
"This is the inner loop"
[(deltaX := deltaX - 1) ~= 0] whileTrue:[
sourceWord := self srcLongAt: srcIndex.
srcAlpha := sourceWord >> 24.
srcAlpha = 255 ifTrue:[
self dstLongAt: dstIndex put: sourceWord.
srcIndex := srcIndex + 4.
dstIndex := dstIndex + 4.
"Now copy as many words as possible with alpha = 255"
[(deltaX := deltaX - 1) ~= 0 and:[
(sourceWord := self srcLongAt: srcIndex) >> 24 = 255]]
whileTrue:[
self dstLongAt: dstIndex put: sourceWord.
srcIndex := srcIndex + 4.
dstIndex := dstIndex + 4.
].
"Adjust deltaX"
deltaX := deltaX + 1.
] ifFalse:[ "srcAlpha ~= 255"
srcAlpha = 0 ifTrue:[
srcIndex := srcIndex + 4.
dstIndex := dstIndex + 4.
"Now skip as many words as possible,"
[(deltaX := deltaX - 1) ~= 0 and:[
(sourceWord := self srcLongAt: srcIndex) >> 24 = 0]]
whileTrue:[
srcIndex := srcIndex + 4.
dstIndex := dstIndex + 4.
].
"Adjust deltaX"
deltaX := deltaX + 1.
] ifFalse:[ "0 < srcAlpha < 255"
"If we have to mix colors then just copy a single word"
destWord := self dstLongAt: dstIndex.
destWord := self alphaBlendScaled: sourceWord with: destWord.
self dstLongAt: dstIndex put: destWord.
srcIndex := srcIndex + 4.
dstIndex := dstIndex + 4.
].
].
].
srcY := srcY + 1.
dstY := dstY + 1.
].
]
{ #category : #'inner loop' }
BitBltSimulation >> alphaSourceBlendBits8 [
"This version assumes
combinationRule = 34
sourcePixSize = 32
destPixSize = 8
sourceForm ~= destForm.
Note: This is not real blending since we don't have the source colors available.
"
| srcIndex dstIndex sourceWord srcAlpha destWord deltaX deltaY
srcY dstY dstMask srcShift adjust mappingTable mapperFlags |
<inline: false>
<var: #mappingTable type:'unsigned int *'>
<var: #sourceWord type: #'unsigned int'>
<var: #destWord type: #'unsigned int'>
<var: #dstMask type: #'unsigned int'>
mappingTable := self default8To32Table.
mapperFlags := cmFlags bitAnd: ColorMapNewStyle bitInvert32.
deltaY := bbH + 1. "So we can pre-decrement"
srcY := sy.
dstY := dy.
mask1 := ((dx bitAnd: 3) * 8).
destMSB ifTrue:[mask1 := 24 - mask1].
mask2 := AllOnes bitXor:(16rFF << mask1).
(dx bitAnd: 1) = 0
ifTrue:[adjust := 0]
ifFalse:[adjust := 16r1F1F1F1F].
(dy bitAnd: 1) = 0
ifTrue:[adjust := adjust bitXor: 16r1F1F1F1F].
"This is the outer loop"
[(deltaY := deltaY - 1) ~= 0] whileTrue:[
adjust := adjust bitXor: 16r1F1F1F1F.
srcIndex := sourceBits + (srcY * sourcePitch) + (sx * 4).
dstIndex := destBits + (dstY * destPitch) + (dx // 4 * 4).
deltaX := bbW + 1. "So we can pre-decrement"
srcShift := mask1.
dstMask := mask2.
"This is the inner loop"
[(deltaX := deltaX - 1) ~= 0] whileTrue:[
sourceWord := ((self srcLongAt: srcIndex) bitAnd: (adjust bitInvert32)) + adjust.
srcAlpha := sourceWord >> 24.
srcAlpha > 31 ifTrue:["Everything below 31 is transparent"
srcAlpha < 224 ifTrue:["Everything above 224 is opaque"
destWord := self dstLongAt: dstIndex.
destWord := destWord bitAnd: dstMask bitInvert32.
destWord := destWord >> srcShift.
destWord := mappingTable at: destWord.
sourceWord := self alphaBlendScaled: sourceWord with: destWord.
].
sourceWord := self mapPixel: sourceWord flags: mapperFlags.
sourceWord := sourceWord << srcShift.
"Store back"
self dstLongAt: dstIndex put: sourceWord mask: dstMask.
].
srcIndex := srcIndex + 4.
destMSB ifTrue:[
srcShift = 0
ifTrue:[dstIndex := dstIndex + 4.
srcShift := 24.
dstMask := 16r00FFFFFF]
ifFalse:[srcShift := srcShift - 8.
dstMask := (dstMask >> 8) bitOr: 16rFF000000].
] ifFalse:[
srcShift = 24
ifTrue:[dstIndex := dstIndex + 4.
srcShift := 0.
dstMask := 16rFFFFFF00]
ifFalse:[srcShift := srcShift + 8.
dstMask := dstMask << 8 bitOr: 255].
].
adjust := adjust bitXor: 16r1F1F1F1F.
].
srcY := srcY + 1.
dstY := dstY + 1.
].
]
{ #category : #'combination rules' }
BitBltSimulation >> bitAnd: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord bitAnd: destinationWord
]
{ #category : #'combination rules' }
BitBltSimulation >> bitAndInvert: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord bitAnd: destinationWord bitInvert32
]
{ #category : #'combination rules' }
BitBltSimulation >> bitInvertAnd: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord bitInvert32 bitAnd: destinationWord
]
{ #category : #'combination rules' }
BitBltSimulation >> bitInvertAndInvert: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord bitInvert32 bitAnd: destinationWord bitInvert32
]
{ #category : #'combination rules' }
BitBltSimulation >> bitInvertDestination: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^destinationWord bitInvert32
]
{ #category : #'combination rules' }
BitBltSimulation >> bitInvertOr: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord bitInvert32 bitOr: destinationWord
]
{ #category : #'combination rules' }
BitBltSimulation >> bitInvertOrInvert: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord bitInvert32 bitOr: destinationWord bitInvert32
]
{ #category : #'combination rules' }
BitBltSimulation >> bitInvertSource: sourceWord with: destinationWord [
<returnTypeC: 'unsigned int'>
<var: #sourceWord type: 'unsigned int'>
<var: #destinationWord type: 'unsigned int'>
^sourceWord bitInvert32
]