/
DoItVariable.class.st
244 lines (195 loc) · 5.27 KB
/
DoItVariable.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
"
I model an access to variables from DoIt scripts. Following example demonstrates an idea:
| temp |
temp := 100.
doItVar := DoItVariable named: #temp fromContext: thisContext.
Smalltalk compiler
bindings: {doItVar};
evaluate: '1+temp'.
I capture a given variable and a context and compile a method nodes using unified reflective API as:
doItVariable read.
doItVariable write: newValue.
This way variables visible from one context are indirectly accessible from another environment (from doit expressions).
For example in ""debugIt expressions"" in Debugger the temp variables from original context are shown as normal variables without any tricks.
To create my instances use following messages:
DoItVariable named: #temp fromContext: thisContext.
DoItVariable fromContext: thisContext variable: aVariable.
Or use a variable message:
aVariable asDoItVariableFrom: aContext
Internal Representation and Key Implementation Points.
Instance Variables
actualVariable: <Variable>
doItContext: <Context>
"
Class {
#name : #DoItVariable,
#superclass : #Variable,
#instVars : [
'actualVariable',
'doItContext'
],
#category : #'Kernel-Variables'
}
{ #category : #'instance creation' }
DoItVariable class >> fromContext: aContext variable: aVariable [
^self new
doItContext: aContext;
actualVariable: aVariable
]
{ #category : #'instance creation' }
DoItVariable class >> named: aString fromContext: aContext [
^self
fromContext: aContext
variable: (aContext lookupVar: aString)
]
{ #category : #accessing }
DoItVariable >> actualVariable [
^ actualVariable
]
{ #category : #accessing }
DoItVariable >> actualVariable: aVariable [
actualVariable := aVariable.
name := actualVariable name
]
{ #category : #converting }
DoItVariable >> asDoItVariableFrom: aContext [
^self
]
{ #category : #accessing }
DoItVariable >> doItContext [
^ doItContext
]
{ #category : #accessing }
DoItVariable >> doItContext: anObject [
doItContext := anObject
]
{ #category : #'code generation' }
DoItVariable >> emitStore: aMethodBuilder [
"generate bytecode to call the reflective write method of the Slot"
| tempName |
tempName := '0slotTempForStackManipulation'.
aMethodBuilder
addTemp: tempName;
storeTemp: tempName;
popTop;
pushLiteral: self;
pushTemp: tempName;
send: #write:
]
{ #category : #'code generation' }
DoItVariable >> emitValue: aMethodBuilder [
aMethodBuilder
pushLiteral: self;
send: #read
]
{ #category : #testing }
DoItVariable >> isArgumentVariable [
^actualVariable isArgumentVariable
]
{ #category : #testing }
DoItVariable >> isClassVariable [
^actualVariable isClassVariable
]
{ #category : #testing }
DoItVariable >> isGlobalVariable [
^actualVariable isGlobalVariable
]
{ #category : #testing }
DoItVariable >> isInstanceVariable [
^actualVariable isInstanceVariable
]
{ #category : #testing }
DoItVariable >> isLiteralVariable [
^actualVariable isLiteralVariable
]
{ #category : #testing }
DoItVariable >> isLocalVariable [
^actualVariable isLocalVariable
]
{ #category : #testing }
DoItVariable >> isReservedVariable [
^actualVariable isReservedVariable
]
{ #category : #testing }
DoItVariable >> isSelfVariable [
^actualVariable isSelfVariable
]
{ #category : #testing }
DoItVariable >> isSuperVariable [
^actualVariable isSuperVariable
]
{ #category : #testing }
DoItVariable >> isTempVariable [
^actualVariable isTempVariable
]
{ #category : #testing }
DoItVariable >> isThisContextVariable [
^actualVariable isThisContextVariable
]
{ #category : #testing }
DoItVariable >> isUndeclaredVariable [
^actualVariable isUndeclaredVariable
]
{ #category : #testing }
DoItVariable >> isUninitialized [
^actualVariable isUninitialized
]
{ #category : #testing }
DoItVariable >> isWorkspaceVariable [
^actualVariable isWorkspaceVariable
]
{ #category : #accessing }
DoItVariable >> key [
^self name
]
{ #category : #'read/write usage' }
DoItVariable >> markEscapingRead [
"ignored, the escape status of the actualVariable does not change"
]
{ #category : #'read/write usage' }
DoItVariable >> markEscapingWrite [
"ignored, the escape status of the actualVariable does not change"
]
{ #category : #'read/write usage' }
DoItVariable >> markRead [
"ignored, the escape status of the actualVariable does not change"
]
{ #category : #'read/write usage' }
DoItVariable >> markRepeatedWrite [
"ignored, the escape status of the actualVariable does not change"
]
{ #category : #'read/write usage' }
DoItVariable >> markWrite [
"ignored, the escape status of the actualVariable does not change"
]
{ #category : #printing }
DoItVariable >> printOn: aStream [
super printOn: aStream.
aStream nextPut: $(.
actualVariable printOn: aStream.
aStream nextPut: $)
]
{ #category : #'meta-object-protocol' }
DoItVariable >> read [
^actualVariable readInContext: doItContext
]
{ #category : #debugging }
DoItVariable >> readInContext: aContext [
^self read
]
{ #category : #accessing }
DoItVariable >> scope [
^ actualVariable scope
]
{ #category : #queries }
DoItVariable >> usingMethods [
^actualVariable usingMethods
]
{ #category : #'meta-object-protocol' }
DoItVariable >> write: aValue [
^actualVariable write: aValue inContext: doItContext
]
{ #category : #debugging }
DoItVariable >> write: aValue inContext: aContext [
self write: aValue
]