-
Notifications
You must be signed in to change notification settings - Fork 20
/
main.tf
179 lines (161 loc) · 5.27 KB
/
main.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
resource "null_resource" "wait_for_master_ssh" {
for_each = var.master_nodes
triggers = {
node_instance_id = each.value.id
}
connection {
host = each.value.floating_ip
user = var.system_user
private_key = var.use_ssh_agent ? null : file(var.ssh_key_file)
agent = var.use_ssh_agent
}
provisioner "remote-exec" {
inline = var.wait_for_commands
}
}
resource "null_resource" "wait_for_edge_ssh" {
for_each = var.edge_nodes
triggers = {
node_instance_id = each.value.id
}
connection {
host = each.value.floating_ip
user = var.system_user
private_key = var.use_ssh_agent ? null : file(var.ssh_key_file)
agent = var.use_ssh_agent
}
provisioner "remote-exec" {
inline = var.wait_for_commands
}
}
resource "null_resource" "wait_for_worker_ssh" {
for_each = var.worker_nodes
triggers = {
node_instance_id = each.value.id
}
connection {
bastion_host = var.bastion_host
host = each.value.internal_ip
user = var.system_user
private_key = var.use_ssh_agent ? null : file(var.ssh_key_file)
agent = var.use_ssh_agent
}
provisioner "remote-exec" {
inline = var.wait_for_commands
}
}
data "openstack_identity_auth_scope_v3" "scope" {
name = "auth_scope"
}
data "openstack_networking_network_v2" "floating_net" {
name = var.floating_network
}
resource "rke_cluster" "cluster" {
depends_on = [var.rke_depends_on, null_resource.wait_for_master_ssh,
null_resource.wait_for_edge_ssh, null_resource.wait_for_worker_ssh]
cluster_name = var.cluster_name
dynamic nodes {
for_each = var.master_nodes
content {
address = nodes.value.floating_ip != "" ? nodes.value.floating_ip : nodes.value.internal_ip
internal_address = nodes.value.internal_ip
hostname_override = nodes.key
user = var.system_user
role = ["controlplane", "etcd"]
labels = var.master_labels
dynamic taints {
for_each = var.master_taints
content {
key = lookup(taints.value, "key")
value = lookup(taints.value, "value")
effect = lookup(taints.value, "effect", "NoSchedule")
}
}
}
}
dynamic nodes {
for_each = var.edge_nodes
content {
address = nodes.value.floating_ip != "" ? nodes.value.floating_ip : nodes.value.internal_ip
internal_address = nodes.value.internal_ip
hostname_override = nodes.key
user = var.system_user
role = ["worker"]
labels = var.edge_labels
dynamic taints {
for_each = var.edge_taints
content {
key = lookup(taints.value, "key")
value = lookup(taints.value, "value")
effect = lookup(taints.value, "effect", "NoSchedule")
}
}
}
}
dynamic nodes {
for_each = var.worker_nodes
content {
address = nodes.value.floating_ip != "" ? nodes.value.floating_ip : nodes.value.internal_ip
internal_address = nodes.value.internal_ip
hostname_override = nodes.key
user = var.system_user
role = ["worker"]
labels = var.worker_labels
dynamic taints {
for_each = var.worker_taints
content {
key = lookup(taints.value, "key")
value = lookup(taints.value, "value")
effect = lookup(taints.value, "effect", "NoSchedule")
}
}
}
}
bastion_host {
address = var.bastion_host
user = var.system_user
}
ssh_agent_auth = var.use_ssh_agent
ssh_key_path = var.ssh_key_file
kubernetes_version = var.k8s_version
network {
mtu = var.mtu
}
ingress {
provider = var.deploy_nginx ? "nginx" : "none"
node_selector = { "node-role.kubernetes.io/edge" = "true" }
}
dynamic cloud_provider {
for_each = var.cloud_provider ? [1] : []
content {
name = "openstack"
openstack_cloud_provider {
global {
username = data.openstack_identity_auth_scope_v3.scope.user_name
password = var.os_password
auth_url = var.os_auth_url
tenant_id = data.openstack_identity_auth_scope_v3.scope.project_id
domain_id = data.openstack_identity_auth_scope_v3.scope.project_domain_id
}
block_storage {
ignore_volume_az = var.ignore_volume_az
}
load_balancer {
floating_network_id = data.openstack_networking_network_v2.floating_net.id
use_octavia = var.use_octavia
}
}
}
}
addons = join("---\n", [templatefile("${path.module}/addons/cinder.yml.tmpl",
{ deploy = var.cloud_provider, types = var.storage_types, default_storage = var.default_storage }),
templatefile("${path.module}/addons/traefik2.yml.tmpl",
{ deploy = var.deploy_traefik, acme_email = var.acme_email, image_tag = var.traefik_image_tag })])
addons_include = var.addons_include != null ? [for addon in var.addons_include : addon] : null
}
resource "local_file" "kube_cluster_yaml" {
count = var.write_kubeconfig ? 1 : 0
filename = "${path.root}/kube_config_cluster.yml"
file_permission = "0600"
sensitive_content = rke_cluster.cluster.kube_config_yaml
}