/
assent_jwt.ex
279 lines (227 loc) · 9.08 KB
/
assent_jwt.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
defmodule Assent.JWTAdapter.AssentJWT do
@moduledoc """
JWT adapter module for parsing JSON Web Tokens natively.
You can append options to the configuration:
jwt_adapter: {Assent.JWTAdapter.AssentJWT, [...]}
See `Assent.JWTAdapter` for more.
"""
alias Assent.{Config, JWTAdapter}
@behaviour Assent.JWTAdapter
defmodule Error do
defexception [:message, :reason, data: nil]
end
@impl JWTAdapter
def sign(claims, alg, secret_or_private_key, opts) do
with {:ok, header} <- encode_header(alg, opts),
{:ok, claims} <- encode_claims(claims, opts) do
do_sign(header, claims, alg, secret_or_private_key)
end
end
defp encode_header(alg, opts) do
header =
case Keyword.has_key?(opts, :private_key_id) do
false -> %{"typ" => "JWT", "alg" => alg}
true -> %{"typ" => "JWT", "alg" => alg, "kid" => Keyword.get(opts, :private_key_id)}
end
case encode_json_base64(header, opts) do
{:ok, encoded_header} ->
{:ok, encoded_header}
{:error, error} ->
{:error, Error.exception(message: "Failed to encode header", reason: error, data: header)}
end
end
defp encode_json_base64(map, opts) do
with {:ok, json_library} <- Config.fetch(opts, :json_library),
{:ok, json} <- json_library.encode(map) do
{:ok, Base.url_encode64(json, padding: false)}
end
end
defp encode_claims(claims, opts) do
case encode_json_base64(claims, opts) do
{:ok, encoded_claims} ->
{:ok, encoded_claims}
{:error, error} ->
{:error, Error.exception(message: "Failed to encode claims", reason: error, data: claims)}
end
end
defp do_sign(header, claims, alg, secret_or_private_key) do
message = header <> "." <> claims
case sign_message(message, alg, secret_or_private_key) do
{:ok, signature} ->
{:ok, "#{message}.#{Base.url_encode64(signature, padding: false)}"}
{:error, error} ->
{:error,
Error.exception(message: "Failed to sign JWT", reason: error, data: {message, alg})}
end
end
defp sign_message(message, "HS" <> sha_bit_size, secret) do
with {:ok, sha_alg} <- sha2_alg(sha_bit_size) do
{:ok, :crypto.mac(:hmac, sha_alg, secret, message)}
end
end
defp sign_message(message, "ES" <> sha_bit_size, private_key) do
# Per https://tools.ietf.org/html/rfc7515#appendix-A.3.1
with {:ok, sha_alg} <- sha2_alg(sha_bit_size),
{:ok, key} <- decode_pem(private_key) do
der_signature = :public_key.sign(message, sha_alg, key)
{:"ECDSA-Sig-Value", r, s} = :public_key.der_decode(:"ECDSA-Sig-Value", der_signature)
r_bin = sha_bit_pad(int_to_bin(r), sha_bit_size)
s_bin = sha_bit_pad(int_to_bin(s), sha_bit_size)
{:ok, r_bin <> s_bin}
end
end
defp sign_message(message, <<_, "S", sha_bit_size::binary>>, private_key) do
with {:ok, sha_alg} <- sha2_alg(sha_bit_size),
{:ok, key} <- decode_pem(private_key) do
{:ok, :public_key.sign(message, sha_alg, key)}
end
end
defp sign_message(_message, alg, _jwk),
do: {:error, "Unsupported JWT alg #{alg} or invalid JWK"}
defp sha2_alg("256"), do: {:ok, :sha256}
defp sha2_alg("384"), do: {:ok, :sha384}
defp sha2_alg("512"), do: {:ok, :sha512}
defp sha2_alg(bit_size), do: {:error, "Invalid SHA-2 algorithm bit size: #{bit_size}"}
defp decode_pem(pem) do
case :public_key.pem_decode(pem) do
[] -> {:error, "Invalid private key"}
[entry] -> {:ok, :public_key.pem_entry_decode(entry)}
_any -> {:error, "Private key should only have one entry"}
end
end
# From erlang crypto lib
defp int_to_bin(x) when x < 0, do: int_to_bin_neg(x, [])
defp int_to_bin(x), do: int_to_bin_pos(x, [])
defp int_to_bin_pos(0, [_ | _] = ds), do: :erlang.list_to_binary(ds)
defp int_to_bin_pos(x, ds), do: int_to_bin_pos(:erlang.bsr(x, 8), [:erlang.band(x, 255) | ds])
defp int_to_bin_neg(-1, [msb | _] = ds) when msb >= 128, do: :erlang.list_to_binary(ds)
defp int_to_bin_neg(x, ds), do: int_to_bin_neg(:erlang.bsr(x, 8), [:erlang.band(x, 255) | ds])
defp sha_bit_pad(binary, "256"), do: lpad_binary(binary, byte_size(binary) - 32)
defp sha_bit_pad(binary, "384"), do: lpad_binary(binary, byte_size(binary) - 48)
defp sha_bit_pad(binary, "512"), do: lpad_binary(binary, byte_size(binary) - 66)
defp lpad_binary(binary, length) when length > 0 do
:binary.copy(<<0>>, length - byte_size(binary)) <> binary
end
defp lpad_binary(binary, _length), do: binary
@impl JWTAdapter
def verify(token, secret_or_public_key, opts) do
with {:ok, encoded_jwt} <- split(token),
{:ok, alg, header} <- decode_header(encoded_jwt.header, opts),
{:ok, claims} <- decode_claims(encoded_jwt.claims, opts),
{:ok, signature} <- decode_signature(encoded_jwt.signature),
{:ok, verified} <-
do_verify(encoded_jwt.header, encoded_jwt.claims, signature, alg, secret_or_public_key) do
{:ok,
%{
header: header,
claims: claims,
signature: signature,
verified?: verified
}}
end
end
defp split(token) do
case String.split(token, ".") do
[header, claims, signature] ->
{:ok, %{header: header, claims: claims, signature: signature}}
parts ->
{:error,
Error.exception(
message: "JWT must have exactly three parts",
reason: :invalid_format,
data: parts
)}
end
end
defp decode_header(header, opts) do
with {:ok, json_library} <- Config.fetch(opts, :json_library),
{:ok, header} <- decode_base64_url(header),
{:ok, header} <- decode_json(header, json_library),
{:ok, alg} <- fetch_alg(header) do
{:ok, alg, header}
else
{:error, error} ->
{:error, Error.exception(message: "Failed to decode header", reason: error, data: header)}
end
end
defp decode_base64_url(encoded) do
case Base.url_decode64(encoded, padding: false) do
{:ok, decoded} -> {:ok, decoded}
:error -> {:error, "Invalid Base64URL"}
end
end
defp decode_json(encoded, json_library) do
case json_library.decode(encoded) do
{:ok, decoded} -> {:ok, decoded}
{:error, error} -> {:error, error}
end
end
defp fetch_alg(%{"alg" => alg}), do: {:ok, alg}
defp fetch_alg(_header), do: {:error, "No \"alg\" found in header"}
defp decode_claims(claims, opts) do
with {:ok, json_library} <- Config.fetch(opts, :json_library),
{:ok, claims} <- decode_base64_url(claims),
{:ok, claims} <- decode_json(claims, json_library) do
{:ok, claims}
else
{:error, error} ->
{:error, Error.exception(message: "Failed to decode claims", reason: error, data: claims)}
end
end
defp decode_signature(signature) do
case decode_base64_url(signature) do
{:ok, signature} ->
{:ok, signature}
{:error, error} ->
{:error,
Error.exception(message: "Failed to decode signature", reason: error, data: signature)}
end
end
defp do_verify(header, claims, signature, alg, secret_or_public_key) do
message = "#{header}.#{claims}"
case verify_message(message, signature, alg, secret_or_public_key) do
{:ok, verified} ->
{:ok, verified}
{:error, error} ->
{:error,
Error.exception(
message: "Failed to verify signature",
reason: error,
data: {message, signature, alg}
)}
end
end
defp verify_message(_message, _signature, "none", _secret), do: {:ok, false}
defp verify_message(_message, _signature, _alg, nil), do: {:ok, false}
defp verify_message(message, signature_1, "HS" <> _rest = alg, secret) when is_binary(secret) do
with {:ok, signature_2} <- sign_message(message, alg, secret) do
{:ok, Assent.constant_time_compare(signature_2, signature_1)}
end
end
defp verify_message(message, signature, "ES" <> sha_bit_size, public_key) do
with {:ok, sha_alg} <- sha2_alg(sha_bit_size),
{:ok, pem} <- decode_key(public_key) do
# Per https://tools.ietf.org/html/rfc7515#appendix-A.3.1
size = :erlang.byte_size(signature)
{r_bin, s_bin} = :erlang.split_binary(signature, Integer.floor_div(size, 2))
r = :crypto.bytes_to_integer(r_bin)
s = :crypto.bytes_to_integer(s_bin)
der_signature = :public_key.der_encode(:"ECDSA-Sig-Value", {:"ECDSA-Sig-Value", r, s})
{:ok, :public_key.verify(message, sha_alg, der_signature, pem)}
end
end
defp verify_message(message, signature, <<_, "S", sha_bit_size::binary>>, public_key) do
with {:ok, sha_alg} <- sha2_alg(sha_bit_size),
{:ok, pem} <- decode_key(public_key) do
{:ok, :public_key.verify(message, sha_alg, signature, pem)}
end
end
defp decode_key(pem) when is_binary(pem), do: decode_pem(pem)
defp decode_key(%{"kty" => "RSA", "n" => n, "e" => e}) do
with {:ok, n} <- decode_base64_url(n),
{:ok, e} <- decode_base64_url(e) do
{:ok, {:RSAPublicKey, :crypto.bytes_to_integer(n), :crypto.bytes_to_integer(e)}}
end
end
defp decode_key(jwk) when is_map(jwk), do: {:error, "Unable to decode the JWK"}
end