-
Notifications
You must be signed in to change notification settings - Fork 2
/
CMakeLists.txt
234 lines (187 loc) · 4.89 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
cmake_minimum_required(VERSION 3.21)
# ---- Options ----
option(COPY_BUILD "Copy the build output to the Fallout 4 directory." TRUE)
# ---- Cache build vars ----
macro(set_from_environment VARIABLE)
if (NOT DEFINED ${VARIABLE} AND DEFINED ENV{${VARIABLE}})
set(${VARIABLE} $ENV{${VARIABLE}})
endif ()
endmacro()
set_from_environment(Fallout4Path)
set_from_environment(VCPKG_ROOT)
set_from_environment(CommonLibF4Path)
if (DEFINED VCPKG_ROOT)
set(CMAKE_TOOLCHAIN_FILE "${VCPKG_ROOT}/scripts/buildsystems/vcpkg.cmake" CACHE STRING "")
set(VCPKG_TARGET_TRIPLET "x64-windows-static" CACHE STRING "")
else ()
message(
WARNING
"Variable VCPKG_ROOT is not set. Continuing without vcpkg."
)
endif ()
set(Boost_USE_STATIC_RUNTIME OFF CACHE BOOL "")
set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>DLL" CACHE STRING "")
# ---- Project ----
project(
po3_BaseObjectSwapperF4
VERSION 2.0.0
LANGUAGES CXX
)
configure_file(
${CMAKE_CURRENT_SOURCE_DIR}/cmake/Version.h.in
${CMAKE_CURRENT_BINARY_DIR}/include/Version.h
@ONLY
)
configure_file(
${CMAKE_CURRENT_SOURCE_DIR}/cmake/version.rc.in
${CMAKE_CURRENT_BINARY_DIR}/version.rc
@ONLY
)
# ---- Include guards ----
if (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR)
message(
FATAL_ERROR
"In-source builds not allowed. Please make a new directory (called a build directory) and run CMake from there."
)
endif ()
# ---- Globals ----
if (MSVC)
if (NOT ${CMAKE_GENERATOR} STREQUAL "Ninja")
add_compile_options(
/MP # Build with Multiple Processes
)
endif ()
endif ()
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION ON)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_DEBUG OFF)
set(Boost_USE_STATIC_LIBS ON)
# ---- Dependencies ----
if (DEFINED CommonLibF4Path AND NOT ${CommonLibF4Path} STREQUAL "" AND IS_DIRECTORY ${CommonLibF4Path})
add_subdirectory(${CommonLibF4Path} CommonLibF4)
else ()
message(
FATAL_ERROR
"Variable CommonLibF4Path is not set."
)
endif ()
find_path(SRELL_INCLUDE_DIRS "srell.hpp")
find_path(CLIBUTIL_INCLUDE_DIRS "CLibUtil/string.hpp")
find_package(spdlog REQUIRED CONFIG)
find_package(unordered_dense CONFIG REQUIRED)
# ---- Add source files ----
include(cmake/sourcelist.cmake)
source_group(
TREE ${CMAKE_CURRENT_SOURCE_DIR}
FILES ${SOURCES}
)
source_group(
TREE ${CMAKE_CURRENT_BINARY_DIR}
FILES ${CMAKE_CURRENT_BINARY_DIR}/include/Version.h
)
# ---- Create DLL ----
add_library(
${PROJECT_NAME}
SHARED
${SOURCES}
${CMAKE_CURRENT_BINARY_DIR}/version.rc
.clang-format
)
target_compile_definitions(
${PROJECT_NAME}
PRIVATE
_UNICODE
)
target_compile_definitions(
CommonLibF4
PUBLIC
F4SE_SUPPORT_XBYAK
)
target_compile_features(
${PROJECT_NAME}
PRIVATE
cxx_std_23
)
target_include_directories(
${PROJECT_NAME}
PRIVATE
${CMAKE_CURRENT_BINARY_DIR}/include
${CMAKE_CURRENT_SOURCE_DIR}/include
${SRELL_INCLUDE_DIRS}
${CLIBUTIL_INCLUDE_DIRS}
)
target_link_libraries(
${PROJECT_NAME}
PRIVATE
CommonLibF4::CommonLibF4
spdlog::spdlog
unordered_dense::unordered_dense
)
target_precompile_headers(
${PROJECT_NAME}
PRIVATE
include/PCH.h
)
if (MSVC)
target_compile_options(
${PROJECT_NAME}
PRIVATE
"/sdl" # Enable Additional Security Checks
"/utf-8" # Set Source and Executable character sets to UTF-8
"/Zi" # Debug Information Format
"/permissive-" # Standards conformance
"/Zc:preprocessor" # Enable preprocessor conformance mode
/W4 # Warning level
/WX # Warning level (warnings are errors)
# disable warnings
"/wd4200" # nonstandard extension used: zero-sized array in struct/union
"/wd4201" # nonstandard extension used: nameless struct/union
"/wd4324" # 'struct_name' : structure was padded due to __declspec(align())
"$<$<CONFIG:DEBUG>:>"
"$<$<CONFIG:RELEASE>:/Zc:inline;/JMC-;/Ob3>"
)
target_link_options(
${PROJECT_NAME}
PRIVATE
/WX # Treat Linker Warnings as Errors
"$<$<CONFIG:DEBUG>:/INCREMENTAL;/OPT:NOREF;/OPT:NOICF>"
"$<$<CONFIG:RELEASE>:/INCREMENTAL:NO;/OPT:REF;/OPT:ICF;/DEBUG:FULL>"
)
endif ()
# ---- File copying ----
if (COPY_BUILD)
if (DEFINED Fallout4Path)
add_custom_command(
TARGET ${PROJECT_NAME}
POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:${PROJECT_NAME}> ${Fallout4Path}/Data/F4SE/Plugins/
COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_PDB_FILE:${PROJECT_NAME}> ${Fallout4Path}/Data/F4SE/Plugins/
)
else ()
message(
WARNING
"Variable Fallout4Path is not defined. Skipping post-build copy command."
)
endif ()
endif ()
# ---- Build artifacts ----
set(SCRIPT "scripts/archive_artifacts.py")
add_custom_target(
create_artifact
COMMAND
"${CMAKE_CURRENT_SOURCE_DIR}/${SCRIPT}"
"--name=\"${PROJECT_NAME}\""
"--dll=\"$<TARGET_FILE:${PROJECT_NAME}>\""
"--pdb=\"$<TARGET_PDB_FILE:${PROJECT_NAME}>\""
WORKING_DIRECTORY
${CMAKE_CURRENT_BINARY_DIR}
SOURCES
${SCRIPT}
)
add_dependencies(
create_artifact
${PROJECT_NAME}
)
source_group(
TREE ${CMAKE_CURRENT_SOURCE_DIR}
FILES ${SCRIPT}
)