-
Notifications
You must be signed in to change notification settings - Fork 3.9k
/
rabbit_stream_reader.erl
2814 lines (2700 loc) · 127 KB
/
rabbit_stream_reader.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% The contents of this file are subject to the Mozilla Public License
%% Version 2.0 (the "License"); you may not use this file except in
%% compliance with the License. You may obtain a copy of the License
%% at https://www.mozilla.org/en-US/MPL/2.0/
%%
%% Software distributed under the License is distributed on an "AS IS"
%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
%% the License for the specific language governing rights and
%% limitations under the License.
%%
%% The Original Code is RabbitMQ.
%%
%% The Initial Developer of the Original Code is Pivotal Software, Inc.
%% Copyright (c) 2020-2021 VMware, Inc. or its affiliates. All rights reserved.
%%
-module(rabbit_stream_reader).
-behaviour(gen_statem).
-include_lib("rabbit_common/include/rabbit.hrl").
-include_lib("rabbitmq_stream_common/include/rabbit_stream.hrl").
-include("rabbit_stream_metrics.hrl").
-type stream() :: binary().
-type publisher_id() :: byte().
-type publisher_reference() :: binary().
-type subscription_id() :: byte().
-record(publisher,
{publisher_id :: publisher_id(),
stream :: stream(),
reference :: undefined | publisher_reference(),
leader :: pid(),
message_counters :: atomics:atomics_ref()}).
-record(consumer,
{socket :: rabbit_net:socket(), %% ranch_transport:socket(),
member_pid :: pid(),
offset :: osiris:offset(),
subscription_id :: subscription_id(),
segment :: osiris_log:state(),
credit :: integer(),
stream :: stream(),
counters :: atomics:atomics_ref(),
properties :: map()}).
-record(stream_connection_state,
{data :: rabbit_stream_core:state(), blocked :: boolean(),
consumers :: #{subscription_id() => #consumer{}}}).
-record(stream_connection,
{name :: binary(),
%% server host
host,
%% client host
peer_host,
%% server port
port,
%% client port
peer_port,
auth_mechanism,
connected_at :: integer(),
helper_sup :: pid(),
socket :: rabbit_net:socket(),
publishers ::
#{publisher_id() =>
#publisher{}}, %% FIXME replace with a list (0-255 lookup faster?)
publisher_to_ids ::
#{{stream(), publisher_reference()} => publisher_id()},
stream_leaders :: #{stream() => pid()},
stream_subscriptions :: #{stream() => [subscription_id()]},
credits :: atomics:atomics_ref(),
authentication_state :: atom(),
user :: undefined | #user{},
virtual_host :: undefined | binary(),
connection_step ::
atom(), % tcp_connected, peer_properties_exchanged, authenticating, authenticated, tuning, tuned, opened, failure, closing, closing_done
frame_max :: integer(),
heartbeat :: undefined | integer(),
heartbeater :: any(),
client_properties = #{} :: #{binary() => binary()},
monitors = #{} :: #{reference() => stream()},
stats_timer :: undefined | reference(),
resource_alarm :: boolean(),
send_file_oct ::
atomics:atomics_ref(), % number of bytes sent with send_file (for metrics)
transport :: tcp | ssl}).
-record(configuration,
{initial_credits :: integer(),
credits_required_for_unblocking :: integer(),
frame_max :: integer(),
heartbeat :: integer()}).
-record(statem_data,
{transport :: module(),
connection :: #stream_connection{},
connection_state :: #stream_connection_state{},
config :: #configuration{}}).
-define(CREATION_EVENT_KEYS,
[pid,
name,
port,
peer_port,
host,
peer_host,
ssl,
peer_cert_subject,
peer_cert_issuer,
peer_cert_validity,
auth_mechanism,
ssl_protocol,
ssl_key_exchange,
ssl_cipher,
ssl_hash,
protocol,
user,
vhost,
protocol,
timeout,
frame_max,
channel_max,
client_properties,
connected_at,
node,
user_who_performed_action]).
-define(SIMPLE_METRICS, [pid, recv_oct, send_oct, reductions]).
-define(OTHER_METRICS,
[recv_cnt,
send_cnt,
send_pend,
state,
channels,
garbage_collection,
timeout]).
-define(AUTH_NOTIFICATION_INFO_KEYS,
[host,
name,
peer_host,
peer_port,
protocol,
auth_mechanism,
ssl,
ssl_protocol,
ssl_cipher,
peer_cert_issuer,
peer_cert_subject,
peer_cert_validity]).
%% client API
-export([start_link/4,
info/2,
consumers_info/2,
publishers_info/2,
in_vhost/2]).
-export([resource_alarm/3]).
%% gen_statem callbacks
-export([callback_mode/0,
terminate/3,
%% not called by gen_statem since gen_statem:enter_loop/4 is used
init/1,
%% states
tcp_connected/3,
peer_properties_exchanged/3,
authenticating/3,
tuning/3,
tuned/3,
open/3,
close_sent/3]).
callback_mode() ->
state_functions.
terminate(Reason, State, _StatemData) ->
rabbit_log:debug("~p terminating in state '~s' with reason '~p'", [?MODULE, State, Reason]).
start_link(KeepaliveSup, Transport, Ref, Opts) ->
{ok, proc_lib:spawn_link(?MODULE, init, [[KeepaliveSup, Transport, Ref, Opts]])}.
init([KeepaliveSup,
Transport,
Ref,
#{initial_credits := InitialCredits,
credits_required_for_unblocking := CreditsRequiredBeforeUnblocking,
frame_max := FrameMax,
heartbeat := Heartbeat,
transport := ConnTransport}]) ->
process_flag(trap_exit, true),
{ok, Sock} =
rabbit_networking:handshake(Ref,
application:get_env(rabbitmq_stream,
proxy_protocol, false)),
RealSocket = rabbit_net:unwrap_socket(Sock),
case rabbit_net:connection_string(Sock, inbound) of
{ok, ConnStr} ->
Credits = atomics:new(1, [{signed, true}]),
SendFileOct = atomics:new(1, [{signed, false}]),
atomics:put(SendFileOct, 1, 0),
init_credit(Credits, InitialCredits),
{PeerHost, PeerPort, Host, Port} =
socket_op(Sock,
fun(S) -> rabbit_net:socket_ends(S, inbound) end),
Connection =
#stream_connection{name =
rabbit_data_coercion:to_binary(ConnStr),
host = Host,
peer_host = PeerHost,
port = Port,
peer_port = PeerPort,
connected_at = os:system_time(milli_seconds),
auth_mechanism = none,
helper_sup = KeepaliveSup,
socket = RealSocket,
publishers = #{},
publisher_to_ids = #{},
stream_leaders = #{},
stream_subscriptions = #{},
credits = Credits,
authentication_state = none,
connection_step = tcp_connected,
frame_max = FrameMax,
resource_alarm = false,
send_file_oct = SendFileOct,
transport = ConnTransport},
State =
#stream_connection_state{consumers = #{},
blocked = false,
data =
rabbit_stream_core:init(undefined)},
Transport:setopts(RealSocket, [{active, once}]),
rabbit_alarm:register(self(), {?MODULE, resource_alarm, []}),
% gen_statem process has its start_link call not return until the init function returns.
% This is problematic, because we won't be able to call ranch:handshake/2
% from the init callback as this would cause a deadlock to happen.
% Therefore, we use the gen_statem:enter_loop/4 function.
% See https://ninenines.eu/docs/en/ranch/2.0/guide/protocols/
gen_statem:enter_loop(?MODULE, [], tcp_connected,
#statem_data{
transport = Transport,
connection = Connection,
connection_state = State,
config = #configuration{
initial_credits = InitialCredits,
credits_required_for_unblocking = CreditsRequiredBeforeUnblocking,
frame_max = FrameMax,
heartbeat = Heartbeat}});
{Error, Reason} ->
rabbit_net:fast_close(RealSocket),
rabbit_log_connection:warning("Closing connection because of ~p ~p",
[Error, Reason])
end.
tcp_connected(info, Msg, StateData) ->
handle_info(Msg, StateData,
fun (NextConnectionStep,
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S}
} = StatemData,
NewConnection,
NewConnectionState) ->
if NextConnectionStep =:= peer_properties_exchanged ->
{next_state, peer_properties_exchanged, StatemData#statem_data{
connection = NewConnection,
connection_state = NewConnectionState
}};
true ->
invalid_transition(Transport, S, ?FUNCTION_NAME, NextConnectionStep)
end
end).
peer_properties_exchanged(info, Msg, StateData) ->
handle_info(Msg, StateData,
fun (NextConnectionStep,
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S}
} = StatemData,
NewConnection,
NewConnectionState) ->
if NextConnectionStep =:= authenticating ->
{next_state, authenticating, StatemData#statem_data{
connection = NewConnection,
connection_state = NewConnectionState
}};
true ->
invalid_transition(Transport, S, ?FUNCTION_NAME, NextConnectionStep)
end
end).
authenticating(info, Msg, StateData) ->
handle_info(Msg, StateData,
fun(NextConnectionStep,
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S},
config = #configuration{
frame_max = FrameMax,
heartbeat = Heartbeat}
} = StatemData,
NewConnection,
NewConnectionState) ->
if NextConnectionStep =:= authenticated ->
Frame = rabbit_stream_core:frame({tune, FrameMax, Heartbeat}),
send(Transport, S, Frame),
{next_state, tuning, StatemData#statem_data{
connection = NewConnection#stream_connection{connection_step
=
tuning},
connection_state = NewConnectionState
}};
true ->
invalid_transition(Transport, S, ?FUNCTION_NAME, NextConnectionStep)
end
end).
tuning(info, Msg, StateData) ->
handle_info(Msg, StateData,
fun (NextConnectionStep,
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S},
config = Configuration
} = StatemData,
NewConnection,
NewConnectionState) ->
case NextConnectionStep of
tuned ->
{next_state, tuned, StatemData#statem_data{
connection = NewConnection,
connection_state = NewConnectionState
}};
opened ->
transition_to_opened(Transport, Configuration, NewConnection, NewConnectionState);
_ ->
invalid_transition(Transport, S, ?FUNCTION_NAME, NextConnectionStep)
end
end).
tuned(info, Msg, StateData) ->
handle_info(Msg, StateData,
fun (NextConnectionStep,
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S},
config = Configuration},
NewConnection, NewConnectionState) ->
if NextConnectionStep =:= opened ->
transition_to_opened(Transport, Configuration, NewConnection, NewConnectionState);
true ->
invalid_transition(Transport, S, ?FUNCTION_NAME, NextConnectionStep)
end
end).
handle_info(Msg, #statem_data{
transport = Transport,
connection = #stream_connection{socket = S, connection_step = PreviousConnectionStep} = Connection,
connection_state = State
} = StatemData, Transition) ->
{OK, Closed, Error, _Passive} = Transport:messages(),
case Msg of
{OK, S, Data} ->
{Connection1, State1} = handle_inbound_data_pre_auth(Transport, Connection, State, Data),
Transport:setopts(S, [{active, once}]),
#stream_connection{connection_step = NewConnectionStep} = Connection1,
rabbit_log_connection:debug("Transitioned from ~s to ~s", [PreviousConnectionStep, NewConnectionStep]),
Transition(NewConnectionStep, StatemData, Connection1, State1);
{Closed, S} ->
rabbit_log_connection:info("Socket ~w closed", [S]),
stop;
{Error, S, Reason} ->
rabbit_log_connection:warning("Socket error ~p [~w]", [Reason, S]),
stop;
{resource_alarm, IsThereAlarm} ->
{keep_state, StatemData#statem_data{
connection = Connection#stream_connection{
resource_alarm = IsThereAlarm},
connection_state = State#stream_connection_state{
blocked = true}}};
Unknown ->
rabbit_log:warning("Received unknown message ~p", [Unknown]),
close_immediately(Transport, S),
stop
end.
transition_to_opened(Transport, Configuration, NewConnection, NewConnectionState) ->
% TODO remove registration to rabbit_stream_connections
% just meant to be able to close the connection remotely
% should be possible once the connections are available in ctl list_connections
pg_local:join(rabbit_stream_connections, self()),
Connection1 =
rabbit_event:init_stats_timer(NewConnection,
#stream_connection.stats_timer),
Connection2 = ensure_stats_timer(Connection1),
Infos =
augment_infos_with_user_provided_connection_name(infos(?CREATION_EVENT_KEYS,
Connection2,
NewConnectionState),
Connection2),
rabbit_core_metrics:connection_created(self(), Infos),
rabbit_event:notify(connection_created, Infos),
rabbit_networking:register_non_amqp_connection(self()),
{next_state, open, #statem_data{
transport = Transport,
connection = Connection2,
connection_state = NewConnectionState,
config = Configuration
}}.
invalid_transition(Transport, Socket, From, To) ->
rabbit_log_connection:warning("Closing socket ~w. Invalid transition from ~s to ~s.",
[Socket, From, To]),
close_immediately(Transport, Socket),
stop.
resource_alarm(ConnectionPid, disk,
{_WasAlarmSetForNode,
IsThereAnyAlarmsForSameResourceInTheCluster, _Node}) ->
ConnectionPid
! {resource_alarm, IsThereAnyAlarmsForSameResourceInTheCluster},
ok;
resource_alarm(_ConnectionPid, _Resource, _Alert) ->
ok.
socket_op(Sock, Fun) ->
RealSocket = rabbit_net:unwrap_socket(Sock),
case Fun(Sock) of
{ok, Res} ->
Res;
{error, Reason} ->
rabbit_log_connection:warning("Error during socket operation ~p", [Reason]),
rabbit_net:fast_close(RealSocket),
exit(normal)
end.
should_unblock(#stream_connection{publishers = Publishers}, _)
when map_size(Publishers) == 0 ->
%% always unblock a connection without publishers
true;
should_unblock(#stream_connection{credits = Credits,
resource_alarm = ResourceAlarm},
#configuration{credits_required_for_unblocking =
CreditsRequiredForUnblocking}) ->
case {ResourceAlarm,
has_enough_credits_to_unblock(Credits, CreditsRequiredForUnblocking)}
of
{true, _} ->
false;
{false, EnoughCreditsToUnblock} ->
EnoughCreditsToUnblock
end.
init_credit(CreditReference, Credits) ->
atomics:put(CreditReference, 1, Credits).
sub_credits(CreditReference, Credits) ->
atomics:sub(CreditReference, 1, Credits).
add_credits(CreditReference, Credits) ->
atomics:add(CreditReference, 1, Credits).
has_credits(CreditReference) ->
atomics:get(CreditReference, 1) > 0.
has_enough_credits_to_unblock(CreditReference,
CreditsRequiredForUnblocking) ->
atomics:get(CreditReference, 1) > CreditsRequiredForUnblocking.
increase_messages_consumed(Counters, Count) ->
rabbit_global_counters:messages_delivered(stream, ?STREAM_QUEUE_TYPE, Count),
atomics:add(Counters, 1, Count).
set_consumer_offset(Counters, Offset) ->
atomics:put(Counters, 2, Offset).
increase_messages_received(Counters, Count) ->
rabbit_global_counters:messages_received(stream, Count),
rabbit_global_counters:messages_received_confirm(stream, Count),
atomics:add(Counters, 1, Count).
increase_messages_confirmed(Counters, Count) ->
rabbit_global_counters:messages_confirmed(stream, Count),
atomics:add(Counters, 2, Count).
increase_messages_errored(Counters, Count) ->
atomics:add(Counters, 3, Count).
messages_consumed(Counters) ->
atomics:get(Counters, 1).
consumer_offset(Counters) ->
atomics:get(Counters, 2).
messages_published(Counters) ->
atomics:get(Counters, 1).
messages_confirmed(Counters) ->
atomics:get(Counters, 2).
messages_errored(Counters) ->
atomics:get(Counters, 3).
stream_stored_offset(Log) ->
osiris_log:committed_offset(Log).
augment_infos_with_user_provided_connection_name(Infos,
#stream_connection{client_properties
=
ClientProperties}) ->
case ClientProperties of
#{<<"connection_name">> := UserProvidedConnectionName} ->
[{user_provided_name, UserProvidedConnectionName} | Infos];
_ ->
Infos
end.
close(Transport, S,
#stream_connection_state{consumers = Consumers}) ->
[osiris_log:close(Log)
|| #consumer{segment = Log} <- maps:values(Consumers)],
Transport:shutdown(S, write),
Transport:close(S).
% Do not read or write any further data from / to Socket.
% Useful to close sockets for unauthenticated clients.
close_immediately(Transport, S) ->
Transport:shutdown(S, read),
Transport:close(S).
open(info,
{resource_alarm, IsThereAlarm},
#statem_data{
transport = Transport,
connection = #stream_connection{
socket = S,
name = ConnectionName,
credits = Credits,
heartbeater = Heartbeater
} = Connection,
connection_state = #stream_connection_state{blocked = Blocked} = State,
config = #configuration{credits_required_for_unblocking = CreditsRequiredForUnblocking}
} = StatemData) ->
rabbit_log_connection:debug("Connection ~p received resource alarm. Alarm "
"on? ~p",
[ConnectionName, IsThereAlarm]),
EnoughCreditsToUnblock =
has_enough_credits_to_unblock(Credits,
CreditsRequiredForUnblocking),
NewBlockedState =
case {IsThereAlarm, EnoughCreditsToUnblock} of
{true, _} ->
true;
{false, EnoughCredits} ->
not EnoughCredits
end,
rabbit_log_connection:debug("Connection ~p had blocked status set to ~p, new "
"blocked status is now ~p",
[ConnectionName, Blocked, NewBlockedState]),
case {Blocked, NewBlockedState} of
{true, false} ->
Transport:setopts(S, [{active, once}]),
ok = rabbit_heartbeat:resume_monitor(Heartbeater),
rabbit_log_connection:debug("Unblocking connection ~p",
[ConnectionName]);
{false, true} ->
ok = rabbit_heartbeat:pause_monitor(Heartbeater),
rabbit_log_connection:debug("Blocking connection ~p after resource alarm",
[ConnectionName]);
_ ->
ok
end,
{keep_state,
StatemData#statem_data{
connection = Connection#stream_connection{resource_alarm = IsThereAlarm},
connection_state = State#stream_connection_state{blocked = NewBlockedState}
}};
open(info,
{OK, S, Data},
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S,
credits = Credits,
heartbeater = Heartbeater
} = Connection,
connection_state = #stream_connection_state{blocked = Blocked} = State,
config = Configuration
} = StatemData)
when OK =:= tcp; OK =:= ssl ->
{Connection1, State1} = handle_inbound_data_post_auth(Transport,
Connection,
State,
Data),
#stream_connection{connection_step = Step} = Connection1,
case Step of
closing ->
close(Transport, S, State),
rabbit_networking:unregister_non_amqp_connection(self()),
notify_connection_closed(Connection1, State1),
stop;
close_sent ->
rabbit_log_connection:debug("Transitioned to close_sent"),
Transport:setopts(S, [{active, once}]),
{next_state, close_sent, StatemData#statem_data{
connection = Connection1,
connection_state = State1
}};
_ ->
State2 =
case Blocked of
true ->
case should_unblock(Connection, Configuration)
of
true ->
Transport:setopts(S, [{active, once}]),
ok =
rabbit_heartbeat:resume_monitor(Heartbeater),
State1#stream_connection_state{blocked =
false};
false ->
State1
end;
false ->
case has_credits(Credits) of
true ->
Transport:setopts(S, [{active, once}]),
State1;
false ->
ok =
rabbit_heartbeat:pause_monitor(Heartbeater),
State1#stream_connection_state{blocked =
true}
end
end,
{keep_state, StatemData#statem_data{
connection = Connection1,
connection_state = State2}}
end;
open(info, {Closed, Socket}, #statem_data{
connection = Connection,
connection_state = State
})
when Closed =:= tcp_closed; Closed =:= ssl_closed ->
demonitor_all_streams(Connection),
rabbit_networking:unregister_non_amqp_connection(self()),
notify_connection_closed(Connection, State),
rabbit_log_connection:warning("Socket ~w closed [~w]", [Socket, self()]),
stop;
open(info, {Error, Socket, Reason}, #statem_data{
connection = Connection,
connection_state = State
})
when Error =:= tcp_error; Error =:= ssl_error ->
demonitor_all_streams(Connection),
rabbit_networking:unregister_non_amqp_connection(self()),
notify_connection_closed(Connection, State),
rabbit_log_connection:error("Socket error ~p [~w] [~w]", [Reason, Socket, self()]),
stop;
open(info,
{'DOWN', MonitorRef, process, _OsirisPid, _Reason},
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S,
monitors = Monitors
} = Connection,
connection_state = State
} = StatemData) ->
{Connection1, State1} =
case Monitors of
#{MonitorRef := Stream} ->
Monitors1 = maps:remove(MonitorRef, Monitors),
C = Connection#stream_connection{monitors = Monitors1},
case
clean_state_after_stream_deletion_or_failure(Stream,
C,
State)
of
{cleaned, NewConnection, NewState} ->
Command =
{metadata_update, Stream,
?RESPONSE_CODE_STREAM_NOT_AVAILABLE},
Frame = rabbit_stream_core:frame(Command),
send(Transport, S, Frame),
rabbit_global_counters:increase_protocol_counter(stream, ?STREAM_NOT_AVAILABLE, 1),
{NewConnection, NewState};
{not_cleaned, SameConnection, SameState} ->
{SameConnection, SameState}
end;
_ ->
{Connection, State}
end,
{keep_state, StatemData#statem_data{
connection = Connection1,
connection_state = State1}};
open(info, heartbeat_send, #statem_data{
transport = Transport,
connection = #stream_connection{socket = S} = Connection,
connection_state = State }) ->
Frame = rabbit_stream_core:frame(heartbeat),
case catch send(Transport, S, Frame) of
ok ->
keep_state_and_data;
Unexpected ->
rabbit_log_connection:info("Heartbeat send error ~p, closing connection",
[Unexpected]),
C1 = demonitor_all_streams(Connection),
close(Transport, C1, State),
stop
end;
open(info, heartbeat_timeout, #statem_data{
transport = Transport,
connection = Connection,
connection_state = State }) ->
rabbit_log_connection:debug("Heartbeat timeout, closing connection"),
C1 = demonitor_all_streams(Connection),
close(Transport, C1, State),
stop;
open(info, {infos, From}, #statem_data{
connection = #stream_connection{
client_properties = ClientProperties
}}) ->
From ! {self(), ClientProperties},
keep_state_and_data;
open(info, emit_stats, #statem_data{
connection = Connection,
connection_state = State} = StatemData) ->
Connection1 = emit_stats(Connection, State),
{keep_state, StatemData#statem_data{connection = Connection1}};
open(info, Unknown, _StatemData) ->
rabbit_log_connection:warning("Received unknown message ~p in state ~s",
[Unknown, ?FUNCTION_NAME]),
%% FIXME send close
keep_state_and_data;
open({call, From}, info, #statem_data{
connection = Connection,
connection_state = State}) ->
{keep_state_and_data, {reply, From, infos(?INFO_ITEMS, Connection, State)}};
open({call, From}, {info, Items}, #statem_data{
connection = Connection,
connection_state = State}) ->
{keep_state_and_data, {reply, From, infos(Items, Connection, State)}};
open({call, From}, {consumers_info, Items}, #statem_data{connection_state = State}) ->
{keep_state_and_data, {reply, From, consumers_infos(Items, State)}};
open({call, From}, {publishers_info, Items}, #statem_data{connection = Connection}) ->
{keep_state_and_data, {reply, From, publishers_infos(Items, Connection)}};
open({call, From}, {shutdown, Explanation}, #statem_data{
transport = Transport,
connection = #stream_connection{socket = S}
= Connection,
connection_state = State}) ->
% likely closing call from the management plugin
rabbit_log_connection:info("Forcing stream connection ~p closing: ~p",
[self(), Explanation]),
demonitor_all_streams(Connection),
rabbit_networking:unregister_non_amqp_connection(self()),
notify_connection_closed(Connection, State),
close(Transport, S, State),
{stop_and_reply, normal, {reply, From, ok}};
open(cast,
{queue_event, _, {osiris_written, _, undefined, CorrelationList}},
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S,
credits = Credits,
heartbeater = Heartbeater,
publishers = Publishers
} = Connection,
connection_state = #stream_connection_state{
blocked = Blocked
} = State,
config = Configuration
} = StatemData) ->
ByPublisher =
lists:foldr(fun({PublisherId, PublishingId}, Acc) ->
case maps:is_key(PublisherId, Publishers) of
true ->
case maps:get(PublisherId, Acc, undefined) of
undefined ->
Acc#{PublisherId => [PublishingId]};
Ids ->
Acc#{PublisherId => [PublishingId | Ids]}
end;
false ->
Acc
end
end,
#{}, CorrelationList),
_ = maps:map(fun(PublisherId, PublishingIds) ->
Command =
{publish_confirm, PublisherId, PublishingIds},
send(Transport, S,
rabbit_stream_core:frame(Command)),
#{PublisherId :=
#publisher{message_counters = Cnt}} =
Publishers,
increase_messages_confirmed(Cnt,
length(PublishingIds))
end,
ByPublisher),
CorrelationIdCount = length(CorrelationList),
add_credits(Credits, CorrelationIdCount),
State1 = case Blocked of
true ->
case should_unblock(Connection, Configuration) of
true ->
Transport:setopts(S, [{active, once}]),
ok =
rabbit_heartbeat:resume_monitor(Heartbeater),
State#stream_connection_state{blocked = false};
false ->
State
end;
false ->
State
end,
{keep_state, StatemData#statem_data{connection_state = State1}};
open(cast,
{queue_event, _QueueResource,
{osiris_written, #resource{name = Stream}, PublisherReference, CorrelationList}},
#statem_data{
transport = Transport,
connection = #stream_connection{socket = S,
credits = Credits,
heartbeater = Heartbeater,
publishers = Publishers,
publisher_to_ids = PublisherRefToIds
} = Connection,
connection_state = #stream_connection_state{
blocked = Blocked
} = State,
config = Configuration
} = StatemData) ->
PublishingIdCount = length(CorrelationList),
case maps:get({Stream, PublisherReference}, PublisherRefToIds,
undefined) of
undefined ->
ok;
PublisherId ->
Command = {publish_confirm, PublisherId, CorrelationList},
send(Transport, S, rabbit_stream_core:frame(Command)),
#{PublisherId := #publisher{message_counters = Counters}} =
Publishers,
increase_messages_confirmed(Counters, PublishingIdCount)
end,
add_credits(Credits, PublishingIdCount),
State1 =
case Blocked of
true ->
case should_unblock(Connection, Configuration) of
true ->
Transport:setopts(S, [{active, once}]),
ok =
rabbit_heartbeat:resume_monitor(Heartbeater),
State#stream_connection_state{blocked = false};
false ->
State
end;
false ->
State
end,
{keep_state, StatemData#statem_data{connection_state = State1}};
open(cast, {queue_event, #resource{name = StreamName},
{osiris_offset, _QueueResource, -1}}, _StatemData) ->
rabbit_log:info("received osiris offset event for ~p with offset ~p",
[StreamName, -1]),
keep_state_and_data;
open(cast,
{queue_event, #resource{name = StreamName},
{osiris_offset, _QueueResource, Offset}},
#statem_data{
transport = Transport,
connection = #stream_connection{
stream_subscriptions = StreamSubscriptions,
send_file_oct = SendFileOct
} = Connection,
connection_state = #stream_connection_state{consumers = Consumers} = State
} = StatemData)
when Offset > -1 ->
{Connection1, State1} =
case maps:get(StreamName, StreamSubscriptions, undefined) of
undefined ->
rabbit_log:info("osiris offset event for ~p, but no subscription "
"(leftover messages after unsubscribe?)",
[StreamName]),
{Connection, State};
[] ->
rabbit_log:info("osiris offset event for ~p, but no registered "
"consumers!",
[StreamName]),
{Connection#stream_connection{stream_subscriptions =
maps:remove(StreamName,
StreamSubscriptions)},
State};
CorrelationIds when is_list(CorrelationIds) ->
Consumers1 =
lists:foldl(fun(CorrelationId, ConsumersAcc) ->
#{CorrelationId := Consumer} =
ConsumersAcc,
#consumer{credit = Credit} =
Consumer,
Consumer1 =
case Credit of
0 -> Consumer;
_ ->
case
send_chunks(Transport,
Consumer,
SendFileOct)
of
{error, Reason} ->
rabbit_log_connection:info("Error while sending chunks: ~p",
[Reason]),
%% likely a connection problem
Consumer;
{{segment, Segment1},
{credit,
Credit1}} ->
Consumer#consumer{segment
=
Segment1,
credit
=
Credit1}
end
end,
ConsumersAcc#{CorrelationId =>
Consumer1}
end,
Consumers, CorrelationIds),
{Connection,
State#stream_connection_state{consumers = Consumers1}}
end,
{keep_state, StatemData#statem_data{
connection = Connection1,
connection_state = State1}};
open(cast, {force_event_refresh, Ref}, #statem_data{
connection = Connection,
connection_state = State} = StatemData) ->
Infos =
augment_infos_with_user_provided_connection_name(infos(?CREATION_EVENT_KEYS,
Connection,
State),
Connection),
rabbit_event:notify(connection_created, Infos, Ref),
Connection1 =
rabbit_event:init_stats_timer(Connection,
#stream_connection.stats_timer),
Connection2 = ensure_stats_timer(Connection1),
{keep_state, StatemData#statem_data{connection = Connection2}}.
close_sent(info, {tcp, S, Data}, #statem_data{
transport = Transport,
connection = Connection,
connection_state = State
} = StatemData) when byte_size(Data) > 1 ->
{Connection1, State1} = handle_inbound_data_post_close(Transport,
Connection,
State,
Data),
#stream_connection{connection_step = Step} = Connection1,
rabbit_log_connection:debug("Transitioned from ~s to ~s", [?FUNCTION_NAME, Step]),
case Step of
closing_done ->
close(Transport, S, State1),
rabbit_networking:unregister_non_amqp_connection(self()),
notify_connection_closed(Connection1, State1),
stop;
_ ->
Transport:setopts(S, [{active, once}]),
{keep_state, StatemData#statem_data{
connection = Connection1,
connection_state = State1
}}
end;
close_sent(info, {tcp_closed, S}, #statem_data{
connection = Connection,
connection_state = State
}) ->
rabbit_networking:unregister_non_amqp_connection(self()),
notify_connection_closed(Connection, State),
rabbit_log_connection:info("Socket ~w closed [~w]", [S, self()]),
stop;
close_sent(info, {tcp_error, S, Reason}, #statem_data{
transport = Transport,
connection = Connection,
connection_state = State
}) ->
rabbit_log_connection:info("Socket error ~p [~w] [~w]", [Reason, S, self()]),
close(Transport, S, State),
rabbit_networking:unregister_non_amqp_connection(self()),
notify_connection_closed(Connection, State),
stop;
close_sent(info,{resource_alarm, IsThereAlarm},
StatemData = #statem_data{connection = Connection}) ->
rabbit_log:info("Ignored resource_alarm ~p in state ~s", [IsThereAlarm, ?FUNCTION_NAME]),
{keep_state, StatemData#statem_data{
connection = Connection#stream_connection{resource_alarm = IsThereAlarm}
}};
close_sent(info, Msg, _StatemData) ->
rabbit_log_connection:warning("Ignored unknown message ~p in state ~s", [Msg, ?FUNCTION_NAME]),
keep_state_and_data.