/
CDClassDefinitionParser.class.st
302 lines (255 loc) · 8.77 KB
/
CDClassDefinitionParser.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
"
I use the default node representation of classes to parse class definition and return a dedicated class tree.
The basic idea behing the implementation is to reuse as much as possible as the current parser infrastructure. This is why this class defines a visitMessageNode: method.
Main public API is
- parse: aString
"
Class {
#name : #CDClassDefinitionParser,
#superclass : #Object,
#instVars : [
'classDefinition',
'subclass'
],
#category : #'ClassParser-Model'
}
{ #category : #parsing }
CDClassDefinitionParser class >> fromASTNode: aNode [
^ self new parseRootNode: aNode
]
{ #category : #parsing }
CDClassDefinitionParser class >> parse: aString [
^ self new parse: aString
]
{ #category : #internal }
CDClassDefinitionParser >> beClassDefinition [
classDefinition := CDClassDefinitionNode new
]
{ #category : #internal }
CDClassDefinitionParser >> beMetaclassDefinition [
classDefinition := CDMetaclassDefinitionNode new
]
{ #category : #'private class factory' }
CDClassDefinitionParser >> classNameNodeClass [
^ CDClassNameNode
]
{ #category : #accessing }
CDClassDefinitionParser >> classVariableNames: aNode [
| slots slotNodes classVariablesString |
classVariablesString := aNode value.
slots := classVariablesString substrings.
slotNodes := slots
collect: [ :slotName | | start |
start := aNode start + (classVariablesString findString: slotName).
CDSharedVariableNode
node: aNode
name: slotName
slotClassName: 'ClassVariableSlot'
start: start
stop: start + slotName size ].
classDefinition sharedSlots: slotNodes
]
{ #category : #testing }
CDClassDefinitionParser >> isInstanceSideDefinition: aRBMessageNode [
"Based on the Point or Point class structure, returns whether the definition is a class or instance side definition."
^ aRBMessageNode receiver isMessage not
]
{ #category : #accessing }
CDClassDefinitionParser >> package: aNode [
classDefinition packageNameNode: aNode astNode: aNode
]
{ #category : #'parsing main' }
CDClassDefinitionParser >> parse: aString [
| expressionTree |
expressionTree := RBParser parseExpression: aString.
expressionTree doSemanticAnalysis.
^ self parseRootNode: expressionTree
]
{ #category : #parsing }
CDClassDefinitionParser >> parseClassName: aNode [
| className superclassNode |
className := (aNode isVariable
ifTrue: [ aNode name ]
ifFalse: [ aNode value ]) asSymbol.
superclassNode := self classNameNodeClass new
originalNode: aNode;
className: className.
classDefinition className: className astNode: superclassNode
]
{ #category : #parsing }
CDClassDefinitionParser >> parseClassName: aNode withType: aSymbol [
self parseClassName: aNode.
classDefinition classKind: aSymbol
]
{ #category : #parsing }
CDClassDefinitionParser >> parseInstanceVariablesFromNode: aNode [
| slots slotNodes instanceVariablesString |
instanceVariablesString := aNode value.
slots := instanceVariablesString substrings.
slotNodes := slots
collect: [ :slotName |
| start |
start := aNode start
+ (instanceVariablesString findString: slotName).
self slotNodeClass
node: aNode
name: slotName
slotClassName: #InstanceVariableSlot
start: start
stop: start + slotName size ].
classDefinition slots: slotNodes
]
{ #category : #parsing }
CDClassDefinitionParser >> parsePoolDictionariesFromNode: aNode [
| shareds sharedPoolNodes sharedPoolString |
sharedPoolString := aNode value.
shareds := sharedPoolString substrings.
sharedPoolNodes := shareds
collect: [ :slotName |
| start |
start := aNode start + (sharedPoolString findString: slotName).
self sharedPoolNodeClass
node: aNode
name: slotName
start: start
stop: start + slotName size ].
classDefinition sharedPools: sharedPoolNodes
]
{ #category : #parsing }
CDClassDefinitionParser >> parseRootNode: expressionTree [
self setAdequateClassDefinitionFrom: expressionTree.
classDefinition originalNode: expressionTree.
expressionTree acceptVisitor: self.
"why do we need this double dispatch?"
^ classDefinition
]
{ #category : #parsing }
CDClassDefinitionParser >> parseSelectorPart: aString withArgument: aNode [
"We could do this with reflection, or with a dictionary and closures.
I chose to use a series of if for readability only."
(#(variableWordSubclass: ephemeronSubclass: weakSubclass: variableByteSubclass: variableSubclass: immediateSubclass: #subclass:) includes: aString)
ifTrue: [ ^ self parseClassName: aNode withType: aString ].
aString = #instanceVariableNames:
ifTrue: [ ^ self parseInstanceVariablesFromNode: aNode ].
aString = #slots:
ifTrue: [ ^ self parseSlotsNodesFromArrayNode: aNode ].
aString = #classVariableNames:
ifTrue: [ ^ self classVariableNames: aNode ].
aString = #category:
ifTrue: [ ^ self package: aNode ].
aString = #package:
ifTrue: [ ^ self package: aNode ].
aString = #uses:
ifTrue: [ ^ self parseTraitDefinitionFromNode: aNode ].
aString = #poolDictionaries:
ifTrue: [ ^ self parsePoolDictionariesFromNode: aNode ].
CDUnrecognizedClassPart new
classDefinition: self;
unrecognizedPart: aString;
signal
]
{ #category : #parsing }
CDClassDefinitionParser >> parseSlotNode: aRBMessageNode [
"what ugly method! Pay attention start and stop should be tested and probably adjusted!"
"when a slot is just 'inst'"
aRBMessageNode isLiteralNode
ifTrue: [ | slot |
slot := self slotNodeClass
node: aRBMessageNode
name: aRBMessageNode value
slotClassName: #InstanceVariableSlot
initializationMessage: self slotInitializationNodeClass new
start: aRBMessageNode start
stop: aRBMessageNode stop.
classDefinition addSlot: slot.
^ self ].
aRBMessageNode selector = '=>'
ifTrue: [
aRBMessageNode arguments first isMessage
ifFalse: [
"when a slot is just 'inst' => InstanceVariableSlot."
aRBMessageNode arguments first isGlobal
ifTrue: [ | slot |
slot := self slotNodeClass
node: aRBMessageNode
name: aRBMessageNode receiver value
slotClassName: aRBMessageNode arguments first name
initializationMessage: self slotInitializationNodeClass new
start: aRBMessageNode start
stop: aRBMessageNode stop.
classDefinition addSlot: slot.
^ self ].
"we will have to do something for example if we have
#x => 2"
]
ifTrue: [
"when a slot is 'inst' => (InstanceVariableSlot default: 5)."
| slot slotDefNode |
slotDefNode := aRBMessageNode.
slot := self slotNodeClass
node: aRBMessageNode
name: slotDefNode receiver value
slotClassName: slotDefNode arguments first receiver name
initializationMessage:
(self slotInitializationNodeClass
selectorParts: aRBMessageNode arguments first selectorParts
argumentParts: aRBMessageNode arguments first arguments)
start: aRBMessageNode start
stop: aRBMessageNode stop.
classDefinition addSlot: slot.
^ self ]
]
]
{ #category : #parsing }
CDClassDefinitionParser >> parseSlotsNodesFromArrayNode: aRBArrayNode [
aRBArrayNode statements do: [ :slotStatement |
self parseSlotNode: slotStatement ]
]
{ #category : #parsing }
CDClassDefinitionParser >> parseSuperclassNode: aSuperclassNode [
| aSuperclassName superclassNode |
aSuperclassName := (aSuperclassNode isLiteralNode
ifTrue: [ aSuperclassNode value asString ]
ifFalse: [ aSuperclassNode name ]) asSymbol.
superclassNode := self classNameNodeClass new
originalNode: aSuperclassNode;
className: aSuperclassName.
classDefinition
superclassName: aSuperclassName
astNode: superclassNode
]
{ #category : #parsing }
CDClassDefinitionParser >> parseTraitDefinitionFromNode: aNode [
| traitComposition |
traitComposition := CDTraitCompositionBuilder new buildFrom: aNode.
classDefinition traitDefinition: traitComposition.
]
{ #category : #internal }
CDClassDefinitionParser >> setAdequateClassDefinitionFrom: expressionTree [
"set a class or metaclass class definition as class definition object."
(self isInstanceSideDefinition: expressionTree)
ifTrue: [ self beClassDefinition ]
ifFalse: [ self beMetaclassDefinition ]
]
{ #category : #'private class factory' }
CDClassDefinitionParser >> sharedPoolNodeClass [
^ CDSharedPoolNode
]
{ #category : #'private class factory' }
CDClassDefinitionParser >> slotInitializationNodeClass [
^ RBSlotInitializationNode
]
{ #category : #'private class factory' }
CDClassDefinitionParser >> slotNodeClass [
^ CDSlotNode
]
{ #category : #parsing }
CDClassDefinitionParser >> visitMessageNode: aRBMessageNode [
(self isInstanceSideDefinition: aRBMessageNode)
ifTrue: [ self parseSuperclassNode: aRBMessageNode receiver ]
ifFalse: [ self parseClassName: aRBMessageNode receiver receiver ].
aRBMessageNode selectorParts
with: aRBMessageNode arguments
do: [ :selectorPart :argument |
self parseSelectorPart: selectorPart withArgument: argument ]
]