/
STONWriter.class.st
589 lines (511 loc) · 15.2 KB
/
STONWriter.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
"
STONWriter serializes objects using the Smalltalk Object Notation format.
Customization options are:
- prettyPrint <Boolean> default is false
if true, produce pretty printed output
- newLine <String> default is String cr
what sequence to use for EOL
- asciiOnly <Boolean> default is false
if true, use \u escapes for all non-ASCII characters
most common control characters are still escaped
- jsonMode <Boolean> default is false
if true, the follow changes occur
- strings are delimited with double quotes
- nil is encoded as null
- symbols are treated as strings
- only STON listClass and STON mapClass instances are allowed as composite objects
it is wise to also use either #error or #ignore as referencePolicy to avoid references
- referencePolicy <#normal|#ignore|#error> default is #normal
if #normal, track and count object references and use references to implement sharing and break cycles
if #error, track object references and signal STONWriterError when a shared reference is encountered
if #ignore, don't track object references which might loop forever on cycles
- keepNewLines <Boolean> default is false
if true, any newline sequence CR, LF or CRLF inside strings or symbols will not be escaped
but will be written as the newline EOF convention
Note that in default STON mode I only use the following named character escapes: \b \t \n \f \' and \\ while in JSON mode \' is replaced by \""
"
Class {
#name : #STONWriter,
#superclass : #Object,
#instVars : [
'writeStream',
'prettyPrint',
'stonCharacters',
'newLine',
'asciiOnly',
'jsonMode',
'keepNewLines',
'referencePolicy',
'level',
'objects'
],
#classVars : [
'STONCharacters',
'STONSimpleSymbolCharacters'
],
#category : #'STON-Core-Writer'
}
{ #category : #'class initialization' }
STONWriter class >> initialize [
"Modification timestamp 20170131"
self initializeSTONCharacters.
self initializeSTONSimpleSymbolCharacters
]
{ #category : #'class initialization' }
STONWriter class >> initializeSTONCharacters [
| escapes |
STONCharacters := Array new: 127.
32 to: 126 do: [ :each |
STONCharacters at: each + 1 put: #pass ].
"This is the minimal STON set of named escapes"
escapes := #( 8 '\b' 9 '\t' 10 '\n' 12 '\f' 13 '\r' 39 '\''' 92 '\\' ).
escapes pairsDo: [ :code :escape |
STONCharacters at: code + 1 put: escape ]
]
{ #category : #'class initialization' }
STONWriter class >> initializeSTONSimpleSymbolCharacters [
"STONSimpleSymbolCharacters asArray collectWithIndex: [ :each :index |
each isZero ifTrue: [ (index - 1) asCharacter ] ]."
STONSimpleSymbolCharacters := ByteArray new: 256 withAll: 1.
1 to: 256 do: [ :each | | char |
char := (each - 1) asCharacter.
(self isSimpleSymbolChar: char)
ifTrue: [
STONSimpleSymbolCharacters at: each put: 0 ] ]
]
{ #category : #private }
STONWriter class >> isSimpleSymbolChar: char [
^ 'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789-_./' includes: char
]
{ #category : #'instance creation' }
STONWriter class >> on: writeStream [
^ self new
on: writeStream;
yourself
]
{ #category : #'initialize-release' }
STONWriter >> asciiOnly: boolean [
asciiOnly := boolean
]
{ #category : #'initialize-release' }
STONWriter >> close [
writeStream ifNotNil: [
writeStream close.
writeStream := nil ]
]
{ #category : #private }
STONWriter >> encodeCharacter: char [
| code encoding |
"STONCharacters contains for the lower 127 characters (codes 0 to 126) either nil (unknown),
#pass (output as is, clean ASCII characters) or a full escape string"
((code := char codePoint) < 127 and: [ (encoding := self stonCharacters at: code + 1) notNil ])
ifTrue: [
(encoding = #pass or: [ jsonMode and: [ char = $' ] ])
ifTrue: [ writeStream nextPut: char ]
ifFalse: [ writeStream nextPutAll: encoding ] ]
ifFalse: [
"always escape Latin1 C1 controls, or when asciiOnly is true"
(code > 16r9F and: [ asciiOnly not ])
ifTrue: [ writeStream nextPut: char ]
ifFalse: [ self escapeUnicode: code ] ]
]
{ #category : #private }
STONWriter >> encodeKey: key value: value [
(jsonMode and: [ key isString not ])
ifTrue: [ self error: 'JSON key names in objects must be strings' ].
self nextPut: key.
self prettyPrintSpace.
writeStream nextPut: $:.
self prettyPrintSpace.
self nextPut: value
]
{ #category : #writing }
STONWriter >> encodeList: elements [
writeStream nextPut: $[.
elements isEmpty
ifTrue: [
self prettyPrintSpace ]
ifFalse: [
self indentedDo: [
self newlineIndent.
elements
do: [ :each | self nextPut: each ]
separatedBy: [ self listElementSeparator ] ].
self newlineIndent ].
writeStream nextPut: $]
]
{ #category : #writing }
STONWriter >> encodeMap: pairs [
| first |
first := true.
writeStream nextPut: ${.
pairs isEmpty
ifTrue: [
self prettyPrintSpace ]
ifFalse: [
self indentedDo: [
self newlineIndent.
pairs keysAndValuesDo: [ :key :value |
first
ifTrue: [ first := false ]
ifFalse: [ self mapElementSeparator ].
self encodeKey: key value: value ] ].
self newlineIndent ].
writeStream nextPut: $}
]
{ #category : #private }
STONWriter >> encodeString: string [
writeStream nextPut: (jsonMode ifTrue: [ $" ] ifFalse: [ $' ]).
keepNewLines
ifTrue: [
self encodeStringKeepingNewLines: string ]
ifFalse: [
string do: [ :each | self encodeCharacter: each ] ].
writeStream nextPut: (jsonMode ifTrue: [ $" ] ifFalse: [ $' ])
]
{ #category : #private }
STONWriter >> encodeStringKeepingNewLines: string [
| input char |
input := string readStream.
[ input atEnd ]
whileFalse: [
char := input next.
char = Character lf
ifTrue: [ writeStream nextPutAll: newLine ]
ifFalse: [
char = Character cr
ifTrue: [
input peekFor: Character lf.
writeStream nextPutAll: newLine ]
ifFalse: [ self encodeCharacter: char ] ] ]
]
{ #category : #'error handling' }
STONWriter >> error: aString [
^ STONWriterError signal: aString
]
{ #category : #'initialize-release' }
STONWriter >> escape: char with: anObject [
"Instruct me to escape char with object, either a replacement string or #pass"
"self escape: $/ with: '\/'."
self assert: (anObject isString | (anObject == #pass)).
self assert: char isOctetCharacter.
self writeableStonCharacters at: char codePoint + 1 put: anObject
]
{ #category : #private }
STONWriter >> escapeUnicode4: codePoint [
writeStream nextPutAll: '\u'.
codePoint printOn: writeStream base: 16 nDigits: 4
]
{ #category : #private }
STONWriter >> escapeUnicode: codePoint [
codePoint <= 16rFFFF
ifTrue: [ self escapeUnicode4: codePoint ]
ifFalse: [
codePoint <= 16r10FFFF
ifTrue: [ | leadSurrogate trailSurrogate shifted |
"Characters not in the Basic Multilingual Plane are encoded as a UTF-16 surrogate pair"
"See https://tools.ietf.org/html/rfc7159#section-7"
shifted := codePoint - 16r10000.
leadSurrogate := 16rD800 + (shifted // 16r400).
trailSurrogate := 16rDC00 + (shifted \\ 16r400).
self escapeUnicode4: leadSurrogate.
self escapeUnicode4: trailSurrogate ]
ifFalse: [ self error: 'Character Unicode code point outside encoder range' ] ]
]
{ #category : #private }
STONWriter >> indentedDo: block [
level := level + 1.
block value.
level := level - 1
]
{ #category : #'initialize-release' }
STONWriter >> initialize [
super initialize.
stonCharacters := STONCharacters.
prettyPrint := false.
newLine := String cr.
level := 0.
referencePolicy := #normal.
jsonMode := keepNewLines := asciiOnly := false.
objects := IdentityDictionary new
]
{ #category : #private }
STONWriter >> isSimpleSymbol: symbol [
(symbol isEmpty or: [ symbol isWideString ])
ifTrue: [ ^ false ].
^ (symbol class
findFirstInString: symbol
inSet: STONSimpleSymbolCharacters
startingAt: 1) = 0
]
{ #category : #accessing }
STONWriter >> jsonMode [
^ jsonMode
]
{ #category : #'initialize-release' }
STONWriter >> jsonMode: boolean [
(jsonMode := boolean)
ifTrue: [
self
escape: $' with: #pass;
escape: $" with: '\"' ]
ifFalse: [
self
escape: $" with: #pass;
escape: $' with: '\''' ]
]
{ #category : #'initialize-release' }
STONWriter >> keepNewLines: boolean [
"If true, any newline CR, LF or CRLF inside strings or symbols will not be escaped
but will instead be converted to the newline convention chosen, see #newLine:
The default is false, where CR, LF or CRLF will be enscaped unchanged."
keepNewLines := boolean
]
{ #category : #private }
STONWriter >> listElementSeparator [
writeStream nextPut: $,.
self newlineIndent
]
{ #category : #private }
STONWriter >> mapElementSeparator [
writeStream nextPut: $,.
self newlineIndent
]
{ #category : #'initialize-release' }
STONWriter >> newLine: string [
"The sequence to use when ending a line, either CR, LF or CRLF"
newLine := string
]
{ #category : #private }
STONWriter >> newlineIndent [
prettyPrint ifTrue: [
writeStream nextPutAll: newLine.
level timesRepeat: [ writeStream tab ] ]
]
{ #category : #public }
STONWriter >> nextPut: anObject [
anObject stonOn: self
]
{ #category : #'initialize-release' }
STONWriter >> on: aWriteStream [
writeStream := aWriteStream
]
{ #category : #'initialize-release' }
STONWriter >> optimizeForLargeStructures [
self class environment
at: #FLLargeIdentityDictionary
ifPresent: [ :identityDictionaryClass | objects := identityDictionaryClass new ].
]
{ #category : #'initialize-release' }
STONWriter >> prettyPrint: boolean [
prettyPrint := boolean
]
{ #category : #private }
STONWriter >> prettyPrintSpace [
prettyPrint ifTrue: [ writeStream space ]
]
{ #category : #'initialize-release' }
STONWriter >> referencePolicy: policy [
self assert: ( #(#normal #ignore #error) includes: policy ).
referencePolicy := policy
]
{ #category : #'initialize-release' }
STONWriter >> reset [
objects removeAll
]
{ #category : #private }
STONWriter >> shortListElementSeparator [
writeStream nextPut: $,.
self prettyPrintSpace
]
{ #category : #private }
STONWriter >> stonCharacters [
^ stonCharacters ifNil: [ stonCharacters := STONCharacters ]
]
{ #category : #private }
STONWriter >> with: object do: block [
| index |
referencePolicy = #ignore
ifTrue: [ ^ block value ].
(index := objects at: object ifAbsent: [ nil ]) notNil
ifTrue: [
referencePolicy = #error
ifTrue: [ ^ self error: 'shared reference detected' ].
self writeReference: index ]
ifFalse: [
index := objects size + 1.
objects at: object put: index.
block value ]
]
{ #category : #writing }
STONWriter >> writeAssociation: association [
jsonMode
ifTrue: [ self error: 'wrong object class for JSON mode' ].
self
encodeKey: association key
value: association value
]
{ #category : #writing }
STONWriter >> writeBoolean: boolean [
writeStream print: boolean
]
{ #category : #writing }
STONWriter >> writeFloat: float [
writeStream print: float
]
{ #category : #writing }
STONWriter >> writeFraction: fraction [
jsonMode
ifTrue: [ self writeFloat: fraction asFloat ]
ifFalse: [ writeStream
print: fraction numerator;
nextPut: $/;
print: fraction denominator ]
]
{ #category : #writing }
STONWriter >> writeInteger: integer [
writeStream print: integer
]
{ #category : #writing }
STONWriter >> writeList: collection [
self with: collection do: [
self encodeList: collection ]
]
{ #category : #writing }
STONWriter >> writeMap: hashedCollection [
self with: hashedCollection do: [
self encodeMap: hashedCollection ]
]
{ #category : #writing }
STONWriter >> writeNull [
jsonMode
ifTrue: [ writeStream nextPutAll: 'null' ]
ifFalse: [ writeStream print: nil ]
]
{ #category : #writing }
STONWriter >> writeObject: anObject [
| instanceVariableNames |
(instanceVariableNames := anObject class stonAllInstVarNames) isEmpty
ifTrue: [
self writeObject: anObject do: [ self encodeMap: #() ] ]
ifFalse: [
self writeObject: anObject streamMap: [ :dictionary |
instanceVariableNames do: [ :each |
(anObject instVarNamed: each)
ifNotNil: [ :value |
dictionary at: each asSymbol put: value ]
ifNil: [
anObject stonShouldWriteNilInstVars
ifTrue: [ dictionary at: each asSymbol put: nil ] ] ] ] ]
]
{ #category : #writing }
STONWriter >> writeObject: anObject do: block [
(jsonMode and: [ anObject class ~= STON listClass and: [ anObject class ~= STON mapClass ] ])
ifTrue: [ self error: 'wrong object class for JSON mode' ].
self with: anObject do: [
writeStream nextPutAll: anObject class stonName.
self prettyPrintSpace.
block value ]
]
{ #category : #writing }
STONWriter >> writeObject: object listSingleton: element [
self writeObject: object do: [
writeStream nextPut: $[.
self
prettyPrintSpace;
nextPut: element;
prettyPrintSpace.
writeStream nextPut: $] ]
]
{ #category : #writing }
STONWriter >> writeObject: anObject named: stonName do: block [
(jsonMode and: [ anObject class ~= STON listClass and: [ anObject class ~= STON mapClass ] ])
ifTrue: [ self error: 'wrong object class for JSON mode' ].
self with: anObject do: [
writeStream nextPutAll: stonName.
self prettyPrintSpace.
block value ]
]
{ #category : #writing }
STONWriter >> writeObject: object named: stonName listSingleton: element [
self writeObject: object named: stonName do: [
writeStream nextPut: $[.
self
prettyPrintSpace;
nextPut: element;
prettyPrintSpace.
writeStream nextPut: $] ]
]
{ #category : #writing }
STONWriter >> writeObject: object streamList: block [
self writeObject: object do: [ | listWriter |
listWriter := STONListWriter on: self.
writeStream nextPut: $[.
self indentedDo: [
self newlineIndent.
block value: listWriter ].
self newlineIndent.
writeStream nextPut: $] ]
]
{ #category : #writing }
STONWriter >> writeObject: object streamMap: block [
self writeObject: object do: [ | mapWriter |
mapWriter := STONMapWriter on: self.
writeStream nextPut: ${.
self indentedDo: [
self newlineIndent.
block value: mapWriter ].
self newlineIndent.
writeStream nextPut: $} ]
]
{ #category : #writing }
STONWriter >> writeObject: object streamShortList: block [
self writeObject: object do: [ | listWriter |
listWriter := STONShortListWriter on: self.
writeStream nextPut: $[.
self indentedDo: [
self prettyPrintSpace.
block value: listWriter ].
self prettyPrintSpace.
writeStream nextPut: $] ]
]
{ #category : #writing }
STONWriter >> writeReference: index [
writeStream
nextPut: $@;
print: index
]
{ #category : #writing }
STONWriter >> writeScaledDecimal: scaledDecimal [
jsonMode
ifTrue: [ self writeFloat: scaledDecimal asFloat ]
ifFalse: [ writeStream
print: scaledDecimal numerator;
nextPut: $/;
print: scaledDecimal denominator;
nextPut: $s;
print: scaledDecimal scale ]
]
{ #category : #writing }
STONWriter >> writeString: string [
self encodeString: string
]
{ #category : #writing }
STONWriter >> writeSymbol: symbol [
jsonMode
ifTrue: [
self writeString: symbol ]
ifFalse: [
writeStream nextPut: $#.
(self isSimpleSymbol: symbol)
ifTrue: [
writeStream nextPutAll: symbol ]
ifFalse: [
self encodeString: symbol ] ]
]
{ #category : #private }
STONWriter >> writeableStonCharacters [
^ self stonCharacters == STONCharacters
ifTrue: [ stonCharacters := stonCharacters copy ]
ifFalse: [ stonCharacters ]
]