forked from twitter/twitter-text
-
Notifications
You must be signed in to change notification settings - Fork 2
/
twitter_text.pest
3774 lines (3724 loc) · 79.2 KB
/
twitter_text.pest
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// Copyright 2019 Robert Sayre
// Licensed under the Apache License, Version 2.0
// http://www.apache.org/licenses/LICENSE-2.0
//
// A tweet is composed of a sequence of text and entities
//
tweet = { SOI ~ (entity | invalid_char | text)+ ~ EOI }
invalid_char = {
"\u{fffe}" | // BOM
"\u{feff}" | // BOM
"\u{ffff}" // Special
}
text = _{ !invalid_char ~ (emoji | ANY) }
//
// An "entity" represents some special content embedded in the
// tweet. This grammar only covers those that have representations
// in the tweet text. There are other types, such as polls, that do not appear in the text.
//
// Pest uses a Parsing Expression Grammar (PEG), so the order of the choices here
// is significant <https://en.wikipedia.org/wiki/Parsing_expression_grammar#Semantics>.
// In particular, placing URLs before other entities helps resolve ambiguities where
// URL fragments might also be interpreted as hashtags (see <goo.gl/4udoLK>).
//
entity = _{ possible_url | possible_hashtag | possible_mention | possible_cashtag }
//
// CASHTAGS
//
cashtag_prefix = { "$" }
cashtag_text = _{ ASCII_ALPHA{1,6} ~ (("." | "_")? ~ ASCII_ALPHA{1,2})? ~ !(ASCII_DIGIT | ASCII_ALPHA) }
cashtag_token = _{ cashtag_prefix ~ cashtag_text }
cashtag = { cashtag_token }
invalid_cashtag_start = _{ (!space ~ text) ~ cashtag_token | cashtag_prefix ~ protocol ~ subdomain_char* }
possible_cashtag = _{ invalid_cashtag_start | (cashtag ~ cashtag_token*) }
//
// HASHTAGS
//
hashtag_prefix = _{ "#" | "＃" }
hashtag_letter_or_mark = _{
UPPERCASE_LETTER | LOWERCASE_LETTER | TITLECASE_LETTER | MODIFIER_LETTER |
OTHER_LETTER | NONSPACING_MARK | ENCLOSING_MARK | SPACING_MARK
}
hashtag_special = _{
DECIMAL_NUMBER | "_" |
"\u{200c}" | "\u{200d}" | "\u{a67e}" | "\u{05be}" | "\u{05f3}" | "\u{05f4}" | "\u{ff5e}" | "\u{301c}" |
"\u{309b}" | "\u{309c}" | "\u{30a0}" | "\u{30fb}" | "\u{3003}" | "\u{0f0b}" | "\u{0f0c}" | "\u{00b7}"
}
hashtag_text = _{ !("\u{fe0f}" | "\u{20e3}") ~ (hashtag_special* ~ hashtag_letter_or_mark+ ~ hashtag_special*)+ }
hashtag = { hashtag_prefix ~ hashtag_text }
invalid_hashtag_start = _{
(("&" | hashtag_letter_or_mark) ~ hashtag_prefix ~ &hashtag_text) |
hashtag_prefix ~ protocol ~ subdomain_char*
}
possible_hashtag = _{ "\u{fe0e}" | "\u{fe0f}" ~ hashtag | invalid_hashtag_start | hashtag }
//
// MENTIONS
//
possible_mention = _{ list | user }
//
// USER
//
user_prefix = _{ "@" | "＠" }
user_char = _{ alphanumeric | "_" }
user_token = _{ user_prefix ~ user_char{1, 20} }
user_invalid_prefix = _{ user_char | "!" | "#" | "$" | "%" | "&" | "*" | user_prefix | protocol }
user_invalid_suffix = _{ user_prefix | latin_accent | "://" | "-" }
rt_prefix = _{ !(user_char | "+" | "~" | "." | "-") | SOI ~ ^"rt" ~ ":"? }
username = { user_token }
user = _{
user_prefix ~ protocol ~ subdomain_char* |
user_token ~ user_token+ | // ignore @text@like@this
user_token ~ user_invalid_suffix |
rt_prefix ~ username |
user_invalid_prefix ~ user_token |
username
}
//
// LIST
//
listname = { user_token }
list_slug = { "/" ~ (ASCII_ALPHA ~ (alphanumeric | "_" | "-"){,24}){1} }
list = { listname ~ list_slug }
//
// REPLY
//
reply = _{ space? ~ username ~ !user_invalid_suffix }
//
// URLs beginning with "http"
//
possible_url = _{ !(user_prefix | hashtag_prefix | cashtag_prefix) ~ (url | uwp) }
url = { tco_url | normal_url }
tco_url = _{
(protocol ~ tco_domain ~ "/" ~ alphanumeric{1,40} ~ (query ~ fragment?)? ~ !(alphanumeric | cyrillic_char | latin_accent)) |
protocol ~ tco_domain ~ "/"? ~ !(alphanumeric | cyrillic_char | latin_accent)
}
tco_domain = { "t.co" }
normal_url = _{ protocol ~ userinfo? ~ host ~ port? ~ path? ~ query? ~ fragment? }
//
// PROTOCOL
//
protocol = _{ ^"http" ~ (^"s")? ~ "://" }
//
// USERINFO
//
pct_encoded = _{ "%" ~ HEX_DIGIT }
sub_delims = _{ "!" | "$" | "&" | "'" | "(" | ")" | "*" | "+" | "," | ";" | "=" }
unreserved = _{ alphanumeric | "-" | "." | "_" | "~" | cyrillic_char }
userinfo = _{ (unreserved | pct_encoded | sub_delims | ":")* ~ "@" }
//
// DOMAINS
//
host = { !"t.co" ~ domain | ipv4_address | ip_literal }
//
// TLD
//
invalid_tld_suffix = _{ 'a'..'z' | '0'..'9' | "@" }
tld = { tld_list ~ !invalid_tld_suffix }
//
// TEXT DOMAINS
//
domain = { (sl_domain | longer_domain) ~ tld }
sl_domain = _{
(domain_segment ~ "." ~ &tld) ~
!((domain_segment ~ "." ~ &tld) | "." ~ &tld | longer_domain)
}
longer_domain = _{ subdomain ~ ("." ~ subdomain)* ~ "." ~ sl_domain }
subdomain = _{ !sl_domain ~ subdomain_segment }
punycode_host = _{ ^"xn" ~ "--" ~ ("-" | alphanumeric)+ }
domain_segment = _{punycode_host | (domain_char ~ ("-"? ~ domain_char)*)+}
domain_char = _{ (non_punctuation ~ ("-"? ~ non_punctuation)+) | non_punctuation }
subdomain_segment = _{punycode_host | subdomain_char+}
subdomain_char = _{ (domain_char ~ "_"? ~ domain_char) | domain_char }
//
// IPv4 ADDRESS
// Adapted from core-pegjs <https://goo.gl/LQPPAi>
//
ipv4_address = _{ dec_octet ~ "." ~ dec_octet ~ "." ~ dec_octet ~ "." ~ dec_octet }
dec_octet = _{
"25" ~ '\u{0030}'..'\u{0035}' | // 250-255
"2" ~ '\u{0030}'..'\u{0034}' ~ '0'..'9' | // 200-249
"1" ~ '0'..'9' ~ '0'..'9' | // 100-199
'\u{0031}'..'\u{0039}' ~ '0'..'9' | // 10-99
'0'..'9' // 0-9
}
//
// IPv6 ADDRESS
// Adapted from core-pegjs <https://goo.gl/LQPPAi>
//
ip_literal = _{ "[" ~ ipv6_address ~ "]" }
ipv6_address = _{
( h16_{6} ~ ls32) |
( "::" ~ h16_{5} ~ ls32) |
(h16_{0,1} ~ "::" ~ h16_{4} ~ ls32) |
(h16_{0,2} ~ "::" ~ h16_{3} ~ ls32) |
(h16_{0,3} ~ "::" ~ h16_{2} ~ ls32) |
(h16_{0,4} ~ "::" ~ h16_{1} ~ ls32) |
(h16_{0,5} ~ "::" ~ ls32) |
(h16_{0,6} ~ "::" ~ h16 ) |
(h16_{0,7} ~ "::" )
}
ls32 = _{ (h16 ~ ":" ~ h16) | ipv4_address }
h16_ = _{ h16 ~ ":" }
h16 = _{ HEX_DIGIT{1,4} }
//
// URL WITHOUT PROTOCOL (UWP)
//
invalid_preceding_url_chars = { "_" | "-" | "." | protocol }
uwp = { invalid_preceding_url_chars ~ uwp_domain | url_without_protocol }
url_without_protocol = { uwp_domain ~ port? ~ path? ~ query? ~ fragment? }
uwp_domain = { (uwp_sl_domain | uwp_longer_domain) ~ tld }
uwp_sl_domain = _{ (uwp_domain_char+ ~ "." ~ &tld) ~ !((uwp_domain_char+ ~ "." ~ &tld) | "." ~ &tld | uwp_sl_domain) }
uwp_longer_domain = _{ uwp_subdomain ~ ("." ~ uwp_subdomain)* ~ "." ~ uwp_sl_domain }
uwp_subdomain = { !uwp_sl_domain ~ uwp_subdomain_char+ }
uwp_subdomain_char = _{ (uwp_domain_char ~ "_"? ~ uwp_domain_char) | uwp_domain_char }
uwp_domain_char = _{
((alphanumeric | latin_accent) ~ ("-"? ~ (alphanumeric | latin_accent))+)
| alphanumeric | latin_accent
}
//
// PORT
//
port = { ":" ~ '1'..'9' ~ ASCII_DIGIT* }
//
// PATH
//
url_general_path = _{ url_path_end | path_punctuation }
url_path_end = _{ alphanumeric | "=" | "_" | "-" | "+" | cyrillic_char | latin_accent | url_balanced_parens }
path_punctuation = _{
"!" | "*" | "\'" | ";" | ":" | "," | "." | "$" | "%" | "[" | "]" | "\u{2013}" | "~" | "|" | "&" | "@"
}
// Allow URL paths to contain up to two nested levels of balanced parens
// 1. Used in Wikipedia URLs like /Primer_(film)
// 2. Used in IIS sessions like /S(dfd346)/
// 3. Used in Rdio URLs like /track/We_Up_(Album_Version_(Edited))/
balanced_paren_path_text = _{ "(" ~ url_general_path+ ~ ")" }
url_balanced_parens = _{
balanced_paren_path_text |
"(" ~ url_general_path* ~ balanced_paren_path_text ~ url_general_path* ~ ")"
}
end_path = _{ (url_path_end | (path_punctuation+ ~ &url_path_end))+ }
segment = _{ (url_general_path+ ~ &"/") | end_path }
path = _{ "/" ~ ((segment ~ ("/" ~ segment)*) ~ ("/")?)?}
//
// QUERY
//
query_punctuation_char = _{
"!" | "?" | "*" | "\'" | "(" | ")" | ";" | ":" | "$" | "%" | "[" | "]" | "." | "," | "~" | "|" | "@"
}
query_end_char = _{ ASCII_ALPHA | ASCII_DIGIT | "-" | "_" | "&" | "=" | "/" | "+"}
query_char = _{ query_end_char | query_punctuation_char+ ~ &query_end_char }
query = _{ "?" ~ query_char+ | "?" ~ &"#" }
//
// FRAGMENT
//
fragment_end = _{ query_end_char | "#" }
fragment_char = _{ fragment_end | query_punctuation_char+ ~ &fragment_end }
fragment = _{ "#" ~ fragment_char* }
//
// General rules
//
alphanumeric = _{ ASCII_ALPHA | ASCII_DIGIT }
latin_accent = _{
'\u{00c0}'..'\u{00d6}' | '\u{00d8}'..'\u{00f6}' | '\u{00f8}'..'\u{00ff}' | '\u{0100}'..'\u{024f}' |
'\u{0253}'..'\u{0254}' | '\u{0256}'..'\u{0257}' | '\u{0259}'..'\u{0259}' | '\u{025b}'..'\u{025b}' |
'\u{0263}'..'\u{0263}' | '\u{0268}'..'\u{0268}' | '\u{026f}'..'\u{026f}' | '\u{0272}'..'\u{0272}' |
'\u{0289}'..'\u{0289}' | '\u{028b}'..'\u{028b}' | '\u{02bb}'..'\u{02bb}' | '\u{0300}'..'\u{036f}' |
'\u{1e00}'..'\u{1eff}'
}
cyrillic_char = _{ '\u{0400}'..'\u{04ff}' }
space = _{
"\u{0020}" | "\u{0085}" | "\u{00A0}" | "\u{1680}" | "\u{180E}" | "\u{2028}" | "\u{2029}" |
"\u{202F}" | "\u{205F}" | "\u{3000}" | '\u{0009}'..'\u{000D}' | '\u{2000}'..'\u{200A}'
}
punctuation_char = _{
"-" | "_" | "!" | "\"" | "#" | "$" | "%" | "&" | "'" | "(" | ")" | "*" | "+" | "," | "." | "/" |
"\\" | ":" | ";" | "<" | "=" | ">" | "?" | "@" | "[" | "]" | "^" | "`" | "{" | "|" | "}" | "~"
}
non_punctuation = _{ !(punctuation_char | space | PUNCTUATION) ~ text }
//
// Emoji
//
emoji = {
man_or_woman_with_optional_skin_tone_and_modifier |
person_with_vs16_or_skin_tone_and_trailing_mf_symbol |
person_with_optional_skin_tone_and_trailing_mf_symbol |
other_zwj_sequences |
emojified_symbols |
default_text_symbols |
variants_allowing_trailing_fe0f_but_not_fe0e |
diversity_emoji_with_optional_skin_tone |
flags_and_regular_emoji
}
// A zero-width-joiner character is used to combine emoji together.
// For example, a face with a skin tone.
zwj = _{ "\u{200d}" }
// A skin tone applied to another emoji
skin_tone = _{ '\u{01f3fb}'..'\u{01f3ff}' }
// A trailing Male or Female symbol
trailing_mf_symbol = _{ zwj ~ (("\u{2640}" | "\u{2642}") ~ "\u{fe0f}"?) }
man_or_woman_with_optional_skin_tone_and_modifier = _{
// Man or Woman
man_or_woman ~
// Followed by an optional skin tone
skin_tone? ~
// Followed by a joined modifier
zwj ~
((("\u{2695}" | "\u{2696}" | "\u{2708}") ~ "\u{fe0f}"?) |
("\u{1f33e}" | "\u{1f373}" | "\u{1f393}" | "\u{1f3a4}" | "\u{1f3a8}" | "\u{1f3eb}" | "\u{1f3ed}" | "\u{1f4bb}" |
"\u{1f4bc}" | "\u{1f527}" | "\u{1f52c}" | "\u{1f680}" | "\u{1f692}" | '\u{1f9b0}'..'\u{1f9b3}')
)
}
person_with_vs16_or_skin_tone_and_trailing_mf_symbol = _{
("\u{26f9}" | "\u{1f3cb}" | "\u{1f3cc}" | "\u{1f574}" | "\u{1f575}") ~
("\u{fe0f}" | skin_tone)? ~ trailing_mf_symbol
}
person_with_optional_skin_tone_and_trailing_mf_symbol = _{
("\u{1f3c3}" | "\u{1f3c4}" | "\u{1f3ca}" | "\u{1f46e}" | "\u{1f471}" | "\u{1f473}" | "\u{1f477}" |
"\u{1f481}" | "\u{1f482}" | "\u{1f486}" | "\u{1f487}" | '\u{1f645}'..'\u{1f647}' | "\u{1f64b}" |
"\u{1f64d}" | "\u{1f64e}" | "\u{1f6a3}" | '\u{1f6b4}'..'\u{1f6b6}' | "\u{1f926}" | "\u{1f935}" |
'\u{1f937}'..'\u{1f939}' | "\u{1f93d}" | "\u{1f93e}" | "\u{1f9b8}" | "\u{1f9b9}" |
'\u{1f9d6}'..'\u{1f9dd}') ~ skin_tone? ~ trailing_mf_symbol
}
other_zwj_sequences = _{
// Starts with Man
("\u{1f468}" ~ zwj ~
(
("\u{1f466}" ~ zwj ~ "\u{1f466}") |
("\u{1f467}" ~ zwj ~ boy_or_girl) |
("\u{1f468}" ~ zwj ~ ("\u{1f466}" ~ zwj ~ "\u{1f466}" | "\u{1f467}" ~ zwj ~ boy_or_girl | boy_or_girl)) |
("\u{1f469}" ~ zwj ~ ("\u{1f466}" ~ zwj ~ "\u{1f466}" | "\u{1f467}" ~ zwj ~ boy_or_girl | boy_or_girl)) |
("\u{2764}" ~ "\u{fe0f}"? ~ zwj ~ ("\u{1f468}" | "\u{1f48b}" ~ zwj ~ "\u{1f468}")) |
boy_or_girl
)
) |
// Starts with Woman
("\u{1f469}" ~ zwj ~
(
("\u{1f466}" ~ zwj ~ "\u{1f466}") |
("\u{1f467}" ~ zwj ~ boy_or_girl) |
("\u{1f469}" ~ zwj ~ ("\u{1f466}" ~ zwj ~ "\u{1f466}" | "\u{1f467}" ~ zwj ~ boy_or_girl | boy_or_girl)) |
("\u{2764}" ~ "\u{fe0f}"? ~ zwj ~ (man_or_woman | "\u{1f48b}" ~ zwj ~ man_or_woman)) |
boy_or_girl
)
) |
// Zombies, genies, dancers, and wrestlers
(("\u{1f9df}" | "\u{1f9de}" | "\u{1f46f}" | "\u{1f93c}") ~ trailing_mf_symbol) |
// Others
("\u{1f3f3}" ~ "\u{fe0f}"? ~ zwj ~ "\u{1f308}") |
("\u{1f3f4}" ~ zwj ~ "\u{2620}" ~ "\u{fe0f}"?) |
("\u{1f441}" ~ "\u{fe0f}"? ~ zwj ~ "\u{1f5e8}" ~ "\u{fe0f}"?)
}
man_or_woman = _{
"\u{1f468}" | "\u{1f469}"
}
boy_or_girl = _{
"\u{1f466}" | "\u{01f467}"
}
// Emojified symbols #, 0, 1, 2, 3, 4, 5, 6, 7, 8, 9 + possible variant selector + keycap
emojified_symbols = _{
("#" | "*" | ASCII_DIGIT) ~ "\u{fe0f}"? ~ "\u{20e3}"
}
default_text_symbols = _{
("©" | "®" | "\u{2122}" | "\u{265f}") ~ "\u{fe0f}"
}
variants_allowing_trailing_fe0f_but_not_fe0e = _{
("\u{203c}" | "\u{2049}" | "\u{2139}" | '\u{2194}'..'\u{2199}' | "\u{21a9}" | "\u{21aa}" | "\u{231a}" |
"\u{231b}" | "\u{2328}" | "\u{23cf}" | '\u{23ed}'..'\u{23ef}' | "\u{23f1}" | "\u{23f2}" | '\u{23f8}'..'\u{23fa}' |
"\u{24c2}" | "\u{25aa}" | "\u{25ab}" | "\u{25b6}" | "\u{25c0}" | '\u{25fb}'..'\u{25fe}' | '\u{2600}'..'\u{2604}' |
"\u{260e}" | "\u{2611}" | "\u{2614}" | "\u{2615}" | "\u{2618}" | "\u{2620}" | "\u{2622}" | "\u{2623}" |
"\u{2626}" | "\u{262a}" | "\u{262e}" | "\u{262f}" | '\u{2638}'..'\u{263a}' | "\u{2640}" | "\u{2642}" |
'\u{2648}'..'\u{2653}' | "\u{2660}" | "\u{2663}" | "\u{2665}" | "\u{2666}" | "\u{2668}" | "\u{267b}" | "\u{267e}" |
"\u{267f}" | '\u{2692}'..'\u{2697}' | "\u{2699}" | "\u{269b}" | "\u{269c}" | "\u{26a0}" | "\u{26a1}" |
"\u{26aa}" | "\u{26ab}" | "\u{26b0}" | "\u{26b1}" | "\u{26bd}" | "\u{26be}" | "\u{26c4}" | "\u{26c5}" |
"\u{26c8}" | "\u{26cf}" | "\u{26d1}" | "\u{26d3}" | "\u{26d4}" | "\u{26e9}" | "\u{26ea}" |
'\u{26f0}'..'\u{26f5}' | "\u{26f8}" | "\u{26fa}" | "\u{26fd}" | "\u{2702}" | "\u{2708}" | "\u{2709}" |
"\u{270f}" | "\u{2712}" | "\u{2714}" | "\u{2716}" | "\u{271d}" | "\u{2721}" | "\u{2733}" | "\u{2734}" |
"\u{2744}" | "\u{2747}" | "\u{2757}" | "\u{2763}" | "\u{2764}" | "\u{27a1}" | "\u{2934}" | "\u{2935}" |
'\u{2b05}'..'\u{2b07}' | "\u{2b1b}" | "\u{2b1c}" | "\u{2b50}" | "\u{2b55}" | "\u{3030}" | "\u{303d}" |
"\u{3297}" | "\u{3299}" | "\u{1f004}" | "\u{1f170}" | "\u{1f171}" | "\u{1f17e}" | "\u{1f17f}" | "\u{1f202}" |
"\u{1f21a}" | "\u{1f22f}" | "\u{1f237}" | "\u{1f321}" | '\u{1f324}'..'\u{1f32c}' | "\u{1f336}" | "\u{1f37d}" |
"\u{1f396}" | "\u{1f397}" | '\u{1f399}'..'\u{1f39b}' | "\u{1f39e}" | "\u{1f39f}" | "\u{1f3cd}" | "\u{1f3ce}" |
'\u{1f3d4}'..'\u{1f3df}' | "\u{1f3f3}" | "\u{1f3f5}" | "\u{1f3f7}" | "\u{1f43f}" | "\u{1f441}" | "\u{1f4fd}" |
"\u{1f549}" | "\u{1f54a}" | "\u{1f56f}" | "\u{1f570}" | "\u{1f573}" | '\u{1f576}'..'\u{1f579}' | "\u{1f587}" |
'\u{1f58a}'..'\u{1f58d}' | "\u{1f5a5}" | "\u{1f5a8}" | "\u{1f5b1}" | "\u{1f5b2}" | "\u{1f5bc}" |
'\u{1f5c2}'..'\u{1f5c4}' | '\u{1f5d1}'..'\u{1f5d3}' | '\u{1f5dc}'..'\u{1f5de}' | "\u{1f5e1}" | "\u{1f5e3}" |
"\u{1f5e8}" | "\u{1f5ef}" | "\u{1f5f3}" | "\u{1f5fa}" | "\u{1f6cb}" | '\u{1f6cd}'..'\u{1f6cf}' |
'\u{1f6e0}'..'\u{1f6e5}' | "\u{1f6e9}" | "\u{1f6f0}" | "\u{1f6f3}") ~
("\u{fe0f}" | !"\u{fe0e}")
}
diversity_emoji_with_optional_skin_tone = _{
((("\u{261d}" | "\u{26f7}" | "\u{26f9}" | "\u{270c}" | "\u{270d}" |
"\u{1f3cb}" | "\u{1f3cc}" | "\u{1f574}" | "\u{1f575}" | "\u{1f590}") ~ ("\u{fe0f}" | !"\u{fe0e}")) |
("\u{270a}" | "\u{270b}" | "\u{1f385}" | '\u{1f3c2}'..'\u{1f3c4}' | "\u{1f3c7}" | "\u{1f3ca}" | "\u{1f442}" |
"\u{1f443}" | '\u{1f446}'..'\u{1f450}' | '\u{1f466}'..'\u{1f469}' | "\u{1f46e}" | '\u{1f470}'..'\u{1f478}' |
"\u{1f47c}" | '\u{1f481}'..'\u{1f483}' | '\u{1f485}'..'\u{1f487}' | "\u{1f4aa}" | "\u{1f57a}" | "\u{1f595}" |
"\u{1f596}" | '\u{1f645}'..'\u{1f647}' | '\u{1f64b}'..'\u{1f64f}' | "\u{1f6a3}" | '\u{1f6b4}'..'\u{1f6b6}' |
"\u{1f6c0}" | "\u{1f6cc}" | '\u{1f918}'..'\u{1f91c}' | "\u{1f91e}" | "\u{1f91f}" | "\u{1f926}" |
'\u{1f930}'..'\u{1f939}' | "\u{1f93d}" | "\u{1f93e}" | "\u{1f9b5}" | "\u{1f9b6}" | "\u{1f9b8}" | "\u{1f9b9}" |
'\u{1f9d1}'..'\u{1f9dd}')) ~ skin_tone?
}
flags_and_regular_emoji = _{
"\u{1f3f4}\u{e0067}\u{e0062}\u{e0065}\u{e006e}\u{e0067}\u{e007f}" |
"\u{1f3f4}\u{e0067}\u{e0062}\u{e0073}\u{e0063}\u{e0074}\u{e007f}" |
"\u{1f3f4}\u{e0067}\u{e0062}\u{e0077}\u{e006c}\u{e0073}\u{e007f}" |
("\u{1f1e6}" ~ ('\u{1f1e8}'..'\u{1f1ec}' | "\u{1f1ee}" | "\u{1f1f1}" | "\u{1f1f2}" | "\u{1f1f4}" |
'\u{1f1f6}'..'\u{1f1fa}' | "\u{1f1fc}" | "\u{1f1fd}" | "\u{1f1ff}")) |
("\u{1f1e7}" ~ ("\u{1f1e6}" | "\u{1f1e7}" | '\u{1f1e9}'..'\u{1f1ef}' | '\u{1f1f1}'..'\u{1f1f4}' |
'\u{1f1f6}'..'\u{1f1f9}' | "\u{1f1fb}" | "\u{1f1fc}" | "\u{1f1fe}" | "\u{1f1ff}")) |
("\u{1f1e8}" ~ ("\u{1f1e6}" | "\u{1f1e8}" | "\u{1f1e9}" | '\u{1f1eb}'..'\u{1f1ee}' |
'\u{1f1f0}'..'\u{1f1f5}' | "\u{1f1f7}" | '\u{1f1fa}'..'\u{1f1ff}')) |
("\u{1f1e9}" ~ ("\u{1f1ea}" | "\u{1f1ec}" | "\u{1f1ef}" | "\u{1f1f0}" | "\u{1f1f2}" | "\u{1f1f4}" | "\u{1f1ff}")) |
("\u{1f1ea}" ~ ("\u{1f1e6}" | "\u{1f1e8}" | "\u{1f1ea}" |
"\u{1f1ec}" | "\u{1f1ed}" | '\u{1f1f7}'..'\u{1f1fa}')) |
("\u{1f1eb}" ~ ('\u{1f1ee}'..'\u{1f1f0}' | "\u{1f1f2}" | "\u{1f1f4}" | "\u{1f1f7}")) |
("\u{1f1ec}" ~ ("\u{1f1e6}" | "\u{1f1e7}" | '\u{1f1e9}'..'\u{1f1ee}' | '\u{1f1f1}'..'\u{1f1f3}' |
'\u{1f1f5}'..'\u{1f1fa}' | "\u{1f1fc}" | "\u{1f1fe}")) |
("\u{1f1ed}" ~ ("\u{1f1f0}" | "\u{1f1f2}" | "\u{1f1f3}" | "\u{1f1f7}" | "\u{1f1f9}" | "\u{1f1fa}" )) |
("\u{1f1ee}" ~ ('\u{1f1e8}'..'\u{1f1ea}' | '\u{1f1f1}'..'\u{1f1f4}' | '\u{1f1f6}'..'\u{1f1f9}')) |
("\u{1f1ef}" ~ ("\u{1f1ea}" | "\u{1f1f2}" | "\u{1f1f4}" | "\u{1f1f5}")) |
("\u{1f1f0}" ~ ("\u{1f1ea}" | '\u{1f1ec}'..'\u{1f1ee}' | "\u{1f1f2}" | "\u{1f1f3}" | "\u{1f1f5}" | "\u{1f1f7}" |
"\u{1f1fc}" | "\u{1f1fe}" | "\u{1f1ff}")) |
("\u{1f1f1}" ~ ('\u{1f1e6}'..'\u{1f1e8}' | "\u{1f1ee}" | "\u{1f1f0}" | '\u{1f1f7}'..'\u{1f1fb}' | "\u{1f1fe}")) |
("\u{1f1f2}" ~ ("\u{1f1e6}" | '\u{1f1e8}'..'\u{1f1ed}' | '\u{1f1f0}'..'\u{1f1ff}')) |
("\u{1f1f3}" ~ ("\u{1f1e6}" | "\u{1f1e8}" | '\u{1f1ea}'..'\u{1f1ec}' | "\u{1f1ee}" | "\u{1f1f1}" | "\u{1f1f4}" |
"\u{1f1f5}" | "\u{1f1f7}" | "\u{1f1fa}" | "\u{1f1ff}")) |
"\u{1f1f4}\u{1f1f2}" |
("\u{1f1f5}" ~ ("\u{1f1e6}" | '\u{1f1ea}'..'\u{1f1ed}' | '\u{1f1f0}'..'\u{1f1f3}' | '\u{1f1f7}'..'\u{1f1f9}' |
"\u{1f1fc}" | "\u{1f1fe}"))|
"\u{1f1f6}\u{1f1e6}" |
("\u{1f1f7}" ~ ("\u{1f1ea}" | "\u{1f1f4}" | "\u{1f1f8}" | "\u{1f1fa}" | "\u{1f1fc}")) |
("\u{1f1f8}" ~ ('\u{1f1e6}'..'\u{1f1ea}' | '\u{1f1ec}'..'\u{1f1f4}' | '\u{1f1f7}'..'\u{1f1f9}' | "\u{1f1fb}" | '\u{1f1fd}'..'\u{1f1ff}')) |
("\u{1f1f9}" ~ ("\u{1f1e6}" | "\u{1f1e8}" | "\u{1f1e9}" | '\u{1f1eb}'..'\u{1f1ed}' | '\u{1f1ef}'..'\u{1f1f4}' | "\u{1f1f7}" | "\u{1f1f9}" | "\u{1f1fb}" | "\u{1f1fc}" | "\u{1f1ff}")) |
("\u{1f1fa}" ~ ("\u{1f1e6}" | "\u{1f1ec}" | "\u{1f1f2}" | "\u{1f1f3}" | "\u{1f1f8}" | "\u{1f1fe}" | "\u{1f1ff}")) |
("\u{1f1fb}" ~ ("\u{1f1e6}" | "\u{1f1e8}" | "\u{1f1ea}" | "\u{1f1ec}" | "\u{1f1ee}" | "\u{1f1f3}" | "\u{1f1fa}")) |
("\u{1f1fc}" ~ ("\u{1f1eb}" | "\u{1f1f8}")) |
"\u{1f1fd}\u{01f1f0}" |
("\u{1f1fe}" ~ ("\u{1f1ea}" | "\u{1f1f9}")) |
("\u{1f1ff}" ~ ("\u{1f1e6}" | "\u{1f1f2}" | "\u{1f1fc}")) |
('\u{23e9}'..'\u{23ec}' | "\u{23f0}" | "\u{23f3}" | "\u{267e}" | "\u{26ce}" | "\u{2705}" | "\u{2728}" |
"\u{274c}" | "\u{274e}" | '\u{2753}'..'\u{2755}' | '\u{2795}'..'\u{2797}' | "\u{27b0}" | "\u{27bf}" |
"\u{e50a}" | "\u{1f0cf}" | "\u{1f18e}" | '\u{1f191}'..'\u{1f19a}' | '\u{1f1e6}'..'\u{1f1ff}' | "\u{1f201}" |
'\u{1f232}'..'\u{1f236}' | '\u{1f238}'..'\u{1f23a}' | "\u{1f250}" | "\u{1f251}" | '\u{1f300}'..'\u{1f320}' |
'\u{1f32d}'..'\u{1f335}' | '\u{1f337}'..'\u{1f37c}' | '\u{1f37e}'..'\u{1f384}' | '\u{1f386}'..'\u{1f393}' |
'\u{1f3a0}'..'\u{1f3c1}' | "\u{1f3c5}" | "\u{1f3c6}" | "\u{1f3c8}" | "\u{1f3c9}" | '\u{1f3cf}'..'\u{1f3d3}' |
'\u{1f3e0}'..'\u{1f3f0}' | "\u{1f3f4}" | '\u{1f3f8}'..'\u{1f43e}' | "\u{1f440}" | "\u{1f444}" | "\u{1f445}" |
'\u{1f451}'..'\u{1f465}' | '\u{1f46a}'..'\u{1f46d}' | "\u{1f46f}" | '\u{1f479}'..'\u{1f47b}' |
'\u{1f47d}'..'\u{1f480}' | "\u{1f484}" | '\u{1f488}'..'\u{1f4a9}' | '\u{1f4ab}'..'\u{1f4fc}' |
'\u{1f4ff}'..'\u{1f53d}' | '\u{1f54b}'..'\u{1f54e}' | '\u{1f550}'..'\u{1f567}' | "\u{1f5a4}" |
'\u{1f5fb}'..'\u{1f644}' | '\u{1f648}'..'\u{1f64a}' | '\u{1f680}'..'\u{1f6a2}' | '\u{1f6a4}'..'\u{1f6b3}' |
'\u{1f6b7}'..'\u{1f6bf}' | '\u{1f6c1}'..'\u{1f6c5}' | '\u{1f6d0}'..'\u{1f6d2}' | "\u{1f6eb}" | "\u{1f6ec}" |
'\u{1f6f4}'..'\u{1f6f9}' | '\u{1f910}'..'\u{1f917}' | "\u{1f91d}" | '\u{1f920}'..'\u{1f925}' |
'\u{1f927}'..'\u{1f92f}' | "\u{1f93a}" | "\u{1f93c}" | '\u{1f940}'..'\u{1f945}' | '\u{1f947}'..'\u{1f970}' |
'\u{1f973}'..'\u{1f976}' | "\u{1f97a}" | '\u{1f97c}'..'\u{1f9a2}' | '\u{1f9b0}'..'\u{1f9b4}' | "\u{1f9b7}" |
'\u{1f9c0}'..'\u{1f9c2}' | "\u{1f9d0}" | '\u{1f9de}'..'\u{1f9ff}') |
"\u{fe0f}"
}
//
// VALIDATION
//
valid_username = { SOI ~ username ~ EOI }
valid_list = { SOI ~ list ~ EOI }
valid_url = { SOI ~ url ~ EOI }
// This rule is generated by tld_gen.py
// See the comments there.
tld_list = _{
^"a" ~
(
^"a" ~
(
^"a"
| ^"rp"
)
| ^"b" ~
(
^"arth"
| ^"b" ~
(
^"ott"
| ^"vie"
)?
| ^"c"
| ^"le"
| ^"ogado"
| ^"udhabi"
)
| ^"c" ~
(
^"ademy"
| ^"c" ~
(
^"enture"
| ^"ountant" ~
(
^"s"
)?
)
| ^"o"
| ^"t" ~
(
^"ive"
| ^"or"
)
)?
| ^"d" ~
(
^"ac"
| ^"s"
| ^"ult"
)?
| ^"e" ~
(
^"g"
| ^"ro"
| ^"tna"
)?
| ^"f" ~
(
^"amilycompany"
| ^"l"
| ^"rica"
)?
| ^"g" ~
(
^"akhan"
| ^"ency"
)?
| ^"i" ~
(
^"g" ~
(
^"o"
)?
| ^"r" ~
(
^"bus"
| ^"force"
| ^"tel"
)
)?
| ^"kdn"
| ^"l" ~
(
^"faromeo"
| ^"i" ~
(
^"baba"
| ^"pay"
)
| ^"l" ~
(
^"finanz"
| ^"state"
| ^"y"
)
| ^"s" ~
(
^"ace"
| ^"tom"
)
)?
| ^"m" ~
(
^"e" ~
(
^"rican" ~
(
^"express"
| ^"family"
)
| ^"x"
)
| ^"fam"
| ^"ica"
| ^"sterdam"
)?
| ^"n" ~
(
^"alytics"
| ^"droid"
| ^"quan"
| ^"z"
)?
| ^"o" ~
(
^"l"
)?
| ^"p" ~
(
^"artments"
| ^"p" ~
(
^"le"
)?
)
| ^"q" ~
(
^"uarelle"
)?
| ^"r" ~
(
^"a" ~
(
^"b"
| ^"mco"
)
| ^"chi"
| ^"my"
| ^"pa"
| ^"t" ~
(
^"e"
)?
)?
| ^"s" ~
(
^"da"
| ^"ia"
| ^"sociates"
)?
| ^"t" ~
(
^"hleta"
| ^"torney"
)?
| ^"u" ~
(
^"ction"
| ^"di" ~
(
^"ble"
| ^"o"
)?
| ^"spost"
| ^"t" ~
(
^"hor"
| ^"o" ~
(
^"s"
)?
)
)?
| ^"vianca"
| ^"w" ~
(
^"s"
)?
| ^"x" ~
(
^"a"
)?
| ^"z" ~
(
^"ure"
)?
)
| ^"b" ~
(
^"a" ~
(
^"by"
| ^"idu"
| ^"n" ~
(
^"a" ~
(
^"mex"
| ^"narepublic"
)
| ^"d"
| ^"k"
)
| ^"r" ~
(
^"c" ~
(
^"elona"
| ^"lay" ~
(
^"card"
| ^"s"
)
)
| ^"efoot"
| ^"gains"
)?
| ^"s" ~
(
^"eball"
| ^"ketball"
)
| ^"uhaus"
| ^"yern"
)?
| ^"b" ~
(
^"c"
| ^"t"
| ^"va"
)?
| ^"c" ~
(
^"g"
| ^"n"
)
| ^"d"
| ^"e" ~
(
^"a" ~
(
^"ts"
| ^"uty"
)
| ^"er"
| ^"ntley"
| ^"rlin"
| ^"st" ~
(
^"buy"
)?
| ^"t"
)?
| ^"f"
| ^"g"
| ^"h" ~
(
^"arti"
)?
| ^"i" ~
(
^"ble"
| ^"d"
| ^"ke"
| ^"ng" ~
(
^"o"
)?
| ^"o"
| ^"z"
)?
| ^"j"
| ^"l" ~
(
^"a" ~
(
^"ck" ~
(
^"friday"
)?
| ^"nco"
)
| ^"o" ~
(
^"ckbuster"
| ^"g"
| ^"omberg"
)
| ^"ue"
)?
| ^"m" ~
(
^"s"
| ^"w"
)?
| ^"n" ~
(
^"l"
| ^"pparibas"
)?
| ^"o" ~
(
^"ats"
| ^"ehringer"
| ^"fa"
| ^"m"
| ^"nd"
| ^"o" ~
(
^"k" ~
(
^"ing"
)?
| ^"ts"
)?
| ^"s" ~
(
^"ch"
| ^"t" ~
(
^"ik"
| ^"on"
)
)
| ^"t"
| ^"utique"
| ^"x"
)?
| ^"q"
| ^"r" ~
(
^"adesco"
| ^"idgestone"
| ^"o" ~
(
^"adway"
| ^"ker"
| ^"ther"
)
| ^"ussels"
)?
| ^"s"
| ^"t"
| ^"u" ~
(
^"dapest"
| ^"gatti"
| ^"ild" ~
(
^"ers"
)?
| ^"siness"
| ^"y"
| ^"zz"
)
| ^"v"
| ^"w"
| ^"y"
| ^"z" ~
(
^"h"
)?
)
| ^"c" ~
(
^"a" ~
(
^"b"
| ^"fe"
| ^"l" ~
(
^"l"
| ^"vinklein"
)?
| ^"m" ~
(
^"era"
| ^"p"
)?
| ^"n" ~
(
^"cerresearch"
| ^"on"
)
| ^"p" ~
(
^"etown"
| ^"ital" ~
(
^"one"
)?
)
| ^"r" ~
(
^"avan"
| ^"ds"
| ^"e" ~
(
^"er" ~
(
^"s"
)?
)?
| ^"s"
| ^"tier"
)?
| ^"s" ~
(
^"a"
| ^"e" ~
(
^"ih"
)?
| ^"h"
| ^"ino"
)
| ^"t" ~
(
^"ering"
| ^"holic"
)?
)?
| ^"b" ~
(
^"a"
| ^"n"
| ^"re"
| ^"s"
)
| ^"c"
| ^"d"
| ^"e" ~
(
^"b"
| ^"nter"
| ^"o"
| ^"rn"
)
| ^"f" ~
(
^"a"
| ^"d"
)?
| ^"g"
| ^"h" ~
(
^"a" ~
(
^"n" ~
(
^"el"
| ^"nel"
)
| ^"se"
| ^"t"
)
| ^"eap"
| ^"intai"
| ^"loe"
| ^"r" ~
(
^"istmas"
| ^"ome"
| ^"ysler"
)
| ^"urch"
)?
| ^"i" ~
(
^"priani"
| ^"rcle"
| ^"sco"
| ^"t" ~
(
^"adel"
| ^"i" ~
(
^"c"
)?
| ^"y" ~
(
^"eats"
)?
)
)?
| ^"k"
| ^"l" ~
(
^"aims"
| ^"eaning"
| ^"i" ~
(
^"ck"
| ^"ni" ~
(
^"c"
| ^"que"
)
)
| ^"o" ~
(
^"thing"
| ^"ud"
)
| ^"ub" ~
(
^"med"
)?
)?
| ^"m"
| ^"n"
| ^"o" ~
(
^"ach"
| ^"des"
| ^"ffee"
| ^"l" ~
(
^"lege"
| ^"ogne"
)
| ^"m" ~