-
Notifications
You must be signed in to change notification settings - Fork 0
/
sql_ex_pieces_providers.clj
201 lines (183 loc) · 6.93 KB
/
sql_ex_pieces_providers.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
(ns seaquell.sql-ex-pieces-providers
"Uses an in-memory Sqlite database to do the SQL exercises at
https://en.wikibooks.org/wiki/SQL_Exercises/Pieces_and_providers"
(:refer-clojure
:exclude [alter distinct drop group-by into set update partition-by when])
(:require [clojure.java.jdbc :as jdb]
[diesel.core :refer [mk-map*]]
[midje.sweet :refer :all :exclude [after before]]
[seaquell.core :refer :all]
[seaquell.engine :refer :all]
[seaquell.sqlite :refer [db-spec]]))
(defn properties [& body]
(mk-map* {} body))
(defn create-tbls [con]
(do-sql
"CREATE TABLE Pieces (
Code INTEGER PRIMARY KEY NOT NULL,
Name TEXT NOT NULL
);"
(db con))
(do-sql
"CREATE TABLE Providers (
Code TEXT PRIMARY KEY NOT NULL,
Name TEXT NOT NULL
);"
(db con))
(do-sql
"CREATE TABLE Provides (
Piece INTEGER
CONSTRAINT fk_Pieces_Code REFERENCES Pieces(Code),
Provider TEXT
CONSTRAINT fk_Providers_Code REFERENCES Providers(Code),
Price INTEGER NOT NULL,
PRIMARY KEY(Piece, Provider)
);"
(db con)))
(defn insert-data [con]
(let [providers (insert :Providers (columns :Code :Name) (db con))
pieces (insert :Pieces (columns :Code :Name) (db con))
provides (insert :Provides (columns :Piece :Provider :Price) (db con))]
(insert! providers (value "HAL" "Clarke Enterprises"))
(insert! providers (value "RBT" "Susan Calvin Corp."))
(insert! providers (value "TNBC" "Skellington Supplies"))
(insert! pieces (values [1 "Sprocket"] [2 "Screw"] [3 "Nut"] [4 "Bolt"]))
(insert! provides
(values [1 "HAL" 10] [1 "RBT" 15] [2 "HAL" 20]
[2 "RBT" 15] [2 "TNBC" 14] [3 "RBT" 50]
[3 "TNBC" 45] [4 "HAL" 5] [4 "RBT" 7]))))
(defn mk-db []
(let [c (db-conn (db-spec))]
(create-tbls c)
(insert-data c)
c))
(defn kw [x] (keyword x))
(let [c (mk-db)]
(fact
"Select the name of all the pieces"
(select! :name (from :pieces) (db c))
=> [{:name "Sprocket"} {:name "Screw"}
{:name "Nut"} {:name "Bolt"}])
(fact
"Select all the providers' data"
(select! :* (from :providers) (db c))
=> [{:code "HAL" :name "Clarke Enterprises"}
{:code "RBT" :name "Susan Calvin Corp."}
{:code "TNBC" :name "Skellington Supplies"}])
(fact
"Obtain the average price of each piece
(show only the piece code and the average price)."
(select! [:piece [:avg :price]] (from :provides) (group-by :piece) (db c))
=> [{(kw "avg(price)") 12.5 :piece 1}
{(kw "avg(price)") 16.333333333333332 :piece 2}
{(kw "avg(price)") 47.5 :piece 3}
{(kw "avg(price)") 6.0 :piece 4}])
(fact
"Obtain the names of all providers who supply piece 1."
;; using INNER JOIN
(select!
:providers.name
(db c)
(from :providers
(inner-join :provides (on {:providers.code :provides.provider
:provides.piece 1}))))
=> [{:name "Clarke Enterprises"} {:name "Susan Calvin Corp."}]
;; using IN predicate
(select!
:name
(db c)
(from :providers)
(where {:code [:in (select :provider
(from :provides)
(where [= :piece 1]))]}))
=> [{:name "Clarke Enterprises"} {:name "Susan Calvin Corp."}])
(fact
"Select the name of pieces provided by provider with code 'HAL'."
;; using INNER JOIN
(select!
:pieces.name
(db c)
(from :pieces
(inner-join :provides (on {:pieces.code :provides.piece
:provides.provider "HAL"}))))
=> [{:name "Sprocket"} {:name "Screw"} {:name "Bolt"}]
;; using IN predicate
(select!
:name
(db c)
(from :pieces)
(where [:in :code (select :piece
(from :provides)
(where {:provider "HAL"}))]))
=> [{:name "Sprocket"} {:name "Screw"} {:name "Bolt"}]
;; using EXISTS predicate
(select!
:name
(db c)
(from :pieces)
(where [:exists (select-from
:provides
(where {:provider "HAL"
:piece :pieces.code}))]))
=> [{:name "Sprocket"} {:name "Screw"} {:name "Bolt"}])
(fact
"For each piece, find the most expensive offering of that piece and
include the piece name, provider name, and price (note that there could
be two providers who supply the same piece at the most expensive price)."
(select!
[:pieces.name (as :piece) :providers.name :as :provider :price]
(db c)
(from
:pieces
(inner-join :provides (on {:pieces.code :piece}))
(inner-join :providers (on {:providers.code :provider})))
(where {:price (select [[max :price]]
(from :provides)
(where {:piece :pieces.code}))}))
=> [{:piece "Sprocket" :price 15 :provider "Susan Calvin Corp."}
{:piece "Screw" :price 20 :provider "Clarke Enterprises"}
{:piece "Nut" :price 50 :provider "Susan Calvin Corp."}
{:piece "Bolt" :price 7 :provider "Susan Calvin Corp."}]))
(let [c (mk-db)]
(fact
"Add an entry to the database to indicate that 'Skellington Supplies'
(code 'TNBC') will provide sprockets (code '1') for 7 cents each."
(insert! :provides (value 1 "TNBC" 7) (db c))
=> [1]
;; Confirm new record, notice use of row-fn, result-set-fn
(select! :provider (from :provides) (where {:piece 1 :price 7})
(db c) (row-fn :provider) (result-set-fn first))
=> "TNBC"))
(let [c (mk-db)]
"Increase all prices by one cent."
(fact
(update! :provides (set {:price [+ :price 1]}) (db c))
=> [9]
;; Confirm raise in price
(select-from! :provides (db c))
=> [{:piece 1 :price 11 :provider "HAL"}
{:piece 1 :price 16 :provider "RBT"}
{:piece 2 :price 21 :provider "HAL"}
{:piece 2 :price 16 :provider "RBT"}
{:piece 2 :price 15 :provider "TNBC"}
{:piece 3 :price 51 :provider "RBT"}
{:piece 3 :price 46 :provider "TNBC"}
{:piece 4 :price 6 :provider "HAL"}
{:piece 4 :price 8 :provider "RBT"}]))
(let [c (mk-db)
w-db (properties (where {:provider "RBT" :piece 4}) (db c))]
(fact
"Update the database to reflect that 'Susan Calvin Corp.' (code 'RBT')
will not supply bolts (code 4)."
(select! :* (from :provides) w-db)
=> [{:piece 4, :price 7, :provider "RBT"}]
(delete! :provides w-db) => [1]
(select! :* (from :provides) w-db) => []))
(let [c (mk-db)
w-db (properties (where {:provider "RBT"}) (db c))]
(fact
"Update the database to reflect that 'Susan Calvin Corp.' (code 'RBT')
will not supply any pieces (the provider should still remain in the
database)."
(delete! :provides w-db) => [4]
(select-from! :provides w-db) => []))