/
OSSDL2FormRenderer.class.st
170 lines (140 loc) · 3.96 KB
/
OSSDL2FormRenderer.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
"
My instances implement OSWindowFormRenderer interface using SDL2 library
"
Class {
#name : #OSSDL2FormRenderer,
#superclass : #OSWindowFormRenderer,
#instVars : [
'texture',
'renderer',
'extent',
'deferUpdates'
],
#pools : [
'SDL2Constants'
],
#category : #'OSWindow-SDL2-Rendering'
}
{ #category : #'updating screen' }
OSSDL2FormRenderer >> copyAndPresentTextureRectangle: rectangle [
| sdlRectangle |
deferUpdates
ifTrue: [ ^ self ].
sdlRectangle := rectangle asSDLRect.
renderer copy: texture srcRect: sdlRectangle dstRect: sdlRectangle.
renderer present
]
{ #category : #private }
OSSDL2FormRenderer >> createRenderer [
renderer := backendWindow sdl2Window createDefaultRenderer.
]
{ #category : #private }
OSSDL2FormRenderer >> createTexture [
texture := renderer createTextureFormat: SDL_PIXELFORMAT_XRGB8888
access: SDL_TEXTUREACCESS_STREAMING width: form width height: form height.
extent := form extent
]
{ #category : #'updating screen' }
OSSDL2FormRenderer >> deferUpdatesWhile: aBlock [
deferUpdates := true.
aBlock ensure: [ deferUpdates := false. ].
self useDeferredUpdates.
]
{ #category : #deleting }
OSSDL2FormRenderer >> destroy [
(texture isNil or: [ renderer isNil ])
ifTrue: [ ^ self ].
texture destroy.
renderer destroy
]
{ #category : #initialization }
OSSDL2FormRenderer >> initialize [
super initialize.
deferUpdates := false.
]
{ #category : #private }
OSSDL2FormRenderer >> primitiveUpdateRectangle: rectangle externalForm: externalForm [
externalForm copy: rectangle from: form to: rectangle origin rule: Form over
]
{ #category : #'updating screen' }
OSSDL2FormRenderer >> updateAll [
self validate
ifFalse: [ ^ self ].
texture updateTexturePixels: form bits pitch: form width * 4.
deferUpdates
ifTrue: [ ^ self ].
renderer copy: texture.
renderer present
]
{ #category : #'updating screen' }
OSSDL2FormRenderer >> updateAreas: allDamage immediate: forceToScreen [
| pixels pitchHolder pitch intersection updateUnion externalForm |
self validate
ifFalse: [ ^ self ].
pixels := ExternalAddress new.
pitchHolder := ExternalAddress allocate: 4.
[
texture lockPixels: pixels pitch: pitchHolder.
pitch := pitchHolder signedLongAt: 1.
] ensure: [ pitchHolder free ].
updateUnion := nil.
[
externalForm := OSSDL2ExternalForm extent: extent depth: 32 bits: pixels.
allDamage do: [ :rectangle |
intersection := rectangle
intersect: (0 @ 0 corner: backendWindow extent)
ifNone: [ nil ].
intersection ifNotNil: [
self primitiveUpdateRectangle: rectangle externalForm: externalForm.
updateUnion ifNil: [
updateUnion := intersection
] ifNotNil: [
updateUnion := updateUnion merge: intersection
]
]
].
] ensure: [
texture unlock.
externalForm destroySurface
].
updateUnion ifNotNil: [
self copyAndPresentTextureRectangle: updateUnion
].
]
{ #category : #'updating screen' }
OSSDL2FormRenderer >> updateRectangle: rectangle [
| intersection pixels pitch pitchHolder externalForm |
intersection := rectangle
intersect: (0 @ 0 corner: backendWindow extent)
ifNone: [ ^ self ].
self validate
ifFalse: [ ^ self ].
pixels := ExternalAddress new.
pitchHolder := ExternalAddress allocate: 4.
[
texture lockPixels: pixels pitch: pitchHolder.
pitch := pitchHolder signedLongAt: 1.
] ensure: [ pitchHolder free ].
[
externalForm := OSSDL2ExternalForm extent: extent depth: 32 bits: pixels.
self primitiveUpdateRectangle: intersection externalForm: externalForm
] ensure: [
texture unlock.
externalForm destroySurface
].
self copyAndPresentTextureRectangle: intersection.
]
{ #category : #private }
OSSDL2FormRenderer >> useDeferredUpdates [
renderer
copy: texture;
present
]
{ #category : #private }
OSSDL2FormRenderer >> validate [
form ifNil: [ ^ false ].
(renderer isNil or: [renderer isNull]) ifTrue: [ self createRenderer ].
(texture isNil or: [texture isNull or: [ form extent ~= extent ]])
ifTrue: [ self createTexture ].
^ true
]