some announcements are not signaled on class changes

[j-brant]

Bug description
If you have a traited class, sometimes class changes are not signaled through the SystemAnnouncer

To Reproduce
Evaluate/inspect this code:

| announcements |
Object subclass: #T1
	instanceVariableNames: ''
	classVariableNames: ''
	package: 'TestPackage'.
#T1 asClass subclass: #T2
	uses: TOne
	instanceVariableNames: ''
	classVariableNames: ''
	package: 'TestPackage'.
#T1 asClass subclass: #T3
	instanceVariableNames: ''
	classVariableNames: ''
	package: 'TestPackage'.

announcements := OrderedCollection new.
SystemAnnouncer uniqueInstance weak when: ClassModificationApplied send: #add: to: announcements.

Model subclass: #T1
	instanceVariableNames: ''
	classVariableNames: ''
	package: 'TestPackage'.
	
announcements add: nil.

Object subclass: #T1
	instanceVariableNames: ''
	classVariableNames: ''
	package: 'TestPackage'.
	
SystemAnnouncer uniqueInstance unsubscribe: announcements.
announcements 

This records the ClassModificationApplied announcements during the recompile of T1 to be under Model and the changing it back to be under Object. Before the nil separator entry there are only announcements for T1 and T3. After the nil, there are announcements for all three classes (T1, T2, & T3).

Expected behavior
All three classes should appear before and after the nil entry as all three classes have been recompiled.

Version information:

• Pharo 10, 11, & 12

Expected development cost
Here's a potential fix:

1. Copy TraitBuilderEnhancer>>#allSlotsForBuilder: to create a TraitBuilderEnhancer>>#slotsForBuilder:

TraitBuilderEnhancer>>slotsForBuilder: aBuilder

	| resultingSlots |
	
	resultingSlots := self
		eliminateDuplicates: aBuilder layoutDefinition slots , aBuilder traitComposition asTraitComposition slotsCopy
		withSuperclassSlots: (aBuilder superclass ifNil: [#()] ifNotNil:[ :x | x allSlots]).

	^ resultingSlots

2. Change one reference to allSlotsForBuilder: to use new method:

TraitBuilderEnhancer>>configureClass: newClass superclass: superclass withLayoutType: layoutType slots: slots
	| resultingSlots |
	self validateTraitComposition: self traitComposition ofClass: builder oldClass.

	resultingSlots := self slotsForBuilder: builder.

	newClass superclass: superclass withLayoutType: layoutType slots: resultingSlots

3. Fix the allSlotsForBuilder: to return all slots:

TraitBuilderEnhancer>>allSlotsForBuilder: aBuilder
	| classSlots traitSlots |
	classSlots := super allSlotsForBuilder: aBuilder.
	traitSlots := aBuilder traitComposition asTraitComposition slotsCopy
			reject: [ :each | classSlots anySatisfy: [ :cs | cs name = each name ] ].
	^ classSlots , traitSlots