-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
207 lines (185 loc) · 6.71 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
/*
* Copyright (c) 2024. Ryan Wong (hello@ryanwebmail.com)
*/
import org.jlleitschuh.gradle.ktlint.reporter.ReporterType
import java.io.FileInputStream
import java.io.InputStreamReader
import java.text.SimpleDateFormat
import java.util.Date
import java.util.Properties
plugins {
alias(libs.plugins.androidApplication)
alias(libs.plugins.jetbrainsKotlinAndroid)
alias(libs.plugins.hilt.android.plugin)
alias(libs.plugins.devtools.ksp)
alias(libs.plugins.gradleKtlint)
alias(libs.plugins.compose.compiler)
}
android {
namespace = "com.rwmobi.fuseduserpreferences"
compileSdk = libs.versions.compilesdk.get().toInt()
signingConfigs {
create("release") {
val isRunningOnCI = System.getenv("BITRISE") == "true"
val keystorePropertiesFile = file("../../keystore.properties")
if (isRunningOnCI) {
println("Signing Config: using environment variables")
keyAlias = System.getenv("CI_ANDROID_KEYSTORE_ALIAS")
keyPassword = System.getenv("CI_ANDROID_KEYSTORE_PRIVATE_KEY_PASSWORD")
storeFile = file(System.getenv("KEYSTORE_LOCATION"))
storePassword = System.getenv("CI_ANDROID_KEYSTORE_PASSWORD")
} else if (keystorePropertiesFile.exists()) {
println("Signing Config: using keystore properties")
val properties = Properties()
InputStreamReader(
FileInputStream(keystorePropertiesFile),
Charsets.UTF_8,
).use { reader ->
properties.load(reader)
}
keyAlias = properties.getProperty("alias")
keyPassword = properties.getProperty("pass")
storeFile = file(properties.getProperty("store"))
storePassword = properties.getProperty("storePass")
} else {
println("Signing Config: skipping signing")
}
}
}
defaultConfig {
applicationId = "com.rwmobi.fuseduserpreferences"
minSdk = libs.versions.minsdk.get().toInt()
targetSdk = libs.versions.targetsdk.get().toInt()
versionCode = 4
versionName = "1.2.0"
testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
vectorDrawables {
useSupportLibrary = true
}
// Bundle output filename
val timestamp = SimpleDateFormat("yyyyMMdd-HHmmss").format(Date())
setProperty("archivesBaseName", "FusedUserPrefs-$versionName-$timestamp")
}
buildTypes {
fun setOutputFileName() {
applicationVariants.all {
val variant = this
variant.outputs
.map { it as com.android.build.gradle.internal.api.BaseVariantOutputImpl }
.forEach { output ->
val timestamp = SimpleDateFormat("yyyyMMdd-HHmmss").format(Date())
val outputFileName =
"FusedUserPrefs-${variant.versionName}-$timestamp-${variant.name}.apk"
output.outputFileName = outputFileName
}
}
}
getByName("debug") {
applicationIdSuffix = ".debug"
isMinifyEnabled = false
isDebuggable = true
setOutputFileName()
}
getByName("release") {
isShrinkResources = true
isMinifyEnabled = true
isDebuggable = false
setProguardFiles(
listOf(
getDefaultProguardFile("proguard-android-optimize.txt"),
"proguard-rules.pro",
),
)
signingConfigs.getByName("release").keyAlias?.let {
signingConfig = signingConfigs.getByName("release")
}
setOutputFileName()
}
}
compileOptions {
sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17
}
kotlinOptions {
jvmTarget = "17"
}
buildFeatures {
compose = true
buildConfig = true
}
testOptions {
animationsDisabled = true
unitTests {
isIncludeAndroidResources = true
}
}
packaging {
resources {
excludes.addAll(
listOf(
"META-INF/proguard/*",
"META-INF/*.kotlin_module",
"META-INF/DEPENDENCIES",
"META-INF/AL2.0",
"META-INF/LGPL2.1",
"META-INF/*.properties",
"/*.properties",
"META-INF/LICENSE*",
),
)
}
}
}
kotlin {
jvmToolchain(17)
}
configure<org.jlleitschuh.gradle.ktlint.KtlintExtension> {
android.set(true)
ignoreFailures.set(true)
reporters {
reporter(ReporterType.PLAIN)
reporter(ReporterType.CHECKSTYLE)
reporter(ReporterType.SARIF)
}
}
tasks.named("preBuild") {
dependsOn(tasks.named("ktlintFormat"))
}
tasks.withType<Test> {
useJUnitPlatform()
}
dependencies {
implementation(libs.androidx.core.ktx)
implementation(libs.androidx.lifecycle.runtime.ktx)
implementation(libs.androidx.activity.compose)
implementation(platform(libs.androidx.compose.bom))
implementation(libs.androidx.ui)
implementation(libs.androidx.ui.graphics)
implementation(libs.androidx.ui.tooling.preview)
implementation(libs.androidx.material3)
implementation(libs.androidx.datastore.preferences)
implementation(libs.androidx.core.ktx)
implementation(libs.androidx.junit.ktx)
implementation(libs.timber)
implementation(libs.androidx.lifecycle.runtime.compose)
testImplementation(libs.junit)
testImplementation(libs.junit.vintage.engine)
testImplementation(libs.kotlinx.coroutines.test)
testImplementation(libs.robolectric)
testImplementation(libs.mockk)
testImplementation(libs.mockk.agent.jvm)
androidTestImplementation(libs.mockk.android)
androidTestImplementation(libs.androidx.junit)
androidTestImplementation(libs.androidx.espresso.core)
androidTestImplementation(platform(libs.androidx.compose.bom))
androidTestImplementation(libs.androidx.ui.test.junit4)
debugImplementation(libs.androidx.ui.tooling)
debugImplementation(libs.androidx.ui.test.manifest)
// Dagger-Hilt
// Hilt does not support ksp yet https://issuetracker.google.com/issues/179057202?pli=1
implementation(libs.hilt.android)
ksp(libs.hilt.compiler)
implementation(libs.hilt.navigation.compose)
kspAndroidTest(libs.hilt.android.compiler)
androidTestImplementation(libs.hilt.android.testing)
}