/
NETiZAP.prw
799 lines (622 loc) · 22.7 KB
/
NETiZAP.prw
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
#include 'protheus.ch'
/* ======================================================================
Classe NETIZAP
Autor Júlio Wittwer
Data 12/2019
Descrição Classe em AdvPL que encapsula o seviço de integracão
com o WhatsApp oferecido pela NETIZAP
Classe criada com base na Documentação da API NETIZAP
https://documenter.getpostman.com/view/2747664/SVSPnmoH?version=latest
*** Este fonte não depende do projeto ZLIB ***
Pode ser compilado em qualquer TOTVS Application Server , Windows ou Linux,
32 ou 64 bits, com build igual ou superior a 7.00.131227
====================================================================== */
#define NETIZAP_ADVPL_BUILD 'NetiZap AdvPL 1.0.0'
#define NETIZAP_DEFAULT_HOST 'http://api.meuaplicativo.vip'
#define NETIZAP_DEFAULT_PORT 13005
// --------------------------------------------------
CLASS NETIZAP FROM LONGNAMECLASS
DATA cHostBase
DATA nPortBase
DATA cLastError
DATA nLastStatus
DATA cHeaderRet
DATA cResponse
DATA cLine
DATA cDestiny
DATA cReference
DATA cText
DATA cQuestion
DATA cApp
DATA cAccessKey
DATA nTimeOutMS
DATA cFileName
DATA cFileType
DATA cFileStream
DATA cProtocol
DATA aHeadOut
DATA cAuthBasic
DATA bLogBlock
METHOD NEW() // Cria um nova instância da classe
METHOD SetLine() // Informa o numero da linha de origem da chamada
METHOD SetAccessKey() // Informa a chave de acesso associada a linha de origem
METHOD SetPort() // Informa a porta do provedor de seviços HTTP ( default = 12005 )
METHOD Reset() // Limpa as propriedades para uma nova requisiçao
METHOD SetLogger() // Informa um Bloco de Codigo de Callback para registro de LOG
// Parametros para uso dos serviços
METHOD SetDestiny() // Informa o numero do destinatario para operações *Send()
METHOD SetReference() // Informa um valor de referencia opcional para operações *Send()
METHOD SetText() // Informa um texto para operações *Send()
METHOD SetQuestion() // Informa as respostas válidas para a operação QuestioSend()
METHOD SetFile() // Informa um tipo, conteudo e nome de arquivo para a operação FileSend()
METHOD SetProtocol() // Informa um numero de protocolo de mensagems para MessageSearch e QuestionSearch
METHOD SetTimeOutMS() // Define o TimeOut em milissegundos para retorno de chamada de API
// Serviços oferecidos
METHOD MessageSend() // Envio de mensagens para um destinatario ou grupo
METHOD QuestionSend() // Envio de uma pergunta com respostas predefinidas
METHOD FileSend() // Envio de mensagem com arquivo anexo
METHOD MessageSearch() // Confirma se uma mensagem foi lida e/ou recebida
METHOD QuestionSearch() // Confirma se uma pergunta enviada foi lida e/ou respondida
METHOD GroupSearch() // Busca por grupos
METHOD BroadcastSearch() // Busca por listas de trannsmissao
METHOD CheckCredits() // Consulta status de creditos da API
METHOD RequestsStart() // Consulta requisições realizadas
// Miscelânea
METHOD GetResponse() // Recupera o corpo da resposta da ultima requisição HTTP
METHOD GetHeaderResponse() // Recupera o HEader HTTP de resposta da ultima requisição HTTP
METHOD GetStatus() // Recupera o codigo HTTP de retorno da ultima requisição HTTP
METHOD GetLastError() // Recupera o últim erro da classe NETIZAP
METHOD ValidBase() // Valida os parametros minimos comuns que devem ser informados
ENDCLASS
// --------------------------------------------------
// Cria a instancia da classe de integração com os valores default
// Permite receber
METHOD NEW(cLine,cAccessKey,nPort) CLASS NETIZAP
::cHostBase := NETIZAP_DEFAULT_HOST
::nPortBase := NETIZAP_DEFAULT_PORT
::cApp := NETIZAP_ADVPL_BUILD
::cAuthBasic := 'Authorization: Basic '+Encode64("user:api")
::nTimeOutMS := (20*1000)
::bLogBlock := NIL
::cLine := ''
::cAccessKey := ''
// Pode receber a linha de origem e a chave de acesso no construtor
// Esses parametros sao necessários para qualquer requisição
If !empty(cLine)
::cLine := cLine
Endif
If !empty(cAccessKey)
::cAccessKey := cAccessKey
Endif
IF !empty(nPort)
::nPortBase := nPort
Endif
// Inicializa todas as demais propriedades relacionadas a API
::cLastError := ''
::cHeaderRet := ''
::cResponse := ''
::cDestiny := ''
::cReference := ''
::cText := ''
::cQuestion := ''
::cFileName := ''
::cFileType := ''
::cFileStream := ''
::cProtocol := ''
// Monta o header HTTP de saída, comum a todas as requisições
::aHeadOut := {}
aadd(::aHeadOut,'Content-Type: application/x-www-form-urlencoded')
aadd(::aHeadOut,::cAuthBasic)
aadd(::aHeadOut,'Accept-Charset: UTF-8')
aadd(::aHeadOut,'User-Agent: Mozilla/4.0 (compatible; Protheus '+GetBuild()+')')
Return self
// Seta um Bloco de Codigo para gravaçao de log de chamadas da API
METHOD SetLogger(bLogBlock) CLASS NETIZAP
::bLogBlock := bLogBlock
REturn
// --------------------------------------------------
// Reseta as propriedades usadas para envio de requisições
METHOD RESET() CLASS NETIZAP
::cLastError := ''
::cHeaderRet := ''
::cResponse := ''
::cDestiny := ''
::cReference := ''
::cText := ''
::cQuestion := ''
::cFileName := ''
::cFileType := ''
::cFileStream := ''
::cProtocol := ''
Return
// --------------------------------------------------
// Informa a chave de acesso para o serviço
METHOD SetAccessKey(cAccessKey) CLASS NETIZAP
::cAccessKey := alltrim(cAccessKey)
Return
// --------------------------------------------------
// Informa a porta HTTP do servidor da API
METHOD SetPort(nPort) CLASS NETIZAP
::nPortBase := nPort
Return
// --------------------------------------------------
// Informa a linha de origem registrada para o serviço
METHOD SetLine(cLine) CLASS NETIZAP
::cLine := alltrim(cLine)
Return
// --------------------------------------------------
// Informa o numero de telefone de destino
METHOD SetDestiny(cDestiny) CLASS NETIZAP
::cDestiny := alltrim(cDestiny)
Return
// --------------------------------------------------
// Informa um valor de referencia para uso posterior
METHOD SetReference(cReference) CLASS NETIZAP
::cReference := alltrim(cReference)
Return
// --------------------------------------------------
// Informa o texto da mensagem
METHOD SetText(cText) CLASS NETIZAP
::cText := alltrim(cText)
Return
// --------------------------------------------------
// Informa resposta(s) para envio de uma questão
METHOD SetQuestion(cQuestion) CLASS NETIZAP
::cQuestion := alltrim(cQuestion)
Return
// --------------------------------------------------
// Informa um arquivo a ser enviado
METHOD SetFile(cFileName,cFileType,cFileStream) CLASS NETIZAP
::cFileName := alltrim(cFileName)
::cFileType := alltrim(Upper(cFileType))
::cFileStream := cFileStream
Return
// --------------------------------------------------
// Reconfigura o timeout de retorno de requisição
// Default = 20000 ( 20 segundos )
METHOD SETTIMEOUTMS(nTimeOutMS) CLASS NETIZAP
::nTimeOutMS := nTimeOutMS
Return
// --------------------------------------------------
// Informa um numero de protocolo de mensagem para uma operação
METHOD SETPROTOCOL(cProtocol) CLASS NETIZAP
::cProtocol := alltrim(cProtocol)
Return
// --------------------------------------------------
// Realiza o envio de uma mensagem
// Requer o numero do telefone de destino e a mensagem
// Permite setar um valor de referencia para uso posterior
METHOD MessageSend() CLASS NETIZAP
Local cUrlPost
Local cUrlParms
Local cPostParms
Local nTimer
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('MessageSend()')
Return .F.
Endif
If empty(::cDestiny)
::cLastError := 'MessageSend() ERROR - Destiny is missing'
Return .F.
Endif
If empty(::cText)
::cLastError := 'MessageSend() ERROR - Text is missing'
Return .F.
Endif
// Monta url/host para a requisição
cUrlPost := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/message_send"
// Monta o Corpo do Post / Formulario
cPostParms := 'App='+UrlEncode(::cApp)
cPostParms += '&AccessKey='+UrlEncode(::cAccessKey)
// Monta os parametros para URL / GET
cUrlParms := 'line=' + UrlEncode(::cLine)
cUrlParms += '&destiny=' + UrlEncode(::cDestiny)
cUrlParms += '&reference=' + UrlEncode(::cReference)
cUrlParms += '&text=' + UrlEncode(::cText)
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPPOST(cUrlPost,cUrlParms,cPostParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlPost,cUrlParms,cPostParms,::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
::cLastError := 'HTTP ERROR ('+cValToChar(::nLastStatus)+') : '+ ::cLastError
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Envio de uma pergunta ao destinatario
// Requer a linha de destino, a mensagem, a(s) resposta(s) válidas
METHOD QuestionSend() CLASS NETIZAP
Local cUrlPost
Local cUrlParms
Local cPostParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('QuestionSend()')
Return .F.
Endif
If empty(::cDestiny)
::cLastError := 'QuestionSend() ERROR - Destiny is missing'
Return .F.
Endif
If empty(::cText)
::cLastError := 'QuestionSend() ERROR - Text is missing'
Return .F.
Endif
If empty(::cQuestion)
::cLastError := 'QuestionSend() ERROR - Question is missing'
Return .F.
Endif
// Monta url/host para a requisição
cUrlPost := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/question_send"
// Monta o Corpo do Post / Formulario
cPostParms := 'App='+UrlEncode(::cApp)
cPostParms += '&AccessKey='+UrlEncode(::cAccessKey)
// Monta os parametros para URL / GET
cUrlParms := 'line=' + ::cLine
cUrlParms += '&destiny=' + ::cDestiny
cUrlParms += '&reference=' + ::cReference
cUrlParms += '&text=' + UrlEncode(::cText)
cUrlParms += '&question=' + UrlEncode(::cQuestion)
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPPOST(cUrlPost,cUrlParms,cPostParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlPost,cUrlParms,cPostParms,::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Envio de mensagem com arquivo anexo
// Requer a linha de destino, a mensagem, o tipo do arquivo,
// o conteudo (binário) e o nome do arquivo a ser informado na memsagem
METHOD FileSend() CLASS NETIZAP
Local cUrlPost
Local cUrlParms
Local cPostParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('FileSend()')
Return .F.
Endif
If empty(::cDestiny)
::cLastError := 'FileSend() ERROR - Destiny is missing'
Return .F.
Endif
If empty(::cText)
::cLastError := 'FileSend() ERROR - Text is missing'
Return .F.
Endif
If empty(::cFileType)
::cLastError := 'FileSend() ERROR - File Type is missing'
Return .F.
Endif
If empty(::cFileStream)
::cLastError := 'FileSend() ERROR - File Stream is missing'
Return .F.
Endif
// Monta url/host para a requisição
cUrlPost := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/file_send"
// Monta o Corpo do Post / Formulario
cPostParms := 'app='+URLEncode(::cApp)
cPostParms += '&key='+URLEncode(::cAccessKey)
cPostParms += '&text='+UrlEncode(::cText)
cPostParms += '&type='+URLEncode(::cFileType)
cPostParms += '&stream='+UrlEncode(::cFileStream)
cPostParms += '&filename='+UrlEncode(::cFileName)
// Monta os parametros para URL / GET
cUrlParms := 'line=' + ::cLine
cUrlParms += '&destiny=' + ::cDestiny
cUrlParms += '&reference=' + ::cReference
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPPOST(cUrlPost,cUrlParms,cPostParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlPost,cUrlParms,cPostParms,::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Busca pelo status de uma determinada mensagem enviada
// Requer o numero do protocolo da mensagem, retornado pelo MEssageSend()
METHOD MessageSearch() CLASS NETIZAP
Local cUrlGet
Local cUrlParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('MessageSearch()')
Return .F.
Endif
If empty(::cProtocol)
::cLastError := 'MessageSearch() ERROR - Protocol is missing'
Return .F.
Endif
// Monta url/host para a requisição
cUrlGet := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/message_search"
// Monta os parametros para URL / GET
cUrlParms := 'line=' + UrlEncode(::cLine)
cUrlParms += '&AccessKey='+UrlEncode(::cAccessKey)
cUrlParms += '&protocol=' + UrlEncode(::cProtocol)
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPGET(cUrlGet,cUrlParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlGet,cUrlParms,"",::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Busca pelo status de uma determinada pergunta enviada
// Requer o numero do protocolo da pergunta , retornado pelo QuestionSend()
METHOD QuestionSearch() CLASS NETIZAP
Local cUrlGet
Local cUrlParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('QuestionSearch()')
Return .F.
Endif
If empty(::cProtocol)
::cLastError := 'QuestionSearch() ERROR - Protocol is missing'
Return .F.
Endif
// Monta url/host para a requisição
cUrlGet := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/question_search"
// Monta os parametros para URL / GET
cUrlParms := 'line=' + UrlEncode(::cLine)
cUrlParms += '&AccessKey='+UrlEncode(::cAccessKey)
cUrlParms += '&protocol=' + UrlEncode(::cProtocol)
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPGET(cUrlGet,cUrlParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlGet,cUrlParms,"",::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Verifica quais os grupos de envio de mensagens estão registrados
// para a linha de origem definida. Nao requer parametros
METHOD GroupSearch() CLASS NETIZAP
Local cUrlGet
Local cUrlParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('GroupSearch()')
Return .F.
Endif
// Monta url/host para a requisição
cUrlGet := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/group_search"
// Monta os parametros para URL / GET
cUrlParms := 'line=' + UrlEncode(::cLine)
cUrlParms += '&AccessKey='+UrlEncode(::cAccessKey)
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPGET(cUrlGet,cUrlParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlGet,cUrlParms,"",::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Consulta as listas de transmissão que estão registrados
// para a linha de origem definida. Nao requer parametros
METHOD BroadcastSearch() CLASS NETIZAP
Local cUrlGet
Local cUrlParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('BroadcastSearch()')
Return .F.
Endif
// Monta url/host para a requisição
cUrlGet := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/broadcast_search"
// Monta os parametros para URL / GET
cUrlParms := 'line=' + UrlEncode(::cLine)
cUrlParms += '&AccessKey='+UrlEncode(::cAccessKey)
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPGET(cUrlGet,cUrlParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlGet,cUrlParms,"",::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Verifica o estado do plano atual junto a NetIZap
// Nao requer parametros adicionais
METHOD CheckCredits() CLASS NETIZAP
Local cUrlGet
Local cUrlParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('CheckCredits()')
Return .F.
Endif
// Monta url/host para a requisição
cUrlGet := ::cHostBase + ":" + cValToChar(::nPortBase) + "/services/check_credits"
// Monta os parametros para URL / GET
cUrlParms := 'line=' + UrlEncode(::cLine)
cUrlParms += '&key='+UrlEncode(::cAccessKey)
// Submete a requisiçao
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPGET(cUrlGet,cUrlParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlGet,cUrlParms,"",::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Consulta o envio de requisições já realizado pela API
// Nao requer parametros adicionais
METHOD RequestsStart() CLASS NETIZAP
Local cUrlGet
Local cUrlParms
::cLastError := ''
// Validação das propriedades necessárias
IF !::ValidBase('RequestsStart()')
Return .F.
Endif
// Monta url/host para a requisição
cUrlGet := ::cHostBase + ":" + cValToChar(::nPortBase) + "/reports/requests_start"
// Monta os parametros para URL / GET
cUrlParms := 'line=' + UrlEncode(::cLine)
cUrlParms += '&AccessKey='+UrlEncode(::cAccessKey)
// Submete a requisiçao GET
::cHeaderRet := ''
nTimer := seconds()
::cResponse := HTTPGET(cUrlGet,cUrlParms,::nTimeOutMS,::aHeadOut,@::cHeaderRet)
nTimer := seconds()-nTimer
IF valtype(::bLogBlock)=='B'
Eval(::bLogBlock,cUrlGet,cUrlParms,"",::cHeaderRet,::cResponse,nTimer)
Endif
// Recupera o status da requisição
::nLastStatus := HttpGetStatus(@::cLastError)
// Avalia se a requisição foi submetida e se o retorno é válido
If ::nLastStatus != 200
IF empty(::cLastError)
::cLastError := 'Unknow Error on HTTPPOST'
Endif
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Obtem a string com a resposta da ultima chamada de API realizada
METHOD GetResponse() CLASS NETIZAP
Return ::cResponse
// --------------------------------------------------
// Obtem o Header HTTP de retorno da ultima chamada de API realizada
METHOD GetHeaderResponse() CLASS NETIZAP
Return ::cHeaderRet
// --------------------------------------------------
// Obtem a descrição do último erro da API
// Observação : Um erro é definido quando não foi possível
// o envio de uma requisição, ou houve um retorno inesperado.
// Cada chamada possui o seu formato de retorno, com um JSON
// informando se a operação foi realizada com sucesso ou não
METHOD GetLastError() CLASS NETIZAP
Return ::cLastError
// --------------------------------------------------
// Retorna o ultimo status HTTP de uma chamada de API
METHOD GetStatus() CLASS NETIZAP
Return ::nLastStatus
// --------------------------------------------------
// Valida os argumentos básicos para envio de qualquer mensagem
// Precisa pelo menos da linha de origem e da access key
METHOD ValidBase(cMethod) CLASS NETIZAP
If empty(::cLine)
::cLastError := cMethod+' ERROR - Line is missing.'
Return .F.
Endif
IF empty(::cAccessKey)
::cLastError := cMethod+' ERROR - AccessKey is missing.'
Return .F.
Endif
Return .T.
// --------------------------------------------------
// Realiza a codificação de dados para URL e/ou POST
STATIC Function URLEncode(cValue)
Local nI , cRet := '', cChar
For nI := 1 to len(cValue)
cChar := substr(cValue,nI,1)
IF asc(cChar) < 32
IF asc(cChar) == 13 // ( CR - Ignora )
LOOP
ElseIF asc(cChar) == 10 // ( LF - TRoca para "\n" )
cRet += '\n'
Else
// Converte para hexadecimal, formato %HH
cRet += '%'+PADL(Upper(__DecToHex(asc(cChar))),2,'0')
Endif
ElseIf cChar >= ' ' .and. cChar <= '/'
// Converte para hexadecimal, formato %HH
cRet += '%'+PADL(Upper(__DecToHex(asc(cChar))),2,'0')
ElseIf cChar >= '0' .and. cChar <= '9'
cRet += cChar
ElseIf cChar >= 'A' .and. cChar <= 'Z'
cRet += cChar
ElseIf cChar >= 'a' .and. cChar <= 'z'
cRet += cChar
Else
// Converte para hexadecimal, formato %HH
cRet += '%'+PADL(Upper(__DecToHex(asc(cChar))),2,'0')
Endif
Next
Return cRet