-
-
Notifications
You must be signed in to change notification settings - Fork 346
/
RBBrowserEnvironmentTest.class.st
613 lines (548 loc) · 24.4 KB
/
RBBrowserEnvironmentTest.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
"
Unit test for RBBrowserEnvironment
"
Class {
#name : 'RBBrowserEnvironmentTest',
#superclass : 'AbstractEnvironmentTestCase',
#instVars : [
'universalEnvironment'
],
#classVars : [
'AClassVariable',
'ClassSideOnlyVariable'
],
#category : 'Refactoring-Environment-Tests',
#package : 'Refactoring-Environment-Tests'
}
{ #category : 'accessing' }
RBBrowserEnvironmentTest class >> accessFromClassSideOnlyVariable [
"testing method. This class variable is only accessed from this class side method"
^ ClassSideOnlyVariable
]
{ #category : 'accessing' }
RBBrowserEnvironmentTest class >> defaultTimeLimit [
^30 seconds
]
{ #category : 'accessing' }
RBBrowserEnvironmentTest class >> packageNamesUnderTest [
^ #('Refactoring-Environment')
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> classNamesFor: anEnvironment [
| classNames allClassNames |
classNames := IdentitySet new
addAll: anEnvironment classNames asSet;
addAll: anEnvironment not classNames;
yourself.
allClassNames := universalEnvironment classNames asSortedCollection.
self assert: classNames asSortedCollection equals: allClassNames.
self assertEmpty: (anEnvironment & anEnvironment not) classNames.
self assert: (anEnvironment | anEnvironment not) classNames asSortedCollection equals: allClassNames
]
{ #category : 'mockup' }
RBBrowserEnvironmentTest >> classVariableReader [
^ AClassVariable
]
{ #category : 'mockup' }
RBBrowserEnvironmentTest >> classVariableWriter [
AClassVariable := nil
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> classesFor: aBrowserEnvironment [
| allClasses |
allClasses := aBrowserEnvironment classes.
allClasses addAll: aBrowserEnvironment not classes.
RBBrowserEnvironment new allClassesDo: [ :each | allClasses remove: each ].
self assertEmpty: allClasses
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> copyFor: aBrowserEnvironment [
| newEnvironment |
newEnvironment := aBrowserEnvironment copy.
self assert: newEnvironment numberSelectors equals: aBrowserEnvironment numberSelectors.
self assert: (newEnvironment not & aBrowserEnvironment) numberSelectors equals: 0
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> keysFor: aBrowserEnvironment [
| allKeys |
allKeys := IdentitySet withAll: aBrowserEnvironment keys.
allKeys addAll: aBrowserEnvironment not keys.
allKeys removeAll: testingEnvironment keys.
self assertEmpty: allKeys
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> labelFor: aBrowserEnvironment [
self deny: aBrowserEnvironment label isNil.
self deny: aBrowserEnvironment label isEmpty.
self deny: aBrowserEnvironment defaultLabel isNil.
self deny: aBrowserEnvironment defaultLabel isEmpty
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> numberSelectorsFor: aBrowserEnvironment [
| numberSelectors numberSelectorsNot |
numberSelectors := aBrowserEnvironment numberSelectors.
numberSelectorsNot := aBrowserEnvironment not numberSelectors.
self assert: numberSelectors + numberSelectorsNot equals: universalEnvironment numberSelectors.
self assert: (aBrowserEnvironment & aBrowserEnvironment not) numberSelectors equals: 0.
self assert: (universalEnvironment & aBrowserEnvironment) numberSelectors equals: numberSelectors.
self assert: (aBrowserEnvironment & universalEnvironment) numberSelectors equals: numberSelectors
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> packagesFor: anEnvironment [
| allPackages |
allPackages := IdentitySet withAll: universalEnvironment packages.
allPackages removeAll: anEnvironment packages.
anEnvironment not packages do: [ :package | allPackages remove: package ifAbsent: [ ] ].
allPackages do: [ :package | self assertEmpty: (universalEnvironment classesInPackage: package) ]
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> protocolsFor: aBrowserEnvironment [
aBrowserEnvironment classesAndSelectorsDo: [ :class :selector |
self assert: (aBrowserEnvironment includesProtocol: (class protocolOfSelector: selector) in: class) ]
]
{ #category : 'running' }
RBBrowserEnvironmentTest >> setUp [
super setUp.
universalEnvironment := RBBrowserEnvironment new
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> storeStringFor: aBrowserEnvironment [
| newEnvironment |
newEnvironment := Smalltalk compiler evaluate: aBrowserEnvironment storeString.
self assert: newEnvironment numberSelectors equals: aBrowserEnvironment numberSelectors.
self assert: (newEnvironment not & aBrowserEnvironment) numberSelectors equals: 0
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testAndAnOrEnvironmentAndAnotherOrEnvironment [
| orEnvironmentWithPackage orEnvironmentWithClass andEnvironment newClass |
"The first or environment contains a single package"
orEnvironmentWithPackage := (universalEnvironment forClasses: { })
|
(universalEnvironment forPackages:
{ self class package }).
orEnvironmentWithClass := (universalEnvironment forClasses:
{ self class })
| (universalEnvironment forPackages: { }).
andEnvironment := orEnvironmentWithClass & orEnvironmentWithPackage.
self
assert: orEnvironmentWithPackage classNames asArray
equals: { self class name }.
self
assert: orEnvironmentWithClass classNames asArray
equals: { self class name }.
self
assert: andEnvironment classNames asArray asArray
equals: { self class name }.
[ "Now we install a new class in the package"
newClass := Object classInstaller make: [ :builder |
builder
superclass: Object;
name: #RBBrowserTemporaryClassForTest;
category: self class package name ].
"Check that the new class belongs in the or environment with a package"
self assert: orEnvironmentWithPackage classNames asSet equals: {
self class name.
#RBBrowserTemporaryClassForTest } asSet.
"Check that the new class does not belong in the and scope"
self deny: (andEnvironment classNames includes: newClass name) ]
ensure: [ newClass removeFromSystem ]
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testAndEnvironment [
| originalEnvironment objectPrintStringEnvironment andEnvironment |
originalEnvironment := universalEnvironment referencesTo: #printOn:.
objectPrintStringEnvironment := universalEnvironment forClass: Object
selectors: #(#fullPrintString).
andEnvironment := objectPrintStringEnvironment & originalEnvironment.
self universalTestFor: andEnvironment.
self assert: andEnvironment numberSelectors equals: 1.
self assert: andEnvironment classNames asArray equals: #(#Object).
self assert: (andEnvironment protocolsFor: Object) size equals: 1.
self assert: (objectPrintStringEnvironment & objectPrintStringEnvironment) packages equals: objectPrintStringEnvironment packages.
andEnvironment := originalEnvironment
& (universalEnvironment referencesTo: #printString).
self assert: andEnvironment numberSelectors
equals: (originalEnvironment referencesTo: #printString) numberSelectors.
self assert: andEnvironment classNames asSortedCollection
equals: (originalEnvironment referencesTo: #printString) classNames
asSortedCollection
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testAndEnvironmentWithStoreOn [
| originalEnvironment objectPrintStringEnvironment andEnvironment |
originalEnvironment := universalEnvironment referencesTo: #storeOn:.
objectPrintStringEnvironment := universalEnvironment forClass: Object
selectors: #(#storeString).
andEnvironment := objectPrintStringEnvironment & originalEnvironment.
self universalTestFor: andEnvironment.
self assert: andEnvironment numberSelectors equals: 1.
self assert: andEnvironment classNames asArray equals: #(#Object).
self assert: (andEnvironment protocolsFor: Object) size equals: 1.
self assert: (objectPrintStringEnvironment & objectPrintStringEnvironment) packages equals: objectPrintStringEnvironment packages.
andEnvironment := originalEnvironment
& (universalEnvironment referencesTo: #printString).
self assert: andEnvironment numberSelectors
equals: (originalEnvironment referencesTo: #printString) numberSelectors.
self assert: andEnvironment classNames asSortedCollection
equals: (originalEnvironment referencesTo: #printString) classNames
asSortedCollection
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testAndPackageEnvironmentAndClassEnvironment [
| packageEnvironment classEnvironment andEnvironment newClass |
"There is a single class in the package"
packageEnvironment := universalEnvironment forPackages:
{ self class package }.
classEnvironment := universalEnvironment forClasses: { self class }.
andEnvironment := packageEnvironment & classEnvironment.
self
assert: packageEnvironment classNames asArray
equals: { self class name }.
self
assert: classEnvironment classNames asArray
equals: { self class name }.
self
assert: andEnvironment classNames asArray asArray
equals: { self class name }.
[ "Now we install a new class in the package"
newClass := Object classInstaller make: [ :builder |
builder
superclass: Object;
name: #RBBrowserTemporaryClassForTest;
package: self class package ].
"Check that the new class does not belong in the scope"
self deny: (andEnvironment classNames includes: newClass name) ]
ensure: [ newClass removeFromSystem ]
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testBrowserEnvironment [
self universalTestFor: RBBrowserEnvironment new
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testClassEnvironment [
| aClassEnvironment |
aClassEnvironment := RBClassEnvironment
onEnvironment: universalEnvironment
classes: (Array with: Object with: Object class).
self universalTestFor: aClassEnvironment.
self deny: (universalEnvironment isClassEnvironment).
self assert: (aClassEnvironment isClassEnvironment).
self assert: (aClassEnvironment packages size) equals: 1.
self assert: (aClassEnvironment implementorsOf: #printString) numberSelectors equals: 1.
self assert: (RBClassEnvironment class: Class) selectors size
equals: Class methods size.
self assert: (RBClassEnvironment class: TSortable) selectors size
equals: TSortable methods size
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testConstructedClassEnvironment [
| environment |
environment := RBClassEnvironment new.
environment
addClass: Object;
addClass: OrderedCollection;
addClass: Collection.
self assert: (environment includesClass: Object).
self assert: (environment includesClass: OrderedCollection).
self assert: (environment includesClass: Collection).
self deny: (environment includesClass: Object class).
environment removeClass: Collection.
self assert: (environment includesClass: Object).
self assert: (environment includesClass: OrderedCollection).
self deny: (environment includesClass: Collection).
self assert: environment numberClasses equals: 2.
environment addClass: Object class.
self assert: environment numberClasses equals: 2.
self assert: (environment includesClass: Object class).
environment removeClass: self class.
self assert: environment numberClasses equals: 2
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testConstructedSelectorEnvironment [
| environment newEnvironment |
environment := RBSelectorEnvironment new.
environment
addClass: Object selector: #printString;
addClass: OrderedCollection selector: #add:;
addClass: Collection.
self assert: (environment includesClass: Object).
self assert: (environment selectorsForClass: Object) size equals: 1.
self assert: (environment includesClass: OrderedCollection).
self assert: (environment selectorsForClass: OrderedCollection) size equals: 1.
self assert: (environment includesClass: Collection).
self assert: (environment selectorsForClass: Collection) size
equals: Collection selectors size.
self deny: (environment includesClass: Object class).
newEnvironment := environment copy.
newEnvironment
removeClass: OrderedCollection;
addClass: Object selector: #printOn:;
removeClass: Object selector: #printString.
self assert: (newEnvironment includesClass: Object).
self deny: (newEnvironment includesSelector: #printString in: Object).
self deny: (newEnvironment includesClass: OrderedCollection).
self assert: (newEnvironment includesClass: Collection).
self assert: newEnvironment numberClasses equals: 2.
self
assert: newEnvironment numberSelectors + 1 equals: environment numberSelectors.
newEnvironment addClass: Object class.
self assert: newEnvironment numberClasses equals: 2.
self assert: (newEnvironment includesClass: Object class).
newEnvironment removeClass: self class.
self assert: newEnvironment numberClasses equals: 2
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testEnvironmentWrapper [
| printString wrapper |
printString := RBBrowserEnvironment new referencesTo: #printString.
wrapper := RBBrowserEnvironmentWrapper onEnvironment: printString.
self assert: wrapper numberSelectors equals: printString numberSelectors.
self assert: wrapper numberClasses equals: printString numberClasses.
self assert: wrapper environment identicalTo: printString
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testHierarchyEnvironment [
| aHierarchyEnvironment |
aHierarchyEnvironment := universalEnvironment forClassHierarchy: RBBrowserEnvironmentTest.
self universalTestFor: aHierarchyEnvironment.
self assert: (aHierarchyEnvironment implementorsOf: #testPackageEnvironment) numberSelectors equals: 1.
self assert: (aHierarchyEnvironment implementorsOf: #setUp) numberSelectors equals:4
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testImplementorsMatching [
| print |
print := RBBrowserEnvironment new implementorsMatching: '*print*'.
self universalTestFor: print.
self assert: (print implementorsOf: #printString) numberSelectors
equals: (RBBrowserEnvironment new implementorsOf: #printString) numberSelectors.
print
classesAndSelectorsDo: [:class :sel | self assert: ('*print*' match: sel)]
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testMatches [
| envEnvironment environmentEnvironment |
envEnvironment := RBBrowserEnvironment new matches: '*env*'.
environmentEnvironment := RBBrowserEnvironment new
referencesTo: #environment.
self assert: (envEnvironment referencesTo: #environment) numberSelectors
equals: environmentEnvironment numberSelectors
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testNotEnvironment [
| notPrintStringEnvironment printStringEnvironment kernelEnvironment notKernelEnvironment |
printStringEnvironment := universalEnvironment referencesTo: #printString.
notPrintStringEnvironment := printStringEnvironment not.
kernelEnvironment := RBPackageEnvironment packageName: 'Kernel'.
notKernelEnvironment := kernelEnvironment not.
self universalTestFor: notPrintStringEnvironment.
self assertEmpty: (notPrintStringEnvironment referencesTo: #printString).
self assert: (notPrintStringEnvironment not includesClass: RBBrowserEnvironmentTest).
self assert: (notPrintStringEnvironment not includesSelector: #testNotEnvironment in: RBBrowserEnvironmentTest).
self deny: (notKernelEnvironment includesPackage: 'Kernel' asPackage).
self assertEmpty: (notKernelEnvironment & kernelEnvironment) packages
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testNotEnvironmentWithClassEnvironments [
| numberEnvironment notNumberEnvironment |
numberEnvironment := RBBrowserEnvironment new forClasses: Number withAllSubclasses.
notNumberEnvironment := numberEnvironment not.
self universalTestFor: notNumberEnvironment.
self deny: (notNumberEnvironment includesClass: Number).
self assertEmpty: (notNumberEnvironment & numberEnvironment) classes.
self assert: (notNumberEnvironment not includesClass: Number)
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testOrEnvironment [
| env1 env2 orEnvironment |
env2 := #printOn:.
env2 := universalEnvironment forClass: Object selectors: #(#fullPrintString).
env1 := universalEnvironment forClass: Object selectors: #(#printOn:).
self assert: (env1 | env2) numberSelectors equals: 2.
self assert: (env2 | env1) numberSelectors equals: 2.
self universalTestFor: env1 | env2.
self assert: (env1 | env1) numberSelectors equals: 1.
orEnvironment := env1 | env1 not.
self assert: (env2 | env1) packages size equals: 1.
self universalTestFor: orEnvironment.
self assert: orEnvironment numberSelectors equals: universalEnvironment numberSelectors.
self assert: orEnvironment classNames asSortedCollection equals: universalEnvironment classNames asSortedCollection.
self
assert: (orEnvironment protocolsFor: Object)
equals: ((universalEnvironment protocolsFor: Object) reject: [ :protocolName | (Object allSelectorsInProtocol: protocolName) isEmpty ])
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testPackageEnvironment [
| aPackageEnvironment |
aPackageEnvironment := universalEnvironment forPackageNames: (Array with: 'Refactoring-Environment-Tests' with: 'Refactoring-Critics-Tests').
self universalTestFor: aPackageEnvironment.
self assert: (aPackageEnvironment implementorsOf: #testPackageEnvironment) numberSelectors equals: 1
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testPragmaEnvironment [
| aPragmaEnvironment |
aPragmaEnvironment := universalEnvironment forPragmas: #(primitive:).
self universalTestFor: aPragmaEnvironment
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testProtocolEnvironment [
| aProtocolEnvironment size |
aProtocolEnvironment := RBProtocolEnvironment
onEnvironment: RBBrowserEnvironment new
class: Object
protocols: #(#printing #testing).
self universalTestFor: aProtocolEnvironment.
self
assert: (aProtocolEnvironment implementorsOf: #printString) numberSelectors
equals: 1.
size := 0.
aProtocolEnvironment classesDo: [:each | size := size + 1].
self assert: size equals: 1.
aProtocolEnvironment selectorsForClass: Object
do:
[:each |
self assert: (#(#printing #testing)
includes: (RBBrowserEnvironment new whichProtocolIncludes: each in: Object))]
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testRemoveSelectorByAndAndNot [
| aBrowserEnvironment objectPrintString |
aBrowserEnvironment := RBBrowserEnvironment new.
objectPrintString := RBSelectorEnvironment
onEnvironment: aBrowserEnvironment.
objectPrintString addClass: Object selector: #printString.
self assert: aBrowserEnvironment numberSelectors - 1
equals: (aBrowserEnvironment & objectPrintString not) numberSelectors.
self universalTestFor: aBrowserEnvironment & objectPrintString not
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testSelectMethods [
| environment |
environment := RBBrowserEnvironment new selectMethods: [ :each | false ].
self assert: environment numberSelectors equals: 0.
self assert: environment numberClasses equals: 0.
environment := RBBrowserEnvironment new selectMethods: [ :each | true ].
self assert: environment numberSelectors equals: RBBrowserEnvironment new numberSelectors.
environment := RBBrowserEnvironment new selectMethods: [ :each | each refersToLiteral: #environment ].
self assert: environment numberSelectors equals: (RBBrowserEnvironment new referencesTo: #environment) numberSelectors
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testSelectorEnvironment [
| printString |
printString := RBBrowserEnvironment new referencesTo: #printString.
self universalTestFor: printString.
self deny: universalEnvironment isSelectorEnvironment.
self assert: printString isSelectorEnvironment.
self assert: printString numberSelectors equals: (printString referencesTo: #printString) numberSelectors.
self assert: printString numberClasses equals: (printString referencesTo: #printString) numberClasses
]
{ #category : 'tests - environments' }
RBBrowserEnvironmentTest >> testSelectorEnvironmentRemovesEmptyClasses [
| printString class |
printString := RBBrowserEnvironment new referencesTo: #printString.
class := printString classes anyOne.
printString selectorsForClass: class do: [ :eachSelector |
printString removeClass: class selector: eachSelector ].
self deny: (printString classes includes: class)
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testSystemIntegrity [
| classes environment |
classes := IdentitySet new.
environment := RBBrowserEnvironment new.
environment allClassesDo: [ :class |
(classes includes: class)
ifFalse: [ classes add: class ]
ifTrue: [ self error: 'The class ' , class name , ' that is available under two or more names. This causes problems with the refactoring browser.' ] ]
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testVariableEnvironmentAddRemove [
| refs |
refs := RBVariableEnvironment new.
refs addClass: self class instanceVariable: 'universalEnvironment'.
self assert: refs numberSelectors > 0.
self assert: refs numberClasses equals: 1.
refs removeClass: self class instanceVariable: 'universalEnvironment'.
self assert: refs numberSelectors equals: 0.
self assert: refs numberClasses equals: 0.
refs addClass: self class instanceVariableReader: 'universalEnvironment'.
self assert: refs numberSelectors > 0.
self assert: refs numberClasses equals: 1.
refs removeClass: self class instanceVariableReader: 'universalEnvironment'.
self assert: refs numberSelectors equals: 0.
self assert: refs numberClasses equals: 0.
refs addClass: self class instanceVariableWriter: 'universalEnvironment'.
self assert: refs numberSelectors > 0.
self assert: refs numberClasses equals: 1.
refs removeClass: self class instanceVariableWriter: 'universalEnvironment'.
self assert: refs numberSelectors equals: 0.
self assert: refs numberClasses equals: 0.
refs addClass: self class classVariable: 'AClassVariable'.
self assert: refs numberSelectors > 0.
self assert: refs numberClasses equals: 1.
refs removeClass: self class classVariable: 'AClassVariable'.
self assert: refs numberSelectors equals: 0.
self assert: refs numberClasses equals: 0
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testVariableEnvironmentClassVars [
"test variable environment for class vars, refered on the class side only"
| classRefs |
classRefs := RBVariableEnvironment referencesToClassVariable: 'ClassSideOnlyVariable' in: self class.
self universalTestFor: classRefs.
self denyEmpty: classRefs methods
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testVariableEnvironmentInstVars [
| refs writers readers classRefs |
self timeLimit: 300 seconds.
refs := RBVariableEnvironment
referencesToInstanceVariable: 'universalEnvironment'
in: self class.
writers := RBVariableEnvironment
writersOfInstanceVariable: 'universalEnvironment'
in: self class.
readers := RBVariableEnvironment
readersOfInstanceVariable: 'universalEnvironment'
in: self class.
classRefs := RBVariableEnvironment
referencesToClassVariable: 'AClassVariable'
in: self class.
self universalTestFor: refs.
self universalTestFor: writers.
self universalTestFor: readers.
self universalTestFor: classRefs.
self deny: universalEnvironment isVariableEnvironment.
self assert: refs isVariableEnvironment.
self assert: refs numberSelectors equals: (writers | readers) numberSelectors
]
{ #category : 'tests' }
RBBrowserEnvironmentTest >> testWithoutClassesRemovesClassesFromSender [
| environment newEnvironment |
environment := (RBBrowserEnvironment new) forClasses: Number withAllSubclasses.
newEnvironment := environment withoutClasses: { Number . Integer }.
self
assert: newEnvironment classes size
equals: environment classes size - 2
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> uniqueClassesIn: aBrowserEnvironment [
| allClasses |
allClasses := IdentitySet new.
aBrowserEnvironment classesDo: [ :each |
self deny: (allClasses includes: each).
allClasses add: each ]
]
{ #category : 'private' }
RBBrowserEnvironmentTest >> universalTestFor: aBrowserEnvironment [
self labelFor: aBrowserEnvironment.
self uniqueClassesIn: aBrowserEnvironment.
self numberSelectorsFor: aBrowserEnvironment.
self storeStringFor: aBrowserEnvironment.
self classNamesFor: aBrowserEnvironment.
self copyFor: aBrowserEnvironment.
self packagesFor: aBrowserEnvironment.
self protocolsFor: aBrowserEnvironment.
self classesFor: aBrowserEnvironment.
self keysFor: aBrowserEnvironment.
self assert: aBrowserEnvironment problemCount = 0 equals: aBrowserEnvironment isEmpty
]