/
app.pro
52 lines (47 loc) · 1.61 KB
/
app.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
#
# PowerKit <https://github.com/rodlie/powerkit>
# Copyright (c) 2018, Ole-André Rodlie <ole.andre.rodlie@gmail.com> All rights reserved.
#
# Available under the 3-clause BSD license
# See the LICENSE file for full details
#
QT += core gui dbus xml
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
TARGET = powerkit
TEMPLATE = app
SOURCES += main.cpp systray.cpp dialog.cpp common.cpp
HEADERS += systray.h dialog.h common.h
LIBS += -L../lib -lPowerKit
INCLUDEPATH += ../lib
include(../powerkit.pri)
DEFINES += APP_VERSION=\"\\\"$${VERSION}\\\"\"
DEFINES += APP_VERSION_EXTRA=\"\\\"$${VERSION_EXTRA}\\\"\"
!CONFIG(no_app_install) {
target.path = $${PREFIX}/bin
INSTALLS += target
!CONFIG(no_doc_install) {
target_docs.path = $${DOCDIR}/$${TARGET}-$${VERSION}$${VERSION_EXTRA}
target_docs.files = ../LICENSE ../README.md ../ChangeLog
INSTALLS += target_docs
}
!CONFIG(no_man_install) {
target_man.path = $${MANDIR}/man1
target_man.files = share/man/$${TARGET}.1
INSTALLS += target_man
}
!CONFIG(no_desktop_install) {
target_desktop.path = $${PREFIX}/share/applications
target_desktop.files = share/applications/$${TARGET}.desktop
INSTALLS += target_desktop
}
!CONFIG(no_autostart_install) {
target_desktop_xdg.path = $${XDGDIR}/autostart
target_desktop_xdg.files = share/autostart/$${TARGET}.desktop
INSTALLS += target_desktop_xdg
}
CONFIG(install_udev_rules) {
target_udev.path = $${UDEVDIR}/rules.d
target_udev.files = share/udev/90-backlight.rules
INSTALLS += target_udev
}
}