-
Notifications
You must be signed in to change notification settings - Fork 0
/
main.tf
383 lines (355 loc) · 11.3 KB
/
main.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
# see https://github.com/hashicorp/terraform
terraform {
required_version = "1.0.4"
required_providers {
# see https://registry.terraform.io/providers/hashicorp/random
random = {
source = "hashicorp/random"
version = "3.1.0"
}
# see https://registry.terraform.io/providers/hashicorp/template
template = {
source = "hashicorp/template"
version = "2.2.0"
}
# see https://registry.terraform.io/providers/hashicorp/vsphere
# see https://github.com/hashicorp/terraform-provider-vsphere
vsphere = {
source = "hashicorp/vsphere"
version = "2.0.2"
}
# see https://registry.terraform.io/providers/rancher/rke
# see https://github.com/rancher/terraform-provider-rke
rke = {
source = "rancher/rke"
version = "1.2.3"
}
}
}
variable "vsphere_user" {
default = "administrator@vsphere.local"
}
variable "vsphere_password" {
default = "password"
sensitive = true
}
variable "vsphere_server" {
default = "vsphere.local"
}
variable "vsphere_datacenter" {
default = "Datacenter"
}
variable "vsphere_compute_cluster" {
default = "Cluster"
}
variable "vsphere_network" {
default = "VM Network"
}
variable "vsphere_datastore" {
default = "Datastore"
}
variable "vsphere_ubuntu_template" {
default = "vagrant-templates/ubuntu-20.04-amd64-vsphere"
}
variable "vsphere_folder" {
default = "rke_example"
}
variable "prefix" {
default = "rke_example"
}
variable "kubernetes_version" {
default = "v1.20.8-rancher1-1"
}
variable "controller_count" {
type = number
default = 1
validation {
condition = var.controller_count >= 1
error_message = "Must be 1 or more."
}
}
variable "worker_count" {
type = number
default = 1
validation {
condition = var.worker_count >= 1
error_message = "Must be 1 or more."
}
}
provider "vsphere" {
user = var.vsphere_user
password = var.vsphere_password
vsphere_server = var.vsphere_server
allow_unverified_ssl = true
}
provider "rke" {
log_file = "rke.log"
}
data "vsphere_datacenter" "datacenter" {
name = var.vsphere_datacenter
}
data "vsphere_compute_cluster" "compute_cluster" {
name = var.vsphere_compute_cluster
datacenter_id = data.vsphere_datacenter.datacenter.id
}
data "vsphere_datastore" "datastore" {
name = var.vsphere_datastore
datacenter_id = data.vsphere_datacenter.datacenter.id
}
data "vsphere_network" "network" {
name = var.vsphere_network
datacenter_id = data.vsphere_datacenter.datacenter.id
}
data "vsphere_virtual_machine" "ubuntu_template" {
name = var.vsphere_ubuntu_template
datacenter_id = data.vsphere_datacenter.datacenter.id
}
# a cloud-init for the controller nodes.
# see journactl -u cloud-init
# see /run/cloud-init/*.log
# see less /usr/share/doc/cloud-init/examples/cloud-config.txt.gz
# see https://www.terraform.io/docs/providers/template/d/cloudinit_config.html
# see https://www.terraform.io/docs/configuration/expressions.html#string-literals
data "template_cloudinit_config" "controller" {
count = var.controller_count
gzip = true
base64_encode = true
part {
content_type = "text/cloud-config"
content = <<-EOF
#cloud-config
hostname: c${count.index}
users:
- name: vagrant
passwd: '$6$rounds=4096$NQ.EmIrGxn$rTvGsI3WIsix9TjWaDfKrt9tm3aa7SX7pzB.PSjbwtLbsplk1HsVzIrZbXwQNce6wmeJXhCq9YFJHDx9bXFHH.'
lock_passwd: false
ssh-authorized-keys:
- ${file("~/.ssh/id_rsa.pub")}
runcmd:
- sed -i '/vagrant insecure public key/d' /home/vagrant/.ssh/authorized_keys
# make sure the vagrant account is not expired.
# NB this is needed when the base image expires the vagrant account.
- usermod --expiredate '' vagrant
EOF
}
}
# a cloud-init for the worker nodes.
data "template_cloudinit_config" "worker" {
count = var.worker_count
gzip = true
base64_encode = true
part {
content_type = "text/cloud-config"
content = <<-EOF
#cloud-config
hostname: w${count.index}
users:
- name: vagrant
passwd: '$6$rounds=4096$NQ.EmIrGxn$rTvGsI3WIsix9TjWaDfKrt9tm3aa7SX7pzB.PSjbwtLbsplk1HsVzIrZbXwQNce6wmeJXhCq9YFJHDx9bXFHH.'
lock_passwd: false
ssh-authorized-keys:
- ${file("~/.ssh/id_rsa.pub")}
runcmd:
- sed -i '/vagrant insecure public key/d' /home/vagrant/.ssh/authorized_keys
# make sure the vagrant account is not expired.
# NB this is needed when the base image expires the vagrant account.
- usermod --expiredate '' vagrant
EOF
}
}
resource "vsphere_folder" "folder" {
path = var.vsphere_folder
type = "vm"
datacenter_id = data.vsphere_datacenter.datacenter.id
}
# see https://www.terraform.io/docs/providers/vsphere/r/virtual_machine.html
resource "vsphere_virtual_machine" "controller" {
count = var.controller_count
folder = vsphere_folder.folder.path
name = "${var.prefix}_c${count.index}"
guest_id = data.vsphere_virtual_machine.ubuntu_template.guest_id
num_cpus = 4
num_cores_per_socket = 4
memory = 4*1024
enable_disk_uuid = true # NB the VM must have disk.EnableUUID=1 for the k8s persistent storage.
resource_pool_id = data.vsphere_compute_cluster.compute_cluster.resource_pool_id
datastore_id = data.vsphere_datastore.datastore.id
scsi_type = data.vsphere_virtual_machine.ubuntu_template.scsi_type
disk {
unit_number = 0
label = "os"
size = max(data.vsphere_virtual_machine.ubuntu_template.disks.0.size, 15) # 15 GB minimum.
eagerly_scrub = data.vsphere_virtual_machine.ubuntu_template.disks.0.eagerly_scrub
thin_provisioned = data.vsphere_virtual_machine.ubuntu_template.disks.0.thin_provisioned
}
network_interface {
network_id = data.vsphere_network.network.id
adapter_type = data.vsphere_virtual_machine.ubuntu_template.network_interface_types.0
}
clone {
template_uuid = data.vsphere_virtual_machine.ubuntu_template.id
}
# NB this extra_config data ends-up inside the VM .vmx file and will be
# exposed by cloud-init-vmware-guestinfo as a cloud-init datasource.
extra_config = {
"guestinfo.userdata" = data.template_cloudinit_config.controller[count.index].rendered
"guestinfo.userdata.encoding" = "gzip+base64"
}
connection {
type = "ssh"
user = "vagrant"
host = self.default_ip_address
private_key = file("~/.ssh/id_rsa")
}
provisioner "file" {
source = "containerd-config.toml.patch"
destination = "/tmp/containerd-config.toml.patch"
}
provisioner "file" {
source = "provision.sh"
destination = "/tmp/provision.sh"
}
# NB in a non-test environment, all the dependencies should already be in
# the base image and we would not needed to ad-hoc provision anything
# here.
provisioner "remote-exec" {
inline = [
"sudo bash /tmp/provision.sh"
]
}
lifecycle {
ignore_changes = [
# ignore changes to the disks because these will be modified by the
# vSphere Cloud Provider driver while attaching Persistent Volume
# Hard Disks.
# see https://github.com/hashicorp/terraform-provider-vsphere/issues/1028
disk,
]
}
}
# see https://www.terraform.io/docs/providers/vsphere/r/virtual_machine.html
resource "vsphere_virtual_machine" "worker" {
count = var.worker_count
folder = vsphere_folder.folder.path
name = "${var.prefix}_w${count.index}"
guest_id = data.vsphere_virtual_machine.ubuntu_template.guest_id
num_cpus = 4
num_cores_per_socket = 4
memory = 8*1024
enable_disk_uuid = true # NB the VM must have disk.EnableUUID=1 for the k8s persistent storage.
resource_pool_id = data.vsphere_compute_cluster.compute_cluster.resource_pool_id
datastore_id = data.vsphere_datastore.datastore.id
scsi_type = data.vsphere_virtual_machine.ubuntu_template.scsi_type
disk {
unit_number = 0
label = "os"
size = max(data.vsphere_virtual_machine.ubuntu_template.disks.0.size, 15) # 15 GB minimum.
eagerly_scrub = data.vsphere_virtual_machine.ubuntu_template.disks.0.eagerly_scrub
thin_provisioned = data.vsphere_virtual_machine.ubuntu_template.disks.0.thin_provisioned
}
network_interface {
network_id = data.vsphere_network.network.id
adapter_type = data.vsphere_virtual_machine.ubuntu_template.network_interface_types.0
}
clone {
template_uuid = data.vsphere_virtual_machine.ubuntu_template.id
}
# NB this extra_config data ends-up inside the VM .vmx file and will be
# exposed by cloud-init-vmware-guestinfo as a cloud-init datasource.
extra_config = {
"guestinfo.userdata" = data.template_cloudinit_config.worker[count.index].rendered
"guestinfo.userdata.encoding" = "gzip+base64"
}
connection {
type = "ssh"
user = "vagrant"
host = self.default_ip_address
private_key = file("~/.ssh/id_rsa")
}
provisioner "file" {
source = "containerd-config.toml.patch"
destination = "/tmp/containerd-config.toml.patch"
}
provisioner "file" {
source = "provision.sh"
destination = "/tmp/provision.sh"
}
# NB in a non-test environment, all the dependencies should already be in
# the base image and we would not needed to ad-hoc provision anything
# here.
provisioner "remote-exec" {
inline = [
"sudo bash /tmp/provision.sh"
]
}
lifecycle {
ignore_changes = [
# ignore changes to the disks because these will be modified by the
# vSphere Cloud Provider driver while attaching Persistent Volume
# Hard Disks.
# see https://github.com/hashicorp/terraform-provider-vsphere/issues/1028
disk,
]
}
}
resource "rke_cluster" "example" {
kubernetes_version = var.kubernetes_version
dynamic "nodes" {
for_each = vsphere_virtual_machine.controller
iterator = it
content {
address = it.value.default_ip_address
user = "vagrant"
role = ["controlplane", "etcd"]
ssh_key = file("~/.ssh/id_rsa")
}
}
dynamic "nodes" {
for_each = vsphere_virtual_machine.worker
iterator = it
content {
address = it.value.default_ip_address
user = "vagrant"
role = ["worker"]
ssh_key = file("~/.ssh/id_rsa")
}
}
upgrade_strategy {
drain = true
max_unavailable_worker = "20%"
}
# see https://rancher.com/docs/rke/latest/en/config-options/cloud-providers/vsphere/
# see https://rancher.com/docs/rke/latest/en/config-options/cloud-providers/vsphere/config-reference/
# see https://rancher.com/docs/rancher/v2.5/en/cluster-admin/volumes-and-storage/examples/vsphere/
cloud_provider {
name = "vsphere"
vsphere_cloud_provider {
global {
insecure_flag = true
}
virtual_center {
name = var.vsphere_server
user = var.vsphere_user
password = var.vsphere_password
datacenters = var.vsphere_datacenter
}
workspace {
server = var.vsphere_server
datacenter = var.vsphere_datacenter
folder = "${vsphere_folder.folder.type}/${vsphere_folder.folder.path}"
# NB vSphere will create a folder named "kubevols" inside this
# datastore. the actual k8s volumes .vmdk will be stored as, e.g.,
# kubernetes-dynamic-pvc-5ed4b014-7db0-425e-97d4-8ff8dd0cd0e1.vmdk.
default_datastore = var.vsphere_datastore
}
}
}
}
output "rke_state" {
sensitive = true
value = rke_cluster.example.rke_state
}
output "kubeconfig" {
sensitive = true
value = rke_cluster.example.kube_config_yaml
}