/
helpers.cljc
382 lines (295 loc) · 11 KB
/
helpers.cljc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
(ns honeysql.helpers
(:refer-clojure :exclude [update])
#?(:cljs (:require-macros [honeysql.helpers :refer [defhelper]])))
(defmulti build-clause (fn [name & args]
name))
(defmethod build-clause :default [_ m & args]
m)
(defn plain-map? [m]
(and
(map? m)
(not (record? m))))
#?(:clj
(defmacro defhelper [helper arglist & more]
(when-not (vector? arglist)
(throw #?(:clj (IllegalArgumentException. "arglist must be a vector")
:cljs (js/Error. "arglist must be a vector"))))
(when-not (= (count arglist) 2)
(throw #?(:clj (IllegalArgumentException. "arglist must have two entries, map and varargs")
:cljs (js/Error. "arglist must have two entries, map and varargs"))))
(let [kw (keyword (name helper))
[m-arg varargs] arglist]
`(do
(defmethod build-clause ~kw ~['_ m-arg varargs] ~@more)
(defn ~helper [& args#]
(let [[m# args#] (if (plain-map? (first args#))
[(first args#) (rest args#)]
[{} args#])]
(build-clause ~kw m# args#)))
;; maintain the original arglist instead of getting
;; ([& args__6880__auto__])
(alter-meta!
(var ~helper)
assoc
:arglists
'(~['& varargs]
~[m-arg '& varargs]))))))
(defn collify [x]
(if (coll? x) x [x]))
(defhelper select [m fields]
(assoc m :select (collify fields)))
(defhelper merge-select [m fields]
(update-in m [:select] concat (collify fields)))
(defhelper un-select [m fields]
(update-in m [:select] #(remove (set (collify fields)) %)))
(defhelper from [m tables]
(assoc m :from (collify tables)))
(defhelper merge-from [m tables]
(update-in m [:from] concat (collify tables)))
(defmethod build-clause :where [_ m pred]
(if (nil? pred)
m
(assoc m :where pred)))
(defn- merge-where-args
"Handle optional args passed to `merge-where` or similar functions. Returns tuple of
[m where-clauses conjunction-operator]"
[args]
(let [[m & args] (if (map? (first args))
args
(cons {} args))
[conjunction & clauses] (if (keyword? (first args))
args
(cons :and args))]
[m (filter some? clauses) conjunction]))
(defn- where-args
"Handle optional args passed to `where` or similar functions. Merges clauses together. Returns tuple of
[m merged-clause]"
[args]
(let [[m clauses conjunction] (merge-where-args args)]
[m (if (<= (count clauses) 1)
(first clauses)
(into [conjunction] clauses))]))
(defn- where-like
"Create a WHERE-style clause with key `k` (e.g. `:where` or `:having`)"
[k args]
(let [[m pred] (where-args args)]
(if (nil? pred)
m
(assoc m k pred))))
(defn where [& args]
(where-like :where args))
(defn- is-clause? [clause x]
(and (sequential? x) (= (first x) clause)))
(defn- merge-where-like
"Merge a WHERE-style clause with key `k` (e.g. `:where` or `:having`)"
[k args]
(let [[m new-clauses conjunction] (merge-where-args args)]
(reduce
(fn [m new-clause]
;; combine existing clause and new clause if they're both of the specified conjunction type, e.g.
;; [:and a b] + [:and c d] -> [:and a b c d]
(update-in m [k] (fn [existing-clause]
(let [existing-subclauses (when (some? existing-clause)
(if (is-clause? conjunction existing-clause)
(rest existing-clause)
[existing-clause]))
new-subclauses (if (is-clause? conjunction new-clause)
(rest new-clause)
[new-clause])
subclauses (concat existing-subclauses new-subclauses)]
(if (> (count subclauses) 1)
(into [conjunction] subclauses)
(first subclauses))))))
m
new-clauses)))
(defn merge-where
"Merge a series of `where-clauses` together. Supports two optional args: a map to merge the results into, and a
`conjunction` to use to combine clauses (defaults to `:and`).
(merge-where [:= :x 1] [:= :y 2])
{:where [:and [:= :x 1] [:= :y 2]]}
(merge-where {:where [:= :x 1]} [:= :y 2])
;; -> {:where [:and [:= :x 1] [:= :y 2]]}
(merge-where :or [:= :x 1] [:= :y 2])
;; -> {:where [:or [:= :x 1] [:= :y 2]]}"
{:arglists '([& where-clauses]
[m-or-conjunction & where-clauses]
[m conjunction & where-clauses])}
[& args]
(merge-where-like :where args))
(defmethod build-clause :merge-where
[_ m where-clause]
(merge-where m where-clause))
(defhelper join [m clauses]
(assoc m :join clauses))
(defhelper merge-join [m clauses]
(update-in m [:join] concat clauses))
(defhelper left-join [m clauses]
(assoc m :left-join clauses))
(defhelper merge-left-join [m clauses]
(update-in m [:left-join] concat clauses))
(defhelper right-join [m clauses]
(assoc m :right-join clauses))
(defhelper merge-right-join [m clauses]
(update-in m [:right-join] concat clauses))
(defhelper full-join [m clauses]
(assoc m :full-join clauses))
(defhelper merge-full-join [m clauses]
(update-in m [:full-join] concat clauses))
(defhelper cross-join [m clauses]
(assoc m :cross-join clauses))
(defhelper merge-cross-join [m clauses]
(update-in m [:cross-join] concat clauses))
(defmethod build-clause :group-by [_ m fields]
(assoc m :group-by (collify fields)))
(defn group [& args]
(let [[m fields] (if (map? (first args))
[(first args) (rest args)]
[{} args])]
(build-clause :group-by m fields)))
(defhelper merge-group-by [m fields]
(update-in m [:group-by] concat (collify fields)))
(defmethod build-clause :having [_ m pred]
(if (nil? pred)
m
(assoc m :having pred)))
(defn having [& args]
(where-like :having args))
(defn merge-having
"Merge a series of `having-clauses` together. Supports two optional args: a map to merge the results into, and a
`conjunction` to use to combine clauses (defaults to `:and`).
(merge-having [:= :x 1] [:= :y 2])
{:having [:and [:= :x 1] [:= :y 2]]}
(merge-having {:having [:= :x 1]} [:= :y 2])
;; -> {:having [:and [:= :x 1] [:= :y 2]]}
(merge-having :or [:= :x 1] [:= :y 2])
;; -> {:having [:or [:= :x 1] [:= :y 2]]}"
{:arglists '([& having-clauses]
[m-or-conjunction & having-clauses]
[m conjunction & having-clauses])}
[& args]
(merge-where-like :having args))
(defmethod build-clause :merge-having
[_ m where-clause]
(merge-having m where-clause))
(defhelper order-by [m fields]
(assoc m :order-by (collify fields)))
(defhelper merge-order-by [m fields]
(update-in m [:order-by] concat (collify fields)))
(defhelper limit [m l]
(if (nil? l)
m
(assoc m :limit (if (coll? l) (first l) l))))
(defhelper offset [m o]
(if (nil? o)
m
(assoc m :offset (if (coll? o) (first o) o))))
(defhelper lock [m lock]
(cond-> m
lock
(assoc :lock lock)))
(defhelper modifiers [m ms]
(if (nil? ms)
m
(assoc m :modifiers (collify ms))))
(defhelper merge-modifiers [m ms]
(if (nil? ms)
m
(update-in m [:modifiers] concat (collify ms))))
(defmethod build-clause :insert-into [_ m table]
(assoc m :insert-into table))
(defn insert-into
([table] (insert-into nil table))
([m table] (build-clause :insert-into m table)))
(defn- check-varargs
"Called for helpers that require unrolled arguments to catch the mistake
of passing a collection as a single argument."
[helper args]
(when (and (coll? args) (= 1 (count args)) (coll? (first args)))
(let [msg (str (name helper) " takes varargs, not a single collection")]
(throw #?(:clj (IllegalArgumentException. msg)
:cljs (js/Error. msg))))))
(defmethod build-clause :columns [_ m fields]
(assoc m :columns (collify fields)))
(defn columns [& args]
(let [[m fields] (if (map? (first args))
[(first args) (rest args)]
[{} args])]
(check-varargs :columns fields)
(build-clause :columns m fields)))
(defmethod build-clause :merge-columns [_ m fields]
(update-in m [:columns] concat (collify fields)))
(defn merge-columns [& args]
(let [[m fields] (if (map? (first args))
[(first args) (rest args)]
[{} args])]
(check-varargs :merge-columns fields)
(build-clause :merge-columns m fields)))
(defhelper composite [m vs]
(if (nil? vs)
m
(assoc m :composite (collify vs))))
(defmethod build-clause :values [_ m vs]
(assoc m :values vs))
(defn values
([vs] (values nil vs))
([m vs] (build-clause :values m vs)))
(defmethod build-clause :merge-values [_ m vs]
(update-in m [:values] concat vs))
(defn merge-values
([vs] (merge-values nil vs))
([m vs] (build-clause :merge-values m vs)))
(defmethod build-clause :query-values [_ m vs]
(assoc m :query-values vs))
(defn query-values
([vs] (values nil vs))
([m vs] (build-clause :query-values m vs)))
(defmethod build-clause :update [_ m table]
(assoc m :update table))
(defn update
([table] (update nil table))
([m table] (build-clause :update m table)))
(defmethod build-clause :set [_ m values]
(assoc m :set values))
;; short for sql set, to avoid name collision with clojure.core/set
(defn sset
([vs] (sset nil vs))
([m vs] (build-clause :set m vs)))
(defmethod build-clause :set0 [_ m values]
(assoc m :set0 values))
;; set with lower priority (before from)
(defn set0
([vs] (set0 nil vs))
([m vs] (build-clause :set0 m vs)))
(defmethod build-clause :set [_ m values]
(assoc m :set values))
;; set with higher priority (after join)
(defn set1
([vs] (set1 nil vs))
([m vs] (build-clause :set1 m vs)))
(defmethod build-clause :delete-from [_ m table]
(assoc m :delete-from table))
(defn delete-from
([table] (delete-from nil table))
([m table] (build-clause :delete-from m table)))
(defmethod build-clause :delete [_ m tables]
(assoc m :delete tables))
(defn delete
([tables] (delete nil tables))
([m tables] (build-clause :delete m tables)))
(defmethod build-clause :truncate [_ m table]
(assoc m :truncate table))
(defn truncate
([table] (truncate nil table))
([m table] (build-clause :truncate m table)))
(defhelper with [m ctes]
(assoc m :with ctes))
(defhelper with-recursive [m ctes]
(assoc m :with-recursive ctes))
(defmethod build-clause :union [_ m maps]
(assoc m :union maps))
(defmethod build-clause :union-all [_ m maps]
(assoc m :union-all maps))
(defmethod build-clause :intersect [_ m maps]
(assoc m :intersect maps))
(defmethod build-clause :except [_ m maps]
(assoc m :except maps))