-
Notifications
You must be signed in to change notification settings - Fork 6
/
handler.gleam
194 lines (185 loc) · 5.62 KB
/
handler.gleam
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
import gleam/dynamic
import gleam/erlang/atom
import gleam/erlang/process.{type Selector, type Subject}
import gleam/function
import gleam/option.{type Option, Some}
import gleam/otp/actor
import gleam/result
import gleam/string
import glisten/socket.{type Socket}
import glisten/socket/transport.{type Transport}
import glisten/socket/options
/// All message types that the handler will receive, or that you can
/// send to the handler process
pub type InternalMessage {
Close
Ready
ReceiveMessage(BitArray)
SslClosed
TcpClosed
}
pub type Message(user_message) {
Internal(InternalMessage)
User(user_message)
}
pub type LoopMessage(user_message) {
Packet(BitArray)
Custom(user_message)
}
pub type ClientIp =
Result(#(#(Int, Int, Int, Int), Int), Nil)
pub type LoopState(user_message, data) {
LoopState(
client_ip: ClientIp,
socket: Socket,
sender: Subject(Message(user_message)),
transport: Transport,
data: data,
)
}
pub type Connection(user_message) {
Connection(
client_ip: ClientIp,
socket: Socket,
transport: Transport,
sender: Subject(Message(user_message)),
)
}
pub type Loop(user_message, data) =
fn(LoopMessage(user_message), data, Connection(user_message)) ->
actor.Next(LoopMessage(user_message), data)
pub type Handler(user_message, data) {
Handler(
socket: Socket,
loop: Loop(user_message, data),
on_init: fn() -> #(data, Option(Selector(user_message))),
on_close: Option(fn(data) -> Nil),
transport: Transport,
)
}
/// Starts an actor for the TCP connection
pub fn start(
handler: Handler(user_message, data),
) -> Result(Subject(Message(user_message)), actor.StartError) {
actor.start_spec(
actor.Spec(
init: fn() {
let subject = process.new_subject()
let #(initial_state, user_selector) = handler.on_init()
let selector =
process.new_selector()
|> process.selecting_record3(atom.create_from_string("tcp"), fn(
_sock,
data,
) {
data
|> dynamic.bit_array
|> result.unwrap(<<>>)
|> ReceiveMessage
})
|> process.selecting_record3(atom.create_from_string("ssl"), fn(
_sock,
data,
) {
data
|> dynamic.bit_array
|> result.unwrap(<<>>)
|> ReceiveMessage
})
|> process.selecting_record2(atom.create_from_string("ssl_closed"), fn(
_nil,
) {
SslClosed
})
|> process.selecting_record2(atom.create_from_string("tcp_closed"), fn(
_nil,
) {
TcpClosed
})
|> process.map_selector(Internal)
|> process.selecting(subject, function.identity)
let selector = case user_selector {
Some(sel) ->
sel
|> process.map_selector(User)
|> process.merge_selector(selector, _)
_ -> selector
}
actor.Ready(
LoopState(
client_ip: handler.transport.peername(handler.socket),
socket: handler.socket,
sender: subject,
transport: handler.transport,
data: initial_state,
),
selector,
)
},
init_timeout: 1000,
loop: fn(msg, state) {
let connection =
Connection(
socket: state.socket,
client_ip: state.client_ip,
transport: state.transport,
sender: state.sender,
)
case msg {
Internal(TcpClosed) | Internal(SslClosed) | Internal(Close) ->
case state.transport.close(state.socket) {
Ok(Nil) -> {
let _ = case handler.on_close {
Some(on_close) -> on_close(state.data)
_ -> Nil
}
actor.Stop(process.Normal)
}
Error(err) -> actor.Stop(process.Abnormal(string.inspect(err)))
}
Internal(Ready) ->
state.socket
|> state.transport.handshake
|> result.replace_error("Failed to handshake socket")
|> result.then(fn(_ok) {
state.transport.set_opts(state.socket, [
options.ActiveMode(options.Once),
])
|> result.replace_error("Failed to set socket active")
})
|> result.replace(actor.continue(state))
|> result.map_error(fn(reason) {
actor.Stop(process.Abnormal(reason))
})
|> result.unwrap_both
User(msg) -> {
let msg = Custom(msg)
case handler.loop(msg, state.data, connection) {
actor.Continue(next_state, _selector) -> {
let assert Ok(Nil) =
state.transport.set_opts(state.socket, [
options.ActiveMode(options.Once),
])
actor.continue(LoopState(..state, data: next_state))
}
actor.Stop(reason) -> actor.Stop(reason)
}
}
Internal(ReceiveMessage(msg)) -> {
let msg = Packet(msg)
case handler.loop(msg, state.data, connection) {
actor.Continue(next_state, _selector) -> {
let assert Ok(Nil) =
state.transport.set_opts(state.socket, [
options.ActiveMode(options.Once),
])
actor.continue(LoopState(..state, data: next_state))
}
actor.Stop(reason) -> actor.Stop(reason)
}
}
}
},
),
)
}