-
-
Notifications
You must be signed in to change notification settings - Fork 1k
/
base.ex
378 lines (311 loc) · 10.3 KB
/
base.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
defmodule Plausible.Stats.Base do
use Plausible.ClickhouseRepo
alias Plausible.Stats.{Query, Filters}
import Ecto.Query
@no_ref "Direct / None"
def base_event_query(site, query) do
events_q = query_events(site, query)
if Enum.any?(Filters.visit_props() ++ ["goal", "page"], &query.filters["visit:" <> &1]) do
sessions_q =
from(
s in query_sessions(site, query),
select: %{session_id: s.session_id}
)
from(
e in events_q,
join: sq in subquery(sessions_q),
on: e.session_id == sq.session_id
)
else
events_q
end
end
def query_events(site, query) do
{first_datetime, last_datetime} = utc_boundaries(query, site.timezone)
q =
from(
e in "events",
where: e.domain == ^site.domain,
where: e.timestamp >= ^first_datetime and e.timestamp < ^last_datetime
)
|> add_sample_hint(query)
q =
case query.filters["event:page"] do
{:is, page} ->
from(e in q, where: e.pathname == ^page)
{:is_not, page} ->
from(e in q, where: e.pathname != ^page)
{:matches, glob_expr} ->
regex = page_regex(glob_expr)
from(e in q, where: fragment("match(?, ?)", e.pathname, ^regex))
{:does_not_match, glob_expr} ->
regex = page_regex(glob_expr)
from(e in q, where: fragment("not(match(?, ?))", e.pathname, ^regex))
{:member, list} ->
from(e in q, where: e.pathname in ^list)
nil ->
q
end
q =
case query.filters["event:name"] do
{:is, name} ->
from(e in q, where: e.name == ^name)
{:member, list} ->
from(e in q, where: e.name in ^list)
nil ->
q
end
q =
case query.filters["event:goal"] do
{:is, :page, path} ->
from(e in q, where: e.pathname == ^path)
{:matches, :page, expr} ->
regex = page_regex(expr)
from(e in q, where: fragment("match(?, ?)", e.pathname, ^regex))
{:is, :event, event} ->
from(e in q, where: e.name == ^event)
nil ->
q
end
Enum.reduce(query.filters, q, fn {filter_key, filter_value}, query ->
case filter_key do
"event:props:" <> prop_name ->
filter_value = elem(filter_value, 1)
if filter_value == "(none)" do
from(
e in query,
where: fragment("not has(?, ?)", field(e, :"meta.key"), ^prop_name)
)
else
from(
e in query,
inner_lateral_join: meta in "meta",
as: :meta,
where: meta.key == ^prop_name and meta.value == ^filter_value
)
end
_ ->
query
end
end)
end
@api_prop_name_to_db %{
"source" => "referrer_source",
"device" => "screen_size",
"screen" => "screen_size",
"os" => "operating_system",
"os_version" => "operating_system_version",
"country" => "country_code",
"region" => "subdivision1_code",
"city" => "city_geoname_id"
}
def query_sessions(site, query) do
{first_datetime, last_datetime} = utc_boundaries(query, site.timezone)
sessions_q =
from(
s in "sessions",
where: s.domain == ^site.domain,
where: s.start >= ^first_datetime and s.start < ^last_datetime
)
|> add_sample_hint(query)
sessions_q =
case {query.filters["visit:goal"], query.filters["visit:page"]} do
{nil, nil} ->
sessions_q
{goal_filter, page_filter} ->
events_query =
Query.put_filter(query, "event:goal", goal_filter)
|> Query.put_filter("event:name", nil)
|> Query.put_filter("event:page", page_filter)
events_q =
from(
s in query_events(site, events_query),
select: %{session_id: fragment("DISTINCT ?", s.session_id)}
)
from(
s in sessions_q,
join: sq in subquery(events_q),
on: s.session_id == sq.session_id
)
end
Enum.reduce(Filters.visit_props(), sessions_q, fn prop_name, sessions_q ->
filter = query.filters["visit:" <> prop_name]
prop_name =
Map.get(@api_prop_name_to_db, prop_name, prop_name)
|> String.to_existing_atom()
case filter do
{:is, value} ->
value = db_prop_val(prop_name, value)
from(s in sessions_q, where: fragment("? = ?", field(s, ^prop_name), ^value))
{:is_not, value} ->
value = db_prop_val(prop_name, value)
from(s in sessions_q, where: fragment("? != ?", field(s, ^prop_name), ^value))
{:member, values} ->
list = Enum.map(values, &db_prop_val(prop_name, &1))
from(s in sessions_q, where: fragment("? in tuple(?)", field(s, ^prop_name), ^list))
{:matches, expr} ->
regex = page_regex(expr)
from(s in sessions_q, where: fragment("match(?, ?)", field(s, ^prop_name), ^regex))
{:does_not_match, expr} ->
regex = page_regex(expr)
from(s in sessions_q, where: fragment("not(match(?, ?))", field(s, ^prop_name), ^regex))
nil ->
sessions_q
_ ->
raise "Unknown filter type"
end
end)
end
def select_event_metrics(q, []), do: q
def select_event_metrics(q, [:pageviews | rest]) do
from(e in q,
select_merge: %{
pageviews:
fragment("toUInt64(round(countIf(? = 'pageview') * any(_sample_factor)))", e.name)
}
)
|> select_event_metrics(rest)
end
def select_event_metrics(q, [:events | rest]) do
from(e in q,
select_merge: %{events: fragment("toUInt64(round(count(*) * any(_sample_factor)))")}
)
|> select_event_metrics(rest)
end
def select_event_metrics(q, [:visitors | rest]) do
from(e in q,
select_merge: %{
visitors: fragment("toUInt64(round(uniq(?) * any(_sample_factor)))", e.user_id)
}
)
|> select_event_metrics(rest)
end
def select_event_metrics(q, [:sample_percent | rest]) do
from(e in q,
select_merge: %{
sample_percent:
fragment("if(any(_sample_factor) > 1, round(100 / any(_sample_factor)), 100)")
}
)
|> select_event_metrics(rest)
end
def select_event_metrics(_, [unknown | _]), do: raise("Unknown metric " <> unknown)
def select_session_metrics(q, []), do: q
def select_session_metrics(q, [:bounce_rate | rest]) do
from(s in q,
select_merge: %{
bounce_rate:
fragment("toUInt32(ifNotFinite(round(sum(is_bounce * sign) / sum(sign) * 100), 0))"),
visits: fragment("toUInt32(sum(sign))")
}
)
|> select_session_metrics(rest)
end
def select_session_metrics(q, [:visits | rest]) do
from(s in q,
select_merge: %{
visits: fragment("toUInt64(round(uniq(?) * any(_sample_factor)))", s.session_id)
}
)
|> select_session_metrics(rest)
end
def select_session_metrics(q, [:pageviews | rest]) do
from(s in q,
select_merge: %{
pageviews:
fragment("toUInt64(round(sum(? * ?) * any(_sample_factor)))", s.sign, s.pageviews)
}
)
|> select_session_metrics(rest)
end
def select_session_metrics(q, [:events | rest]) do
from(s in q,
select_merge: %{
events: fragment("toUInt64(round(sum(? * ?) * any(_sample_factor)))", s.sign, s.events)
}
)
|> select_session_metrics(rest)
end
def select_session_metrics(q, [:visitors | rest]) do
from(s in q,
select_merge: %{
visitors: fragment("toUInt64(round(uniq(?) * any(_sample_factor)))", s.user_id)
}
)
|> select_session_metrics(rest)
end
def select_session_metrics(q, [:visit_duration | rest]) do
from(s in q,
select_merge: %{
:visit_duration =>
fragment("toUInt32(ifNotFinite(round(sum(duration * sign) / sum(sign)), 0))")
}
)
|> select_session_metrics(rest)
end
def select_session_metrics(q, [:sample_percent | rest]) do
from(e in q,
select_merge: %{
sample_percent:
fragment("if(any(_sample_factor) > 1, round(100 / any(_sample_factor)), 100)")
}
)
|> select_event_metrics(rest)
end
def filter_converted_sessions(db_query, site, query) do
if query.filters["event:name"] || query.filters["event:page"] || query.filters["event:goal"] do
converted_sessions =
from(e in query_events(site, query),
select: %{session_id: fragment("DISTINCT ?", e.session_id)}
)
from(s in db_query,
join: cs in subquery(converted_sessions),
on: s.session_id == cs.session_id
)
else
db_query
end
end
defp db_prop_val(:referrer_source, @no_ref), do: ""
defp db_prop_val(:referrer, @no_ref), do: ""
defp db_prop_val(:utm_medium, @no_ref), do: ""
defp db_prop_val(:utm_source, @no_ref), do: ""
defp db_prop_val(:utm_campaign, @no_ref), do: ""
defp db_prop_val(:utm_content, @no_ref), do: ""
defp db_prop_val(:utm_term, @no_ref), do: ""
defp db_prop_val(_, val), do: val
def utc_boundaries(%Query{period: "realtime"}, _timezone) do
last_datetime = NaiveDateTime.utc_now() |> Timex.shift(seconds: 5)
first_datetime = NaiveDateTime.utc_now() |> Timex.shift(minutes: -5)
{first_datetime, last_datetime}
end
def utc_boundaries(%Query{period: "30m"}, _timezone) do
last_datetime = NaiveDateTime.utc_now() |> Timex.shift(seconds: 5)
first_datetime = NaiveDateTime.utc_now() |> Timex.shift(minutes: -30)
{first_datetime, last_datetime}
end
def utc_boundaries(%Query{date_range: date_range}, timezone) do
{:ok, first} = NaiveDateTime.new(date_range.first, ~T[00:00:00])
first_datetime =
Timex.to_datetime(first, timezone)
|> Timex.Timezone.convert("UTC")
{:ok, last} = NaiveDateTime.new(date_range.last |> Timex.shift(days: 1), ~T[00:00:00])
last_datetime =
Timex.to_datetime(last, timezone)
|> Timex.Timezone.convert("UTC")
{first_datetime, last_datetime}
end
def page_regex(expr) do
"^#{expr}$"
|> String.replace(~r/\*\*/, ".*")
|> String.replace(~r/(?<!\.)\*/, "[^/]*")
end
defp add_sample_hint(db_q, query) do
case query.sample_threshold do
"infinite" ->
db_q
threshold ->
from(e in db_q, hints: [sample: threshold])
end
end
end