/
rabbit_fifo.erl
2418 lines (2240 loc) · 107 KB
/
rabbit_fifo.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% This Source Code Form is subject to the terms of the Mozilla Public
%% License, v. 2.0. If a copy of the MPL was not distributed with this
%% file, You can obtain one at https://mozilla.org/MPL/2.0/.
%%
%% Copyright (c) 2007-2021 VMware, Inc. or its affiliates. All rights reserved.
%%
%%
%% before post gc 1M msg: 203MB, after recovery + gc: 203MB
-module(rabbit_fifo).
-behaviour(ra_machine).
-compile(inline_list_funcs).
-compile(inline).
-compile({no_auto_import, [apply/3]}).
-dialyzer(no_improper_lists).
-include("rabbit_fifo.hrl").
-include_lib("rabbit_common/include/rabbit.hrl").
-export([
%% ra_machine callbacks
init/1,
apply/3,
state_enter/2,
tick/2,
overview/1,
get_checked_out/4,
%% versioning
version/0,
which_module/1,
%% aux
init_aux/1,
handle_aux/6,
% queries
query_messages_ready/1,
query_messages_checked_out/1,
query_messages_total/1,
query_processes/1,
query_ra_indexes/1,
query_consumer_count/1,
query_consumers/1,
query_stat/1,
query_single_active_consumer/1,
query_in_memory_usage/1,
query_peek/2,
query_notify_decorators_info/1,
usage/1,
zero/1,
%% misc
dehydrate_state/1,
normalize/1,
get_msg_header/1,
get_header/2,
%% protocol helpers
make_enqueue/3,
make_register_enqueuer/1,
make_checkout/3,
make_settle/2,
make_return/2,
make_discard/2,
make_credit/4,
make_purge/0,
make_purge_nodes/1,
make_update_config/1,
make_garbage_collection/0
]).
%% command records representing all the protocol actions that are supported
-record(enqueue, {pid :: option(pid()),
seq :: option(msg_seqno()),
msg :: raw_msg()}).
-record(register_enqueuer, {pid :: pid()}).
-record(checkout, {consumer_id :: consumer_id(),
spec :: checkout_spec(),
meta :: consumer_meta()}).
-record(settle, {consumer_id :: consumer_id(),
msg_ids :: [msg_id()]}).
-record(return, {consumer_id :: consumer_id(),
msg_ids :: [msg_id()]}).
-record(discard, {consumer_id :: consumer_id(),
msg_ids :: [msg_id()]}).
-record(credit, {consumer_id :: consumer_id(),
credit :: non_neg_integer(),
delivery_count :: non_neg_integer(),
drain :: boolean()}).
-record(purge, {}).
-record(purge_nodes, {nodes :: [node()]}).
-record(update_config, {config :: config()}).
-record(garbage_collection, {}).
-opaque protocol() ::
#enqueue{} |
#register_enqueuer{} |
#checkout{} |
#settle{} |
#return{} |
#discard{} |
#credit{} |
#purge{} |
#purge_nodes{} |
#update_config{} |
#garbage_collection{}.
-type command() :: protocol() | rabbit_fifo_dlx:protocol() | ra_machine:builtin_command().
%% all the command types supported by ra fifo
-type client_msg() :: delivery().
%% the messages `rabbit_fifo' can send to consumers.
-opaque state() :: #?MODULE{}.
-export_type([protocol/0,
delivery/0,
command/0,
credit_mode/0,
consumer_tag/0,
consumer_meta/0,
consumer_id/0,
client_msg/0,
msg/0,
msg_id/0,
msg_seqno/0,
delivery_msg/0,
state/0,
config/0]).
-spec init(config()) -> state().
init(#{name := Name,
queue_resource := Resource} = Conf) ->
update_config(Conf, #?MODULE{cfg = #cfg{name = Name,
resource = Resource}}).
update_config(Conf, State) ->
DLH = maps:get(dead_letter_handling, Conf, undefined),
BLH = maps:get(become_leader_handler, Conf, undefined),
RCI = maps:get(release_cursor_interval, Conf, ?RELEASE_CURSOR_EVERY),
Overflow = maps:get(overflow_strategy, Conf, drop_head),
MaxLength = maps:get(max_length, Conf, undefined),
MaxBytes = maps:get(max_bytes, Conf, undefined),
MaxMemoryLength = maps:get(max_in_memory_length, Conf, undefined),
MaxMemoryBytes = maps:get(max_in_memory_bytes, Conf, undefined),
DeliveryLimit = maps:get(delivery_limit, Conf, undefined),
Expires = maps:get(expires, Conf, undefined),
ConsumerStrategy = case maps:get(single_active_consumer_on, Conf, false) of
true ->
single_active;
false ->
competing
end,
Cfg = State#?MODULE.cfg,
RCISpec = {RCI, RCI},
LastActive = maps:get(created, Conf, undefined),
MaxMemoryBytes = maps:get(max_in_memory_bytes, Conf, undefined),
State#?MODULE{cfg = Cfg#cfg{release_cursor_interval = RCISpec,
dead_letter_handling = DLH,
become_leader_handler = BLH,
overflow_strategy = Overflow,
max_length = MaxLength,
max_bytes = MaxBytes,
max_in_memory_length = MaxMemoryLength,
max_in_memory_bytes = MaxMemoryBytes,
consumer_strategy = ConsumerStrategy,
delivery_limit = DeliveryLimit,
expires = Expires},
last_active = LastActive}.
zero(_) ->
0.
% msg_ids are scoped per consumer
% ra_indexes holds all raft indexes for enqueues currently on queue
-spec apply(ra_machine:command_meta_data(), command(), state()) ->
{state(), Reply :: term(), ra_machine:effects()} |
{state(), Reply :: term()}.
apply(Meta, #enqueue{pid = From, seq = Seq,
msg = RawMsg}, State00) ->
apply_enqueue(Meta, From, Seq, RawMsg, State00);
apply(_Meta, #register_enqueuer{pid = Pid},
#?MODULE{enqueuers = Enqueuers0,
cfg = #cfg{overflow_strategy = Overflow}} = State0) ->
State = case maps:is_key(Pid, Enqueuers0) of
true ->
%% if the enqueuer exits just echo the overflow state
State0;
false ->
State0#?MODULE{enqueuers = Enqueuers0#{Pid => #enqueuer{}}}
end,
Res = case is_over_limit(State) of
true when Overflow == reject_publish ->
reject_publish;
_ ->
ok
end,
{State, Res, [{monitor, process, Pid}]};
apply(Meta,
#settle{msg_ids = MsgIds, consumer_id = ConsumerId},
#?MODULE{consumers = Cons0} = State) ->
case Cons0 of
#{ConsumerId := Con0} ->
complete_and_checkout(Meta, MsgIds, ConsumerId,
Con0, [], State);
_ ->
{State, ok}
end;
apply(Meta, #discard{msg_ids = MsgIds, consumer_id = ConsumerId},
#?MODULE{consumers = Cons0} = State0) ->
case Cons0 of
#{ConsumerId := #consumer{checked_out = Checked} = Con0} ->
case at_least_once_dlx(State0) of
true ->
{State, ok, Effects} = discard(MsgIds, Meta, ConsumerId, Checked, [], State0),
checkout(Meta, State0, State, Effects, false);
false ->
% Discarded maintains same order as MsgIds (so that publishing to
% dead-letter exchange will be in same order as messages got rejected)
Discarded = lists:filtermap(fun(Id) ->
case maps:find(Id, Checked) of
{ok, Msg} ->
{true, Msg};
error ->
false
end
end, MsgIds),
Effects = dead_letter_effects(rejected, Discarded, State0, []),
complete_and_checkout(Meta, MsgIds, ConsumerId, Con0,
Effects, State0)
end;
_ ->
{State0, ok}
end;
apply(Meta, #return{msg_ids = MsgIds, consumer_id = ConsumerId},
#?MODULE{consumers = Cons0} = State) ->
case Cons0 of
#{ConsumerId := #consumer{checked_out = Checked0}} ->
Returned = maps:with(MsgIds, Checked0),
return(Meta, ConsumerId, Returned, [], State);
_ ->
{State, ok}
end;
apply(Meta, #credit{credit = NewCredit, delivery_count = RemoteDelCnt,
drain = Drain, consumer_id = ConsumerId},
#?MODULE{consumers = Cons0,
service_queue = ServiceQueue0,
waiting_consumers = Waiting0} = State0) ->
case Cons0 of
#{ConsumerId := #consumer{delivery_count = DelCnt} = Con0} ->
%% this can go below 0 when credit is reduced
C = max(0, RemoteDelCnt + NewCredit - DelCnt),
%% grant the credit
Con1 = Con0#consumer{credit = C},
ServiceQueue = maybe_queue_consumer(ConsumerId, Con1,
ServiceQueue0),
Cons = maps:put(ConsumerId, Con1, Cons0),
{State1, ok, Effects} =
checkout(Meta, State0,
State0#?MODULE{service_queue = ServiceQueue,
consumers = Cons}, [], false),
Response = {send_credit_reply, messages_ready(State1)},
%% by this point all checkouts for the updated credit value
%% should be processed so we can evaluate the drain
case Drain of
false ->
%% just return the result of the checkout
{State1, Response, Effects};
true ->
Con = #consumer{credit = PostCred} =
maps:get(ConsumerId, State1#?MODULE.consumers),
%% add the outstanding credit to the delivery count
DeliveryCount = Con#consumer.delivery_count + PostCred,
Consumers = maps:put(ConsumerId,
Con#consumer{delivery_count = DeliveryCount,
credit = 0},
State1#?MODULE.consumers),
Drained = Con#consumer.credit,
{CTag, _} = ConsumerId,
{State1#?MODULE{consumers = Consumers},
%% returning a multi response with two client actions
%% for the channel to execute
{multi, [Response, {send_drained, {CTag, Drained}}]},
Effects}
end;
_ when Waiting0 /= [] ->
%% there are waiting consuemrs
case lists:keytake(ConsumerId, 1, Waiting0) of
{value, {_, Con0 = #consumer{delivery_count = DelCnt}}, Waiting} ->
%% the consumer is a waiting one
%% grant the credit
C = max(0, RemoteDelCnt + NewCredit - DelCnt),
Con = Con0#consumer{credit = C},
State = State0#?MODULE{waiting_consumers =
[{ConsumerId, Con} | Waiting]},
{State, {send_credit_reply, messages_ready(State)}};
false ->
{State0, ok}
end;
_ ->
%% credit for unknown consumer - just ignore
{State0, ok}
end;
apply(_, #checkout{spec = {dequeue, _}},
#?MODULE{cfg = #cfg{consumer_strategy = single_active}} = State0) ->
{State0, {error, {unsupported, single_active_consumer}}};
apply(#{index := Index,
system_time := Ts,
from := From} = Meta, #checkout{spec = {dequeue, Settlement},
meta = ConsumerMeta,
consumer_id = ConsumerId},
#?MODULE{consumers = Consumers} = State00) ->
%% dequeue always updates last_active
State0 = State00#?MODULE{last_active = Ts},
%% all dequeue operations result in keeping the queue from expiring
Exists = maps:is_key(ConsumerId, Consumers),
case messages_ready(State0) of
0 ->
update_smallest_raft_index(Index, {dequeue, empty}, State0,
[notify_decorators_effect(State0)]);
_ when Exists ->
%% a dequeue using the same consumer_id isn't possible at this point
{State0, {dequeue, empty}};
Ready ->
State1 = update_consumer(ConsumerId, ConsumerMeta,
{once, 1, simple_prefetch}, 0,
State0),
{success, _, MsgId, Msg, State2} = checkout_one(Meta, State1),
{State4, Effects1} = case Settlement of
unsettled ->
{_, Pid} = ConsumerId,
{State2, [{monitor, process, Pid}]};
settled ->
%% immediately settle the checkout
{State3, _, Effects0} =
apply(Meta, make_settle(ConsumerId, [MsgId]),
State2),
{State3, Effects0}
end,
{Reply, Effects2} =
case Msg of
?INDEX_MSG(RaftIdx, ?DISK_MSG(Header)) ->
{'$ra_no_reply',
[reply_log_effect(RaftIdx, MsgId, Header, Ready - 1, From) |
Effects1]};
?INDEX_MSG(_, ?MSG(Header, Body)) ->
{{dequeue, {MsgId, {Header, Body}}, Ready-1}, Effects1}
end,
NotifyEffect = notify_decorators_effect(State4),
case evaluate_limit(Index, false, State0, State4, [NotifyEffect | Effects2]) of
{State, true, Effects} ->
update_smallest_raft_index(Index, Reply, State, Effects);
{State, false, Effects} ->
{State, Reply, Effects}
end
end;
apply(#{index := Idx} = Meta,
#checkout{spec = cancel,
consumer_id = ConsumerId}, State0) ->
{State1, Effects1} = cancel_consumer(Meta, ConsumerId, State0, [],
consumer_cancel),
{State, Reply, Effects} = checkout(Meta, State0, State1, Effects1),
update_smallest_raft_index(Idx, Reply, State, Effects);
apply(Meta, #checkout{spec = Spec, meta = ConsumerMeta,
consumer_id = {_, Pid} = ConsumerId},
State0) ->
Priority = get_priority_from_args(ConsumerMeta),
State1 = update_consumer(ConsumerId, ConsumerMeta, Spec, Priority, State0),
checkout(Meta, State0, State1, [{monitor, process, Pid}]);
apply(#{index := Index}, #purge{},
#?MODULE{messages_total = Tot,
returns = Returns,
messages = Messages,
ra_indexes = Indexes0} = State0) ->
Total = messages_ready(State0),
Indexes1 = lists:foldl(fun (?INDEX_MSG(I, _), Acc0) when is_integer(I) ->
rabbit_fifo_index:delete(I, Acc0);
(_, Acc) ->
Acc
end, Indexes0, lqueue:to_list(Returns)),
%%TODO purge discarded messages
% Indexes2 = lists:foldl(fun (?INDEX_MSG(I, _), Acc0) when is_integer(I) ->
% rabbit_fifo_index:delete(I, Acc0);
% (_, Acc) ->
% Acc
% end, Indexes1, lqueue:to_list(Discards)),
Indexes = lists:foldl(fun (?INDEX_MSG(I, _), Acc0) when is_integer(I) ->
rabbit_fifo_index:delete(I, Acc0);
(_, Acc) ->
Acc
end, Indexes1, lqueue:to_list(Messages)),
State1 = State0#?MODULE{ra_indexes = Indexes,
messages = lqueue:new(),
messages_total = Tot - Total,
returns = lqueue:new(),
msg_bytes_enqueue = 0,
prefix_msgs = {0, [], 0, []},
msg_bytes_in_memory = 0,
msgs_ready_in_memory = 0},
Effects0 = [garbage_collection],
Reply = {purge, Total},
{State, _, Effects} = evaluate_limit(Index, false, State0,
State1, Effects0),
update_smallest_raft_index(Index, Reply, State, Effects);
apply(#{index := Idx}, #garbage_collection{}, State) ->
update_smallest_raft_index(Idx, ok, State, [{aux, garbage_collection}]);
apply(#{system_time := Ts} = Meta, {down, Pid, noconnection},
#?MODULE{consumers = Cons0,
cfg = #cfg{consumer_strategy = single_active},
waiting_consumers = Waiting0,
enqueuers = Enqs0} = State0) ->
Node = node(Pid),
%% if the pid refers to an active or cancelled consumer,
%% mark it as suspected and return it to the waiting queue
{State1, Effects0} =
maps:fold(fun({_, P} = Cid, C0, {S0, E0})
when node(P) =:= Node ->
%% the consumer should be returned to waiting
%% and checked out messages should be returned
Effs = consumer_update_active_effects(
S0, Cid, C0, false, suspected_down, E0),
Checked = C0#consumer.checked_out,
Credit = increase_credit(C0, maps:size(Checked)),
{St, Effs1} = return_all(Meta, S0, Effs,
Cid, C0#consumer{credit = Credit}),
%% if the consumer was cancelled there is a chance it got
%% removed when returning hence we need to be defensive here
Waiting = case St#?MODULE.consumers of
#{Cid := C} ->
Waiting0 ++ [{Cid, C}];
_ ->
Waiting0
end,
{St#?MODULE{consumers = maps:remove(Cid, St#?MODULE.consumers),
waiting_consumers = Waiting,
last_active = Ts},
Effs1};
(_, _, S) ->
S
end, {State0, []}, Cons0),
WaitingConsumers = update_waiting_consumer_status(Node, State1,
suspected_down),
%% select a new consumer from the waiting queue and run a checkout
State2 = State1#?MODULE{waiting_consumers = WaitingConsumers},
{State, Effects1} = activate_next_consumer(State2, Effects0),
%% mark any enquers as suspected
Enqs = maps:map(fun(P, E) when node(P) =:= Node ->
E#enqueuer{status = suspected_down};
(_, E) -> E
end, Enqs0),
Effects = [{monitor, node, Node} | Effects1],
checkout(Meta, State0, State#?MODULE{enqueuers = Enqs}, Effects);
apply(#{system_time := Ts} = Meta, {down, Pid, noconnection},
#?MODULE{consumers = Cons0,
enqueuers = Enqs0} = State0) ->
%% A node has been disconnected. This doesn't necessarily mean that
%% any processes on this node are down, they _may_ come back so here
%% we just mark them as suspected (effectively deactivated)
%% and return all checked out messages to the main queue for delivery to any
%% live consumers
%%
%% all pids for the disconnected node will be marked as suspected not just
%% the one we got the `down' command for
Node = node(Pid),
{State, Effects1} =
maps:fold(
fun({_, P} = Cid, #consumer{checked_out = Checked0,
status = up} = C0,
{St0, Eff}) when node(P) =:= Node ->
Credit = increase_credit(C0, map_size(Checked0)),
C = C0#consumer{status = suspected_down,
credit = Credit},
{St, Eff0} = return_all(Meta, St0, Eff, Cid, C),
Eff1 = consumer_update_active_effects(St, Cid, C, false,
suspected_down, Eff0),
{St, Eff1};
(_, _, {St, Eff}) ->
{St, Eff}
end, {State0, []}, Cons0),
Enqs = maps:map(fun(P, E) when node(P) =:= Node ->
E#enqueuer{status = suspected_down};
(_, E) -> E
end, Enqs0),
% Monitor the node so that we can "unsuspect" these processes when the node
% comes back, then re-issue all monitors and discover the final fate of
% these processes
Effects = case maps:size(State#?MODULE.consumers) of
0 ->
[{aux, inactive}, {monitor, node, Node}];
_ ->
[{monitor, node, Node}]
end ++ Effects1,
checkout(Meta, State0, State#?MODULE{enqueuers = Enqs,
last_active = Ts}, Effects);
apply(Meta, {down, Pid, _Info}, State0) ->
{State, Effects} = handle_down(Meta, Pid, State0),
checkout(Meta, State0, State, Effects);
apply(Meta, {nodeup, Node}, #?MODULE{consumers = Cons0,
enqueuers = Enqs0,
service_queue = _SQ0} = State0) ->
%% A node we are monitoring has come back.
%% If we have suspected any processes of being
%% down we should now re-issue the monitors for them to detect if they're
%% actually down or not
Monitors = [{monitor, process, P}
|| P <- suspected_pids_for(Node, State0)],
Enqs1 = maps:map(fun(P, E) when node(P) =:= Node ->
E#enqueuer{status = up};
(_, E) -> E
end, Enqs0),
ConsumerUpdateActiveFun = consumer_active_flag_update_function(State0),
%% mark all consumers as up
{State1, Effects1} =
maps:fold(fun({_, P} = ConsumerId, C, {SAcc, EAcc})
when (node(P) =:= Node) and
(C#consumer.status =/= cancelled) ->
EAcc1 = ConsumerUpdateActiveFun(SAcc, ConsumerId,
C, true, up, EAcc),
{update_or_remove_sub(Meta, ConsumerId,
C#consumer{status = up},
SAcc), EAcc1};
(_, _, Acc) ->
Acc
end, {State0, Monitors}, Cons0),
Waiting = update_waiting_consumer_status(Node, State1, up),
State2 = State1#?MODULE{
enqueuers = Enqs1,
waiting_consumers = Waiting},
{State, Effects} = activate_next_consumer(State2, Effects1),
checkout(Meta, State0, State, Effects);
apply(_, {nodedown, _Node}, State) ->
{State, ok};
apply(#{index := Idx} = Meta, #purge_nodes{nodes = Nodes}, State0) ->
{State, Effects} = lists:foldl(fun(Node, {S, E}) ->
purge_node(Meta, Node, S, E)
end, {State0, []}, Nodes),
update_smallest_raft_index(Idx, ok, State, Effects);
apply(#{index := Idx} = Meta, #update_config{config = Conf}, State0) ->
{State, Reply, Effects} = checkout(Meta, State0, update_config(Conf, State0), []),
update_smallest_raft_index(Idx, Reply, State, Effects);
apply(_Meta, {machine_version, FromVersion, ToVersion}, V0State) ->
State = convert(FromVersion, ToVersion, V0State),
{State, ok, []};
%%TODO are there better approach to
%% 1. matching against opaque rabbit_fifo_dlx:protocol / record (without exposing all the protocol details), and
%% 2. Separate the logic running in rabbit_fifo and rabbit_fifo_dlx when dead-letter messages is acked?
apply(#{index := IncomingRaftIdx} = Meta, {dlx, Cmd},
#?MODULE{dlx = DlxState0,
messages_total = Total0,
ra_indexes = Indexes0} = State0) when element(1, Cmd) =:= settle ->
{DlxState, Acked} = rabbit_fifo_dlx:apply(Meta, Cmd, DlxState0),
Indexes = delete_indexes(Acked, Indexes0),
Total = Total0 - map_size(Acked),
State1 = State0#?MODULE{dlx = DlxState,
messages_total = Total,
ra_indexes = Indexes},
{State, ok, Effects} = checkout(Meta, State0, State1, [], false),
update_smallest_raft_index(IncomingRaftIdx, State, Effects);
apply(Meta, {dlx, Cmd}, #?MODULE{dlx = DlxState0} = State) ->
{DlxState, Reply, Effects} = rabbit_fifo_dlx:apply(Meta, Cmd, DlxState0),
{State#?MODULE{dlx = DlxState}, Reply, Effects};
apply(_Meta, Cmd, State) ->
%% handle unhandled commands gracefully
rabbit_log:debug("rabbit_fifo: unhandled command ~W", [Cmd, 10]),
{State, ok, []}.
% convert_v0_to_v1(V0State0) ->
% V0State = rabbit_fifo_v0:normalize_for_v1(V0State0),
% V0Msgs = rabbit_fifo_v0:get_field(messages, V0State),
% V1Msgs = lqueue:from_list(lists:sort(maps:to_list(V0Msgs))),
% V0Enqs = rabbit_fifo_v0:get_field(enqueuers, V0State),
% V1Enqs = maps:map(
% fun (_EPid, E) ->
% #enqueuer{next_seqno = element(2, E),
% pending = element(3, E),
% status = element(4, E)}
% end, V0Enqs),
% V0Cons = rabbit_fifo_v0:get_field(consumers, V0State),
% V1Cons = maps:map(
% fun (_CId, C0) ->
% %% add the priority field
% list_to_tuple(tuple_to_list(C0) ++ [0])
% end, V0Cons),
% V0SQ = rabbit_fifo_v0:get_field(service_queue, V0State),
% V1SQ = priority_queue:from_list([{0, C} || C <- queue:to_list(V0SQ)]),
% Cfg = #cfg{name = rabbit_fifo_v0:get_cfg_field(name, V0State),
% resource = rabbit_fifo_v0:get_cfg_field(resource, V0State),
% release_cursor_interval = rabbit_fifo_v0:get_cfg_field(release_cursor_interval, V0State),
% dead_letter_handler = rabbit_fifo_v0:get_cfg_field(dead_letter_handler, V0State),
% become_leader_handler = rabbit_fifo_v0:get_cfg_field(become_leader_handler, V0State),
% %% TODO: what if policy enabling reject_publish was applied before conversion?
% overflow_strategy = drop_head,
% max_length = rabbit_fifo_v0:get_cfg_field(max_length, V0State),
% max_bytes = rabbit_fifo_v0:get_cfg_field(max_bytes, V0State),
% consumer_strategy = rabbit_fifo_v0:get_cfg_field(consumer_strategy, V0State),
% delivery_limit = rabbit_fifo_v0:get_cfg_field(delivery_limit, V0State),
% max_in_memory_length = rabbit_fifo_v0:get_cfg_field(max_in_memory_length, V0State),
% max_in_memory_bytes = rabbit_fifo_v0:get_cfg_field(max_in_memory_bytes, V0State)
% },
% #?MODULE{cfg = Cfg,
% messages = V1Msgs,
% next_msg_num = rabbit_fifo_v0:get_field(next_msg_num, V0State),
% returns = rabbit_fifo_v0:get_field(returns, V0State),
% enqueue_count = rabbit_fifo_v0:get_field(enqueue_count, V0State),
% enqueuers = V1Enqs,
% ra_indexes = rabbit_fifo_v0:get_field(ra_indexes, V0State),
% release_cursors = rabbit_fifo_v0:get_field(release_cursors, V0State),
% consumers = V1Cons,
% service_queue = V1SQ,
% prefix_msgs = rabbit_fifo_v0:get_field(prefix_msgs, V0State),
% msg_bytes_enqueue = rabbit_fifo_v0:get_field(msg_bytes_enqueue, V0State),
% msg_bytes_checkout = rabbit_fifo_v0:get_field(msg_bytes_checkout, V0State),
% waiting_consumers = rabbit_fifo_v0:get_field(waiting_consumers, V0State),
% msg_bytes_in_memory = rabbit_fifo_v0:get_field(msg_bytes_in_memory, V0State),
% msgs_ready_in_memory = rabbit_fifo_v0:get_field(msgs_ready_in_memory, V0State)
% }.
convert_msg({RaftIdx, {Header, empty}}) ->
?INDEX_MSG(RaftIdx, ?DISK_MSG(Header));
convert_msg({RaftIdx, {Header, Msg}}) when is_integer(RaftIdx) ->
?INDEX_MSG(RaftIdx, ?TUPLE(Header, Msg));
convert_msg({'$empty_msg', Header}) ->
?DISK_MSG(Header);
convert_msg({'$prefix_msg', Header}) ->
?PREFIX_MEM_MSG(Header).
convert_v1_to_v2(V1State) ->
IndexesV1 = rabbit_fifo_v1:get_field(ra_indexes, V1State),
ReturnsV1 = rabbit_fifo_v1:get_field(returns, V1State),
MessagesV1 = rabbit_fifo_v1:get_field(messages, V1State),
% EnqueuersV1 = rabbit_fifo_v1:get_field(enqueuers, V1State),
ConsumersV1 = rabbit_fifo_v1:get_field(consumers, V1State),
%% remove all raft idx in messages from index
MessagesV2 = lqueue:foldl(fun ({_, IdxMsg}, Acc) ->
lqueue:in(convert_msg(IdxMsg), Acc)
end, lqueue:new(), MessagesV1),
ReturnsV2 = lqueue:foldl(fun ({_SeqId, Msg}, Acc) ->
lqueue:in(convert_msg(Msg), Acc)
end, lqueue:new(), ReturnsV1),
ConsumersV2 = maps:map(
fun (_, #consumer{checked_out = Ch} = C) ->
C#consumer{
checked_out = maps:map(
fun (_, {_SeqId, IdxMsg}) ->
convert_msg(IdxMsg)
end, Ch)}
end, ConsumersV1),
DLH = case rabbit_fifo_v1:get_cfg_field(dead_letter_handler, V1State) of
undefined ->
undefined;
{_M, _F, _Args = [_DLX = undefined|_]} ->
undefined;
{_M, _F, _Args} = MFA ->
%%TODO with at_least_once being the new default in RabbitMQ 3.10,
%% should we instead directly convert to at_least_once here?
{at_most_once, MFA}
end,
%% Then add all pending messages back into the index
Cfg = #cfg{name = rabbit_fifo_v1:get_cfg_field(name, V1State),
resource = rabbit_fifo_v1:get_cfg_field(resource, V1State),
release_cursor_interval = rabbit_fifo_v1:get_cfg_field(release_cursor_interval, V1State),
dead_letter_handling = DLH,
become_leader_handler = rabbit_fifo_v1:get_cfg_field(become_leader_handler, V1State),
%% TODO: what if policy enabling reject_publish was applied before conversion?
overflow_strategy = rabbit_fifo_v1:get_cfg_field(overflow_strategy, V1State),
max_length = rabbit_fifo_v1:get_cfg_field(max_length, V1State),
max_bytes = rabbit_fifo_v1:get_cfg_field(max_bytes, V1State),
consumer_strategy = rabbit_fifo_v1:get_cfg_field(consumer_strategy, V1State),
delivery_limit = rabbit_fifo_v1:get_cfg_field(delivery_limit, V1State),
max_in_memory_length = rabbit_fifo_v1:get_cfg_field(max_in_memory_length, V1State),
max_in_memory_bytes = rabbit_fifo_v1:get_cfg_field(max_in_memory_bytes, V1State),
expires = rabbit_fifo_v1:get_cfg_field(expires, V1State)
},
#?MODULE{
cfg = Cfg,
messages = MessagesV2,
messages_total = rabbit_fifo_v1:query_messages_total(V1State),
returns = ReturnsV2,
enqueue_count = rabbit_fifo_v1:get_field(enqueue_count, V1State),
enqueuers = rabbit_fifo_v1:get_field(enqueuers, V1State),
ra_indexes = IndexesV1,
release_cursors = rabbit_fifo_v1:get_field(release_cursors, V1State),
consumers = ConsumersV2,
service_queue = rabbit_fifo_v1:get_field(service_queue, V1State),
prefix_msgs = rabbit_fifo_v1:get_field(prefix_msgs, V1State),
msg_bytes_enqueue = rabbit_fifo_v1:get_field(msg_bytes_enqueue, V1State),
msg_bytes_checkout = rabbit_fifo_v1:get_field(msg_bytes_checkout, V1State),
waiting_consumers = rabbit_fifo_v1:get_field(waiting_consumers, V1State),
msg_bytes_in_memory = rabbit_fifo_v1:get_field(msg_bytes_in_memory, V1State),
msgs_ready_in_memory = rabbit_fifo_v1:get_field(msgs_ready_in_memory, V1State),
last_active = rabbit_fifo_v1:get_field(last_active, V1State)
}.
purge_node(Meta, Node, State, Effects) ->
lists:foldl(fun(Pid, {S0, E0}) ->
{S, E} = handle_down(Meta, Pid, S0),
{S, E0 ++ E}
end, {State, Effects}, all_pids_for(Node, State)).
%% any downs that re not noconnection
handle_down(Meta, Pid, #?MODULE{consumers = Cons0,
enqueuers = Enqs0} = State0) ->
% Remove any enqueuer for the same pid and enqueue any pending messages
% This should be ok as we won't see any more enqueues from this pid
State1 = case maps:take(Pid, Enqs0) of
{#enqueuer{pending = Pend}, Enqs} ->
lists:foldl(fun ({_, RIdx, RawMsg}, S) ->
enqueue(RIdx, RawMsg, S)
end, State0#?MODULE{enqueuers = Enqs}, Pend);
error ->
State0
end,
{Effects1, State2} = handle_waiting_consumer_down(Pid, State1),
% return checked out messages to main queue
% Find the consumers for the down pid
DownConsumers = maps:keys(
maps:filter(fun({_, P}, _) -> P =:= Pid end, Cons0)),
lists:foldl(fun(ConsumerId, {S, E}) ->
cancel_consumer(Meta, ConsumerId, S, E, down)
end, {State2, Effects1}, DownConsumers).
consumer_active_flag_update_function(#?MODULE{cfg = #cfg{consumer_strategy = competing}}) ->
fun(State, ConsumerId, Consumer, Active, ActivityStatus, Effects) ->
consumer_update_active_effects(State, ConsumerId, Consumer, Active,
ActivityStatus, Effects)
end;
consumer_active_flag_update_function(#?MODULE{cfg = #cfg{consumer_strategy = single_active}}) ->
fun(_, _, _, _, _, Effects) ->
Effects
end.
handle_waiting_consumer_down(_Pid,
#?MODULE{cfg = #cfg{consumer_strategy = competing}} = State) ->
{[], State};
handle_waiting_consumer_down(_Pid,
#?MODULE{cfg = #cfg{consumer_strategy = single_active},
waiting_consumers = []} = State) ->
{[], State};
handle_waiting_consumer_down(Pid,
#?MODULE{cfg = #cfg{consumer_strategy = single_active},
waiting_consumers = WaitingConsumers0} = State0) ->
% get cancel effects for down waiting consumers
Down = lists:filter(fun({{_, P}, _}) -> P =:= Pid end,
WaitingConsumers0),
Effects = lists:foldl(fun ({ConsumerId, _}, Effects) ->
cancel_consumer_effects(ConsumerId, State0,
Effects)
end, [], Down),
% update state to have only up waiting consumers
StillUp = lists:filter(fun({{_, P}, _}) -> P =/= Pid end,
WaitingConsumers0),
State = State0#?MODULE{waiting_consumers = StillUp},
{Effects, State}.
update_waiting_consumer_status(Node,
#?MODULE{waiting_consumers = WaitingConsumers},
Status) ->
[begin
case node(Pid) of
Node ->
{ConsumerId, Consumer#consumer{status = Status}};
_ ->
{ConsumerId, Consumer}
end
end || {{_, Pid} = ConsumerId, Consumer} <- WaitingConsumers,
Consumer#consumer.status =/= cancelled].
-spec state_enter(ra_server:ra_state(), state()) -> ra_machine:effects().
state_enter(RaState, #?MODULE{cfg = #cfg{name = QName},
dlx = DlxState} = State) ->
case at_least_once_dlx(State) of
true ->
rabbit_fifo_dlx:state_enter(RaState, QName, DlxState);
false ->
ok
end,
state_enter0(RaState, State).
state_enter0(leader, #?MODULE{consumers = Cons,
enqueuers = Enqs,
waiting_consumers = WaitingConsumers,
cfg = #cfg{name = Name,
resource = Resource,
become_leader_handler = BLH},
prefix_msgs = {0, [], 0, []}
}) ->
% return effects to monitor all current consumers and enqueuers
Pids = lists:usort(maps:keys(Enqs)
++ [P || {_, P} <- maps:keys(Cons)]
++ [P || {{_, P}, _} <- WaitingConsumers]),
Mons = [{monitor, process, P} || P <- Pids],
Nots = [{send_msg, P, leader_change, ra_event} || P <- Pids],
NodeMons = lists:usort([{monitor, node, node(P)} || P <- Pids]),
FHReservation = [{mod_call, rabbit_quorum_queue, file_handle_leader_reservation, [Resource]}],
Effects = Mons ++ Nots ++ NodeMons ++ FHReservation,
case BLH of
undefined ->
Effects;
{Mod, Fun, Args} ->
[{mod_call, Mod, Fun, Args ++ [Name]} | Effects]
end;
state_enter0(eol, #?MODULE{enqueuers = Enqs,
consumers = Custs0,
waiting_consumers = WaitingConsumers0}) ->
Custs = maps:fold(fun({_, P}, V, S) -> S#{P => V} end, #{}, Custs0),
WaitingConsumers1 = lists:foldl(fun({{_, P}, V}, Acc) -> Acc#{P => V} end,
#{}, WaitingConsumers0),
AllConsumers = maps:merge(Custs, WaitingConsumers1),
[{send_msg, P, eol, ra_event}
|| P <- maps:keys(maps:merge(Enqs, AllConsumers))] ++
[{aux, eol},
{mod_call, rabbit_quorum_queue, file_handle_release_reservation, []}];
state_enter0(State, #?MODULE{cfg = #cfg{resource = _Resource}}) when State =/= leader ->
FHReservation = {mod_call, rabbit_quorum_queue, file_handle_other_reservation, []},
[FHReservation];
state_enter0(_, _) ->
%% catch all as not handling all states
[].
-spec tick(non_neg_integer(), state()) -> ra_machine:effects().
tick(Ts, #?MODULE{cfg = #cfg{name = Name,
resource = QName},
msg_bytes_enqueue = EnqueueBytes,
msg_bytes_checkout = CheckoutBytes} = State) ->
case is_expired(Ts, State) of
true ->
[{mod_call, rabbit_quorum_queue, spawn_deleter, [QName]}];
false ->
Metrics = {Name,
messages_ready(State),
num_checked_out(State), % checked out
messages_total(State),
query_consumer_count(State), % Consumers
EnqueueBytes,
CheckoutBytes},
[{mod_call, rabbit_quorum_queue,
handle_tick, [QName, Metrics, all_nodes(State)]}]
end.
-spec overview(state()) -> map().
overview(#?MODULE{consumers = Cons,
enqueuers = Enqs,
release_cursors = Cursors,
enqueue_count = EnqCount,
dlx = DlxState,
msg_bytes_enqueue = EnqueueBytes,
msg_bytes_checkout = CheckoutBytes,
cfg = Cfg} = State) ->
Conf = #{name => Cfg#cfg.name,
resource => Cfg#cfg.resource,
release_cursor_interval => Cfg#cfg.release_cursor_interval,
dead_lettering_enabled => undefined =/= Cfg#cfg.dead_letter_handling,
max_length => Cfg#cfg.max_length,
max_bytes => Cfg#cfg.max_bytes,
consumer_strategy => Cfg#cfg.consumer_strategy,
max_in_memory_length => Cfg#cfg.max_in_memory_length,
max_in_memory_bytes => Cfg#cfg.max_in_memory_bytes,
expires => Cfg#cfg.expires,
delivery_limit => Cfg#cfg.delivery_limit
},
{Smallest, _} = smallest_raft_index(State),
Overview = #{type => ?MODULE,
config => Conf,
num_consumers => maps:size(Cons),
num_checked_out => num_checked_out(State),
num_enqueuers => maps:size(Enqs),
num_ready_messages => messages_ready(State),
num_messages => messages_total(State),
num_release_cursors => lqueue:len(Cursors),
release_cursors => [{I, messages_total(S)} || {_, I, S} <- lqueue:to_list(Cursors)],
release_cursor_enqueue_counter => EnqCount,
enqueue_message_bytes => EnqueueBytes,
checkout_message_bytes => CheckoutBytes,
smallest_raft_index => Smallest},
DlxOverview = rabbit_fifo_dlx:overview(DlxState),
maps:merge(Overview, DlxOverview).
-spec get_checked_out(consumer_id(), msg_id(), msg_id(), state()) ->
[delivery_msg()].
get_checked_out(Cid, From, To, #?MODULE{consumers = Consumers}) ->
case Consumers of
#{Cid := #consumer{checked_out = Checked}} ->
[begin
?INDEX_MSG(_, ?MSG(H, M)) = maps:get(K, Checked),
{K, {H, M}}
end || K <- lists:seq(From, To), maps:is_key(K, Checked)];
_ ->
[]
end.
-spec version() -> pos_integer().
version() -> 2.
which_module(0) -> rabbit_fifo_v0;
which_module(1) -> rabbit_fifo_v1;
which_module(2) -> ?MODULE.
-record(aux_gc, {last_raft_idx = 0 :: ra:index()}).
-record(aux, {name :: atom(),
capacity :: term(),
gc = #aux_gc{} :: #aux_gc{}}).
init_aux(Name) when is_atom(Name) ->
%% TODO: catch specific exception throw if table already exists
ok = ra_machine_ets:create_table(rabbit_fifo_usage,
[named_table, set, public,
{write_concurrency, true}]),
Now = erlang:monotonic_time(micro_seconds),
#aux{name = Name,
capacity = {inactive, Now, 1, 1.0}}.
handle_aux(leader, _, garbage_collection, State, Log, MacState) ->
% ra_log_wal:force_roll_over(ra_log_wal),
{no_reply, force_eval_gc(Log, MacState, State), Log};
handle_aux(follower, _, garbage_collection, State, Log, MacState) ->
% ra_log_wal:force_roll_over(ra_log_wal),
{no_reply, force_eval_gc(Log, MacState, State), Log};
handle_aux(_RaState, cast, eval, Aux0, Log, _MacState) ->
{no_reply, Aux0, Log};
handle_aux(_RaState, cast, Cmd, #aux{capacity = Use0} = Aux0,
Log, _MacState)
when Cmd == active orelse Cmd == inactive ->
{no_reply, Aux0#aux{capacity = update_use(Use0, Cmd)}, Log};
handle_aux(_RaState, cast, tick, #aux{name = Name,
capacity = Use0} = State0,
Log, MacState) ->
true = ets:insert(rabbit_fifo_usage,
{Name, capacity(Use0)}),
Aux = eval_gc(Log, MacState, State0),
{no_reply, Aux, Log};
handle_aux(_RaState, cast, eol, #aux{name = Name} = Aux, Log, _) ->
ets:delete(rabbit_fifo_usage, Name),
{no_reply, Aux, Log};
handle_aux(_RaState, {call, _From}, oldest_entry_timestamp, Aux,
Log, #?MODULE{ra_indexes = Indexes}) ->
Ts = case rabbit_fifo_index:smallest(Indexes) of
%% if there are no entries, we return current timestamp
%% so that any previously obtained entries are considered older than this
undefined ->
erlang:system_time(millisecond);
Idx when is_integer(Idx) ->
{{_, _, {_, Meta, _, _}}, _Log1} = ra_log:fetch(Idx, Log),
#{ts := Timestamp} = Meta,
Timestamp
end,
{reply, {ok, Ts}, Aux, Log};
handle_aux(_RaState, {call, _From}, {peek, Pos}, Aux0,
Log0, MacState) ->
case rabbit_fifo:query_peek(Pos, MacState) of
{ok, ?INDEX_MSG(Idx, ?DISK_MSG(Header))} ->
%% need to re-hydrate from the log
{{_, _, {_, _, Cmd, _}}, Log} = ra_log:fetch(Idx, Log0),
#enqueue{msg = Msg} = Cmd,
{reply, {ok, {Header, Msg}}, Aux0, Log};
{ok, ?INDEX_MSG(_Idx, ?MSG(Header, Msg))} ->
{reply, {ok, {Header, Msg}}, Aux0, Log0};
Err ->
{reply, Err, Aux0, Log0}
end.
eval_gc(Log, #?MODULE{cfg = #cfg{resource = QR}} = MacState,
#aux{gc = #aux_gc{last_raft_idx = LastGcIdx} = Gc} = AuxState) ->
{Idx, _} = ra_log:last_index_term(Log),
{memory, Mem} = erlang:process_info(self(), memory),
case messages_total(MacState) of
0 when Idx > LastGcIdx andalso
Mem > ?GC_MEM_LIMIT_B ->
garbage_collect(),
{memory, MemAfter} = erlang:process_info(self(), memory),
rabbit_log:debug("~s: full GC sweep complete. "
"Process memory changed from ~.2fMB to ~.2fMB.",
[rabbit_misc:rs(QR), Mem/?MB, MemAfter/?MB]),
AuxState#aux{gc = Gc#aux_gc{last_raft_idx = Idx}};
_ ->
AuxState
end.
force_eval_gc(Log, #?MODULE{cfg = #cfg{resource = QR}},
#aux{gc = #aux_gc{last_raft_idx = LastGcIdx} = Gc} = AuxState) ->
{Idx, _} = ra_log:last_index_term(Log),
{memory, Mem} = erlang:process_info(self(), memory),