-
-
Notifications
You must be signed in to change notification settings - Fork 346
/
ReflectiveMethod.class.st
302 lines (250 loc) · 8.08 KB
/
ReflectiveMethod.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
"
I am a method, but not a compiled method storing bytecode, but a high-level model of a method referencing the AST.
to be compatible to CompiledMethod, I forward sends to a compiled method of myself.
When I am installed in a class, #run:with:in: will compile a new compiledMethod and install it. This compiledMethod has a reference to me. We form a ""twin"" were we reference each other and either can be installed.
call #invalidate to force the installation of the ReflectiveMethod, and therefore code generation on the next execution.
"
Class {
#name : 'ReflectiveMethod',
#superclass : 'Object',
#type : 'variable',
#instVars : [
'ast',
'compiledMethod',
'linkCount'
],
#category : 'Reflectivity-Core',
#package : 'Reflectivity',
#tag : 'Core'
}
{ #category : 'instance creation' }
ReflectiveMethod class >> on: aCompiledMethod [
^self new
compiledMethod: aCompiledMethod
]
{ #category : 'accessing' }
ReflectiveMethod >> ast [
^ast
]
{ #category : 'evaluation' }
ReflectiveMethod >> compileAST [
| method |
OCASTSemanticCleaner clean: ast.
ast compilationContext
semanticAnalyzerClass: RFSemanticAnalyzer;
astTranslatorClass: RFASTTranslator.
ast doSemanticAnalysis. "force semantic analysis"
method := ast generateMethod.
"#generateMethod sets the generated method as a property, put back the old"
ast compiledMethod: compiledMethod.
method sourcePointer: compiledMethod sourcePointer.
^method.
]
{ #category : 'evaluation' }
ReflectiveMethod >> compileAndInstallCompiledMethod [
self wrapperNeeded ifTrue: [ self generatePrimitiveWrapper ].
self recompileAST.
self installCompiledMethod
]
{ #category : 'accessing' }
ReflectiveMethod >> compiledMethod [
^compiledMethod
]
{ #category : 'accessing' }
ReflectiveMethod >> compiledMethod: aCompiledMethod [
compiledMethod := aCompiledMethod.
ast := compiledMethod ast
]
{ #category : 'invalidate' }
ReflectiveMethod >> createTwin [
"do nothing"
]
{ #category : 'invalidate' }
ReflectiveMethod >> decreaseLinkCount [
linkCount := linkCount - 1
]
{ #category : 'invalidate' }
ReflectiveMethod >> destroyTwin [
(ast hasProperty: #wrapperMethod) ifTrue: [ ast := compiledMethod parseTree ].
self recompileAST.
self installCompiledMethod.
compiledMethod reflectiveMethod: nil.
self class codeSupportAnnouncer unsubscribe: self.
self class codeChangeAnnouncer unsubscribe: self
]
{ #category : 'forwarding' }
ReflectiveMethod >> doesNotUnderstand: aMessage [
^aMessage sendTo: compiledMethod
]
{ #category : 'forwarding' }
ReflectiveMethod >> flushCache [
"See MethodDictionary class comment."
<primitive: 116>
]
{ #category : 'evaluation' }
ReflectiveMethod >> generatePrimitiveWrapper [
| wrappedMethod send wrapperMethod assignmentNode |
wrappedMethod := self compileAST.
send := RBMessageNode
receiver: RBVariableNode selfNode
selector: #rFwithArgs:executeMethod:
arguments: {
(RBArrayNode statements: ast arguments).
(RBLiteralNode value: self compiledMethod) }.
assignmentNode := RBAssignmentNode
variable: (RBVariableNode named: #RFReifyValueVar)
value: send.
wrapperMethod := RBMethodNode
selector: ast selector
arguments: ast arguments
body: assignmentNode asSequenceNode.
wrapperMethod methodClass: ast methodClass.
wrapperMethod propertyAt: #wrapperMethod put: true.
ast hasMetalink ifTrue: [
wrapperMethod propertyAt: #links put: (ast propertyAt: #links) ].
ast := wrapperMethod
]
{ #category : 'testing' }
ReflectiveMethod >> hasMetaLinks [
^self linkCount > 0
]
{ #category : 'invalidate' }
ReflectiveMethod >> increaseLinkCount [
linkCount := self linkCount + 1
]
{ #category : 'invalidate' }
ReflectiveMethod >> installCompiledMethod [
self installMethod: compiledMethod.
ASTCache default at: compiledMethod put: ast
]
{ #category : 'invalidate' }
ReflectiveMethod >> installLink: aMetaLink [
self increaseLinkCount.
(self ast hasOption: #optionCompileOnLinkInstallation for: aMetaLink)
ifTrue: [ self compileAndInstallCompiledMethod ]
]
{ #category : 'invalidate' }
ReflectiveMethod >> installMethod: aMethod [
"add to method dictionary"
ast methodClass methodDict at: aMethod selector put: aMethod
]
{ #category : 'invalidate' }
ReflectiveMethod >> installReflectiveMethod [
self installMethod: self
]
{ #category : 'invalidate' }
ReflectiveMethod >> invalidate [
"nop: I am already installed"
]
{ #category : 'forwarding' }
ReflectiveMethod >> isFromTrait [
^ compiledMethod isFromTrait
]
{ #category : 'accessing' }
ReflectiveMethod >> linkCount [
^linkCount ifNil: [ linkCount := 0 ]
]
{ #category : 'accessing' }
ReflectiveMethod >> linkCount: aNumber [
linkCount := aNumber
]
{ #category : 'invalidate' }
ReflectiveMethod >> metaLinkOptions [
^{
#invalidate -> #( + optionCompileOnLinkInstallation).
#increaseLinkCount -> #( + optionCompileOnLinkInstallation).
#linkCount: -> #( + optionCompileOnLinkInstallation).
#methodClass: -> #( + optionCompileOnLinkInstallation).
#compiledMethod: -> #( + optionCompileOnLinkInstallation).
#ast -> #( + optionCompileOnLinkInstallation).
#installCompiledMethod -> #( + optionCompileOnLinkInstallation).
#installReflectiveMethod -> #( + optionCompileOnLinkInstallation).
#installMethod:-> #( + optionCompileOnLinkInstallation).
#installLink: -> #( + optionCompileOnLinkInstallation).
#removeLink: -> #( + optionCompileOnLinkInstallation).
#selector: -> #( + optionCompileOnLinkInstallation).
#run:with:in: -> #( + optionCompileOnLinkInstallation).
#compiledMethod -> #( + optionCompileOnLinkInstallation).
#reflectiveMethod -> #( + optionCompileOnLinkInstallation).
#decreaseLinkCount -> #( + optionCompileOnLinkInstallation).
#metaLinkOptions -> #( + optionCompileOnLinkInstallation)
}
]
{ #category : 'forwarding' }
ReflectiveMethod >> methodClass: aClass [
^compiledMethod methodClass: aClass
]
{ #category : 'removing' }
ReflectiveMethod >> package [
^ self extensionPackage ifNil: [ self origin package ]
]
{ #category : 'printing' }
ReflectiveMethod >> printOn: aStream [
"Overrides method inherited from the byte arrayed collection."
aStream
print: ast methodClass;
nextPutAll: '>>';
store: self selector;
nextPutAll: ' (ReflectiveMethod)'
]
{ #category : 'evaluation' }
ReflectiveMethod >> recompileAST [
compiledMethod := self compileAST.
ast compiledMethod: compiledMethod.
compiledMethod reflectiveMethod: self
]
{ #category : 'accessing' }
ReflectiveMethod >> reflectiveMethod [
^self
]
{ #category : 'removing' }
ReflectiveMethod >> removeFromPackage [
self isFromTrait ifFalse: [ self package ifNotNil: [ :package | package removeMethod: self ] ]
]
{ #category : 'invalidate' }
ReflectiveMethod >> removeLink: aMetaLink [
(aMetaLink optionCompileOnLinkInstallation or: [ compiledMethod isRealPrimitive ])
ifTrue: [ self compileAndInstallCompiledMethod ]
ifFalse: [ compiledMethod invalidate ].
self decreaseLinkCount.
self linkCount = 0 ifTrue: [ self destroyTwin ]
]
{ #category : 'evaluation' }
ReflectiveMethod >> run: aSelector with: anArray in: aReceiver [
"we install the old one as the compiler might need it"
self installCompiledMethod.
self compileAndInstallCompiledMethod.
^aReceiver rFwithArgs: anArray executeMethod: compiledMethod
]
{ #category : 'forwarding' }
ReflectiveMethod >> selector [
^compiledMethod selector
]
{ #category : 'forwarding' }
ReflectiveMethod >> selector: aSymbol [
^compiledMethod selector: aSymbol
]
{ #category : 'spotter' }
ReflectiveMethod >> spotterActDefault [
^ self compiledMethod spotterActDefault
]
{ #category : 'spotter' }
ReflectiveMethod >> spotterItemsFor: aStep [
"do nothing for compiled method"
]
{ #category : 'spotter' }
ReflectiveMethod >> spotterPreviewIn: aComposite [
<spotterPreview: 10>
self compiledMethod spotterPreviewIn: aComposite
]
{ #category : 'spotter' }
ReflectiveMethod >> spotterSelectFor: aStep [
self compiledMethod spotterSelectFor: aStep
]
{ #category : 'evaluation' }
ReflectiveMethod >> wrapperNeeded [
ast hasMetalink ifFalse: [ ^false ].
compiledMethod isRealPrimitive ifTrue: [ ^true ].
ast hasMetalinkAfter ifTrue: [ ^true ].
^false
]