-
Notifications
You must be signed in to change notification settings - Fork 3.9k
/
rabbit_amqqueue.erl
1989 lines (1705 loc) · 76.5 KB
/
rabbit_amqqueue.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% This Source Code Form is subject to the terms of the Mozilla Public
%% License, v. 2.0. If a copy of the MPL was not distributed with this
%% file, You can obtain one at https://mozilla.org/MPL/2.0/.
%%
%% Copyright (c) 2007-2023 VMware, Inc. or its affiliates. All rights reserved.
%%
-module(rabbit_amqqueue).
-export([warn_file_limit/0]).
-export([recover/1, stop/1, start/1, declare/6, declare/7,
delete_immediately/1, delete_exclusive/2, delete/4, purge/1,
forget_all_durable/1]).
-export([pseudo_queue/2, pseudo_queue/3, immutable/1]).
-export([exists/1, lookup/1, lookup/2, lookup_many/1, lookup_durable_queue/1,
not_found_or_absent_dirty/1,
with/2, with/3, with_or_die/2,
assert_equivalence/5,
augment_declare_args/5,
check_exclusive_access/2, with_exclusive_access_or_die/3,
stat/1, deliver/2,
requeue/3, ack/3, reject/4]).
-export([not_found/1, absent/2]).
-export([list/0, list_durable/0, list/1, info_keys/0, info/1, info/2, info_all/1, info_all/2,
emit_info_all/5, list_local/1, info_local/1,
emit_info_local/4, emit_info_down/4]).
-export([count/0]).
-export([list_down/1, count/1, list_names/0, list_names/1, list_local_names/0,
list_local_names_down/0]).
-export([list_by_type/1, sample_local_queues/0, sample_n_by_name/2, sample_n/2]).
-export([force_event_refresh/1, notify_policy_changed/1]).
-export([consumers/1, consumers_all/1, emit_consumers_all/4, consumer_info_keys/0]).
-export([basic_get/5, basic_consume/12, basic_cancel/5, notify_decorators/1]).
-export([notify_sent/2, notify_sent_queue_down/1, resume/2]).
-export([notify_down_all/2, notify_down_all/3, activate_limit_all/2, credit/5]).
-export([on_node_up/1, on_node_down/1]).
-export([update/2, store_queue/1, update_decorators/1, policy_changed/2]).
-export([update_mirroring/1, sync_mirrors/1, cancel_sync_mirrors/1]).
-export([emit_unresponsive/6, emit_unresponsive_local/5, is_unresponsive/2]).
-export([has_synchronised_mirrors_online/1, is_match/2, is_in_virtual_host/2]).
-export([is_replicated/1, is_exclusive/1, is_not_exclusive/1, is_dead_exclusive/1]).
-export([list_local_quorum_queues/0, list_local_quorum_queue_names/0, list_local_stream_queues/0,
list_local_mirrored_classic_queues/0, list_local_mirrored_classic_names/0,
list_local_leaders/0, list_local_followers/0, get_quorum_nodes/1,
list_local_mirrored_classic_without_synchronised_mirrors/0,
list_local_mirrored_classic_without_synchronised_mirrors_for_cli/0,
list_local_quorum_queues_with_name_matching/1,
list_local_quorum_queues_with_name_matching/2]).
-export([ensure_rabbit_queue_record_is_initialized/1]).
-export([format/1]).
-export([delete_immediately_by_resource/1]).
-export([delete_crashed/1,
delete_crashed/2,
delete_crashed_internal/2]).
-export([pid_of/1, pid_of/2]).
-export([mark_local_durable_queues_stopped/1]).
-export([rebalance/3]).
-export([collect_info_all/2]).
-export([is_policy_applicable/2, declare_args/0, consume_args/0]).
-export([is_server_named_allowed/1]).
-export([check_max_age/1]).
-export([get_queue_type/1, get_resource_vhost_name/1, get_resource_name/1]).
-export([deactivate_limit_all/2]).
-export([prepend_extra_bcc/1]).
%% internal
-export([internal_declare/2, internal_delete/2, run_backing_queue/3,
set_ram_duration_target/2, set_maximum_since_use/2,
emit_consumers_local/3, internal_delete/3]).
-include_lib("rabbit_common/include/rabbit.hrl").
-include_lib("stdlib/include/qlc.hrl").
-include("amqqueue.hrl").
-define(INTEGER_ARG_TYPES, [byte, short, signedint, long,
unsignedbyte, unsignedshort, unsignedint]).
-define(IS_CLASSIC(QPid), is_pid(QPid)).
-define(IS_QUORUM(QPid), is_tuple(QPid)).
%%----------------------------------------------------------------------------
-export_type([name/0, qmsg/0, absent_reason/0]).
-type name() :: rabbit_types:r('queue').
-type qpids() :: [pid()].
-type qlen() :: rabbit_types:ok(non_neg_integer()).
-type qfun(A) :: fun ((amqqueue:amqqueue()) -> A | no_return()).
-type qmsg() :: {name(), pid() | {atom(), pid()}, msg_id(),
boolean(), rabbit_types:message()}.
-type msg_id() :: non_neg_integer().
-type ok_or_errors() ::
'ok' | {'error', [{'error' | 'exit' | 'throw', any()}]}.
-type absent_reason() :: 'nodedown' | 'crashed' | stopped | timeout.
-type queue_not_found() :: not_found.
-type queue_absent() :: {'absent', amqqueue:amqqueue(), absent_reason()}.
-type not_found_or_absent() :: queue_not_found() | queue_absent().
%%----------------------------------------------------------------------------
-define(CONSUMER_INFO_KEYS,
[queue_name, channel_pid, consumer_tag, ack_required, prefetch_count,
active, activity_status, arguments]).
warn_file_limit() ->
DurableQueues = find_recoverable_queues(),
L = length(DurableQueues),
%% if there are not enough file handles, the server might hang
%% when trying to recover queues, warn the user:
case file_handle_cache:get_limit() < L of
true ->
rabbit_log:warning(
"Recovering ~tp queues, available file handles: ~tp. Please increase max open file handles limit to at least ~tp!",
[L, file_handle_cache:get_limit(), L]);
false ->
ok
end.
-spec recover(rabbit_types:vhost()) ->
{Recovered :: [amqqueue:amqqueue()],
Failed :: [amqqueue:amqqueue()]}.
recover(VHost) ->
AllDurable = find_local_durable_queues(VHost),
rabbit_queue_type:recover(VHost, AllDurable).
filter_pid_per_type(QPids) ->
lists:partition(fun(QPid) -> ?IS_CLASSIC(QPid) end, QPids).
filter_resource_per_type(Resources) ->
Queues = [begin
{ok, Q} = lookup(Resource),
QPid = amqqueue:get_pid(Q),
{Resource, QPid}
end || Resource <- Resources],
lists:partition(fun({_Resource, QPid}) -> ?IS_CLASSIC(QPid) end, Queues).
-spec stop(rabbit_types:vhost()) -> 'ok'.
stop(VHost) ->
%% Classic queues
ok = rabbit_amqqueue_sup_sup:stop_for_vhost(VHost),
{ok, BQ} = application:get_env(rabbit, backing_queue_module),
ok = BQ:stop(VHost),
rabbit_quorum_queue:stop(VHost).
-spec start([amqqueue:amqqueue()]) -> 'ok'.
start(Qs) ->
%% At this point all recovered queues and their bindings are
%% visible to routing, so now it is safe for them to complete
%% their initialisation (which may involve interacting with other
%% queues).
_ = [amqqueue:get_pid(Q) ! {self(), go}
|| Q <- Qs,
%% All queues are supposed to be classic here.
amqqueue:is_classic(Q)],
ok.
mark_local_durable_queues_stopped(VHostName) ->
rabbit_db_queue:update_durable(
fun(Q) ->
amqqueue:set_state(Q, stopped)
end,
fun(Q) ->
amqqueue:get_vhost(Q) =:= VHostName andalso
rabbit_queue_type:is_recoverable(Q) andalso
amqqueue:get_type(Q) =:= rabbit_classic_queue andalso
amqqueue:get_state(Q) =/= stopped
end).
find_local_durable_queues(VHostName) ->
rabbit_db_queue:filter_all_durable(fun(Q) ->
amqqueue:get_vhost(Q) =:= VHostName andalso
rabbit_queue_type:is_recoverable(Q)
end).
find_recoverable_queues() ->
rabbit_db_queue:filter_all_durable(fun(Q) ->
rabbit_queue_type:is_recoverable(Q)
end).
-spec declare(name(),
boolean(),
boolean(),
rabbit_framing:amqp_table(),
rabbit_types:maybe(pid()),
rabbit_types:username()) ->
{'new' | 'existing' | 'owner_died', amqqueue:amqqueue()} |
{'new', amqqueue:amqqueue(), rabbit_fifo_client:state()} |
{'absent', amqqueue:amqqueue(), absent_reason()} |
{protocol_error, Type :: atom(), Reason :: string(), Args :: term()}.
declare(QueueName, Durable, AutoDelete, Args, Owner, ActingUser) ->
declare(QueueName, Durable, AutoDelete, Args, Owner, ActingUser, node()).
%% The Node argument suggests where the queue (leader if mirrored)
%% should be. Note that in some cases (e.g. with "nodes" policy in
%% effect) this might not be possible to satisfy.
-spec declare(name(),
boolean(),
boolean(),
rabbit_framing:amqp_table(),
rabbit_types:maybe(pid()),
rabbit_types:username(),
node() | {'ignore_location', node()}) ->
{'new' | 'existing' | 'owner_died', amqqueue:amqqueue()} |
{'absent', amqqueue:amqqueue(), absent_reason()} |
{protocol_error, Type :: atom(), Reason :: string(), Args :: term()}.
declare(QueueName = #resource{virtual_host = VHost}, Durable, AutoDelete, Args,
Owner, ActingUser, Node) ->
ok = check_declare_arguments(QueueName, Args),
Type = get_queue_type(Args),
case rabbit_queue_type:is_enabled(Type) of
true ->
Q = amqqueue:new(QueueName,
none,
Durable,
AutoDelete,
Owner,
Args,
VHost,
#{user => ActingUser},
Type),
rabbit_queue_type:declare(Q, Node);
false ->
{protocol_error, internal_error,
"Cannot declare a queue '~ts' of type '~ts' on node '~ts': "
"the corresponding feature flag is disabled",
[rabbit_misc:rs(QueueName), Type, Node]}
end.
get_queue_type(Args) ->
case rabbit_misc:table_lookup(Args, <<"x-queue-type">>) of
undefined ->
rabbit_queue_type:default();
{_, V} ->
rabbit_queue_type:discover(V)
end.
-spec internal_declare(amqqueue:amqqueue(), boolean()) ->
{created | existing, amqqueue:amqqueue()} | queue_absent().
internal_declare(Q, Recover) ->
do_internal_declare(Q, Recover).
do_internal_declare(Q0, true) ->
Q = amqqueue:set_state(Q0, live),
ok = store_queue(Q),
{created, Q0};
do_internal_declare(Q0, false) ->
Q = rabbit_policy:set(amqqueue:set_state(Q0, live)),
Queue = rabbit_queue_decorator:set(Q),
rabbit_db_queue:create_or_get(Queue).
-spec update
(name(), fun((amqqueue:amqqueue()) -> amqqueue:amqqueue())) ->
'not_found' | amqqueue:amqqueue().
update(Name, Fun) ->
rabbit_db_queue:update(Name, Fun).
%% only really used for quorum queues to ensure the rabbit_queue record
%% is initialised
ensure_rabbit_queue_record_is_initialized(Q) ->
store_queue(Q).
-spec store_queue(amqqueue:amqqueue()) -> 'ok'.
store_queue(Q0) ->
Q = rabbit_queue_decorator:set(Q0),
rabbit_db_queue:set(Q).
-spec update_decorators(name()) -> 'ok'.
update_decorators(Name) ->
rabbit_db_queue:update_decorators(Name).
-spec policy_changed(amqqueue:amqqueue(), amqqueue:amqqueue()) ->
'ok'.
policy_changed(Q1, Q2) ->
Decorators1 = amqqueue:get_decorators(Q1),
Decorators2 = amqqueue:get_decorators(Q2),
rabbit_mirror_queue_misc:update_mirrors(Q1, Q2),
D1 = rabbit_queue_decorator:select(Decorators1),
D2 = rabbit_queue_decorator:select(Decorators2),
[ok = M:policy_changed(Q1, Q2) || M <- lists:usort(D1 ++ D2)],
%% Make sure we emit a stats event even if nothing
%% mirroring-related has changed - the policy may have changed anyway.
notify_policy_changed(Q2).
is_policy_applicable(Q, Policy) when ?is_amqqueue(Q) ->
rabbit_queue_type:is_policy_applicable(Q, Policy);
is_policy_applicable(QName, Policy) ->
case lookup(QName) of
{ok, Q} ->
rabbit_queue_type:is_policy_applicable(Q, Policy);
_ ->
%% Defaults to previous behaviour. Apply always
true
end.
is_server_named_allowed(Args) ->
Type = get_queue_type(Args),
rabbit_queue_type:is_server_named_allowed(Type).
-spec lookup
(name()) ->
rabbit_types:ok(amqqueue:amqqueue()) |
rabbit_types:error('not_found');
([name()]) ->
[amqqueue:amqqueue()].
lookup(Name) when is_record(Name, resource) ->
rabbit_db_queue:get(Name).
lookup_durable_queue(QName) ->
rabbit_db_queue:get_durable(QName).
-spec lookup_many ([name()]) -> [amqqueue:amqqueue()].
lookup_many([]) -> []; %% optimisation
lookup_many(Names) when is_list(Names) ->
rabbit_db_queue:get_many(Names).
-spec lookup(binary(), binary()) ->
rabbit_types:ok(amqqueue:amqqueue()) |
rabbit_types:error('not_found').
lookup(Name, VHost)
when is_binary(Name) andalso
is_binary(VHost) ->
QName = rabbit_misc:r(VHost, queue, Name),
lookup(QName).
-spec exists(name()) -> boolean().
exists(Name) ->
rabbit_db_queue:exists(Name).
-spec not_found_or_absent_dirty(name()) -> not_found_or_absent().
not_found_or_absent_dirty(Name) ->
%% We should read from both tables inside a tx, to get a
%% consistent view. But the chances of an inconsistency are small,
%% and only affect the error kind.
case rabbit_db_queue:get_durable(Name) of
{error, not_found} ->
not_found;
{ok, Q} ->
{absent, Q, nodedown}
end.
-spec get_rebalance_lock(pid()) ->
{true, {rebalance_queues, pid()}} | false.
get_rebalance_lock(Pid) when is_pid(Pid) ->
Id = {rebalance_queues, Pid},
Nodes = [node()|nodes()],
%% Note that we're not re-trying. We want to immediately know
%% if a re-balance is taking place and stop accordingly.
case global:set_lock(Id, Nodes, 0) of
true ->
{true, Id};
false ->
false
end.
-spec rebalance('all' | 'quorum' | 'classic', binary(), binary()) ->
{ok, [{node(), pos_integer()}]} | {error, term()}.
rebalance(Type, VhostSpec, QueueSpec) ->
%% We have not yet acquired the rebalance_queues global lock.
maybe_rebalance(get_rebalance_lock(self()), Type, VhostSpec, QueueSpec).
maybe_rebalance({true, Id}, Type, VhostSpec, QueueSpec) ->
rabbit_log:info("Starting queue rebalance operation: '~ts' for vhosts matching '~ts' and queues matching '~ts'",
[Type, VhostSpec, QueueSpec]),
Running = rabbit_maintenance:filter_out_drained_nodes_consistent_read(rabbit_nodes:all_running()),
NumRunning = length(Running),
ToRebalance = [Q || Q <- rabbit_amqqueue:list(),
filter_per_type(Type, Q),
is_replicated(Q),
is_match(amqqueue:get_vhost(Q), VhostSpec) andalso
is_match(get_resource_name(amqqueue:get_name(Q)), QueueSpec)],
NumToRebalance = length(ToRebalance),
ByNode = group_by_node(ToRebalance),
Rem = case (NumToRebalance rem NumRunning) of
0 -> 0;
_ -> 1
end,
MaxQueuesDesired = (NumToRebalance div NumRunning) + Rem,
Result = iterative_rebalance(ByNode, MaxQueuesDesired),
global:del_lock(Id),
rabbit_log:info("Finished queue rebalance operation"),
Result;
maybe_rebalance(false, _Type, _VhostSpec, _QueueSpec) ->
rabbit_log:warning("Queue rebalance operation is in progress, please wait."),
{error, rebalance_in_progress}.
%% Stream queues don't yet support rebalance
filter_per_type(all, Q) ->
?amqqueue_is_quorum(Q) or ?amqqueue_is_classic(Q) or ?amqqueue_is_stream(Q);
filter_per_type(quorum, Q) ->
?amqqueue_is_quorum(Q);
filter_per_type(stream, Q) ->
?amqqueue_is_stream(Q);
filter_per_type(classic, Q) ->
?amqqueue_is_classic(Q).
rebalance_module(Q) when ?amqqueue_is_quorum(Q) ->
rabbit_quorum_queue;
rebalance_module(Q) when ?amqqueue_is_stream(Q) ->
rabbit_stream_queue;
rebalance_module(Q) when ?amqqueue_is_classic(Q) ->
rabbit_mirror_queue_misc.
get_resource_name(#resource{name = Name}) ->
Name.
get_resource_vhost_name(#resource{virtual_host = VHostName}) ->
VHostName.
is_match(Subj, RegEx) ->
nomatch /= re:run(Subj, RegEx).
iterative_rebalance(ByNode, MaxQueuesDesired) ->
case maybe_migrate(ByNode, MaxQueuesDesired) of
{ok, Summary} ->
rabbit_log:info("All queue leaders are balanced"),
{ok, Summary};
{migrated, Other} ->
iterative_rebalance(Other, MaxQueuesDesired);
{not_migrated, Other} ->
iterative_rebalance(Other, MaxQueuesDesired)
end.
maybe_migrate(ByNode, MaxQueuesDesired) ->
maybe_migrate(ByNode, MaxQueuesDesired, maps:keys(ByNode)).
column_name(rabbit_classic_queue) -> <<"Number of replicated classic queues">>;
column_name(rabbit_quorum_queue) -> <<"Number of quorum queues">>;
column_name(rabbit_stream_queue) -> <<"Number of streams">>;
column_name(Other) -> Other.
maybe_migrate(ByNode, _, []) ->
ByNodeAndType = maps:map(fun(_Node, Queues) -> maps:groups_from_list(fun({_, Q, _}) -> column_name(?amqqueue_v2_field_type(Q)) end, Queues) end, ByNode),
CountByNodeAndType = maps:map(fun(_Node, Type) -> maps:map(fun (_, Qs)-> length(Qs) end, Type) end, ByNodeAndType),
{ok, maps:values(maps:map(fun(Node,Counts) -> [{<<"Node name">>, Node} | maps:to_list(Counts)] end, CountByNodeAndType))};
maybe_migrate(ByNode, MaxQueuesDesired, [N | Nodes]) ->
case maps:get(N, ByNode, []) of
[{_, Q, false} = Queue | Queues] = All when length(All) > MaxQueuesDesired ->
Name = amqqueue:get_name(Q),
Module = rebalance_module(Q),
Candidates = rabbit_maintenance:filter_out_drained_nodes_local_read(Module:get_replicas(Q) -- [N]),
case Candidates of
[] ->
{not_migrated, update_not_migrated_queue(N, Queue, Queues, ByNode)};
_ ->
[{Length, Destination} | _] = sort_by_number_of_queues(Candidates, ByNode),
rabbit_log:info("Migrating queue ~tp from node ~tp with ~tp queues to node ~tp with ~tp queues",
[Name, N, length(All), Destination, Length]),
case Module:transfer_leadership(Q, Destination) of
{migrated, NewNode} ->
rabbit_log:info("Queue ~tp migrated to ~tp", [Name, NewNode]),
{migrated, update_migrated_queue(NewNode, N, Queue, Queues, ByNode)};
{not_migrated, Reason} ->
rabbit_log:warning("Error migrating queue ~tp: ~tp", [Name, Reason]),
{not_migrated, update_not_migrated_queue(N, Queue, Queues, ByNode)}
end
end;
[{_, _, true} | _] = All when length(All) > MaxQueuesDesired ->
rabbit_log:warning("Node ~tp contains ~tp queues, but all have already migrated. "
"Do nothing", [N, length(All)]),
maybe_migrate(ByNode, MaxQueuesDesired, Nodes);
All ->
rabbit_log:debug("Node ~tp only contains ~tp queues, do nothing",
[N, length(All)]),
maybe_migrate(ByNode, MaxQueuesDesired, Nodes)
end.
update_not_migrated_queue(N, {Entries, Q, _}, Queues, ByNode) ->
maps:update(N, Queues ++ [{Entries, Q, true}], ByNode).
update_migrated_queue(NewNode, OldNode, {Entries, Q, _}, Queues, ByNode) ->
maps:update_with(NewNode,
fun(L) -> L ++ [{Entries, Q, true}] end,
[{Entries, Q, true}], maps:update(OldNode, Queues, ByNode)).
sort_by_number_of_queues(Nodes, ByNode) ->
lists:keysort(1,
lists:map(fun(Node) ->
{num_queues(Node, ByNode), Node}
end, Nodes)).
num_queues(Node, ByNode) ->
length(maps:get(Node, ByNode, [])).
group_by_node(Queues) ->
ByNode = lists:foldl(fun(Q, Acc) ->
Module = rebalance_module(Q),
Length = Module:queue_length(Q),
case amqqueue:qnode(Q) of
undefined -> Acc;
Node ->
maps:update_with(Node,
fun(L) -> [{Length, Q, false} | L] end,
[{Length, Q, false}], Acc)
end
end, #{}, Queues),
maps:map(fun(_K, V) -> lists:keysort(1, V) end, ByNode).
-spec with(name(),
qfun(A),
fun((not_found_or_absent()) -> rabbit_types:channel_exit())) ->
A | rabbit_types:channel_exit().
with(Name, F, E) ->
with(Name, F, E, 2000).
with(#resource{} = Name, F, E, RetriesLeft) ->
case lookup(Name) of
{ok, Q} when ?amqqueue_state_is(Q, live) andalso RetriesLeft =:= 0 ->
%% Something bad happened to that queue, we are bailing out
%% on processing current request.
E({absent, Q, timeout});
{ok, Q} when ?amqqueue_state_is(Q, stopped) andalso RetriesLeft =:= 0 ->
%% The queue was stopped and not migrated
E({absent, Q, stopped});
%% The queue process has crashed with unknown error
{ok, Q} when ?amqqueue_state_is(Q, crashed) ->
E({absent, Q, crashed});
%% The queue process has been stopped by a supervisor.
%% In that case a synchronised mirror can take over
%% so we should retry.
{ok, Q} when ?amqqueue_state_is(Q, stopped) ->
%% The queue process was stopped by the supervisor
rabbit_misc:with_exit_handler(
fun () -> retry_wait(Q, F, E, RetriesLeft) end,
fun () -> F(Q) end);
%% The queue is supposed to be active.
%% The leader node can go away or queue can be killed
%% so we retry, waiting for a mirror to take over.
{ok, Q} when ?amqqueue_state_is(Q, live) ->
%% We check is_process_alive(QPid) in case we receive a
%% nodedown (for example) in F() that has nothing to do
%% with the QPid. F() should be written s.t. that this
%% cannot happen, so we bail if it does since that
%% indicates a code bug and we don't want to get stuck in
%% the retry loop.
rabbit_misc:with_exit_handler(
fun () -> retry_wait(Q, F, E, RetriesLeft) end,
fun () -> F(Q) end);
{error, not_found} ->
E(not_found_or_absent_dirty(Name))
end.
-spec retry_wait(amqqueue:amqqueue(),
qfun(A),
fun((not_found_or_absent()) -> rabbit_types:channel_exit()),
non_neg_integer()) ->
A | rabbit_types:channel_exit().
retry_wait(Q, F, E, RetriesLeft) ->
Name = amqqueue:get_name(Q),
QPid = amqqueue:get_pid(Q),
QState = amqqueue:get_state(Q),
case {QState, is_replicated(Q)} of
%% We don't want to repeat an operation if
%% there are no mirrors to migrate to
{stopped, false} ->
E({absent, Q, stopped});
_ ->
case rabbit_mnesia:is_process_alive(QPid) of
true ->
% rabbitmq-server#1682
% The old check would have crashed here,
% instead, log it and run the exit fun. absent & alive is weird,
% but better than crashing with badmatch,true
rabbit_log:debug("Unexpected alive queue process ~tp", [QPid]),
E({absent, Q, alive});
false ->
ok % Expected result
end,
timer:sleep(30),
with(Name, F, E, RetriesLeft - 1)
end.
-spec with(name(), qfun(A)) ->
A | rabbit_types:error(not_found_or_absent()).
with(Name, F) -> with(Name, F, fun (E) -> {error, E} end).
-spec with_or_die(name(), qfun(A)) -> A | rabbit_types:channel_exit().
with_or_die(Name, F) ->
with(Name, F, die_fun(Name)).
-spec die_fun(name()) ->
fun((not_found_or_absent()) -> rabbit_types:channel_exit()).
die_fun(Name) ->
fun (not_found) -> not_found(Name);
({absent, Q, Reason}) -> absent(Q, Reason)
end.
-spec not_found(name()) -> rabbit_types:channel_exit().
not_found(R) -> rabbit_misc:protocol_error(not_found, "no ~ts", [rabbit_misc:rs(R)]).
-spec absent(amqqueue:amqqueue(), absent_reason()) ->
rabbit_types:channel_exit().
absent(Q, AbsentReason) ->
QueueName = amqqueue:get_name(Q),
QPid = amqqueue:get_pid(Q),
IsDurable = amqqueue:is_durable(Q),
priv_absent(QueueName, QPid, IsDurable, AbsentReason).
-spec priv_absent(name(), pid(), boolean(), absent_reason()) ->
rabbit_types:channel_exit().
priv_absent(QueueName, QPid, true, nodedown) ->
%% The assertion of durability is mainly there because we mention
%% durability in the error message. That way we will hopefully
%% notice if at some future point our logic changes s.t. we get
%% here with non-durable queues.
rabbit_misc:protocol_error(
not_found,
"home node '~ts' of durable ~ts is down or inaccessible",
[amqqueue:qnode(QPid), rabbit_misc:rs(QueueName)]);
priv_absent(QueueName, _QPid, _IsDurable, stopped) ->
rabbit_misc:protocol_error(
not_found,
"~ts process is stopped by supervisor", [rabbit_misc:rs(QueueName)]);
priv_absent(QueueName, _QPid, _IsDurable, crashed) ->
rabbit_misc:protocol_error(
not_found,
"~ts has crashed and failed to restart", [rabbit_misc:rs(QueueName)]);
priv_absent(QueueName, _QPid, _IsDurable, timeout) ->
rabbit_misc:protocol_error(
not_found,
"failed to perform operation on ~ts due to timeout", [rabbit_misc:rs(QueueName)]);
priv_absent(QueueName, QPid, _IsDurable, alive) ->
rabbit_misc:protocol_error(
not_found,
"failed to perform operation on ~ts: its leader ~w may be stopping or being demoted",
[rabbit_misc:rs(QueueName), QPid]).
-spec assert_equivalence
(amqqueue:amqqueue(), boolean(), boolean(),
rabbit_framing:amqp_table(), rabbit_types:maybe(pid())) ->
'ok' | rabbit_types:channel_exit() | rabbit_types:connection_exit().
assert_equivalence(Q, DurableDeclare, AutoDeleteDeclare, Args1, Owner) ->
QName = amqqueue:get_name(Q),
DurableQ = amqqueue:is_durable(Q),
AutoDeleteQ = amqqueue:is_auto_delete(Q),
ok = check_exclusive_access(Q, Owner, strict),
ok = rabbit_misc:assert_field_equivalence(DurableQ, DurableDeclare, QName, durable),
ok = rabbit_misc:assert_field_equivalence(AutoDeleteQ, AutoDeleteDeclare, QName, auto_delete),
ok = assert_args_equivalence(Q, Args1).
-spec augment_declare_args(vhost:name(), boolean(),
boolean(), boolean(),
rabbit_framing:amqp_table()) ->
rabbit_framing:amqp_table().
augment_declare_args(VHost, Durable, Exclusive, AutoDelete, Args0) ->
V = rabbit_vhost:lookup(VHost),
HasQTypeArg = rabbit_misc:table_lookup(Args0, <<"x-queue-type">>) =/= undefined,
case vhost:get_metadata(V) of
#{default_queue_type := DefaultQueueType}
when is_binary(DefaultQueueType) andalso
not HasQTypeArg ->
Type = rabbit_queue_type:discover(DefaultQueueType),
case rabbit_queue_type:is_compatible(Type, Durable,
Exclusive, AutoDelete) of
true ->
%% patch up declare arguments with x-queue-type if there
%% is a vhost default set the queue is druable and not exclusive
%% and there is no queue type argument
%% present
rabbit_misc:set_table_value(Args0,
<<"x-queue-type">>,
longstr,
DefaultQueueType);
false ->
Args0
end;
_ ->
Args0
end.
-spec check_exclusive_access(amqqueue:amqqueue(), pid()) ->
'ok' | rabbit_types:channel_exit().
check_exclusive_access(Q, Owner) -> check_exclusive_access(Q, Owner, lax).
check_exclusive_access(Q, Owner, _MatchType)
when ?amqqueue_exclusive_owner_is(Q, Owner) ->
ok;
check_exclusive_access(Q, _ReaderPid, lax)
when ?amqqueue_exclusive_owner_is(Q, none) ->
ok;
check_exclusive_access(Q, _ReaderPid, _MatchType) ->
QueueName = amqqueue:get_name(Q),
rabbit_misc:protocol_error(
resource_locked,
"cannot obtain exclusive access to locked ~ts. It could be originally "
"declared on another connection or the exclusive property value does not "
"match that of the original declaration.",
[rabbit_misc:rs(QueueName)]).
-spec with_exclusive_access_or_die(name(), pid(), qfun(A)) ->
A | rabbit_types:channel_exit().
with_exclusive_access_or_die(Name, ReaderPid, F) ->
with_or_die(Name,
fun (Q) -> check_exclusive_access(Q, ReaderPid), F(Q) end).
assert_args_equivalence(Q, NewArgs) ->
ExistingArgs = amqqueue:get_arguments(Q),
QueueName = amqqueue:get_name(Q),
Type = amqqueue:get_type(Q),
QueueTypeArgs = rabbit_queue_type:arguments(queue_arguments, Type),
rabbit_misc:assert_args_equivalence(ExistingArgs, NewArgs, QueueName, QueueTypeArgs).
check_declare_arguments(QueueName, Args) ->
check_arguments_type_and_value(QueueName, Args, [{<<"x-queue-type">>, fun check_queue_type/2}]),
Type = get_queue_type(Args),
QueueTypeArgs = rabbit_queue_type:arguments(queue_arguments, Type),
Validators = lists:filter(fun({Arg, _}) -> lists:member(Arg, QueueTypeArgs) end, declare_args()),
check_arguments_type_and_value(QueueName, Args, Validators),
InvalidArgs = rabbit_queue_type:arguments(queue_arguments) -- QueueTypeArgs,
check_arguments_key(QueueName, Type, Args, InvalidArgs).
check_consume_arguments(QueueName, QueueType, Args) ->
QueueTypeArgs = rabbit_queue_type:arguments(consumer_arguments, QueueType),
Validators = lists:filter(fun({Arg, _}) -> lists:member(Arg, QueueTypeArgs) end, consume_args()),
check_arguments_type_and_value(QueueName, Args, Validators),
InvalidArgs = rabbit_queue_type:arguments(consumer_arguments) -- QueueTypeArgs,
check_arguments_key(QueueName, QueueType, Args, InvalidArgs).
check_arguments_type_and_value(QueueName, Args, Validators) ->
[case rabbit_misc:table_lookup(Args, Key) of
undefined -> ok;
TypeVal -> case Fun(TypeVal, Args) of
ok -> ok;
{error, Error} -> rabbit_misc:protocol_error(
precondition_failed,
"invalid arg '~ts' for ~ts: ~255p",
[Key, rabbit_misc:rs(QueueName),
Error])
end
end || {Key, Fun} <- Validators],
ok.
check_arguments_key(QueueName, QueueType, Args, InvalidArgs) ->
lists:foreach(fun(Arg) ->
ArgKey = element(1, Arg),
case lists:member(ArgKey, InvalidArgs) of
false ->
ok;
true ->
rabbit_misc:protocol_error(
precondition_failed,
"invalid arg '~ts' for ~ts of queue type ~ts",
[ArgKey, rabbit_misc:rs(QueueName), QueueType])
end
end, Args).
declare_args() ->
[{<<"x-expires">>, fun check_expires_arg/2},
{<<"x-message-ttl">>, fun check_message_ttl_arg/2},
{<<"x-dead-letter-exchange">>, fun check_dlxname_arg/2},
{<<"x-dead-letter-routing-key">>, fun check_dlxrk_arg/2},
{<<"x-dead-letter-strategy">>, fun check_dlxstrategy_arg/2},
{<<"x-max-length">>, fun check_non_neg_int_arg/2},
{<<"x-max-length-bytes">>, fun check_non_neg_int_arg/2},
{<<"x-max-in-memory-length">>, fun check_non_neg_int_arg/2},
{<<"x-max-in-memory-bytes">>, fun check_non_neg_int_arg/2},
{<<"x-max-priority">>, fun check_max_priority_arg/2},
{<<"x-overflow">>, fun check_overflow/2},
{<<"x-queue-mode">>, fun check_queue_mode/2},
{<<"x-queue-version">>, fun check_queue_version/2},
{<<"x-single-active-consumer">>, fun check_single_active_consumer_arg/2},
{<<"x-queue-type">>, fun check_queue_type/2},
{<<"x-quorum-initial-group-size">>, fun check_initial_cluster_size_arg/2},
{<<"x-max-age">>, fun check_max_age_arg/2},
{<<"x-stream-max-segment-size-bytes">>, fun check_non_neg_int_arg/2},
{<<"x-initial-cluster-size">>, fun check_initial_cluster_size_arg/2},
{<<"x-queue-leader-locator">>, fun check_queue_leader_locator_arg/2}].
consume_args() -> [{<<"x-priority">>, fun check_int_arg/2},
{<<"x-cancel-on-ha-failover">>, fun check_bool_arg/2},
{<<"x-stream-offset">>, fun check_stream_offset_arg/2}].
check_int_arg({Type, _}, _) ->
case lists:member(Type, ?INTEGER_ARG_TYPES) of
true -> ok;
false -> {error, rabbit_misc:format("expected integer, got ~tp", [Type])}
end;
check_int_arg(Val, _) when is_integer(Val) ->
ok;
check_int_arg(_Val, _) ->
{error, {unacceptable_type, "expected integer"}}.
check_bool_arg({bool, _}, _) -> ok;
check_bool_arg({Type, _}, _) -> {error, {unacceptable_type, Type}};
check_bool_arg(true, _) -> ok;
check_bool_arg(false, _) -> ok;
check_bool_arg(_Val, _) -> {error, {unacceptable_type, "expected boolean"}}.
check_non_neg_int_arg({Type, Val}, Args) ->
case check_int_arg({Type, Val}, Args) of
ok when Val >= 0 -> ok;
ok -> {error, {value_negative, Val}};
Error -> Error
end;
check_non_neg_int_arg(Val, Args) ->
case check_int_arg(Val, Args) of
ok when Val >= 0 -> ok;
ok -> {error, {value_negative, Val}};
Error -> Error
end.
check_expires_arg({Type, Val}, Args) ->
case check_int_arg({Type, Val}, Args) of
ok when Val == 0 -> {error, {value_zero, Val}};
ok -> rabbit_misc:check_expiry(Val);
Error -> Error
end;
check_expires_arg(Val, Args) ->
case check_int_arg(Val, Args) of
ok when Val == 0 -> {error, {value_zero, Val}};
ok -> rabbit_misc:check_expiry(Val);
Error -> Error
end.
check_message_ttl_arg({Type, Val}, Args) ->
case check_int_arg({Type, Val}, Args) of
ok -> rabbit_misc:check_expiry(Val);
Error -> Error
end;
check_message_ttl_arg(Val, Args) ->
case check_int_arg(Val, Args) of
ok -> rabbit_misc:check_expiry(Val);
Error -> Error
end.
check_max_priority_arg({Type, Val}, Args) ->
case check_non_neg_int_arg({Type, Val}, Args) of
ok when Val =< ?MAX_SUPPORTED_PRIORITY -> ok;
ok -> {error, {max_value_exceeded, Val}};
Error -> Error
end;
check_max_priority_arg(Val, Args) ->
case check_non_neg_int_arg(Val, Args) of
ok when Val =< ?MAX_SUPPORTED_PRIORITY -> ok;
ok -> {error, {max_value_exceeded, Val}};
Error -> Error
end.
check_single_active_consumer_arg({Type, Val}, Args) ->
check_bool_arg({Type, Val}, Args);
check_single_active_consumer_arg(Val, Args) ->
check_bool_arg(Val, Args).
check_initial_cluster_size_arg({Type, Val}, Args) ->
case check_non_neg_int_arg({Type, Val}, Args) of
ok when Val == 0 -> {error, {value_zero, Val}};
ok -> ok;
Error -> Error
end;
check_initial_cluster_size_arg(Val, Args) ->
case check_non_neg_int_arg(Val, Args) of
ok when Val == 0 -> {error, {value_zero, Val}};
ok -> ok;
Error -> Error
end.
check_max_age_arg({longstr, Val}, _Args) ->
case check_max_age(Val) of
{error, _} = E ->
E;
_ ->
ok
end;
check_max_age_arg({Type, _}, _Args) ->
{error, {unacceptable_type, Type}}.
check_max_age(MaxAge) ->
case re:run(MaxAge, "(^[0-9]*)(.*)", [{capture, all_but_first, list}]) of
{match, [Value, Unit]} ->
case list_to_integer(Value) of
I when I > 0 ->
case lists:member(Unit, ["Y", "M", "D", "h", "m", "s"]) of
true ->
Int = list_to_integer(Value),
Int * unit_value_in_ms(Unit);
false ->
{error, invalid_max_age}
end;
_ ->
{error, invalid_max_age}
end;
_ ->
{error, invalid_max_age}
end.
unit_value_in_ms("Y") ->
365 * unit_value_in_ms("D");
unit_value_in_ms("M") ->
30 * unit_value_in_ms("D");
unit_value_in_ms("D") ->
24 * unit_value_in_ms("h");
unit_value_in_ms("h") ->
3600 * unit_value_in_ms("s");
unit_value_in_ms("m") ->
60 * unit_value_in_ms("s");
unit_value_in_ms("s") ->
1000.
%% Note that the validity of x-dead-letter-exchange is already verified
%% by rabbit_channel's queue.declare handler.
check_dlxname_arg({longstr, _}, _) -> ok;
check_dlxname_arg({Type, _}, _) -> {error, {unacceptable_type, Type}};
check_dlxname_arg(Val, _) when is_list(Val) or is_binary(Val) -> ok;
check_dlxname_arg(_Val, _) -> {error, {unacceptable_type, "expected a string (valid exchange name)"}}.
check_dlxrk_arg({longstr, _}, Args) ->
case rabbit_misc:table_lookup(Args, <<"x-dead-letter-exchange">>) of
undefined -> {error, routing_key_but_no_dlx_defined};
_ -> ok
end;
check_dlxrk_arg({Type, _}, _Args) ->
{error, {unacceptable_type, Type}};
check_dlxrk_arg(Val, Args) when is_binary(Val) ->
case rabbit_misc:table_lookup(Args, <<"x-dead-letter-exchange">>) of
undefined -> {error, routing_key_but_no_dlx_defined};
_ -> ok
end;
check_dlxrk_arg(_Val, _Args) ->
{error, {unacceptable_type, "expected a string"}}.
-define(KNOWN_DLX_STRATEGIES, [<<"at-most-once">>, <<"at-least-once">>]).
check_dlxstrategy_arg({longstr, Val}, _Args) ->
case lists:member(Val, ?KNOWN_DLX_STRATEGIES) of
true -> ok;
false -> {error, invalid_dlx_strategy}
end;
check_dlxstrategy_arg({Type, _}, _Args) ->
{error, {unacceptable_type, Type}};
check_dlxstrategy_arg(Val, _Args) when is_binary(Val) ->
case lists:member(Val, ?KNOWN_DLX_STRATEGIES) of
true -> ok;
false -> {error, invalid_dlx_strategy}
end;
check_dlxstrategy_arg(_Val, _Args) ->
{error, invalid_dlx_strategy}.
-define(KNOWN_OVERFLOW_MODES, [<<"drop-head">>, <<"reject-publish">>, <<"reject-publish-dlx">>]).
check_overflow({longstr, Val}, _Args) ->
case lists:member(Val, ?KNOWN_OVERFLOW_MODES) of
true -> ok;
false -> {error, invalid_overflow}
end;
check_overflow({Type, _}, _Args) ->
{error, {unacceptable_type, Type}};
check_overflow(Val, _Args) when is_binary(Val) ->
case lists:member(Val, ?KNOWN_OVERFLOW_MODES) of
true -> ok;
false -> {error, invalid_overflow}
end;
check_overflow(_Val, _Args) ->
{error, invalid_overflow}.
check_queue_leader_locator_arg({longstr, Val}, _Args) ->
case lists:member(Val, rabbit_queue_location:queue_leader_locators()) of
true -> ok;
false -> {error, invalid_queue_locator_arg}
end;
check_queue_leader_locator_arg({Type, _}, _Args) ->
{error, {unacceptable_type, Type}};
check_queue_leader_locator_arg(Val, _Args) when is_binary(Val) ->
case lists:member(Val, rabbit_queue_location:queue_leader_locators()) of
true -> ok;
false -> {error, invalid_queue_locator_arg}
end;
check_queue_leader_locator_arg(_Val, _Args) ->
{error, invalid_queue_locator_arg}.
check_stream_offset_arg(Val, _Args) ->