-
-
Notifications
You must be signed in to change notification settings - Fork 46
/
class_loader.clj
76 lines (65 loc) · 3 KB
/
class_loader.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
(ns polylith.clj.core.common.class-loader
(:require [clojure.java.io :as io]
[clojure.string :as str]
[polylith.clj.core.util.interface.color :as color])
(:import (java.net URLClassLoader URL)))
(def base-classloader
(or (.getClassLoader clojure.lang.RT)
(.getContextClassLoader (Thread/currentThread))))
(def ext-classloader
(.getParent ^ClassLoader base-classloader))
(defn- url-classloader [url-array ext]
(URLClassLoader.
url-array
ext))
(defmacro with-classloader [class-loader & body]
`(binding [*use-context-classloader* true]
(let [cl# (.getContextClassLoader (Thread/currentThread))]
(try (.setContextClassLoader (Thread/currentThread) ~class-loader)
~@body
(finally
(.setContextClassLoader (Thread/currentThread) cl#))))))
(defn invoke-in* [^ClassLoader class-loader class-name method & [signature & params]]
(let [class (.loadClass class-loader class-name)
signature (into-array Class (or signature []))
method (.getDeclaredMethod class method signature)]
(.invoke method class (into-array Object params))))
(defmacro invoke-in
"Invoke class-method (with optional signature) inside the given classloader, passing the optional params."
[class-loader class-method & args]
(let [class (namespace class-method)
method (name class-method)]
`(invoke-in* ~class-loader ~class ~method ~@args)))
(defn printable? [object]
(or (nil? object)
(and (class object)
(.getClassLoader (class object)))))
(defn eval-in* [class-loader form]
(let [print-read-eval (fn [form]
(->> (pr-str form)
(invoke-in class-loader clojure.lang.RT/readString [String])
(invoke-in class-loader clojure.lang.Compiler/eval [Object])))]
(with-classloader class-loader
(let [result (print-read-eval form)]
(if-not (printable? result)
result
(let [string (invoke-in class-loader clojure.lang.RT/printString [Object] result)]
(try
(read-string string)
(catch RuntimeException _
result))))))))
(defn eval-in [class-loader form]
(eval-in* class-loader `(clojure.main/with-bindings (eval '~form))))
(defn ^URL path->url [path]
(let [lib? (str/ends-with? path ".jar")]
(io/as-url (str "file:" path (when-not lib? "/")))))
(defn create-class-loader [paths color-mode]
(try
(let [url-array (into-array URL (map path->url paths))
^URLClassLoader class-loader (url-classloader url-array ext-classloader)]
(.loadClass class-loader "clojure.lang.RT")
(eval-in* class-loader '(require 'clojure.main))
class-loader)
(catch Exception e
(println (str (color/error color-mode "Couldn't create classloader for paths: ") paths " "
(color/error color-mode e))))))