/
RBMethodArgumentsSelector.class.st
259 lines (201 loc) · 6.02 KB
/
RBMethodArgumentsSelector.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
"
I am an editor to select values in a method that should be passed as arguments.
Usage:
RBMethodArgumentsSelector
openOn: { 'argumentList' }
and: { '#argumentList' }
in: (RBParser parseMethod: 'update: argumentList
self changed: #argumentList;
changed: #argumentIndex.
self changed: #isUpEnabled;
changed: #isDownEnabled;
changed: #isOkEnabled.
labelMorph contents: self methodName printString')
"
Class {
#name : #RBMethodArgumentsSelector,
#superclass : #DialogWindow,
#instVars : [
'arguments',
'values',
'argsAndValues',
'argumentsList',
'selectedArgumentIndex',
'valuesList',
'selectedValueIndex',
'selectedAssociationIndex',
'sourceCodeMorph',
'tree'
],
#category : #'Refactoring2-Transformations-Utilities'
}
{ #category : #'instance creation' }
RBMethodArgumentsSelector class >> on: arguments and: values in: sourceCode [
^ self basicNew
initializeWith: arguments
and: values
in: sourceCode
]
{ #category : #'instance creation' }
RBMethodArgumentsSelector class >> openOn: arguments and: values in: sourceCode [
^ (self
on: arguments
and: values
in: sourceCode) openModal
]
{ #category : #actions }
RBMethodArgumentsSelector >> addAssociation [
[ | argument value |
argument := argumentsList at: self argumentIndex.
value := valuesList at: self valueIndex.
"replace occurrences in code"
tree := RBParseTreeRewriter
replace: value
with: argument in: tree.
"add new entry"
argsAndValues at: argument put: value.
"remove from lists"
argumentsList removeAt: self argumentIndex.
valuesList removeAt: self valueIndex.
sourceCodeMorph contents: self sourceCode.
self changed: #associations; changed: #arguments;
changed: #values; changed: #isOkEnabled ]
on: Error do: [ self inform: 'Please select one argument and one value.' ]
]
{ #category : #accessing }
RBMethodArgumentsSelector >> argumentIndex [
^ selectedArgumentIndex ifNil: [ selectedArgumentIndex := 0 ]
]
{ #category : #accessing }
RBMethodArgumentsSelector >> argumentIndex: anInteger [
selectedArgumentIndex := anInteger.
self changed: #argumentIndex
]
{ #category : #accessing }
RBMethodArgumentsSelector >> arguments [
^ argumentsList ifNil: [ argumentsList := arguments asOrderedCollection ]
]
{ #category : #accessing }
RBMethodArgumentsSelector >> argumentsAndValues [
^ argsAndValues
]
{ #category : #accessing }
RBMethodArgumentsSelector >> associationIndex [
^ selectedAssociationIndex ifNil: [ selectedAssociationIndex := 0 ]
]
{ #category : #accessing }
RBMethodArgumentsSelector >> associationIndex: anInteger [
selectedAssociationIndex := anInteger.
self changed: #associationIndex
]
{ #category : #accessing }
RBMethodArgumentsSelector >> associations [
^ argsAndValues associations collect: #asString
]
{ #category : #initialization }
RBMethodArgumentsSelector >> initializeWith: aCollection and: anotherCollection in: aTree [
arguments := aCollection.
values := anotherCollection.
tree := aTree.
argsAndValues := Dictionary new.
self initialize.
self title: 'There are extra arguments in this method. Please map a value to each extra argument.' translated
]
{ #category : #testing }
RBMethodArgumentsSelector >> isOkEnabled [
^ argumentsList isEmpty
]
{ #category : #actions }
RBMethodArgumentsSelector >> newContentMorph [
^ (self newColumn: {
(self newRow: {
"the arguments"
self newGroupbox: 'Arguments' for: (self newColumn: {
(self newListFor: self
list: #arguments
selected: #argumentIndex
changeSelected: #argumentIndex:
help: nil)
hResizing: #spaceFill;
yourself }).
"the values"
self newGroupbox: 'Values' for: (self newColumn: {
(self newListFor: self
list: #values
selected: #valueIndex
changeSelected: #valueIndex:
help: nil)
hResizing: #spaceFill;
yourself }).
"add an association"
(self newRow: {
self newButtonFor: self action: #addAssociation
label: 'v' help: 'Map'.})
hResizing: #shrinkWrap}).
"source code preview"
(self newRow: {
self newGroupbox: 'Preview' for: (self newColumn: {
sourceCodeMorph := (self newText: tree formattedCode)
extent: 400@400;
hResizing: #rigid }) }).
"associations"
(self newRow: {
self newGroupbox: 'Associations' for: (self newColumn: {
(self newListFor: self
list: #associations
selected: #associationIndex
changeSelected: #associationIndex:
help: nil)
hResizing: #spaceFill;
yourself. }).
"remove association"
(self newRow: {
self newButtonFor: self action: #removeAssociation
label: '^' help: 'Unmap'.})
hResizing: #shrinkWrap }).
}) vResizing: #shrinkWrap
]
{ #category : #controls }
RBMethodArgumentsSelector >> newOKButton [
^ self newOKButtonFor: self getEnabled: #isOkEnabled
]
{ #category : #accessing }
RBMethodArgumentsSelector >> newTree [
^ tree
]
{ #category : #actions }
RBMethodArgumentsSelector >> removeAssociation [
[ | association argument value |
association := argsAndValues associations at: self associationIndex.
argument := association key.
value := association value.
"replace occurrences in code"
tree := RBParseTreeRewriter
replace: argument
with: value in: tree.
"remove entry"
argsAndValues removeKey: argument.
argumentsList add: argument.
valuesList add: value.
sourceCodeMorph contents: self sourceCode.
self changed: #associations; changed: #arguments;
changed: #values; changed: #isOkEnabled ]
on: Error do: [ self inform: 'Please select one association to remove.' ]
]
{ #category : #accessing }
RBMethodArgumentsSelector >> sourceCode [
^ tree formattedCode
]
{ #category : #accessing }
RBMethodArgumentsSelector >> valueIndex [
^ selectedValueIndex ifNil: [ selectedValueIndex := 0 ]
]
{ #category : #accessing }
RBMethodArgumentsSelector >> valueIndex: anInteger [
selectedValueIndex := anInteger.
self changed: #valueIndex
]
{ #category : #accessing }
RBMethodArgumentsSelector >> values [
^ valuesList ifNil: [ valuesList := values asOrderedCollection ]
]