-
Notifications
You must be signed in to change notification settings - Fork 1
/
K_Pst.mod
executable file
·72 lines (62 loc) · 1.19 KB
/
K_Pst.mod
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
:Comment : The persistent component of the K current
:Reference : : Voltage-gated K+ channels in layer 5 neocortical pyramidal neurones from young rats:subtypes and gradients,Korngreen and Sakmann, J. Physiology, 2000
:Comment : shifted -10 mv to correct for junction potential
:Comment: corrected rates using q10 = 2.3, target temperature 34, orginal 21
NEURON {
SUFFIX K_Pst
USEION k READ ek WRITE ik
RANGE gK_Pstbar, gK_Pst, ik
}
UNITS {
(S) = (siemens)
(mV) = (millivolt)
(mA) = (milliamp)
}
PARAMETER {
gK_Pstbar = 0.00001 (S/cm2)
}
ASSIGNED {
v (mV)
ek (mV)
ik (mA/cm2)
gK_Pst (S/cm2)
mInf
mTau
hInf
hTau
}
STATE {
m
h
}
BREAKPOINT {
SOLVE states METHOD cnexp
gK_Pst = gK_Pstbar*m*m*h
ik = gK_Pst*(v-ek)
}
DERIVATIVE states {
rates()
m' = (mInf-m)/mTau
h' = (hInf-h)/hTau
}
INITIAL{
rates()
m = mInf
h = hInf
}
PROCEDURE rates(){
LOCAL qt
qt = 2.3^((34-21)/10)
UNITSOFF
v = v + 10
mInf = (1/(1 + exp(-(v+1)/12)))
if(v<-50){
mTau = (1.25+175.03*exp(-v * -0.026))/qt
}else{
mTau = ((1.25+13*exp(-v*0.026)))/qt
}
hInf = 1/(1 + exp(-(v+54)/-11))
hTau = (360+(1010+24*(v+55))*exp(-((v+75)/48)^2))/qt
v = v - 10
UNITSON
}