/
MCSnapshotBrowserTest.class.st
347 lines (283 loc) · 8.88 KB
/
MCSnapshotBrowserTest.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
Class {
#name : #MCSnapshotBrowserTest,
#superclass : #MCTestCase,
#instVars : [
'model',
'morph'
],
#category : #'Monticello-Tests-Snapshots'
}
{ #category : #private }
MCSnapshotBrowserTest >> allCategories [
^ Array with: model extensionsCategory with: self mockCategoryName.
]
{ #category : #private }
MCSnapshotBrowserTest >> allMethods [
^ MCSnapshotResource current definitions
select: [:def | def isMethodDefinition]
thenCollect: [:def | def selector]
]
{ #category : #private }
MCSnapshotBrowserTest >> allProtocols [
^ MCSnapshotResource current definitions
select: [:def | def isMethodDefinition]
thenCollect: [:def | def category]
]
{ #category : #morphic }
MCSnapshotBrowserTest >> annotationTextMorph [
^ (self morphsOfClass: TextMorph) first
]
{ #category : #asserting }
MCSnapshotBrowserTest >> assertAListIncludes: anArrayOfStrings [
self listMorphs
detect: [:m | m getList includesAll: anArrayOfStrings]
ifNone: [self assert: false].
]
{ #category : #asserting }
MCSnapshotBrowserTest >> assertAListMatches: strings [
| lists |
lists := self listMorphs collect: #getList.
lists
detect: [ :list|
(list size = strings size) and: [list includesAll: strings]]
ifNone: [
self fail: 'Could not find all "', strings asArray asString, '" ',
'in any of "', (lists collect: #asArray) asArray asString, '"' ].
]
{ #category : #asserting }
MCSnapshotBrowserTest >> assertButtonExists: aString [
self buttonMorphs detect: [:m | m label = aString] ifNone: [self assert: false].
]
{ #category : #asserting }
MCSnapshotBrowserTest >> assertButtonOn: aString [
self assert: (self findButtonWithLabel: aString) getModelState.
]
{ #category : #asserting }
MCSnapshotBrowserTest >> assertTextIs: aString [
self
assert: self textMorph text
equals: aString
]
{ #category : #morphic }
MCSnapshotBrowserTest >> buttonMorphs [
^ self morphsOfClass: PluggableButtonMorph
]
{ #category : #private }
MCSnapshotBrowserTest >> classABooleanMethods [
^ #(falsehood moreTruth truth)
]
{ #category : #private }
MCSnapshotBrowserTest >> classAClassProtocols [
^ self protocolsForClass: self mockClassA class.
]
{ #category : #private }
MCSnapshotBrowserTest >> classAComment [
^ self mockClassA organization classComment.
]
{ #category : #private }
MCSnapshotBrowserTest >> classADefinitionString [
^ self mockClassA oldDefinition
]
{ #category : #private }
MCSnapshotBrowserTest >> classAProtocols [
^ self protocolsForClass: self mockClassA.
]
{ #category : #private }
MCSnapshotBrowserTest >> classAclassDefinitionString [
^ self mockClassA class definitionWithoutSlots
]
{ #category : #simulating }
MCSnapshotBrowserTest >> clickOnButton: aString [
(self findButtonWithLabel: aString) performAction.
]
{ #category : #simulating }
MCSnapshotBrowserTest >> clickOnListItem: aString [
| listMorph |
listMorph := self findListContaining: aString.
listMorph changeModelSelection: (listMorph getList indexOf: aString).
]
{ #category : #private }
MCSnapshotBrowserTest >> definedClasses [
^ MCSnapshotResource current definitions
select: [:def | def isClassDefinition]
thenCollect: [:def | def className].
]
{ #category : #asserting }
MCSnapshotBrowserTest >> denyAListHasSelection: aString [
| found |
found := true.
self listMorphs
detect: [:m | m selection = aString]
ifNone: [found := false].
self deny: found.
]
{ #category : #asserting }
MCSnapshotBrowserTest >> denyAListIncludesAnyOf: anArrayOfStrings [
| found |
found := true.
self listMorphs
detect: [:m | m getList includesAnyOf: anArrayOfStrings]
ifNone: [found := false].
self deny: found.
]
{ #category : #asserting }
MCSnapshotBrowserTest >> denyButtonOn: aString [
self deny: (self findButtonWithLabel: aString) getModelState.
]
{ #category : #private }
MCSnapshotBrowserTest >> falsehoodMethodSource [
^ 'falsehood
^ false'
]
{ #category : #morphic }
MCSnapshotBrowserTest >> findButtonWithLabel: aString [
^ self buttonMorphs detect: [:m | m label = aString]
]
{ #category : #morphic }
MCSnapshotBrowserTest >> findListContaining: aString [
^ self listMorphs detect: [:m | m getList includes: aString]
]
{ #category : #morphic }
MCSnapshotBrowserTest >> listMorphs [
^ self morphsOfClass: PluggableListMorph
]
{ #category : #morphic }
MCSnapshotBrowserTest >> morphsOfClass: aMorphClass [
| morphs |
morphs := OrderedCollection new.
morph allMorphsDo: [:m | (m isKindOf: aMorphClass) ifTrue: [morphs add: m]].
^ morphs
]
{ #category : #private }
MCSnapshotBrowserTest >> protocolsForClass: aClass [
^ aClass organization allCategories
]
{ #category : #selecting }
MCSnapshotBrowserTest >> selectMockClassA [
self clickOnListItem: self mockCategoryName.
self clickOnListItem: 'MCMockClassA'.
]
{ #category : #running }
MCSnapshotBrowserTest >> setUp [
super setUp.
model := MCSnapshotBrowser forSnapshot: MCSnapshotResource current snapshot.
morph := model buildWindow.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testButtonMutex [
self assertButtonOn: 'instance'.
self denyButtonOn: '?'.
self denyButtonOn: 'class'.
self clickOnButton: '?'.
self assertButtonOn: '?'.
self denyButtonOn: 'instance'.
self denyButtonOn: 'class'.
self clickOnButton: 'class'.
self assertButtonOn: 'class'.
self denyButtonOn: '?'.
self denyButtonOn: 'instance'.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testCategorySelected [
self clickOnListItem: self mockCategoryName.
self assertAListMatches: self allCategories.
self assertAListMatches: self definedClasses.
self denyAListIncludesAnyOf: self allProtocols.
self denyAListIncludesAnyOf: self allMethods.
self assertTextIs: ''.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testClassSelected [
self selectMockClassA.
self assertAListMatches: self allCategories.
self assertAListMatches: self definedClasses.
self assertAListMatches: self classAProtocols.
self denyAListIncludesAnyOf: self allMethods.
self assertTextIs: self classADefinitionString.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testClassSideClassSelected [
self clickOnButton: 'class'.
self selectMockClassA.
self assertAListMatches: self allCategories.
self assertAListMatches: self definedClasses.
self assertAListMatches: self classAClassProtocols.
self denyAListIncludesAnyOf: self allMethods.
self assertTextIs: self classAclassDefinitionString.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testComment [
self clickOnButton: '?'.
self assertTextIs: ''.
self clickOnListItem: self mockCategoryName.
self assertTextIs: ''.
self clickOnListItem: 'MCMockClassA'.
self assertTextIs: self classAComment.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testFourColumns [
self assert: self listMorphs size = 4.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testMethodIsCleared [
self clickOnListItem: self mockCategoryName.
self clickOnListItem: 'MCMockClassA'.
self clickOnListItem: 'boolean'.
self clickOnListItem: 'falsehood'.
self clickOnListItem: AllProtocol defaultName.
self denyAListHasSelection: 'falsehood'.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testMethodSelected [
self clickOnListItem: self mockCategoryName.
self clickOnListItem: 'MCMockClassA'.
self clickOnListItem: 'boolean'.
self clickOnListItem: 'falsehood'.
self assertAListMatches: self allCategories.
self assertAListMatches: self definedClasses.
self assertAListMatches: self classAProtocols.
self assertAListMatches: self classABooleanMethods.
self assertTextIs: self falsehoodMethodSource.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testNoSelection [
self assertAListMatches: self allCategories.
self denyAListIncludesAnyOf: self definedClasses.
self denyAListIncludesAnyOf: self allProtocols.
self denyAListIncludesAnyOf: self allMethods.
"and if there I need to see the packages scripts (or none)"
self assertTextIs: '(package defines no scripts)'.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testProtocolIsCleared [
self clickOnListItem: self mockCategoryName.
self clickOnListItem: 'MCMockASubclass'.
self clickOnListItem: 'as yet unclassified'.
self clickOnListItem: 'MCMockClassA'.
self denyAListHasSelection: 'as yet unclassified'.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testProtocolSelected [
self clickOnListItem: self mockCategoryName.
self clickOnListItem: 'MCMockClassA'.
self clickOnListItem: 'boolean'.
self assertAListMatches: self allCategories.
self assertAListMatches: self definedClasses.
self assertAListMatches: self classAProtocols.
self assertAListMatches: self classABooleanMethods.
self assertTextIs: ''.
]
{ #category : #testing }
MCSnapshotBrowserTest >> testTextPane [
self textMorph
]
{ #category : #testing }
MCSnapshotBrowserTest >> testThreeButtons [
self assertButtonExists: 'instance'.
self assertButtonExists: '?'.
self assertButtonExists: 'class'.
]
{ #category : #morphic }
MCSnapshotBrowserTest >> textMorph [
^ (self morphsOfClass: RubPluggableTextMorph) last
]